URL https://opencores.org/ocsvn/ao486/ao486/trunk

Subversion Repositories ao486

[/] [ao486/] [trunk/] [syn/] [components/] [ps2/] [software/] [exe_bsp/] [HAL/] [src/] [alt_mcount.S] - Blame information for rev 2

Details | Compare with Previous | View Log


/******************************************************************************
*                                                                             *
* License Agreement                                                           *
*                                                                             *
* Copyright (c) 2003-2010 Altera Corporation, San Jose, California, USA.      *
* All rights reserved.                                                        *
*                                                                             *
* Permission is hereby granted, free of charge, to any person obtaining a     *
* copy of this software and associated documentation files (the "Software"),  *
* to deal in the Software without restriction, including without limitation   *
* the rights to use, copy, modify, merge, publish, distribute, sublicense,    *
* and/or sell copies of the Software, and to permit persons to whom the       *
* Software is furnished to do so, subject to the following conditions:        *
*                                                                             *
* The above copyright notice and this permission notice shall be included in  *
* all copies or substantial portions of the Software.                         *
*                                                                             *
* THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR  *
* IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,    *
* FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE *
* AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER      *
* LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING     *
* FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER         *
* DEALINGS IN THE SOFTWARE.                                                   *
*                                                                             *
* This agreement shall be governed in all respects by the laws of the State   *
* of California and by the laws of the United States of America.              *
*                                                                             *
******************************************************************************/
 
/*  mcount or _mcount is inserted by GCC before the function prologue of every
 *  function when a program is compiled for profiling. At the start of mcount,
 *  we guarantee that:
 *  ra = self_pc (an address in the function which called mcount)
 *  r8 = from_pc (an address in the function which called mcount's caller)
 *
 *  Because this is always called at the start of a function we can corrupt
 *  r2,r3 and r11-r15.  We must not corrupt r4-r7 (because they might contain
 *  function arguments for the instrumented function) or r8 (which holds ra
 *  for the instrumented function).
 */
 
        .global __mcount_fn_head
 
        .global mcount
 
        /* _mcount is used by gcc4 */
        .global _mcount
 
_mcount:
mcount:
        /* Use a hash to speed up locating fn_entry.  We use bits 5 upwards to choose
         * the bucket because bits 1:0 will always be 0, and because the distribution
         * of values for bits 4:2 won't be even (aligning on cache line boundaries
         * will skew it).  Higher bits should be fairly random.
         */
        /* fn_head = mcount_fn_head + (((unsigned int)self_pc >> 5) & (HASH_BUCKETS - 1)); */
 
        srli    r2, ra, 3
        movhi   r3, %hiadj(__mcount_fn_head)
        addi    r3, r3, %lo(__mcount_fn_head)
        andi    r2, r2, 0xFC
        add     r11, r2, r3
 
        /* The fast case is where we have already allocated a function arc, and so
         * also a function pointer.
         */
 
        /* First find the function being called (using self_pc) */
        mov     r10, r11
0:
        ldw     r10, 0(r10)
        beq     r10, zero, .Lnew_arc
        ldw     r2, 4(r10)
        bne     r2, ra, 0b
 
        /* Found a function entry for this PC. Now look for an arc with a matching
         * from_pc value. There will always be at least one arc. */
        ldw     r3, 8(r10)
0:
        ldw     r2, 4(r3)
        beq     r2, r8, .Lfound_arc
        ldw     r3, 0(r3)
        bne     r3, zero, 0b
 
.Lnew_arc:
        addi    sp, sp, -24
 
.LCFI0:
        stw     ra, 0(sp)
        stw     r4, 4(sp)
        stw     r5, 8(sp)
        stw     r6, 12(sp)
        stw     r7, 16(sp)
        stw     r8, 20(sp)
 
