URL https://opencores.org/ocsvn/next186_soc_pc/next186_soc_pc/trunk

Subversion Repositories next186_soc_pc

[/] [next186_soc_pc/] [trunk/] [SW/] [bootload_BIOS_SD/] [bootstrap.asm] - Blame information for rev 3

Details | Compare with Previous | View Log


; This file is part of the Next186 SoC PC project
; http://opencores.org/project,next186
 
; Filename: bootstrap.asm
; Description: Part of the Next186 SoC PC project, bootstrap "ROM" code (RAM initialized with cache)
; Version 1.0
; Creation date: Jun2013
 
; Author: Nicolae Dumitrache
; e-mail: ndumitrache@opencores.org
 
; -------------------------------------------------------------------------------------
 
; Copyright (C) 2013 Nicolae Dumitrache
 
; This source file may be used and distributed without
; restriction provided that this copyright statement is not
; removed from the file and that any derivative work contains
; the original copyright notice and the associated disclaimer.
 
; This source file is free software; you can redistribute it
; and/or modify it under the terms of the GNU Lesser General
; Public License as published by the Free Software Foundation;
; either version 2.1 of the License, or (at your option) any
; later version.
 
; This source is distributed in the hope that it will be
; useful, but WITHOUT ANY WARRANTY; without even the implied
; warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR
; PURPOSE. See the GNU Lesser General Public License for more
; details.
 
; You should have received a copy of the GNU Lesser General
; Public License along with this source; if not, download it
; from http://www.opencores.org/lgpl.shtml
 
; -----------------------------------------------------------------------
 
; Additional Comments:
; Assembled with MASM v6.14.8444
; No hardware resources are required for the bootstrap ROM, I use only the initial value of the cache memory
; BIOS will be read from the last BIOSSIZE sectors of SD Card and placed in DRAM at F000:(-BIOSSIZE*512)
; SD HC card required
 
 
 
.186
.model tiny
.code
 
 
BIOSSIZE    EQU     16      ; sectors
BOOTOFFSET  EQU     0fc00h  ; bootstrap code offset in segment 0f000h
 
; this code is for bootstrap deployment only, it will not be present in ROM (cache)
;---------------- EXECUTE -----------------
                org             100h        ; this code is loaded at 0f000h:100h
exec    label near
 
                mov             si, begin
                mov             di, BOOTOFFSET
                mov             cx, 256*4/2 ; last 4 cache lines (from total 8)
                rep             movsw
                db              0eah
                dw              0, -1       ; CPU reset, execute bootstrap
 
 
; Loads BIOS (8K = 16 sectors) from last sectors of SD card (if present)
; If no SD card detected, wait on RS232 115200bps and load program at F000:100h
; the following code is placed in the last 1kB of cache (last 4 lines), each with the dirty bit set
; the corresponding position in RAM will be F000:BOOTOFFSET
; ----------------- RS232 bootstrap - last 256byte cache line ---------------
        org     200h
begin label far               ; this code is placed at F000:BOOTOFFSET
 
                cli
                cld
                mov             ax, cs        ; cs = 0f000h
                mov             ds, ax
                mov             es, ax
                mov             ss, ax
                mov             sp, BOOTOFFSET
                xor             ax, ax        ; map seg0
                out             80h, ax
                mov             al, 0bh       ; map text segB
                out             8bh, ax
                mov             al, 0fh       ; map ROM segF
                out             8fh, ax
                mov             al, 34h
                out             43h, al
                xor             al, al
                out             40h, al
                out             40h, al       ; program PIT for RS232
 
                call            sdinit_
                test            ax, ax
                jz              short RS232
                mov             dx, ax
                shr             dx, 6
                shl             ax, 10
                mov             cx, BIOSSIZE       ;  sectors
                sub             ax, cx
                sbb             dx, 0
                xor             bx, bx       ; read BIOSSIZE/2 KB BIOS at 0f000h:0h
nextsect:
                push            ax
                push            dx
                push            cx
                call            sdread_
                dec             cx
                pop             cx
                pop             dx
                pop             ax
                jnz             short RS232  ; cx was not 1
                add             ax, 1
                adc             dx, 0
                add             bx, 512
                loop            nextsect
                cmp             word ptr ds:[0], 'eN'
                jne             short RS232
                cmp             word ptr ds:[2], 'tx'
                je              short   BIOSOK
 
