URL https://opencores.org/ocsvn/altor32/altor32/trunk

Subversion Repositories altor32

[/] [altor32/] [trunk/] [rtl/] [cpu/] [altor32_exec.v] - Blame information for rev 32

Go to most recent revision | Details | Compare with Previous | View Log


//-----------------------------------------------------------------
//                           AltOR32 
//                Alternative Lightweight OpenRisc 
//                            V2.0
//                     Ultra-Embedded.com
//                   Copyright 2011 - 2013
//
//               Email: admin@ultra-embedded.com
//
//                       License: LGPL
//-----------------------------------------------------------------
//
// Copyright (C) 2011 - 2013 Ultra-Embedded.com
//
// This source file may be used and distributed without         
// restriction provided that this copyright statement is not    
// removed from the file and that any derivative work contains  
// the original copyright notice and the associated disclaimer. 
//
// This source file is free software; you can redistribute it   
// and/or modify it under the terms of the GNU Lesser General   
// Public License as published by the Free Software Foundation; 
// either version 2.1 of the License, or (at your option) any   
// later version.
//
// This source is distributed in the hope that it will be       
// useful, but WITHOUT ANY WARRANTY; without even the implied   
// warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR      
// PURPOSE.  See the GNU Lesser General Public License for more 
// details.
//
// You should have received a copy of the GNU Lesser General    
// Public License along with this source; if not, write to the 
// Free Software Foundation, Inc., 59 Temple Place, Suite 330, 
// Boston, MA  02111-1307  USA
//-----------------------------------------------------------------
 
//`define CONF_CORE_DEBUG
//`define CONF_CORE_TRACE
 
//-----------------------------------------------------------------
// Includes
//-----------------------------------------------------------------
`include "altor32_defs.v"
 
//-----------------------------------------------------------------
// Module - Instruction Execute
//-----------------------------------------------------------------
module altor32_exec
(
    // General
    input               clk_i /*verilator public*/,
    input               rst_i /*verilator public*/,
 
    // Maskable interrupt    
    input               intr_i /*verilator public*/,
 
    // Unmaskable interrupt
    input               nmi_i /*verilator public*/,
 
    // Fault
    output reg          fault_o /*verilator public*/,
 
    // Breakpoint / Trap
    output reg          break_o /*verilator public*/,
 
    // Cache control
    output reg          icache_flush_o /*verilator public*/,
    output reg          dcache_flush_o /*verilator public*/,
 
    // Branch
    output              branch_o /*verilator public*/,
    output [31:0]       branch_pc_o /*verilator public*/,
    output              stall_o /*verilator public*/,
 
    // Opcode & arguments
    input [31:0]        opcode_i /*verilator public*/,
    input [31:0]        opcode_pc_i /*verilator public*/,
    input               opcode_valid_i /*verilator public*/,
 
    // Reg A
    input [4:0]         reg_ra_i /*verilator public*/,
    input [31:0]        reg_ra_value_i /*verilator public*/,
 
    // Reg B
    input [4:0]         reg_rb_i /*verilator public*/,
    input [31:0]        reg_rb_value_i /*verilator public*/,
 
    // Reg D
    input [4:0]         reg_rd_i /*verilator public*/,
 
    // Output
    output [31:0]       opcode_o /*verilator public*/,
    output [4:0]        reg_rd_o /*verilator public*/,
    output [31:0]       reg_rd_value_o /*verilator public*/,
    output              mult_o /*verilator public*/,
    output [31:0]       mult_res_o /*verilator public*/,
 
    // Register write back bypass
    input [4:0]         wb_rd_i /*verilator public*/,
    input [31:0]        wb_rd_value_i /*verilator public*/,
 
    // Memory Interface
    output reg [31:0]   dmem_addr_o /*verilator public*/,
    output reg [31:0]   dmem_data_out_o /*verilator public*/,
    input [31:0]        dmem_data_in_i /*verilator public*/,
    output reg [3:0]    dmem_sel_o /*verilator public*/,
    output reg          dmem_we_o /*verilator public*/,
    output reg          dmem_stb_o /*verilator public*/,
    output reg          dmem_cyc_o /*verilator public*/,
    input               dmem_stall_i /*verilator public*/,
    input               dmem_ack_i /*verilator public*/
);
 
//-----------------------------------------------------------------
// Params
//-----------------------------------------------------------------
parameter           BOOT_VECTOR         = 32'h00000000;
parameter           ISR_VECTOR          = 32'h00000000;
 
//-----------------------------------------------------------------
// Registers
//-----------------------------------------------------------------
 
// Branch PC
reg [31:0] r_pc_branch;
reg        r_pc_fetch;
reg        r_stall;
 
// Exception saved program counter
reg [31:0] r_epc;
 
// Supervisor register
reg [31:0] r_sr;
 
// Exception saved supervisor register
reg [31:0] r_esr;
 
// Destination register number (post execute stage)
reg [4:0] r_e_rd;
 
// Current opcode (PC for debug)
reg [31:0] r_e_opcode;
reg [31:0] r_e_opcode_pc;
 
// ALU input A
reg [31:0] r_e_alu_a;
 
// ALU input B
reg [31:0] r_e_alu_b;
 
// ALU output
wire [31:0] r_e_result;
 
// Resolved RA/RB register contents
wire [31:0] ra_value_resolved;
wire [31:0] rb_value_resolved;
wire        resolve_failed;
 
// ALU Carry
wire alu_carry_out;
wire alu_carry_update;
 
// ALU operation selection
reg [3:0] r_e_alu_func;
 
// Load instruction details
reg [4:0] r_load_rd;
reg [7:0] r_load_inst;
reg [1:0] r_load_offset;
 
// Load forwarding
wire         load_insn;
wire [31:0]  load_result;
 
// Memory access?
reg r_mem_load;
reg r_mem_store;
reg r_mem_access;
 
wire load_pending;
wire store_pending;
wire load_insert;
wire load_stall;
 
reg d_mem_load;
 
// Delayed NMI
reg r_nmi;
 
// SIM PUTC
`ifdef SIM_EXT_PUTC
    reg [7:0] r_putc;
`endif
 
//-----------------------------------------------------------------
// Instantiation
//-----------------------------------------------------------------
 
// ALU
altor32_alu alu
(
    // ALU operation select
    .op_i(r_e_alu_func),
 
    // Operands
    .a_i(r_e_alu_a),
    .b_i(r_e_alu_b),
    .c_i(r_sr[`OR32_SR_CY]),
 
    // Result
    .p_o(r_e_result),
 
    // Carry
    .c_o(alu_carry_out),
    .c_update_o(alu_carry_update)
);
 
// Load result forwarding
altor32_lfu
u_lfu
(
    // Opcode
    .opcode_i(r_load_inst),
 
    // Memory load result
    .mem_result_i(dmem_data_in_i),
    .mem_offset_i(r_load_offset),
 
    // Result
    .load_result_o(load_result),
    .load_insn_o(load_insn)
);
 