.LCFI1:
        /* __mcount_record(orig_ra, orig_r8, fn_entry, *fn_head); */
        mov     r4, ra
        mov     r5, r8
        mov     r6, r10
        mov     r7, r11
        call     __mcount_record
 
        /* restore registers from the stack */
        ldw     ra, 0(sp)
        ldw     r4, 4(sp)
        ldw     r5, 8(sp)
        ldw     r6, 12(sp)
        ldw     r7, 16(sp)
        ldw     r8, 20(sp)
 
        addi    sp, sp, 24
 
.LCFI2:
        ret
 
.Lfound_arc:
        /* We've found the correct arc record.  Increment the count and return */
        ldw     r2, 8(r3)
        addi    r2, r2, 1
        stw     r2, 8(r3)
        ret
 
.Lmcount_end:
 
 
 
/*
 * Dwarf2 debug information for the function.  This provides GDB with the
 * information it needs to backtrace out of this function.
 */
 
        .section    .debug_frame,"",@progbits
.LCIE:
        .4byte   2f - 1f               /* Length */
1:
        .4byte   0xffffffff            /* CIE id */
        .byte    0x1                   /* Version */
        .string  ""                    /* Augmentation */
        .uleb128 0x1                   /* Code alignment factor */
        .sleb128 -4                    /* Data alignment factor */
        .byte    0x1f                  /* Return address register */
 
        .byte    0xc                   /* Define CFA */
        .uleb128 0x1b                  /*   Register 27 (sp) */
        .uleb128 0x0                   /*   Offset 0 */
 
        .align   2                     /* Padding */
2:
 
.LFDE_mcount:
        .4byte   2f - 1f               /* Length */
1:
        .4byte   .LCIE                 /* Pointer to CIE */
        .4byte   mcount                /* Start of table entry */
        .4byte   .Lmcount_end - mcount /* Size of table entry */
 
        .byte    0x4                   /* Advance location */
        .4byte   .LCFI0 - mcount       /*   to .LCFI0 */
        .byte    0xe                   /* Define CFA offset */
        .uleb128 24                    /*   to 24     */
 
        .byte    0x4                   /* Advance location */
        .4byte   .LCFI1 - .LCFI0       /*   to .LCFI1 */
        .byte    0x9f                  /* Store ra    */
        .uleb128 0x6                   /*   at CFA-24 */
        .byte    0x84                  /* Store r4    */
        .uleb128 0x5                   /*   at CFA-20 */
        .byte    0x85                  /* Store r5    */
        .uleb128 0x4                   /*   at CFA-16 */
        .byte    0x86                  /* Store r6    */
        .uleb128 0x3                   /*   at CFA-12 */
        .byte    0x87                  /* Store r7    */
        .uleb128 0x2                   /*   at CFA-8  */
        .byte    0x88                  /* Store r8    */
        .uleb128 0x1                   /*   at CFA-4  */
 
        .byte    0x4                   /* Advance location */
        .4byte   .LCFI2 - .LCFI1       /*   to .LCFI2 */
        .byte    0xe                   /* Define CFA offset */
        .uleb128 0                     /*   to 0      */
        .byte    0x8                   /* Same value  */
        .uleb128 31                    /*   for ra    */
        .byte    0x8                   /* Same value  */
        .uleb128 4                     /*   for r4    */
        .byte    0x8                   /* Same value  */
        .uleb128 5                     /*   for r5    */
        .byte    0x8                   /* Same value  */
        .uleb128 6                     /*   for r6    */
        .byte    0x8                   /* Same value  */
        .uleb128 7                     /*   for r7    */
        .byte    0x8                   /* Same value  */
        .uleb128 8                     /*   for r8    */
 
        .align   2
2:
 