RS232:
                mov             dx, 3c0h
                mov             al, 10h
                out             dx, al
                mov             al, 8h
                out             dx, al      ; set text mode
                mov             dx, 3d4h
                mov             al, 0ah
                out             dx, al
                inc             dx
                mov             al, 1 shl 5 ; hide cursor
                out             dx, al
                dec             dx
                mov             al, 0ch
                out             dx, al
                inc             dx
                mov             al, 0
                out             dx, al
                dec             dx
                mov             al, 0dh
                out             dx, al
                inc             dx
                mov             al, 0
                out             dx, al      ; reset video offset
 
                push            0b800h      ; clear screen
                pop             es
                xor             di, di
                mov             cx, 25*80
                xor             ax, ax
                rep             stosw
 
                mov             dx, 3c8h    ; set palette entry 1
                mov             ax, 101h
                out             dx, al
                inc             dx
                mov             al, 2ah
                out             dx, al
                out             dx, al
                out             dx, al
 
                xor             di, di
                mov             si, booterrmsg + BOOTOFFSET - begin
                lodsb
nextchar:
                stosw
                lodsb
                test            al, al
                jnz             short nextchar
 
                mov             bh, 8
flush:
                mov             al, [bx]
                dec             bh
                jnz             flush
 
                mov             si, 100h
                call            srecb
                mov             bh, ah
                call            srecb
                mov             bl, ah
 
sloop:
                call            srecb
                mov             [si], ah
                inc             si
                dec             bx
                jnz             sloop
                xor             sp, sp
                mov             ss, sp
                db              0eah
                dw              100h,0f000h ; execute loaded program
 
BIOSOK:
                mov             si, reloc + BOOTOFFSET - begin
                mov             di, bx
                mov             cx, endreloc - reloc
                rep             movsb       ; relocate code from reloc to endreloc after loaded BIOS
                mov             di, -BIOSSIZE*512
                xor             si, si
                mov             cx, BIOSSIZE*512/2
                jmp             bx
reloc:
                rep             movsw
                db              0eah
                dw              0, -1       ; CPU reset, execute BIOS
endreloc:
 
 
; ----------------  serial receive byte 115200 bps --------------
srecb:
                mov             ah, 80h
                mov             dx, 3dah
                mov             cx, -5aeh ; (half start bit)
srstb:
                in              al, dx
                shr             al, 2
                jc              srstb
 
                in              al, 40h ; lo counter
                add             ch, al
                in              al, 40h ; hi counter, ignore
l1:
                call            dlybit
                in              al, dx
                shr             al, 2
                rcr             ah, 1
                jnc             l1
dlybit:
                sub             cx, 0a5bh  ;  (full bit)
dly1:
                in              al, 40h
                cmp             al, ch
                in              al, 40h
                jnz             dly1
                ret
 
;---------------------  read/write byte ----------------------
sdrb:
                mov             al, 0ffh
sdsb:               ; in AL=byte, DX = 03dah, out AX=result
                mov             ah, 1
sdsb1:
                out             dx, al
                add             ax, ax
                jnc             sdsb1
                in              ax, dx
                ret
 
;---------------------  write block ----------------------
sdwblk:              ; in DS:SI=data ptr, DX=03dah, CX=size
                lodsb
                call            sdsb
                loop            sdwblk
                ret
 
;---------------------  read block ----------------------
sdrblk:              ; in DS:DI=data ptr, DX=03dah, CX=size
                call            sdrb
                mov             [di], ah
                inc             di
                loop            sdrblk
                ret
 
;---------------------  write command ----------------------
sdcmd8T:
                call    sdrb
sdcmd:              ; in DS:SI=6 bytes cmd buffer, DX=03dah, out AH = 0ffh on error
                mov             cx, 6
                call            sdwblk
sdresp:
                xor             si, si
sdresp1:
                call            sdrb
                inc             si
                jz              sdcmd1
                cmp             ah, 0ffh
                je              sdresp1
sdcmd1:
                ret
 
;---------------------  read one sector ----------------------
sdread_ proc near   ; DX:AX sector, DS:BX buffer, returns CX=read sectors
                push            ax
                mov             al, dl
                push            ax
                mov             dl, 51h     ; CMD17
                push            dx
                mov             si, sp
 
                mov             dx, 3dah
                mov             ah, 1
                out             dx, ax      ; CS on
                call            sdcmd
                add             sp, 6
                or              ah, ah
                jnz             sdr1        ; error (cx=0)
                call            sdresp      ; wait for 0feh token
                cmp             ah, 0feh
                jne             sdr1        ; read token error (cx=0)
                mov             ch, 2       ; 512 bytes
                mov             di, bx
                call            sdrblk
                call            sdrb        ; ignore CRC
                call            sdrb        ; ignore CRC
                inc             cx          ; 1 block
 sdr1:
                xor             ax, ax
                out             dx, ax
                call            sdrb        ; 8T
                ret