// Load / store pending logic
altor32_lsu
u_lsu
(
    // Current instruction
    .opcode_valid_i(opcode_valid_i & ~r_pc_fetch),
    .opcode_i({2'b00,opcode_i[31:26]}),
 
    // Load / Store pending
    .load_pending_i(r_mem_load),
    .store_pending_i(r_mem_store),
 
    // Load dest register
    .rd_load_i(r_load_rd),
 
    // Load insn in WB stage
    .load_wb_i(d_mem_load),
 
    // Memory status
    .mem_access_i(r_mem_access),
    .mem_ack_i(dmem_ack_i),
 
    // Load / store still pending
    .load_pending_o(load_pending),
    .store_pending_o(store_pending),
 
    // Insert load result into pipeline
    .write_result_o(load_insert),
 
    // Stall pipeline due
    .stall_o(load_stall)
);
 
// Operand forwarding
altor32_dfu
u_dfu
(
    // Input registers
    .ra_i(reg_ra_i),
    .rb_i(reg_rb_i),
 
    // Input register contents
    .ra_regval_i(reg_ra_value_i),
    .rb_regval_i(reg_rb_value_i),
 
    // Dest register (EXEC stage)
    .rd_ex_i(r_e_rd),
 
    // Dest register (WB stage)
    .rd_wb_i(wb_rd_i),
 
    // Load pending / target
    .load_pending_i(load_pending),
    .rd_load_i(r_load_rd),
 
    // Multiplier status
    .mult_lo_ex_i(1'b0),
    .mult_hi_ex_i(1'b0),
    .mult_lo_wb_i(1'b0),
    .mult_hi_wb_i(1'b0),
 
    // Multiplier result
    .result_mult_i(64'b0),
 
    // Result (EXEC)
    .result_ex_i(r_e_result),
 
    // Result (WB)
    .result_wb_i(wb_rd_value_i),
 
    // Resolved register values
    .result_ra_o(ra_value_resolved),
    .result_rb_o(rb_value_resolved),
 
    // Stall due to failed resolve
    .stall_o(resolve_failed)
);
 
//-----------------------------------------------------------------
// Opcode decode
//-----------------------------------------------------------------
reg [7:0]  inst_r;
reg [7:0]  alu_op_r;
reg [1:0]  shift_op_r;
reg [15:0] sfxx_op_r;
reg [15:0] uint16_r;
reg [31:0] uint32_r;
reg [31:0] int32_r;
reg [31:0] store_int32_r;
reg [15:0] mxspr_uint16_r;
reg [31:0] target_int26_r;
reg [31:0] reg_ra_r;
reg [31:0] reg_rb_r;
reg [31:0] shift_rb_r;
reg [31:0] shift_imm_r;
 
always @ *
begin
    // Instruction
    inst_r               = {2'b00,opcode_i[31:26]};
 
    // Sub instructions
    alu_op_r             = {opcode_i[9:6],opcode_i[3:0]};
    sfxx_op_r            = {5'b00,opcode_i[31:21]};
    shift_op_r           = opcode_i[7:6];
 
    // Branch target
    target_int26_r       = sign_extend_imm26(opcode_i[25:0]);
 
    // Store immediate
    store_int32_r        = sign_extend_imm16({opcode_i[25:21],opcode_i[10:0]});
 
    // Signed & unsigned imm -> 32-bits
    uint16_r             = opcode_i[15:0];
    int32_r              = sign_extend_imm16(opcode_i[15:0]);
    uint32_r             = extend_imm16(opcode_i[15:0]);
 
    // Register values [ra/rb]
    reg_ra_r             = ra_value_resolved;
    reg_rb_r             = rb_value_resolved;
 
    // Shift ammount (from register[rb])
    shift_rb_r           = {26'b00,rb_value_resolved[5:0]};
 
    // Shift ammount (from immediate)
    shift_imm_r          = {26'b00,opcode_i[5:0]};
 
    // MTSPR/MFSPR operand
    mxspr_uint16_r       = (ra_value_resolved[15:0] | {5'b00000,opcode_i[10:0]});
end
 
//-----------------------------------------------------------------
// Instruction Decode
//-----------------------------------------------------------------
wire inst_add_w     = (inst_r == `INST_OR32_ALU) & (alu_op_r == `INST_OR32_ADD);  // l.add
wire inst_addc_w    = (inst_r == `INST_OR32_ALU) & (alu_op_r == `INST_OR32_ADDC); // l.addc
wire inst_and_w     = (inst_r == `INST_OR32_ALU) & (alu_op_r == `INST_OR32_AND);  // l.and
wire inst_or_w      = (inst_r == `INST_OR32_ALU) & (alu_op_r == `INST_OR32_OR);   // l.or
wire inst_sll_w     = (inst_r == `INST_OR32_ALU) & (alu_op_r == `INST_OR32_SLL);  // l.sll
wire inst_sra_w     = (inst_r == `INST_OR32_ALU) & (alu_op_r == `INST_OR32_SRA);  // l.sra
wire inst_srl_w     = (inst_r == `INST_OR32_ALU) & (alu_op_r == `INST_OR32_SRL);  // l.srl
wire inst_sub_w     = (inst_r == `INST_OR32_ALU) & (alu_op_r == `INST_OR32_SUB);  // l.sub
wire inst_xor_w     = (inst_r == `INST_OR32_ALU) & (alu_op_r == `INST_OR32_XOR);  // l.xor
 
wire inst_addi_w    = (inst_r == `INST_OR32_ADDI);  // l.addi
wire inst_andi_w    = (inst_r == `INST_OR32_ANDI);  // l.andi
wire inst_bf_w      = (inst_r == `INST_OR32_BF);    // l.bf
wire inst_bnf_w     = (inst_r == `INST_OR32_BNF);   // l.bnf
wire inst_j_w       = (inst_r == `INST_OR32_J);     // l.j
wire inst_jal_w     = (inst_r == `INST_OR32_JAL);   // l.jal
wire inst_jalr_w    = (inst_r == `INST_OR32_JALR);  // l.jalr
wire inst_jr_w      = (inst_r == `INST_OR32_JR);    // l.jr
wire inst_lbs_w     = (inst_r == `INST_OR32_LBS);   // l.lbs
wire inst_lhs_w     = (inst_r == `INST_OR32_LHS);   // l.lhs
wire inst_lws_w     = (inst_r == `INST_OR32_LWS);   // l.lws
wire inst_lbz_w     = (inst_r == `INST_OR32_LBZ);   // l.lbz
wire inst_lhz_w     = (inst_r == `INST_OR32_LHZ);   // l.lhz
wire inst_lwz_w     = (inst_r == `INST_OR32_LWZ);   // l.lwz
wire inst_mfspr_w   = (inst_r == `INST_OR32_MFSPR); // l.mfspr
wire inst_mtspr_w   = (inst_r == `INST_OR32_MTSPR); // l.mtspr
wire inst_movhi_w   = (inst_r == `INST_OR32_MOVHI); // l.movhi
wire inst_nop_w     = (inst_r == `INST_OR32_NOP);   // l.nop
wire inst_ori_w     = (inst_r == `INST_OR32_ORI);   // l.ori
wire inst_rfe_w     = (inst_r == `INST_OR32_RFE);   // l.rfe
 
wire inst_sb_w      = (inst_r == `INST_OR32_SB);    // l.sb
wire inst_sh_w      = (inst_r == `INST_OR32_SH);    // l.sh
wire inst_sw_w      = (inst_r == `INST_OR32_SW);    // l.sw
 
wire inst_slli_w    = (inst_r == `INST_OR32_SHIFTI) & (shift_op_r == `INST_OR32_SLLI);  // l.slli
wire inst_srai_w    = (inst_r == `INST_OR32_SHIFTI) & (shift_op_r == `INST_OR32_SRAI);  // l.srai
wire inst_srli_w    = (inst_r == `INST_OR32_SHIFTI) & (shift_op_r == `INST_OR32_SRLI);  // l.srli
 
wire inst_xori_w    = (inst_r == `INST_OR32_XORI);   // l.xori
 
wire inst_sfxx_w    = (inst_r == `INST_OR32_SFXX);
wire inst_sfxxi_w   = (inst_r == `INST_OR32_SFXXI);
 
wire inst_sfeq_w    = (inst_r == `INST_OR32_SFXX) & (sfxx_op_r == `INST_OR32_SFEQ);   // l.sfeq
wire inst_sfges_w   = (inst_r == `INST_OR32_SFXX) & (sfxx_op_r == `INST_OR32_SFGES);  // l.sfges
 
wire inst_sfgeu_w   = (inst_r == `INST_OR32_SFXX) & (sfxx_op_r == `INST_OR32_SFGEU);  // l.sfgeu
wire inst_sfgts_w   = (inst_r == `INST_OR32_SFXX) & (sfxx_op_r == `INST_OR32_SFGTS);  // l.sfgts
wire inst_sfgtu_w   = (inst_r == `INST_OR32_SFXX) & (sfxx_op_r == `INST_OR32_SFGTU);  // l.sfgtu
wire inst_sfles_w   = (inst_r == `INST_OR32_SFXX) & (sfxx_op_r == `INST_OR32_SFLES);  // l.sfles
wire inst_sfleu_w   = (inst_r == `INST_OR32_SFXX) & (sfxx_op_r == `INST_OR32_SFLEU);  // l.sfleu
wire inst_sflts_w   = (inst_r == `INST_OR32_SFXX) & (sfxx_op_r == `INST_OR32_SFLTS);  // l.sflts
wire inst_sfltu_w   = (inst_r == `INST_OR32_SFXX) & (sfxx_op_r == `INST_OR32_SFLTU);  // l.sfltu
wire inst_sfne_w    = (inst_r == `INST_OR32_SFXX) & (sfxx_op_r == `INST_OR32_SFNE);   // l.sfne
 
wire inst_sfeqi_w   = (inst_r == `INST_OR32_SFXXI) & (sfxx_op_r == `INST_OR32_SFEQI);  // l.sfeqi
wire inst_sfgesi_w  = (inst_r == `INST_OR32_SFXXI) & (sfxx_op_r == `INST_OR32_SFGESI); // l.sfgesi
wire inst_sfgeui_w  = (inst_r == `INST_OR32_SFXXI) & (sfxx_op_r == `INST_OR32_SFGEUI); // l.sfgeui
wire inst_sfgtsi_w  = (inst_r == `INST_OR32_SFXXI) & (sfxx_op_r == `INST_OR32_SFGTSI); // l.sfgtsi
wire inst_sfgtui_w  = (inst_r == `INST_OR32_SFXXI) & (sfxx_op_r == `INST_OR32_SFGTUI); // l.sfgtui
wire inst_sflesi_w  = (inst_r == `INST_OR32_SFXXI) & (sfxx_op_r == `INST_OR32_SFLESI); // l.sflesi
 
wire inst_sfleui_w  = (inst_r == `INST_OR32_SFXXI) & (sfxx_op_r == `INST_OR32_SFLEUI); // l.sfleui
wire inst_sfltsi_w  = (inst_r == `INST_OR32_SFXXI) & (sfxx_op_r == `INST_OR32_SFLTSI); // l.sfltsi
wire inst_sfltui_w  = (inst_r == `INST_OR32_SFXXI) & (sfxx_op_r == `INST_OR32_SFLTUI); // l.sfltui
wire inst_sfnei_w   = (inst_r == `INST_OR32_SFXXI) & (sfxx_op_r == `INST_OR32_SFNEI);  // l.sfnei
 
wire inst_sys_w     = (inst_r == `INST_OR32_MISC) & (opcode_i[31:24] == `INST_OR32_SYS);  // l.sys
wire inst_trap_w    = (inst_r == `INST_OR32_MISC) & (opcode_i[31:24] == `INST_OR32_TRAP); // l.trap
 
//-----------------------------------------------------------------
// Stall / Execute
//-----------------------------------------------------------------
reg execute_inst_r;
reg stall_inst_r;
 
always @ *
begin
    execute_inst_r  = 1'b1;
    stall_inst_r    = 1'b0;
 
    // No opcode ready or branch delay slot
    if (~opcode_valid_i | r_pc_fetch)
        execute_inst_r  = 1'b0;
    // Valid instruction, but load result / operand not ready
    else if (resolve_failed | load_stall)
        stall_inst_r    = 1'b1;
end
 
//-----------------------------------------------------------------
// Next PC
//-----------------------------------------------------------------
reg [31:0]  next_pc_r;
 
always @ *
begin
    // Next expected PC (current PC + 4)
    next_pc_r  = (opcode_pc_i + 4);
end
 
//-----------------------------------------------------------------
// Next SR
//-----------------------------------------------------------------
reg [31:0]  next_sr_r;
reg         compare_result_r;
always @ *
begin
    next_sr_r = r_sr;
 
    // Latch carry if updated
    if (alu_carry_update)
        next_sr_r[`OR32_SR_CY] = alu_carry_out;
 
    // If valid instruction, check if SR needs updating
    if (execute_inst_r & ~stall_inst_r)
    begin
      case (1'b1)
      inst_mtspr_w:
      begin
          case (mxspr_uint16_r)
          // SR - Supervision register
          `SPR_REG_SR:
          begin
              next_sr_r = reg_rb_r;
 
              // Don't store cache flush requests
              next_sr_r[`OR32_SR_ICACHE_FLUSH] = 1'b0;
              next_sr_r[`OR32_SR_DCACHE_FLUSH] = 1'b0;
          end
          default:
            ;
          endcase
      end
      inst_rfe_w:
          next_sr_r = r_esr;
      inst_sfxx_w,
      inst_sfxxi_w:
           next_sr_r[`OR32_SR_F] = compare_result_r;
      default:
        ;
      endcase
    end
end
 
//-----------------------------------------------------------------
// Next EPC/ESR
//-----------------------------------------------------------------
reg [31:0]  next_epc_r;
reg [31:0]  next_esr_r;
 
always @ *
begin
    next_epc_r = r_epc;
    next_esr_r = r_esr;
 
    case (1'b1)
    inst_mtspr_w: // l.mtspr
    begin
       case (mxspr_uint16_r)
           // EPCR - EPC Exception saved PC
           `SPR_REG_EPCR:   next_epc_r = reg_rb_r;
 
           // ESR - Exception saved SR
           `SPR_REG_ESR:    next_esr_r = reg_rb_r;
       endcase
    end
    default:
      ;
    endcase
end
 
//-----------------------------------------------------------------
// ALU inputs
//-----------------------------------------------------------------
 
// ALU operation selection
reg [3:0]  alu_func_r;
 
// ALU operands
reg [31:0] alu_input_a_r;
reg [31:0] alu_input_b_r;
reg        write_rd_r;
 
always @ *
begin
   alu_func_r     = `ALU_NONE;
   alu_input_a_r  = 32'b0;
   alu_input_b_r  = 32'b0;
   write_rd_r     = 1'b0;
 
   case (1'b1)
 
     inst_add_w: // l.add
     begin
       alu_func_r     = `ALU_ADD;
       alu_input_a_r  = reg_ra_r;
       alu_input_b_r  = reg_rb_r;
       write_rd_r     = 1'b1;
     end
 
     inst_addc_w: // l.addc
     begin
         alu_func_r     = `ALU_ADDC;
         alu_input_a_r  = reg_ra_r;
         alu_input_b_r  = reg_rb_r;
         write_rd_r     = 1'b1;
     end
 
     inst_and_w: // l.and
     begin
         alu_func_r     = `ALU_AND;
         alu_input_a_r  = reg_ra_r;
         alu_input_b_r  = reg_rb_r;
         write_rd_r     = 1'b1;
     end
 
     inst_or_w: // l.or
     begin
         alu_func_r     = `ALU_OR;
         alu_input_a_r  = reg_ra_r;
         alu_input_b_r  = reg_rb_r;
         write_rd_r     = 1'b1;
     end
 
     inst_sll_w: // l.sll
     begin
         alu_func_r     = `ALU_SHIFTL;
         alu_input_a_r  = reg_ra_r;
         alu_input_b_r  = shift_rb_r;
         write_rd_r     = 1'b1;
     end
 
     inst_sra_w: // l.sra
     begin
         alu_func_r     = `ALU_SHIRTR_ARITH;
         alu_input_a_r  = reg_ra_r;
         alu_input_b_r  = shift_rb_r;
         write_rd_r     = 1'b1;
     end
 
     inst_srl_w: // l.srl
     begin
         alu_func_r     = `ALU_SHIFTR;
         alu_input_a_r  = reg_ra_r;
         alu_input_b_r  = shift_rb_r;
         write_rd_r     = 1'b1;
     end
 
     inst_sub_w: // l.sub
     begin
         alu_func_r     = `ALU_SUB;
         alu_input_a_r  = reg_ra_r;
         alu_input_b_r  = reg_rb_r;
         write_rd_r     = 1'b1;
     end
 
     inst_xor_w: // l.xor
     begin
         alu_func_r     = `ALU_XOR;
         alu_input_a_r  = reg_ra_r;
         alu_input_b_r  = reg_rb_r;
         write_rd_r     = 1'b1;
     end
 
     inst_addi_w: // l.addi
     begin
         alu_func_r     = `ALU_ADD;
         alu_input_a_r  = reg_ra_r;
         alu_input_b_r  = int32_r;
         write_rd_r     = 1'b1;
     end
 
     inst_andi_w: // l.andi
     begin
         alu_func_r     = `ALU_AND;
         alu_input_a_r  = reg_ra_r;
         alu_input_b_r  = uint32_r;
         write_rd_r     = 1'b1;
     end
 
     inst_jal_w: // l.jal
     begin
         alu_input_a_r  = next_pc_r;
         write_rd_r     = 1'b1;
     end
 
     inst_jalr_w: // l.jalr
     begin
         alu_input_a_r  = next_pc_r;
         write_rd_r     = 1'b1;
     end
 
     inst_mfspr_w: // l.mfspr
     begin
        case (mxspr_uint16_r)
           // SR - Supervision register
           `SPR_REG_SR:
           begin
               alu_input_a_r = next_sr_r;
               write_rd_r    = 1'b1;
           end
 
           // EPCR - EPC Exception saved PC
           `SPR_REG_EPCR:
           begin
               alu_input_a_r  = r_epc;
               write_rd_r     = 1'b1;
           end
 
           // ESR - Exception saved SR
           `SPR_REG_ESR:
           begin
               alu_input_a_r  = r_esr;
               write_rd_r     = 1'b1;
           end
           default:
              ;
        endcase
     end
 
     inst_movhi_w: // l.movhi
     begin
         alu_input_a_r  = {uint16_r,16'h0000};
         write_rd_r     = 1'b1;
     end
 
     inst_ori_w: // l.ori
     begin
         alu_func_r     = `ALU_OR;
         alu_input_a_r  = reg_ra_r;
         alu_input_b_r  = uint32_r;
         write_rd_r     = 1'b1;
     end
 
     inst_slli_w: // l.slli
     begin
         alu_func_r     = `ALU_SHIFTL;
         alu_input_a_r  = reg_ra_r;
         alu_input_b_r  = shift_imm_r;
         write_rd_r     = 1'b1;
     end
 
     inst_srai_w: // l.srai
     begin
         alu_func_r     = `ALU_SHIRTR_ARITH;
         alu_input_a_r  = reg_ra_r;
         alu_input_b_r  = shift_imm_r;
         write_rd_r     = 1'b1;
     end
 
     inst_srli_w: // l.srli
     begin
         alu_func_r     = `ALU_SHIFTR;
         alu_input_a_r  = reg_ra_r;
         alu_input_b_r  = shift_imm_r;
         write_rd_r     = 1'b1;
     end
 
     // l.lbs l.lhs l.lws l.lbz l.lhz l.lwz
     inst_lbs_w,
     inst_lhs_w,
     inst_lws_w,
     inst_lbz_w,
     inst_lhz_w,
     inst_lwz_w:
          write_rd_r    = 1'b1;
 
     inst_xori_w: // l.xori
     begin
         alu_func_r     = `ALU_XOR;
         alu_input_a_r  = reg_ra_r;
         alu_input_b_r  = int32_r;
         write_rd_r     = 1'b1;
     end
     default:
        ;
   endcase
end
 
//-----------------------------------------------------------------
// Comparisons
//-----------------------------------------------------------------
reg [31:0] compare_a_r;
reg [31:0] compare_b_r;
always @ *
begin
    compare_a_r = reg_ra_r;
    compare_b_r = reg_rb_r;
 
    case (1'b1)
    inst_sfeqi_w,  // l.sfeqi
    inst_sfgesi_w, // l.sfgesi
    inst_sfgeui_w, // l.sfgeui
    inst_sfgtsi_w, // l.sfgtsi
    inst_sfgtui_w, // l.sfgtui
    inst_sflesi_w, // l.sflesi
    inst_sfleui_w, // l.sfleui
    inst_sfltsi_w, // l.sfltsi
    inst_sfltui_w, // l.sfltui
    inst_sfnei_w:  // l.sfnei
        compare_b_r = int32_r;
    default:
        ;
    endcase
end
 
reg compare_equal_r;
reg compare_gts_r;
reg compare_gt_r;
reg compare_lts_r;
reg compare_lt_r;
always @ *
begin
    if (compare_a_r == compare_b_r)
        compare_equal_r = 1'b1;
    else
        compare_equal_r = 1'b0;
 
    compare_lts_r = less_than_signed(compare_a_r, compare_b_r);
 
    if (compare_a_r < compare_b_r)
        compare_lt_r = 1'b1;
    else
        compare_lt_r = 1'b0;
 
    // Greater than (signed)
    compare_gts_r = ~(compare_lts_r | compare_equal_r);
 
    if (compare_a_r > compare_b_r)
        compare_gt_r = 1'b1;
    else
        compare_gt_r = 1'b0;
end
 
always @ *
begin
    compare_result_r = 1'b0;
 
    case (1'b1)
    inst_sfeq_w, // l.sfeq
    inst_sfeqi_w: // l.sfeqi
        compare_result_r = compare_equal_r;
 
    inst_sfges_w,  // l.sfges
    inst_sfgesi_w: // l.sfgesi
        compare_result_r = compare_gts_r | compare_equal_r;
 
    inst_sfgeu_w,  // l.sfgeu
    inst_sfgeui_w: // l.sfgeui
        compare_result_r = compare_gt_r | compare_equal_r;
 
    inst_sfgts_w,  // l.sfgts
    inst_sfgtsi_w: // l.sfgtsi
        compare_result_r = compare_gts_r;
 
    inst_sfgtu_w,  // l.sfgtu
    inst_sfgtui_w: // l.sfgtui
        compare_result_r = compare_gt_r;
 
    inst_sfles_w,  // l.sfles
    inst_sflesi_w: // l.sflesi
        compare_result_r = compare_lts_r | compare_equal_r;
 
    inst_sfleu_w,  // l.sfleu
 
    inst_sfleui_w: // l.sfleui
        compare_result_r = compare_lt_r | compare_equal_r;
 
    inst_sflts_w,  // l.sflts
 
    inst_sfltsi_w: // l.sfltsi
        compare_result_r = compare_lts_r;
 
    inst_sfltu_w,  // l.sfltu
 
    inst_sfltui_w: // l.sfltui
        compare_result_r = compare_lt_r;
 
    inst_sfne_w,  // l.sfne
 
    inst_sfnei_w: // l.sfnei
        compare_result_r = ~compare_equal_r;
    default:
        ;
    endcase
end
 
//-----------------------------------------------------------------
// Load/Store operation?
//-----------------------------------------------------------------
reg         load_inst_r;
reg         store_inst_r;
reg [31:0]  mem_addr_r;
always @ *
begin
    load_inst_r  = inst_lbs_w | inst_lhs_w | inst_lws_w |
                   inst_lbz_w | inst_lhz_w | inst_lwz_w;
    store_inst_r = inst_sb_w  | inst_sh_w  | inst_sw_w;
 
    // Memory address is relative to RA
    mem_addr_r = reg_ra_r + (store_inst_r ? store_int32_r : int32_r);
end
 
//-----------------------------------------------------------------
// Branches
//-----------------------------------------------------------------
reg         branch_r;
reg         branch_link_r;
reg [31:0]  branch_target_r;
reg         branch_except_r;
 
always @ *
begin
 
    branch_r        = 1'b0;
    branch_link_r   = 1'b0;
    branch_except_r = 1'b0;
 
    // Default branch target is relative to current PC
    branch_target_r = (opcode_pc_i + {target_int26_r[29:0],2'b00});
 
    case (1'b1)
    inst_bf_w: // l.bf
        branch_r      = r_sr[`OR32_SR_F];
 
    inst_bnf_w: // l.bnf
        branch_r      = ~r_sr[`OR32_SR_F];
 
    inst_j_w: // l.j
        branch_r      = 1'b1;
 
    inst_jal_w: // l.jal
    begin
        // Write to REG_9_LR
        branch_link_r = 1'b1;
        branch_r      = 1'b1;
    end
 
    inst_jalr_w: // l.jalr
    begin
        // Write to REG_9_LR
        branch_link_r   = 1'b1;
        branch_r        = 1'b1;
        branch_target_r = reg_rb_r;
    end
 
    inst_jr_w: // l.jr
    begin
        branch_r        = 1'b1;
        branch_target_r = reg_rb_r;
    end
 
    inst_rfe_w: // l.rfe
    begin
        branch_r        = 1'b1;
        branch_target_r = r_epc;
    end
 
    inst_sys_w: // l.sys
    begin
        branch_r        = 1'b1;
        branch_except_r = 1'b1;
        branch_target_r = ISR_VECTOR + `VECTOR_SYSCALL;
    end
 
    inst_trap_w: // l.trap
    begin
        branch_r        = 1'b1;
        branch_except_r = 1'b1;
        branch_target_r = ISR_VECTOR + `VECTOR_TRAP;
    end
 
    default:
        ;
    endcase
end
 
//-----------------------------------------------------------------
// Invalid instruction
//-----------------------------------------------------------------
reg invalid_inst_r;
 
always @ *
begin
    case (1'b1)
       inst_add_w,
       inst_addc_w,
       inst_and_w,
       inst_or_w,
       inst_sll_w,
       inst_sra_w,
       inst_srl_w,
       inst_sub_w,
       inst_xor_w,
       inst_addi_w,
       inst_andi_w,
       inst_bf_w,
       inst_bnf_w,
       inst_j_w,
       inst_jal_w,
       inst_jalr_w,
       inst_jr_w,
       inst_lbs_w,
       inst_lhs_w,
       inst_lws_w,
       inst_lbz_w,
       inst_lhz_w,
       inst_lwz_w,
       inst_mfspr_w,
       inst_mtspr_w,
       inst_movhi_w,
       inst_nop_w,
       inst_ori_w,
       inst_rfe_w,
       inst_sb_w,
       inst_sh_w,
       inst_sw_w,
       inst_xori_w,
       inst_slli_w,
       inst_srai_w,
       inst_srli_w,
       inst_sfeq_w,
       inst_sfeqi_w,
       inst_sfges_w,
       inst_sfgesi_w,
       inst_sfgeu_w,
       inst_sfgeui_w,
       inst_sfgts_w,
       inst_sfgtsi_w,
       inst_sfgtu_w,
       inst_sfgtui_w,
       inst_sfles_w,
       inst_sflesi_w,
       inst_sfleu_w,
       inst_sfleui_w,
       inst_sflts_w,
       inst_sfltsi_w,
       inst_sfltu_w,
       inst_sfltui_w,
       inst_sfne_w,
       inst_sfnei_w,
       inst_sys_w,
       inst_trap_w:
          invalid_inst_r = 1'b0;
       default:
          invalid_inst_r = 1'b1;
    endcase
end
 
//-----------------------------------------------------------------
// Execute: ALU control
//-----------------------------------------------------------------
always @ (posedge clk_i or posedge rst_i)
begin
   if (rst_i == 1'b1)
   begin
       r_e_alu_func         <= `ALU_NONE;
       r_e_alu_a            <= 32'h00000000;
       r_e_alu_b            <= 32'h00000000;
       r_e_rd               <= 5'b00000;
   end
   else
   begin
       //---------------------------------------------------------------
       // Instruction not ready
       //---------------------------------------------------------------
       if (~execute_inst_r | stall_inst_r)
       begin
           // Insert load result?
           if (load_insert)
           begin
               // Feed load result into pipeline
               r_e_alu_func   <= `ALU_NONE;
               r_e_alu_a      <= load_result;
               r_e_alu_b      <= 32'b0;
               r_e_rd         <= r_load_rd;
           end
           else
           begin
               // No ALU operation (output == input_a)
               r_e_alu_func   <= `ALU_NONE;
               r_e_alu_a      <= 32'b0;
               r_e_alu_b      <= 32'b0;
               r_e_rd         <= 5'b0;
           end
       end
       //---------------------------------------------------------------
       // Valid instruction
       //---------------------------------------------------------------
       else if (~invalid_inst_r)
       begin
           // Update ALU input flops
           r_e_alu_func         <= alu_func_r;
           r_e_alu_a            <= alu_input_a_r;
           r_e_alu_b            <= alu_input_b_r;
 
           // Branch and link (Rd = LR/R9)
           if (branch_link_r)
              r_e_rd            <= 5'd9;
           // Instruction with register writeback
           else if (write_rd_r)
              r_e_rd            <= reg_rd_i;
           else
              r_e_rd            <= 5'b0;
       end
   end
end
 
//-----------------------------------------------------------------
// Execute: Update executed PC / opcode
//-----------------------------------------------------------------
always @ (posedge clk_i or posedge rst_i)
begin
   if (rst_i == 1'b1)
   begin
       r_e_opcode           <= 32'h00000000;
       r_e_opcode_pc        <= 32'h00000000;
 
       r_stall              <= 1'b0;
   end
   else
   begin
       r_stall              <= stall_inst_r;
 
       // Instruction not ready
       if (~execute_inst_r | stall_inst_r)
       begin
           // Store bubble opcode
           r_e_opcode            <= `OPCODE_INST_BUBBLE;
           r_e_opcode_pc         <= opcode_pc_i;
       end
       // Valid instruction
       else if (~invalid_inst_r)
       begin
           // Store opcode
           r_e_opcode            <= opcode_i;
           r_e_opcode_pc         <= opcode_pc_i;
 
        `ifdef CONF_CORE_TRACE
           $display("%08x: Execute 0x%08x", opcode_pc_i, opcode_i);
           $display(" rA[%d] = 0x%08x", reg_ra_i, reg_ra_r);
           $display(" rB[%d] = 0x%08x", reg_rb_i, reg_rb_r);
        `endif
       end
   end
end
 
//-----------------------------------------------------------------
// Execute: Branch / exceptions
//-----------------------------------------------------------------
always @ (posedge clk_i or posedge rst_i)
begin
   if (rst_i == 1'b1)
   begin
       r_pc_branch          <= 32'h00000000;
       r_pc_fetch           <= 1'b0;
 
       // Status registers
       r_epc                <= 32'h00000000;
       r_sr                 <= 32'h00000000;
       r_esr                <= 32'h00000000;
 
       fault_o              <= 1'b0;
 
       r_nmi                <= 1'b0;
   end
   else
   begin
      // Record NMI in-case it can't be processed this cycle
      if (nmi_i)
          r_nmi             <= 1'b1;
 
       // Reset branch request
       r_pc_fetch           <= 1'b0;
 
       // Update SR
       r_sr                 <= next_sr_r;
 
       // Instruction ready
       if (execute_inst_r & ~stall_inst_r)
       begin
           // Exception: Instruction opcode not valid / supported, invalid PC
           if (invalid_inst_r || (opcode_pc_i[1:0] != 2'b00))
           begin
                // Save PC of next instruction
                r_epc       <= next_pc_r;
                r_esr       <= next_sr_r;
 
                // Disable further interrupts
                r_sr        <= 32'b0;
 
                // Set PC to exception vector
                if (invalid_inst_r)
                    r_pc_branch <= ISR_VECTOR + `VECTOR_ILLEGAL_INST;
                else
                    r_pc_branch <= ISR_VECTOR + `VECTOR_BUS_ERROR;
                r_pc_fetch  <= 1'b1;
 
                fault_o     <= 1'b1;
           end
           // Exception: Syscall / Break
           else if (branch_except_r)
           begin
                // Save PC of next instruction
                r_epc       <= next_pc_r;
                r_esr       <= next_sr_r;
 
                // Disable further interrupts
                r_sr        <= 32'b0;
 
                // Set PC to exception vector
                r_pc_branch <= branch_target_r;
                r_pc_fetch  <= 1'b1;
 
    `ifdef CONF_CORE_DEBUG
               $display(" Exception 0x%08x", branch_target_r);
    `endif
           end
           // Non-maskable interrupt
           else if (nmi_i | r_nmi)
           begin
                r_nmi       <= 1'b0;
 
                // Save PC of next instruction
                if (branch_r)
                    r_epc <= branch_target_r;
                // Next expected PC (current PC + 4)
                else
                    r_epc <= next_pc_r;
 
                r_esr       <= next_sr_r;
 
                // Disable further interrupts
                r_sr        <= 32'b0;
 
                // Set PC to exception vector
                r_pc_branch <= ISR_VECTOR + `VECTOR_NMI;
                r_pc_fetch  <= 1'b1;
 
    `ifdef CONF_CORE_DEBUG
               $display(" NMI 0x%08x", ISR_VECTOR + `VECTOR_NMI);
    `endif
           end
           // External interrupt
           else if (intr_i && next_sr_r[`OR32_SR_IEE])
           begin
                // Save PC of next instruction & SR
                if (branch_r)
                    r_epc <= branch_target_r;
                // Next expected PC (current PC + 4)
                else
                    r_epc <= next_pc_r;
 
                r_esr       <= next_sr_r;
 
                // Disable further interrupts
                r_sr        <= 32'b0;
 
                // Set PC to external interrupt vector
                r_pc_branch <= ISR_VECTOR + `VECTOR_EXTINT;
                r_pc_fetch  <= 1'b1;
 
    `ifdef CONF_CORE_DEBUG
               $display(" External Interrupt 0x%08x", ISR_VECTOR + `VECTOR_EXTINT);
    `endif
           end
           // Branch (l.bf, l.bnf, l.j, l.jal, l.jr, l.jalr, l.rfe)
           else if (branch_r)
           begin
                // Perform branch
                r_pc_branch    <= branch_target_r;
                r_pc_fetch     <= 1'b1;
 
    `ifdef CONF_CORE_DEBUG
               $display(" Branch to 0x%08x", branch_target_r);
    `endif
           end
           // Non branch
           else
           begin
                // Update EPC / ESR which may have been updated
                // by an MTSPR write
                r_epc          <= next_epc_r;
                r_esr          <= next_esr_r;
           end
      end
   end
end
 
//-----------------------------------------------------------------
// Execute: Memory operations
//-----------------------------------------------------------------
always @ (posedge clk_i or posedge rst_i)
begin
   if (rst_i == 1'b1)
   begin
       // Data memory
       dmem_addr_o          <= 32'h00000000;
       dmem_data_out_o      <= 32'h00000000;
       dmem_we_o            <= 1'b0;
       dmem_sel_o           <= 4'b0000;
       dmem_stb_o           <= 1'b0;
       dmem_cyc_o           <= 1'b0;
 
       r_mem_load           <= 1'b0;
       r_mem_store          <= 1'b0;
       r_mem_access         <= 1'b0;
 
       r_load_rd            <= 5'b00000;
       r_load_inst          <= 8'h00;
       r_load_offset        <= 2'b00;
 
       d_mem_load           <= 1'b0;
   end
   else
   begin
 
       // If memory access accepted by slave
       if (~dmem_stall_i)
           dmem_stb_o   <= 1'b0;
 
       if (dmem_ack_i)
            dmem_cyc_o  <= 1'b0;
       r_mem_access     <= 1'b0;
       d_mem_load       <= r_mem_access & r_mem_load;
 
       // Pending accesses
       r_mem_load   <= load_pending;
       r_mem_store  <= store_pending;
 
       //---------------------------------------------------------------
       // Valid instruction
       //---------------------------------------------------------------
       if (execute_inst_r & ~stall_inst_r & ~invalid_inst_r)
       begin
           // Branch and link (Rd = LR/R9)
           if (branch_link_r)
           begin
              // Load outstanding, check if result target is being
              // overwritten (to avoid WAR hazard)
              if (r_load_rd == 5'd9)
                  // Ditch load result when it arrives
                  r_load_rd     <= 5'b00000;
           end
           // Instruction with register writeback
           else if (write_rd_r)
           begin
              // Load outstanding, check if result target is being
              // overwritten (to avoid WAR hazard)
              if (reg_rd_i == r_load_rd && ~load_inst_r)
                  // Ditch load result when it arrives
                  r_load_rd     <= 5'b00000;
           end
 
           case (1'b1)
 
             // l.lbs l.lhs l.lws l.lbz l.lhz l.lwz
             load_inst_r:
             begin
                 dmem_addr_o      <= mem_addr_r;
                 dmem_data_out_o  <= 32'h00000000;
                 dmem_sel_o       <= 4'b1111;
                 dmem_we_o        <= 1'b0;
                 dmem_stb_o       <= 1'b1;
                 dmem_cyc_o       <= 1'b1;
 
                 // Mark load as pending
                 r_mem_load      <= 1'b1;
                 r_mem_access    <= 1'b1;
 
                 // Record target register
                 r_load_rd        <= reg_rd_i;
                 r_load_inst      <= inst_r;
                 r_load_offset    <= mem_addr_r[1:0];
 
  `ifdef CONF_CORE_DEBUG
                 $display(" Load from 0x%08x to R%d", mem_addr_r, reg_rd_i);
  `endif
             end
 
             inst_sb_w: // l.sb
             begin
                 dmem_addr_o <= mem_addr_r;
                 r_mem_access <= 1'b1;
                 case (mem_addr_r[1:0])
                     2'b00 :
                     begin
                         dmem_data_out_o  <= {reg_rb_r[7:0],24'h000000};
                         dmem_sel_o       <= 4'b1000;
                         dmem_we_o        <= 1'b1;
                         dmem_stb_o       <= 1'b1;
                         dmem_cyc_o       <= 1'b1;
                         r_mem_store      <= 1'b1;
                     end
                     2'b01 :
                     begin
                         dmem_data_out_o  <= {{8'h00,reg_rb_r[7:0]},16'h0000};
                         dmem_sel_o       <= 4'b0100;
                         dmem_we_o        <= 1'b1;
                         dmem_stb_o       <= 1'b1;
                         dmem_cyc_o       <= 1'b1;
                         r_mem_store      <= 1'b1;
                     end
                     2'b10 :
                     begin
                         dmem_data_out_o  <= {{16'h0000,reg_rb_r[7:0]},8'h00};
                         dmem_sel_o       <= 4'b0010;
                         dmem_we_o        <= 1'b1;
                         dmem_stb_o       <= 1'b1;
                         dmem_cyc_o       <= 1'b1;
                         r_mem_store      <= 1'b1;
                     end
                     2'b11 :
                     begin
                         dmem_data_out_o  <= {24'h000000,reg_rb_r[7:0]};
                         dmem_sel_o       <= 4'b0001;
                         dmem_we_o        <= 1'b1;
                         dmem_stb_o       <= 1'b1;
                         dmem_cyc_o       <= 1'b1;
                         r_mem_store      <= 1'b1;
                     end
                     default :
                        ;
                 endcase
             end
 
            inst_sh_w: // l.sh
            begin
                 dmem_addr_o <= mem_addr_r;
                 r_mem_access <= 1'b1;
                 case (mem_addr_r[1:0])
                     2'b00 :
                     begin
                         dmem_data_out_o  <= {reg_rb_r[15:0],16'h0000};
                         dmem_sel_o       <= 4'b1100;
                         dmem_we_o        <= 1'b1;
                         dmem_stb_o       <= 1'b1;
                         dmem_cyc_o       <= 1'b1;
                         r_mem_store      <= 1'b1;
                     end
                     2'b10 :
                     begin
                         dmem_data_out_o  <= {16'h0000,reg_rb_r[15:0]};
                         dmem_sel_o       <= 4'b0011;
                         dmem_we_o        <= 1'b1;
                         dmem_stb_o       <= 1'b1;
                         dmem_cyc_o       <= 1'b1;
                         r_mem_store      <= 1'b1;
                     end
                     default :
                        ;
                 endcase
            end
 
            inst_sw_w: // l.sw
            begin
                 dmem_addr_o      <= mem_addr_r;
                 dmem_data_out_o  <= reg_rb_r;
                 dmem_sel_o       <= 4'b1111;
                 dmem_we_o        <= 1'b1;
                 dmem_stb_o       <= 1'b1;
                 dmem_cyc_o       <= 1'b1;
                 r_mem_access     <= 1'b1;
                 r_mem_store      <= 1'b1;
 
  `ifdef CONF_CORE_DEBUG
                 $display(" Store R%d to 0x%08x = 0x%08x", reg_rb_i, {mem_addr_r[31:2],2'b00}, reg_rb_r);
  `endif
            end
            default:
                ;
         endcase
       end
   end
end
 
//-----------------------------------------------------------------
// Execute: Misc operations
//-----------------------------------------------------------------
always @ (posedge clk_i or posedge rst_i)
begin
   if (rst_i == 1'b1)
   begin
       break_o              <= 1'b0;
       icache_flush_o       <= 1'b0;
       dcache_flush_o       <= 1'b0;
   end
   else
   begin
       break_o              <= 1'b0;
       icache_flush_o       <= 1'b0;
       dcache_flush_o       <= 1'b0;
 
       //---------------------------------------------------------------
       // Valid instruction
       //---------------------------------------------------------------
       if (execute_inst_r & ~stall_inst_r & ~invalid_inst_r)
       begin
          case (1'b1)
          inst_mtspr_w: // l.mtspr
          begin
               case (mxspr_uint16_r)
                   // SR - Supervision register
                   `SPR_REG_SR:
                   begin
                       // Cache flush request?
                       icache_flush_o <= reg_rb_r[`OR32_SR_ICACHE_FLUSH];
                       dcache_flush_o <= reg_rb_r[`OR32_SR_DCACHE_FLUSH];
                   end
               endcase
          end
 
          inst_trap_w: // l.trap
              break_o <= 1'b1;
          default:
              ;
         endcase
       end
   end
end
 
//-----------------------------------------------------------------
// Execute: NOP (simulation) operations
//-----------------------------------------------------------------
`ifdef SIMULATION
    always @ (posedge clk_i or posedge rst_i)
    begin
       if (rst_i == 1'b1)
       begin
    `ifdef SIM_EXT_PUTC
          r_putc                <= 8'b0;
    `endif
       end
       else
       begin
    `ifdef SIM_EXT_PUTC
          r_putc                <= 8'b0;
    `endif
           //---------------------------------------------------------------
           // Valid instruction
           //---------------------------------------------------------------
           if (execute_inst_r & ~stall_inst_r & ~invalid_inst_r)
           begin
 
               case (1'b1)
               inst_nop_w: // l.nop
                begin
                    case (uint16_r)
                    // NOP_PUTC
                    16'h0004:
                    begin
      `ifdef SIM_EXT_PUTC
                      r_putc  <= reg_ra_r[7:0];
      `else
                      $write("%c", reg_ra_r[7:0]);
      `endif
                    end
                    // NOP
                    16'h0000: ;
                    endcase
                end
                default:
                    ;
             endcase
           end
       end
    end
`endif
 
//-------------------------------------------------------------------
// Assignments
//-------------------------------------------------------------------
 
assign branch_pc_o          = r_pc_branch;
assign branch_o             = r_pc_fetch;
assign stall_o              = r_stall;
 
assign opcode_o             = r_e_opcode;
 
assign reg_rd_o             = r_e_rd;
assign reg_rd_value_o       = r_e_result;
 
assign mult_o               = 1'b0;
assign mult_res_o           = 32'b0;
 
`include "altor32_funcs.v"
 
//-------------------------------------------------------------------
// Hooks for debug
//-------------------------------------------------------------------
`ifdef verilator
   function [31:0] get_opcode_ex;
      // verilator public
      get_opcode_ex = r_e_opcode;
   endfunction
   function [31:0] get_pc_ex;
      // verilator public
      get_pc_ex = r_e_opcode_pc;
   endfunction
   function [7:0] get_putc;
      // verilator public
   `ifdef SIM_EXT_PUTC
      get_putc = r_putc;
   `else
      get_putc = 8'b0;
   `endif
   endfunction
   function [0:0] get_reg_valid;
      // verilator public
      get_reg_valid = ~(resolve_failed | load_stall);
   endfunction
   function [4:0] get_reg_ra;
      // verilator public
      get_reg_ra = reg_ra_i;
   endfunction
   function [31:0] get_reg_ra_value;
      // verilator public
      get_reg_ra_value = ra_value_resolved;
   endfunction
   function [4:0] get_reg_rb;
      // verilator public
      get_reg_rb = reg_rb_i;
   endfunction
   function [31:0] get_reg_rb_value;
      // verilator public
      get_reg_rb_value = rb_value_resolved;
   endfunction
`endif
 
endmodule

Line No.	Rev	Author	Line
1	27	ultra_embe	`//-----------------------------------------------------------------`
2			`// AltOR32`
3			`// Alternative Lightweight OpenRisc`
4			`// V2.0`
5			`// Ultra-Embedded.com`
6			`// Copyright 2011 - 2013`
7			`//`
8			`// Email: admin@ultra-embedded.com`
9			`//`
10			`// License: LGPL`
11			`//-----------------------------------------------------------------`
12			`//`
13			`// Copyright (C) 2011 - 2013 Ultra-Embedded.com`
14			`//`
15			`// This source file may be used and distributed without`
16			`// restriction provided that this copyright statement is not`
17			`// removed from the file and that any derivative work contains`
18			`// the original copyright notice and the associated disclaimer.`
19			`//`
20			`// This source file is free software; you can redistribute it`
21			`// and/or modify it under the terms of the GNU Lesser General`
22			`// Public License as published by the Free Software Foundation;`
23			`// either version 2.1 of the License, or (at your option) any`
24			`// later version.`
25			`//`
26			`// This source is distributed in the hope that it will be`
27			`// useful, but WITHOUT ANY WARRANTY; without even the implied`
28			`// warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR`
29			`// PURPOSE. See the GNU Lesser General Public License for more`
30			`// details.`
31			`//`
32			`// You should have received a copy of the GNU Lesser General`
33			`// Public License along with this source; if not, write to the`
34			`// Free Software Foundation, Inc., 59 Temple Place, Suite 330,`
35			`// Boston, MA 02111-1307 USA`
36			`//-----------------------------------------------------------------`
37
38			//`define CONF_CORE_DEBUG
39			//`define CONF_CORE_TRACE
40
41			`//-----------------------------------------------------------------`
42			`// Includes`
43			`//-----------------------------------------------------------------`
44			`include "altor32_defs.v"
45
46			`//-----------------------------------------------------------------`
47			`// Module - Instruction Execute`
48			`//-----------------------------------------------------------------`
49			`module altor32_exec`
50			`(`
51			`// General`
52			`input clk_i /verilator public/,`
53			`input rst_i /verilator public/,`
54
55			`// Maskable interrupt`
56			`input intr_i /verilator public/,`
57
58			`// Unmaskable interrupt`
59			`input nmi_i /verilator public/,`
60
61			`// Fault`
62			`output reg fault_o /verilator public/,`
63
64			`// Breakpoint / Trap`
65			`output reg break_o /verilator public/,`
66
67			`// Cache control`
68			`output reg icache_flush_o /verilator public/,`
69			`output reg dcache_flush_o /verilator public/,`
70
71			`// Branch`
72			`output branch_o /verilator public/,`
73			`output [31:0] branch_pc_o /verilator public/,`
74			`output stall_o /verilator public/,`
75
76			`// Opcode & arguments`
77			`input [31:0] opcode_i /verilator public/,`
78			`input [31:0] opcode_pc_i /verilator public/,`
79			`input opcode_valid_i /verilator public/,`
80
81			`// Reg A`
82			`input [4:0] reg_ra_i /verilator public/,`
83			`input [31:0] reg_ra_value_i /verilator public/,`
84
85			`// Reg B`
86			`input [4:0] reg_rb_i /verilator public/,`
87			`input [31:0] reg_rb_value_i /verilator public/,`
88
89			`// Reg D`
90			`input [4:0] reg_rd_i /verilator public/,`
91
92			`// Output`
93			`output [31:0] opcode_o /verilator public/,`
94			`output [4:0] reg_rd_o /verilator public/,`
95			`output [31:0] reg_rd_value_o /verilator public/,`
96			`output mult_o /verilator public/,`
97			`output [31:0] mult_res_o /verilator public/,`
98
99			`// Register write back bypass`
100			`input [4:0] wb_rd_i /verilator public/,`
101			`input [31:0] wb_rd_value_i /verilator public/,`
102
103			`// Memory Interface`
104			`output reg [31:0] dmem_addr_o /verilator public/,`
105			`output reg [31:0] dmem_data_out_o /verilator public/,`
106			`input [31:0] dmem_data_in_i /verilator public/,`
107	32	ultra_embe	`output reg [3:0] dmem_sel_o /verilator public/,`
108			`output reg dmem_we_o /verilator public/,`
109			`output reg dmem_stb_o /verilator public/,`
110			`output reg dmem_cyc_o /verilator public/,`
111			`input dmem_stall_i /verilator public/,`
112	27	ultra_embe	`input dmem_ack_i /verilator public/`
113			`);`
114
115			`//-----------------------------------------------------------------`
116			`// Params`
117			`//-----------------------------------------------------------------`
118			`parameter BOOT_VECTOR = 32'h00000000;`
119			`parameter ISR_VECTOR = 32'h00000000;`
120
121			`//-----------------------------------------------------------------`
122			`// Registers`
123			`//-----------------------------------------------------------------`
124
125			`// Branch PC`
126			`reg [31:0] r_pc_branch;`
127			`reg r_pc_fetch;`
128			`reg r_stall;`
129
130			`// Exception saved program counter`
131			`reg [31:0] r_epc;`
132
133			`// Supervisor register`
134			`reg [31:0] r_sr;`
135
136			`// Exception saved supervisor register`
137			`reg [31:0] r_esr;`
138
139			`// Destination register number (post execute stage)`
140			`reg [4:0] r_e_rd;`
141
142			`// Current opcode (PC for debug)`
143			`reg [31:0] r_e_opcode;`
144			`reg [31:0] r_e_opcode_pc;`
145
146			`// ALU input A`
147			`reg [31:0] r_e_alu_a;`
148
149			`// ALU input B`
150			`reg [31:0] r_e_alu_b;`
151
152			`// ALU output`
153			`wire [31:0] r_e_result;`
154
155			`// Resolved RA/RB register contents`
156			`wire [31:0] ra_value_resolved;`
157			`wire [31:0] rb_value_resolved;`
158			`wire resolve_failed;`
159
160			`// ALU Carry`
161			`wire alu_carry_out;`
162			`wire alu_carry_update;`
163
164			`// ALU operation selection`
165			`reg [3:0] r_e_alu_func;`
166
167			`// Load instruction details`
168			`reg [4:0] r_load_rd;`
169			`reg [7:0] r_load_inst;`
170			`reg [1:0] r_load_offset;`
171
172			`// Load forwarding`
173			`wire load_insn;`
174			`wire [31:0] load_result;`
175
176			`// Memory access?`
177			`reg r_mem_load;`
178			`reg r_mem_store;`
179			`reg r_mem_access;`
180
181			`wire load_pending;`
182			`wire store_pending;`
183			`wire load_insert;`
184			`wire load_stall;`
185
186			`reg d_mem_load;`
187
188			`// Delayed NMI`
189			`reg r_nmi;`
190
191	31	ultra_embe	`// SIM PUTC`
192			`ifdef SIM_EXT_PUTC
193			`reg [7:0] r_putc;`
194			`endif
195
196	27	ultra_embe	`//-----------------------------------------------------------------`
197			`// Instantiation`
198			`//-----------------------------------------------------------------`
199
200			`// ALU`
201			`altor32_alu alu`
202			`(`
203			`// ALU operation select`
204			`.op_i(r_e_alu_func),`
205
206			`// Operands`
207			`.a_i(r_e_alu_a),`
208			`.b_i(r_e_alu_b),`
209			.c_i(r_sr[`OR32_SR_CY]),
210
211			`// Result`
212			`.p_o(r_e_result),`
213
214			`// Carry`
215			`.c_o(alu_carry_out),`
216			`.c_update_o(alu_carry_update)`
217			`);`
218
219			`// Load result forwarding`
220			`altor32_lfu`
221			`u_lfu`
222			`(`
223			`// Opcode`
224			`.opcode_i(r_load_inst),`
225
226			`// Memory load result`
227			`.mem_result_i(dmem_data_in_i),`
228			`.mem_offset_i(r_load_offset),`
229
230			`// Result`
231			`.load_result_o(load_result),`
232			`.load_insn_o(load_insn)`
233			`);`
234
235			`// Load / store pending logic`
236			`altor32_lsu`
237			`u_lsu`
238			`(`
239			`// Current instruction`
240			`.opcode_valid_i(opcode_valid_i & ~r_pc_fetch),`
241			`.opcode_i({2'b00,opcode_i[31:26]}),`
242
243			`// Load / Store pending`
244			`.load_pending_i(r_mem_load),`
245			`.store_pending_i(r_mem_store),`
246
247			`// Load dest register`
248			`.rd_load_i(r_load_rd),`
249
250			`// Load insn in WB stage`
251			`.load_wb_i(d_mem_load),`
252
253			`// Memory status`
254			`.mem_access_i(r_mem_access),`
255			`.mem_ack_i(dmem_ack_i),`
256
257			`// Load / store still pending`
258			`.load_pending_o(load_pending),`
259			`.store_pending_o(store_pending),`
260
261			`// Insert load result into pipeline`
262			`.write_result_o(load_insert),`
263
264			`// Stall pipeline due`
265			`.stall_o(load_stall)`
266			`);`
267
268			`// Operand forwarding`
269			`altor32_dfu`
270			`u_dfu`
271			`(`
272			`// Input registers`
273			`.ra_i(reg_ra_i),`
274			`.rb_i(reg_rb_i),`
275
276			`// Input register contents`
277			`.ra_regval_i(reg_ra_value_i),`
278			`.rb_regval_i(reg_rb_value_i),`
279
280			`// Dest register (EXEC stage)`
281			`.rd_ex_i(r_e_rd),`
282
283			`// Dest register (WB stage)`
284			`.rd_wb_i(wb_rd_i),`
285
286			`// Load pending / target`
287			`.load_pending_i(load_pending),`
288			`.rd_load_i(r_load_rd),`
289
290			`// Multiplier status`
291			`.mult_lo_ex_i(1'b0),`
292			`.mult_hi_ex_i(1'b0),`
293			`.mult_lo_wb_i(1'b0),`
294			`.mult_hi_wb_i(1'b0),`
295
296			`// Multiplier result`
297			`.result_mult_i(64'b0),`
298
299			`// Result (EXEC)`
300			`.result_ex_i(r_e_result),`
301
302			`// Result (WB)`
303			`.result_wb_i(wb_rd_value_i),`
304
305			`// Resolved register values`
306			`.result_ra_o(ra_value_resolved),`
307			`.result_rb_o(rb_value_resolved),`
308
309			`// Stall due to failed resolve`
310			`.stall_o(resolve_failed)`
311			`);`
312
313	31	ultra_embe	`//-----------------------------------------------------------------`
314			`// Opcode decode`
315			`//-----------------------------------------------------------------`
316			`reg [7:0] inst_r;`
317			`reg [7:0] alu_op_r;`
318			`reg [1:0] shift_op_r;`
319			`reg [15:0] sfxx_op_r;`
320			`reg [15:0] uint16_r;`
321			`reg [31:0] uint32_r;`
322			`reg [31:0] int32_r;`
323			`reg [31:0] store_int32_r;`
324			`reg [15:0] mxspr_uint16_r;`
325			`reg [31:0] target_int26_r;`
326			`reg [31:0] reg_ra_r;`
327			`reg [31:0] reg_rb_r;`
328			`reg [31:0] shift_rb_r;`
329			`reg [31:0] shift_imm_r;`
330	27	ultra_embe
331	31	ultra_embe	`always @ *`
332	27	ultra_embe	`begin`
333	31	ultra_embe	`// Instruction`
334			`inst_r = {2'b00,opcode_i[31:26]};`
335	27	ultra_embe
336	31	ultra_embe	`// Sub instructions`
337			`alu_op_r = {opcode_i[9:6],opcode_i[3:0]};`
338			`sfxx_op_r = {5'b00,opcode_i[31:21]};`
339			`shift_op_r = opcode_i[7:6];`
340	27	ultra_embe
341	31	ultra_embe	`// Branch target`
342			`target_int26_r = sign_extend_imm26(opcode_i[25:0]);`
343	27	ultra_embe
344	31	ultra_embe	`// Store immediate`
345			`store_int32_r = sign_extend_imm16({opcode_i[25:21],opcode_i[10:0]});`
346	27	ultra_embe
347	31	ultra_embe	`// Signed & unsigned imm -> 32-bits`
348			`uint16_r = opcode_i[15:0];`
349			`int32_r = sign_extend_imm16(opcode_i[15:0]);`
350			`uint32_r = extend_imm16(opcode_i[15:0]);`
351	27	ultra_embe
352	31	ultra_embe	`// Register values [ra/rb]`
353			`reg_ra_r = ra_value_resolved;`
354			`reg_rb_r = rb_value_resolved;`
355	27	ultra_embe
356	31	ultra_embe	`// Shift ammount (from register[rb])`
357			`shift_rb_r = {26'b00,rb_value_resolved[5:0]};`
358	27	ultra_embe
359	31	ultra_embe	`// Shift ammount (from immediate)`
360			`shift_imm_r = {26'b00,opcode_i[5:0]};`
361	27	ultra_embe
362	31	ultra_embe	`// MTSPR/MFSPR operand`
363			`mxspr_uint16_r = (ra_value_resolved[15:0] \| {5'b00000,opcode_i[10:0]});`
364			`end`
365	27	ultra_embe
366	31	ultra_embe	`//-----------------------------------------------------------------`
367			`// Instruction Decode`
368			`//-----------------------------------------------------------------`
369			wire inst_add_w = (inst_r == `INST_OR32_ALU) & (alu_op_r == `INST_OR32_ADD); // l.add
370			wire inst_addc_w = (inst_r == `INST_OR32_ALU) & (alu_op_r == `INST_OR32_ADDC); // l.addc
371			wire inst_and_w = (inst_r == `INST_OR32_ALU) & (alu_op_r == `INST_OR32_AND); // l.and
372			wire inst_or_w = (inst_r == `INST_OR32_ALU) & (alu_op_r == `INST_OR32_OR); // l.or
373			wire inst_sll_w = (inst_r == `INST_OR32_ALU) & (alu_op_r == `INST_OR32_SLL); // l.sll
374			wire inst_sra_w = (inst_r == `INST_OR32_ALU) & (alu_op_r == `INST_OR32_SRA); // l.sra
375			wire inst_srl_w = (inst_r == `INST_OR32_ALU) & (alu_op_r == `INST_OR32_SRL); // l.srl
376			wire inst_sub_w = (inst_r == `INST_OR32_ALU) & (alu_op_r == `INST_OR32_SUB); // l.sub
377			wire inst_xor_w = (inst_r == `INST_OR32_ALU) & (alu_op_r == `INST_OR32_XOR); // l.xor
378	27	ultra_embe
379	31	ultra_embe	wire inst_addi_w = (inst_r == `INST_OR32_ADDI); // l.addi
380			wire inst_andi_w = (inst_r == `INST_OR32_ANDI); // l.andi
381			wire inst_bf_w = (inst_r == `INST_OR32_BF); // l.bf
382			wire inst_bnf_w = (inst_r == `INST_OR32_BNF); // l.bnf
383			wire inst_j_w = (inst_r == `INST_OR32_J); // l.j
384			wire inst_jal_w = (inst_r == `INST_OR32_JAL); // l.jal
385			wire inst_jalr_w = (inst_r == `INST_OR32_JALR); // l.jalr
386			wire inst_jr_w = (inst_r == `INST_OR32_JR); // l.jr
387			wire inst_lbs_w = (inst_r == `INST_OR32_LBS); // l.lbs
388			wire inst_lhs_w = (inst_r == `INST_OR32_LHS); // l.lhs
389			wire inst_lws_w = (inst_r == `INST_OR32_LWS); // l.lws
390			wire inst_lbz_w = (inst_r == `INST_OR32_LBZ); // l.lbz
391			wire inst_lhz_w = (inst_r == `INST_OR32_LHZ); // l.lhz
392			wire inst_lwz_w = (inst_r == `INST_OR32_LWZ); // l.lwz
393			wire inst_mfspr_w = (inst_r == `INST_OR32_MFSPR); // l.mfspr
394			wire inst_mtspr_w = (inst_r == `INST_OR32_MTSPR); // l.mtspr
395			wire inst_movhi_w = (inst_r == `INST_OR32_MOVHI); // l.movhi
396			wire inst_nop_w = (inst_r == `INST_OR32_NOP); // l.nop
397			wire inst_ori_w = (inst_r == `INST_OR32_ORI); // l.ori
398			wire inst_rfe_w = (inst_r == `INST_OR32_RFE); // l.rfe
399	27	ultra_embe
400	31	ultra_embe	wire inst_sb_w = (inst_r == `INST_OR32_SB); // l.sb
401			wire inst_sh_w = (inst_r == `INST_OR32_SH); // l.sh
402			wire inst_sw_w = (inst_r == `INST_OR32_SW); // l.sw
403	27	ultra_embe
404	31	ultra_embe	wire inst_slli_w = (inst_r == `INST_OR32_SHIFTI) & (shift_op_r == `INST_OR32_SLLI); // l.slli
405			wire inst_srai_w = (inst_r == `INST_OR32_SHIFTI) & (shift_op_r == `INST_OR32_SRAI); // l.srai
406			wire inst_srli_w = (inst_r == `INST_OR32_SHIFTI) & (shift_op_r == `INST_OR32_SRLI); // l.srli
407	27	ultra_embe
408	31	ultra_embe	wire inst_xori_w = (inst_r == `INST_OR32_XORI); // l.xori
409	27	ultra_embe
410	31	ultra_embe	wire inst_sfxx_w = (inst_r == `INST_OR32_SFXX);
411			wire inst_sfxxi_w = (inst_r == `INST_OR32_SFXXI);
412	27	ultra_embe
413	31	ultra_embe	wire inst_sfeq_w = (inst_r == `INST_OR32_SFXX) & (sfxx_op_r == `INST_OR32_SFEQ); // l.sfeq
414			wire inst_sfges_w = (inst_r == `INST_OR32_SFXX) & (sfxx_op_r == `INST_OR32_SFGES); // l.sfges
415	27	ultra_embe
416	31	ultra_embe	wire inst_sfgeu_w = (inst_r == `INST_OR32_SFXX) & (sfxx_op_r == `INST_OR32_SFGEU); // l.sfgeu
417			wire inst_sfgts_w = (inst_r == `INST_OR32_SFXX) & (sfxx_op_r == `INST_OR32_SFGTS); // l.sfgts
418			wire inst_sfgtu_w = (inst_r == `INST_OR32_SFXX) & (sfxx_op_r == `INST_OR32_SFGTU); // l.sfgtu
419			wire inst_sfles_w = (inst_r == `INST_OR32_SFXX) & (sfxx_op_r == `INST_OR32_SFLES); // l.sfles
420			wire inst_sfleu_w = (inst_r == `INST_OR32_SFXX) & (sfxx_op_r == `INST_OR32_SFLEU); // l.sfleu
421			wire inst_sflts_w = (inst_r == `INST_OR32_SFXX) & (sfxx_op_r == `INST_OR32_SFLTS); // l.sflts
422			wire inst_sfltu_w = (inst_r == `INST_OR32_SFXX) & (sfxx_op_r == `INST_OR32_SFLTU); // l.sfltu
423			wire inst_sfne_w = (inst_r == `INST_OR32_SFXX) & (sfxx_op_r == `INST_OR32_SFNE); // l.sfne
424	27	ultra_embe
425	31	ultra_embe	wire inst_sfeqi_w = (inst_r == `INST_OR32_SFXXI) & (sfxx_op_r == `INST_OR32_SFEQI); // l.sfeqi
426			wire inst_sfgesi_w = (inst_r == `INST_OR32_SFXXI) & (sfxx_op_r == `INST_OR32_SFGESI); // l.sfgesi
427			wire inst_sfgeui_w = (inst_r == `INST_OR32_SFXXI) & (sfxx_op_r == `INST_OR32_SFGEUI); // l.sfgeui
428			wire inst_sfgtsi_w = (inst_r == `INST_OR32_SFXXI) & (sfxx_op_r == `INST_OR32_SFGTSI); // l.sfgtsi
429			wire inst_sfgtui_w = (inst_r == `INST_OR32_SFXXI) & (sfxx_op_r == `INST_OR32_SFGTUI); // l.sfgtui
430			wire inst_sflesi_w = (inst_r == `INST_OR32_SFXXI) & (sfxx_op_r == `INST_OR32_SFLESI); // l.sflesi
431	27	ultra_embe
432	31	ultra_embe	wire inst_sfleui_w = (inst_r == `INST_OR32_SFXXI) & (sfxx_op_r == `INST_OR32_SFLEUI); // l.sfleui
433			wire inst_sfltsi_w = (inst_r == `INST_OR32_SFXXI) & (sfxx_op_r == `INST_OR32_SFLTSI); // l.sfltsi
434			wire inst_sfltui_w = (inst_r == `INST_OR32_SFXXI) & (sfxx_op_r == `INST_OR32_SFLTUI); // l.sfltui
435			wire inst_sfnei_w = (inst_r == `INST_OR32_SFXXI) & (sfxx_op_r == `INST_OR32_SFNEI); // l.sfnei
436	27	ultra_embe
437	31	ultra_embe	wire inst_sys_w = (inst_r == `INST_OR32_MISC) & (opcode_i[31:24] == `INST_OR32_SYS); // l.sys
438			wire inst_trap_w = (inst_r == `INST_OR32_MISC) & (opcode_i[31:24] == `INST_OR32_TRAP); // l.trap
439	27	ultra_embe
440	31	ultra_embe	`//-----------------------------------------------------------------`
441			`// Stall / Execute`
442			`//-----------------------------------------------------------------`
443			`reg execute_inst_r;`
444			`reg stall_inst_r;`
445	27	ultra_embe
446	31	ultra_embe	`always @ *`
447			`begin`
448			`execute_inst_r = 1'b1;`
449			`stall_inst_r = 1'b0;`
450	27	ultra_embe
451	31	ultra_embe	`// No opcode ready or branch delay slot`
452			`if (~opcode_valid_i \| r_pc_fetch)`
453			`execute_inst_r = 1'b0;`
454			`// Valid instruction, but load result / operand not ready`
455			`else if (resolve_failed \| load_stall)`
456			`stall_inst_r = 1'b1;`
457			`end`
458	27	ultra_embe
459	31	ultra_embe	`//-----------------------------------------------------------------`
460			`// Next PC`
461			`//-----------------------------------------------------------------`
462			`reg [31:0] next_pc_r;`
463	27	ultra_embe
464	31	ultra_embe	`always @ *`
465			`begin`
466			`// Next expected PC (current PC + 4)`
467			`next_pc_r = (opcode_pc_i + 4);`
468			`end`
469	27	ultra_embe
470	31	ultra_embe	`//-----------------------------------------------------------------`
471			`// Next SR`
472			`//-----------------------------------------------------------------`
473			`reg [31:0] next_sr_r;`
474			`reg compare_result_r;`
475			`always @ *`
476			`begin`
477			`next_sr_r = r_sr;`
478	27	ultra_embe
479	31	ultra_embe	`// Latch carry if updated`
480			`if (alu_carry_update)`
481			next_sr_r[`OR32_SR_CY] = alu_carry_out;
482	27	ultra_embe
483	31	ultra_embe	`// If valid instruction, check if SR needs updating`
484			`if (execute_inst_r & ~stall_inst_r)`
485			`begin`
486			`case (1'b1)`
487			`inst_mtspr_w:`
488			`begin`
489			`case (mxspr_uint16_r)`
490			`// SR - Supervision register`
491			`SPR_REG_SR:
492			`begin`
493			`next_sr_r = reg_rb_r;`
494	27	ultra_embe
495	31	ultra_embe	`// Don't store cache flush requests`
496			next_sr_r[`OR32_SR_ICACHE_FLUSH] = 1'b0;
497			next_sr_r[`OR32_SR_DCACHE_FLUSH] = 1'b0;
498			`end`
499			`default:`
500			`;`

Browse

Tools

Subversion Repositories altor32

[/] [altor32/] [trunk/] [rtl/] [cpu/] [altor32_exec.v] - Blame information for rev 32