Line No.	Rev	Author	Line
1	2	alfik	`/******************************************************************************`
2			`* *`
3			`* License Agreement *`
4			`* *`
5			`* Copyright (c) 2003-2010 Altera Corporation, San Jose, California, USA. *`
6			`* All rights reserved. *`
7			`* *`
8			`* Permission is hereby granted, free of charge, to any person obtaining a *`
9			`* copy of this software and associated documentation files (the "Software"), *`
10			`* to deal in the Software without restriction, including without limitation *`
11			`* the rights to use, copy, modify, merge, publish, distribute, sublicense, *`
12			`* and/or sell copies of the Software, and to permit persons to whom the *`
13			`* Software is furnished to do so, subject to the following conditions: *`
14			`* *`
15			`* The above copyright notice and this permission notice shall be included in *`
16			`* all copies or substantial portions of the Software. *`
17			`* *`
18			`* THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR *`
19			`* IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY, *`
20			`* FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE *`
21			`* AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER *`
22			`* LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING *`
23			`* FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER *`
24			`* DEALINGS IN THE SOFTWARE. *`
25			`* *`
26			`* This agreement shall be governed in all respects by the laws of the State *`
27			`* of California and by the laws of the United States of America. *`
28			`* *`
29			`******************************************************************************/`
30
31			`/* mcount or _mcount is inserted by GCC before the function prologue of every`
32			`* function when a program is compiled for profiling. At the start of mcount,`
33			`* we guarantee that:`
34			`* ra = self_pc (an address in the function which called mcount)`
35			`* r8 = from_pc (an address in the function which called mcount's caller)`
36			`*`
37			`* Because this is always called at the start of a function we can corrupt`
38			`* r2,r3 and r11-r15. We must not corrupt r4-r7 (because they might contain`
39			`* function arguments for the instrumented function) or r8 (which holds ra`
40			`* for the instrumented function).`
41			`*/`
42
43			`.global __mcount_fn_head`
44
45			`.global mcount`
46
47			`/* _mcount is used by gcc4 */`
48			`.global _mcount`
49
50			`_mcount:`
51			`mcount:`
52			`/* Use a hash to speed up locating fn_entry. We use bits 5 upwards to choose`
53			`* the bucket because bits 1:0 will always be 0, and because the distribution`
54			`* of values for bits 4:2 won't be even (aligning on cache line boundaries`
55			`* will skew it). Higher bits should be fairly random.`
56			`*/`
57			`/* fn_head = mcount_fn_head + (((unsigned int)self_pc >> 5) & (HASH_BUCKETS - 1)); */`
58
59			`srli r2, ra, 3`
60			`movhi r3, %hiadj(__mcount_fn_head)`
61			`addi r3, r3, %lo(__mcount_fn_head)`
62			`andi r2, r2, 0xFC`
63			`add r11, r2, r3`
64
65			`/* The fast case is where we have already allocated a function arc, and so`
66			`* also a function pointer.`
67			`*/`
68
69			`/* First find the function being called (using self_pc) */`
70			`mov r10, r11`
71			`0:`
72			`ldw r10, 0(r10)`
73			`beq r10, zero, .Lnew_arc`
74			`ldw r2, 4(r10)`
75			`bne r2, ra, 0b`
76
77			`/* Found a function entry for this PC. Now look for an arc with a matching`
78			`* from_pc value. There will always be at least one arc. */`
79			`ldw r3, 8(r10)`
80			`0:`
81			`ldw r2, 4(r3)`
82			`beq r2, r8, .Lfound_arc`
83			`ldw r3, 0(r3)`
84			`bne r3, zero, 0b`
85
86			`.Lnew_arc:`
87			`addi sp, sp, -24`
88
89			`.LCFI0:`
90			`stw ra, 0(sp)`
91			`stw r4, 4(sp)`
92			`stw r5, 8(sp)`
93			`stw r6, 12(sp)`
94			`stw r7, 16(sp)`
95			`stw r8, 20(sp)`
96
97			`.LCFI1:`
98			`/* __mcount_record(orig_ra, orig_r8, fn_entry, fn_head); /`
99			`mov r4, ra`
100			`mov r5, r8`
101			`mov r6, r10`
102			`mov r7, r11`
103			`call __mcount_record`
104
105			`/* restore registers from the stack */`
106			`ldw ra, 0(sp)`
107			`ldw r4, 4(sp)`
108			`ldw r5, 8(sp)`
109			`ldw r6, 12(sp)`
110			`ldw r7, 16(sp)`
111			`ldw r8, 20(sp)`
112
113			`addi sp, sp, 24`
114
115			`.LCFI2:`
116			`ret`
117
118			`.Lfound_arc:`
119			`/* We've found the correct arc record. Increment the count and return */`
120			`ldw r2, 8(r3)`
121			`addi r2, r2, 1`
122			`stw r2, 8(r3)`
123			`ret`
124
125			`.Lmcount_end:`
126
127
128
129			`/*`
130			`* Dwarf2 debug information for the function. This provides GDB with the`
131			`* information it needs to backtrace out of this function.`
132			`*/`
133
134			`.section .debug_frame,"",@progbits`
135			`.LCIE:`
136			`.4byte 2f - 1f /* Length */`
137			`1:`
138			`.4byte 0xffffffff /* CIE id */`
139			`.byte 0x1 /* Version */`
140			`.string "" /* Augmentation */`
141			`.uleb128 0x1 /* Code alignment factor */`
142			`.sleb128 -4 /* Data alignment factor */`
143			`.byte 0x1f /* Return address register */`
144
145			`.byte 0xc /* Define CFA */`
146			`.uleb128 0x1b /* Register 27 (sp) */`
147			`.uleb128 0x0 /* Offset 0 */`
148
149			`.align 2 /* Padding */`
150			`2:`
151
152			`.LFDE_mcount:`
153			`.4byte 2f - 1f /* Length */`
154			`1:`
155			`.4byte .LCIE /* Pointer to CIE */`
156			`.4byte mcount /* Start of table entry */`
157			`.4byte .Lmcount_end - mcount /* Size of table entry */`
158
159			`.byte 0x4 /* Advance location */`
160			`.4byte .LCFI0 - mcount /* to .LCFI0 */`
161			`.byte 0xe /* Define CFA offset */`
162			`.uleb128 24 /* to 24 */`
163
164			`.byte 0x4 /* Advance location */`
165			`.4byte .LCFI1 - .LCFI0 /* to .LCFI1 */`
166			`.byte 0x9f /* Store ra */`
167			`.uleb128 0x6 /* at CFA-24 */`
168			`.byte 0x84 /* Store r4 */`
169			`.uleb128 0x5 /* at CFA-20 */`
170			`.byte 0x85 /* Store r5 */`
171			`.uleb128 0x4 /* at CFA-16 */`
172			`.byte 0x86 /* Store r6 */`
173			`.uleb128 0x3 /* at CFA-12 */`
174			`.byte 0x87 /* Store r7 */`
175			`.uleb128 0x2 /* at CFA-8 */`
176			`.byte 0x88 /* Store r8 */`
177			`.uleb128 0x1 /* at CFA-4 */`
178
179			`.byte 0x4 /* Advance location */`
180			`.4byte .LCFI2 - .LCFI1 /* to .LCFI2 */`
181			`.byte 0xe /* Define CFA offset */`
182			`.uleb128 0 /* to 0 */`
183			`.byte 0x8 /* Same value */`
184			`.uleb128 31 /* for ra */`
185			`.byte 0x8 /* Same value */`
186			`.uleb128 4 /* for r4 */`
187			`.byte 0x8 /* Same value */`
188			`.uleb128 5 /* for r5 */`
189			`.byte 0x8 /* Same value */`
190			`.uleb128 6 /* for r6 */`
191			`.byte 0x8 /* Same value */`
192			`.uleb128 7 /* for r7 */`
193			`.byte 0x8 /* Same value */`
194			`.uleb128 8 /* for r8 */`
195
196			`.align 2`
197			`2:`
198

Browse

Tools

Subversion Repositories ao486

[/] [ao486/] [trunk/] [syn/] [components/] [ps2/] [software/] [exe_bsp/] [HAL/] [src/] [alt_mcount.S] - Blame information for rev 2