sdread_ endp
 
;---------------------  init SD ----------------------
sdinit_ proc near       ; returns AX = num kilosectors
                mov             dx, 3dah
                mov             cx, 10
sdinit1:                   ; send 80T
                call            sdrb
                loop            sdinit1
 
                mov             ah, 1
                out             dx, ax       ; select SD
 
                mov             si, SD_CMD0 + BOOTOFFSET - begin
                call            sdcmd
                dec             ah
                jnz             sdexit      ; error
 
                mov             si, SD_CMD8 + BOOTOFFSET - begin
                call            sdcmd8T
                dec             ah
                jnz             sdexit      ; error
                mov             cl, 4
                sub             sp, cx
                mov             di, sp
                call            sdrblk
                pop             ax
                pop             ax
                cmp             ah, 0aah
                jne             sdexit      ; CMD8 error
repinit:
                mov             si, SD_CMD55 + BOOTOFFSET - begin
                call            sdcmd8T
                call            sdrb
                mov             si, SD_CMD41 + BOOTOFFSET - begin
                call            sdcmd
                dec             ah
                jz              repinit
 
                mov             si, SD_CMD58 + BOOTOFFSET - begin
                call            sdcmd8T
                mov             cl, 4
                sub             sp, cx
                mov             di, sp
                call            sdrblk
                pop             ax
                test            al, 40h     ; test OCR bit 30 (CCS)
                pop             ax
                jz              sdexit      ; no SDHC
 
                mov             si, SD_CMD9 + BOOTOFFSET - begin ; get size info
                call            sdcmd8T
                or              ah, ah
                jnz             sdexit
                call            sdresp      ; wait for 0feh token
                cmp             ah, 0feh
                jne             sdexit
                mov             cl, 18      ; 16bytes + 2bytes CRC
                sub             sp, cx
                mov             di, sp
                call            sdrblk
                mov             cx, [di-10]
                xchg            cl, ch
                inc             cx
                mov             sp, di
sdexit:
                xor             ax, ax      ; raise CS
                out             dx, ax
                call    sdrb
                mov             ax, cx
                ret
sdinit_ endp
 
 
booterrmsg  db  'BIOS not present on SDCard last 8KB, waiting on RS232 (115200bps, f000:100) ...', 0
SD_CMD0         db              40h, 0, 0, 0, 0, 95h
SD_CMD8         db              48h, 0, 0, 1, 0aah, 087h
SD_CMD9         db              49h, 0, 0, 0, 0, 0ffh
SD_CMD41        db              69h, 40h, 0, 0, 0, 0ffh
SD_CMD55        db              77h, 0, 0, 0, 0, 0ffh
SD_CMD58        db              7ah, 0, 0, 0, 0, 0ffh
 
 
; ---------------- RESET ------------------
                org 05f0h
start:
                db              0eah
                dw              BOOTOFFSET, 0f000h
                db              0,0,0,0,0,0,0,0,0,0,0
 
end exec

Browse

Tools

Subversion Repositories next186_soc_pc

[/] [next186_soc_pc/] [trunk/] [SW/] [bootload_BIOS_SD/] [bootstrap.asm] - Blame information for rev 3

Line No.	Rev	Author	Line
1	3	ndumitrach	`; This file is part of the Next186 SoC PC project`
2			`; http://opencores.org/project,next186`
3
4			`; Filename: bootstrap.asm`
5			`; Description: Part of the Next186 SoC PC project, bootstrap "ROM" code (RAM initialized with cache)`
6			`; Version 1.0`
7			`; Creation date: Jun2013`
8
9			`; Author: Nicolae Dumitrache`
10			`; e-mail: ndumitrache@opencores.org`
11
12			`; -------------------------------------------------------------------------------------`
13
14			`; Copyright (C) 2013 Nicolae Dumitrache`
15
16			`; This source file may be used and distributed without`
17			`; restriction provided that this copyright statement is not`
18			`; removed from the file and that any derivative work contains`
19			`; the original copyright notice and the associated disclaimer.`
20
21			`; This source file is free software; you can redistribute it`
22			`; and/or modify it under the terms of the GNU Lesser General`
23			`; Public License as published by the Free Software Foundation;`
24			`; either version 2.1 of the License, or (at your option) any`
25			`; later version.`
26
27			`; This source is distributed in the hope that it will be`
28			`; useful, but WITHOUT ANY WARRANTY; without even the implied`
29			`; warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR`
30			`; PURPOSE. See the GNU Lesser General Public License for more`
31			`; details.`
32
33			`; You should have received a copy of the GNU Lesser General`
34			`; Public License along with this source; if not, download it`
35			`; from http://www.opencores.org/lgpl.shtml`
36
37			`; -----------------------------------------------------------------------`
38
39			`; Additional Comments:`
40			`; Assembled with MASM v6.14.8444`
41			`; No hardware resources are required for the bootstrap ROM, I use only the initial value of the cache memory`
42			`; BIOS will be read from the last BIOSSIZE sectors of SD Card and placed in DRAM at F000:(-BIOSSIZE*512)`
43			`; SD HC card required`
44
45
46
47			`.186`
48			`.model tiny`
49			`.code`
50
51
52			`BIOSSIZE EQU 16 ; sectors`
53			`BOOTOFFSET EQU 0fc00h ; bootstrap code offset in segment 0f000h`
54
55			`; this code is for bootstrap deployment only, it will not be present in ROM (cache)`
56			`;---------------- EXECUTE -----------------`
57			`org 100h ; this code is loaded at 0f000h:100h`
58			`exec label near`
59
60			`mov si, begin`
61			`mov di, BOOTOFFSET`
62			`mov cx, 256*4/2 ; last 4 cache lines (from total 8)`
63			`rep movsw`
64			`db 0eah`
65			`dw 0, -1 ; CPU reset, execute bootstrap`
66
67
68			`; Loads BIOS (8K = 16 sectors) from last sectors of SD card (if present)`
69			`; If no SD card detected, wait on RS232 115200bps and load program at F000:100h`
70			`; the following code is placed in the last 1kB of cache (last 4 lines), each with the dirty bit set`
71			`; the corresponding position in RAM will be F000:BOOTOFFSET`
72			`; ----------------- RS232 bootstrap - last 256byte cache line ---------------`
73			`org 200h`
74			`begin label far ; this code is placed at F000:BOOTOFFSET`
75
76			`cli`
77			`cld`
78			`mov ax, cs ; cs = 0f000h`
79			`mov ds, ax`
80			`mov es, ax`
81			`mov ss, ax`
82			`mov sp, BOOTOFFSET`
83			`xor ax, ax ; map seg0`
84			`out 80h, ax`
85			`mov al, 0bh ; map text segB`
86			`out 8bh, ax`
87			`mov al, 0fh ; map ROM segF`
88			`out 8fh, ax`
89			`mov al, 34h`
90			`out 43h, al`
91			`xor al, al`
92			`out 40h, al`
93			`out 40h, al ; program PIT for RS232`
94
95			`call sdinit_`
96			`test ax, ax`
97			`jz short RS232`
98			`mov dx, ax`
99			`shr dx, 6`
100			`shl ax, 10`
101			`mov cx, BIOSSIZE ; sectors`
102			`sub ax, cx`
103			`sbb dx, 0`
104			`xor bx, bx ; read BIOSSIZE/2 KB BIOS at 0f000h:0h`
105			`nextsect:`
106			`push ax`
107			`push dx`
108			`push cx`
109			`call sdread_`
110			`dec cx`
111			`pop cx`
112			`pop dx`
113			`pop ax`
114			`jnz short RS232 ; cx was not 1`
115			`add ax, 1`
116			`adc dx, 0`
117			`add bx, 512`
118			`loop nextsect`
119			`cmp word ptr ds:[0], 'eN'`
120			`jne short RS232`
121			`cmp word ptr ds:[2], 'tx'`
122			`je short BIOSOK`
123
124			`RS232:`
125			`mov dx, 3c0h`
126			`mov al, 10h`
127			`out dx, al`
128			`mov al, 8h`
129			`out dx, al ; set text mode`
130			`mov dx, 3d4h`
131			`mov al, 0ah`
132			`out dx, al`
133			`inc dx`
134			`mov al, 1 shl 5 ; hide cursor`
135			`out dx, al`
136			`dec dx`
137			`mov al, 0ch`
138			`out dx, al`
139			`inc dx`
140			`mov al, 0`
141			`out dx, al`
142			`dec dx`
143			`mov al, 0dh`
144			`out dx, al`
145			`inc dx`
146			`mov al, 0`
147			`out dx, al ; reset video offset`
148
149			`push 0b800h ; clear screen`
150			`pop es`
151			`xor di, di`
152			`mov cx, 25*80`
153			`xor ax, ax`
154			`rep stosw`
155
156			`mov dx, 3c8h ; set palette entry 1`
157			`mov ax, 101h`
158			`out dx, al`
159			`inc dx`
160			`mov al, 2ah`
161			`out dx, al`
162			`out dx, al`
163			`out dx, al`
164
165			`xor di, di`
166			`mov si, booterrmsg + BOOTOFFSET - begin`
167			`lodsb`
168			`nextchar:`
169			`stosw`
170			`lodsb`
171			`test al, al`
172			`jnz short nextchar`
173
174			`mov bh, 8`
175			`flush:`
176			`mov al, [bx]`
177			`dec bh`
178			`jnz flush`
179
180			`mov si, 100h`
181			`call srecb`
182			`mov bh, ah`
183			`call srecb`
184			`mov bl, ah`
185
186			`sloop:`
187			`call srecb`
188			`mov [si], ah`
189			`inc si`
190			`dec bx`
191			`jnz sloop`
192			`xor sp, sp`
193			`mov ss, sp`
194			`db 0eah`
195			`dw 100h,0f000h ; execute loaded program`
196
197			`BIOSOK:`
198			`mov si, reloc + BOOTOFFSET - begin`
199			`mov di, bx`
200			`mov cx, endreloc - reloc`
201			`rep movsb ; relocate code from reloc to endreloc after loaded BIOS`
202			`mov di, -BIOSSIZE*512`
203			`xor si, si`
204			`mov cx, BIOSSIZE*512/2`
205			`jmp bx`
206			`reloc:`
207			`rep movsw`
208			`db 0eah`
209			`dw 0, -1 ; CPU reset, execute BIOS`
210			`endreloc:`
211
212
213			`; ---------------- serial receive byte 115200 bps --------------`
214			`srecb:`
215			`mov ah, 80h`
216			`mov dx, 3dah`
217			`mov cx, -5aeh ; (half start bit)`
218			`srstb:`
219			`in al, dx`
220			`shr al, 2`
221			`jc srstb`
222
223			`in al, 40h ; lo counter`
224			`add ch, al`
225			`in al, 40h ; hi counter, ignore`
226			`l1:`
227			`call dlybit`
228			`in al, dx`
229			`shr al, 2`
230			`rcr ah, 1`
231			`jnc l1`
232			`dlybit:`
233			`sub cx, 0a5bh ; (full bit)`
234			`dly1:`
235			`in al, 40h`
236			`cmp al, ch`
237			`in al, 40h`
238			`jnz dly1`
239			`ret`
240
241			`;--------------------- read/write byte ----------------------`
242			`sdrb:`
243			`mov al, 0ffh`
244			`sdsb: ; in AL=byte, DX = 03dah, out AX=result`
245			`mov ah, 1`
246			`sdsb1:`
247			`out dx, al`
248			`add ax, ax`
249			`jnc sdsb1`
250			`in ax, dx`
251			`ret`
252
253			`;--------------------- write block ----------------------`
254			`sdwblk: ; in DS:SI=data ptr, DX=03dah, CX=size`
255			`lodsb`
256			`call sdsb`
257			`loop sdwblk`
258			`ret`
259
260			`;--------------------- read block ----------------------`
261			`sdrblk: ; in DS:DI=data ptr, DX=03dah, CX=size`
262			`call sdrb`
263			`mov [di], ah`
264			`inc di`
265			`loop sdrblk`
266			`ret`
267
268			`;--------------------- write command ----------------------`
269			`sdcmd8T:`
270			`call sdrb`
271			`sdcmd: ; in DS:SI=6 bytes cmd buffer, DX=03dah, out AH = 0ffh on error`
272			`mov cx, 6`
273			`call sdwblk`
274			`sdresp:`
275			`xor si, si`
276			`sdresp1:`
277			`call sdrb`
278			`inc si`
279			`jz sdcmd1`
280			`cmp ah, 0ffh`
281			`je sdresp1`
282			`sdcmd1:`
283			`ret`
284
285			`;--------------------- read one sector ----------------------`
286			`sdread_ proc near ; DX:AX sector, DS:BX buffer, returns CX=read sectors`
287			`push ax`
288			`mov al, dl`
289			`push ax`
290			`mov dl, 51h ; CMD17`
291			`push dx`
292			`mov si, sp`
293
294			`mov dx, 3dah`
295			`mov ah, 1`
296			`out dx, ax ; CS on`
297			`call sdcmd`
298			`add sp, 6`
299			`or ah, ah`
300			`jnz sdr1 ; error (cx=0)`
301			`call sdresp ; wait for 0feh token`
302			`cmp ah, 0feh`
303			`jne sdr1 ; read token error (cx=0)`
304			`mov ch, 2 ; 512 bytes`
305			`mov di, bx`
306			`call sdrblk`
307			`call sdrb ; ignore CRC`
308			`call sdrb ; ignore CRC`
309			`inc cx ; 1 block`
310			`sdr1:`
311			`xor ax, ax`
312			`out dx, ax`
313			`call sdrb ; 8T`
314			`ret`
315			`sdread_ endp`
316
317			`;--------------------- init SD ----------------------`
318			`sdinit_ proc near ; returns AX = num kilosectors`
319			`mov dx, 3dah`
320			`mov cx, 10`
321			`sdinit1: ; send 80T`
322			`call sdrb`
323			`loop sdinit1`
324
325			`mov ah, 1`
326			`out dx, ax ; select SD`
327
328			`mov si, SD_CMD0 + BOOTOFFSET - begin`
329			`call sdcmd`
330			`dec ah`
331			`jnz sdexit ; error`
332
333			`mov si, SD_CMD8 + BOOTOFFSET - begin`
334			`call sdcmd8T`
335			`dec ah`
336			`jnz sdexit ; error`
337			`mov cl, 4`
338			`sub sp, cx`
339			`mov di, sp`
340			`call sdrblk`
341			`pop ax`
342			`pop ax`
343			`cmp ah, 0aah`
344			`jne sdexit ; CMD8 error`
345			`repinit:`
346			`mov si, SD_CMD55 + BOOTOFFSET - begin`
347			`call sdcmd8T`
348			`call sdrb`
349			`mov si, SD_CMD41 + BOOTOFFSET - begin`
350			`call sdcmd`
351			`dec ah`
352			`jz repinit`
353
354			`mov si, SD_CMD58 + BOOTOFFSET - begin`
355			`call sdcmd8T`
356			`mov cl, 4`
357			`sub sp, cx`
358			`mov di, sp`
359			`call sdrblk`
360			`pop ax`
361			`test al, 40h ; test OCR bit 30 (CCS)`
362			`pop ax`
363			`jz sdexit ; no SDHC`
364
365			`mov si, SD_CMD9 + BOOTOFFSET - begin ; get size info`
366			`call sdcmd8T`
367			`or ah, ah`
368			`jnz sdexit`
369			`call sdresp ; wait for 0feh token`
370			`cmp ah, 0feh`
371			`jne sdexit`
372			`mov cl, 18 ; 16bytes + 2bytes CRC`
373			`sub sp, cx`
374			`mov di, sp`
375			`call sdrblk`
376			`mov cx, [di-10]`
377			`xchg cl, ch`
378			`inc cx`
379			`mov sp, di`
380			`sdexit:`
381			`xor ax, ax ; raise CS`
382			`out dx, ax`
383			`call sdrb`
384			`mov ax, cx`
385			`ret`
386			`sdinit_ endp`
387
388
389			`booterrmsg db 'BIOS not present on SDCard last 8KB, waiting on RS232 (115200bps, f000:100) ...', 0`
390			`SD_CMD0 db 40h, 0, 0, 0, 0, 95h`
391			`SD_CMD8 db 48h, 0, 0, 1, 0aah, 087h`
392			`SD_CMD9 db 49h, 0, 0, 0, 0, 0ffh`
393			`SD_CMD41 db 69h, 40h, 0, 0, 0, 0ffh`
394			`SD_CMD55 db 77h, 0, 0, 0, 0, 0ffh`
395			`SD_CMD58 db 7ah, 0, 0, 0, 0, 0ffh`
396
397
398			`; ---------------- RESET ------------------`
399			`org 05f0h`
400			`start:`
401			`db 0eah`
402			`dw BOOTOFFSET, 0f000h`
403			`db 0,0,0,0,0,0,0,0,0,0,0`
404
405			`end exec`