URL https://opencores.org/ocsvn/dbg_interface/dbg_interface/trunk

Subversion Repositories dbg_interface

[/] [dbg_interface/] [trunk/] [rtl/] [verilog/] [dbg_wb.v] - Blame information for rev 121

Go to most recent revision | Details | Compare with Previous | View Log


//////////////////////////////////////////////////////////////////////
////                                                              ////
////  dbg_wb.v                                                    ////
////                                                              ////
////                                                              ////
////  This file is part of the SoC/OpenRISC Development Interface ////
////  http://www.opencores.org/projects/DebugInterface/           ////
////                                                              ////
////  Author(s):                                                  ////
////       Igor Mohor (igorm@opencores.org)                       ////
////                                                              ////
////                                                              ////
////  All additional information is avaliable in the README.txt   ////
////  file.                                                       ////
////                                                              ////
//////////////////////////////////////////////////////////////////////
////                                                              ////
//// Copyright (C) 2000 - 2003 Authors                            ////
////                                                              ////
//// This source file may be used and distributed without         ////
//// restriction provided that this copyright statement is not    ////
//// removed from the file and that any derivative work contains  ////
//// the original copyright notice and the associated disclaimer. ////
////                                                              ////
//// This source file is free software; you can redistribute it   ////
//// and/or modify it under the terms of the GNU Lesser General   ////
//// Public License as published by the Free Software Foundation; ////
//// either version 2.1 of the License, or (at your option) any   ////
//// later version.                                               ////
////                                                              ////
//// This source is distributed in the hope that it will be       ////
//// useful, but WITHOUT ANY WARRANTY; without even the implied   ////
//// warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR      ////
//// PURPOSE.  See the GNU Lesser General Public License for more ////
//// details.                                                     ////
////                                                              ////
//// You should have received a copy of the GNU Lesser General    ////
//// Public License along with this source; if not, download it   ////
//// from http://www.opencores.org/lgpl.shtml                     ////
////                                                              ////
//////////////////////////////////////////////////////////////////////
//
// CVS Revision History
//
// $Log: not supported by cvs2svn $
// Revision 1.16  2004/01/19 07:32:41  simons
// Reset values width added because of FV, a good sentence changed because some tools can not handle it.
//
// Revision 1.15  2004/01/17 18:01:24  mohor
// New version.
//
// Revision 1.14  2004/01/16 14:51:33  mohor
// cpu registers added.
//
// Revision 1.13  2004/01/15 12:09:43  mohor
// Working.
//
// Revision 1.12  2004/01/14 22:59:18  mohor
// Temp version.
//
// Revision 1.11  2004/01/14 12:29:40  mohor
// temp version. Resets will be changed in next version.
//
// Revision 1.10  2004/01/13 11:28:14  mohor
// tmp version.
//
// Revision 1.9  2004/01/10 07:50:24  mohor
// temp version.
//
// Revision 1.8  2004/01/09 12:48:44  mohor
// tmp version.
//
// Revision 1.7  2004/01/08 17:53:36  mohor
// tmp version.
//
// Revision 1.6  2004/01/07 11:58:56  mohor
// temp4 version.
//
// Revision 1.5  2004/01/06 17:15:19  mohor
// temp3 version.
//
// Revision 1.4  2004/01/05 12:16:00  mohor
// tmp2 version.
//
// Revision 1.3  2003/12/23 16:22:46  mohor
// Tmp version.
//
// Revision 1.2  2003/12/23 15:26:26  mohor
// Small fix.
//
// Revision 1.1  2003/12/23 15:09:04  mohor
// New directory structure. New version of the debug interface.
//
//
//
 
// synopsys translate_off
`include "timescale.v"
// synopsys translate_on
`include "dbg_wb_defines.v"
 
// Top module
module dbg_wb(
                // JTAG signals
                tck_i,
                tdi_i,
                tdo_o,
 
                // TAP states
                shift_dr_i,
                pause_dr_i,
                update_dr_i,
 
                wishbone_ce_i,
                crc_match_i,
                crc_en_o,
                shift_crc_o,
                rst_i,
 
                // WISHBONE common signals
                wb_clk_i,
 
                // WISHBONE master interface
                wb_adr_o, wb_dat_o, wb_dat_i, wb_cyc_o, wb_stb_o, wb_sel_o,
                wb_we_o, wb_ack_i, wb_cab_o, wb_err_i, wb_cti_o, wb_bte_o
 
              );
 
// JTAG signals
input         tck_i;
input         tdi_i;
output        tdo_o;
 
// TAP states
input         shift_dr_i;
input         pause_dr_i;
input         update_dr_i;
 
input         wishbone_ce_i;
input         crc_match_i;
output        crc_en_o;
output        shift_crc_o;
input         rst_i;
// WISHBONE common signals
input         wb_clk_i;
 
// WISHBONE master interface
output [31:0] wb_adr_o;
output [31:0] wb_dat_o;
input  [31:0] wb_dat_i;
output        wb_cyc_o;
output        wb_stb_o;
output  [3:0] wb_sel_o;
output        wb_we_o;
input         wb_ack_i;
output        wb_cab_o;
input         wb_err_i;
output  [2:0] wb_cti_o;
output  [1:0] wb_bte_o;
 
reg           wb_cyc_o;
reg    [31:0] wb_adr_o;
reg    [31:0] wb_dat_o;
reg     [3:0] wb_sel_o;
 
reg           tdo_o;
 
reg    [50:0] dr;
wire          enable;
wire          cmd_cnt_en;
reg     [1:0] cmd_cnt;
wire          cmd_cnt_end;
reg           cmd_cnt_end_q;
wire          addr_len_cnt_en;
reg     [5:0] addr_len_cnt;
reg     [5:0] addr_len_cnt_limit;
wire          addr_len_cnt_end;
wire          crc_cnt_en;
reg     [5:0] crc_cnt;
wire          crc_cnt_end;
reg           crc_cnt_end_q;
wire          data_cnt_en;
reg    [18:0] data_cnt;
reg    [18:0] data_cnt_limit;
wire          data_cnt_end;
reg           data_cnt_end_q;
reg           status_reset_en;
 
reg           crc_match_reg;
 
reg     [2:0] cmd, cmd_old, dr_cmd_latched;
reg    [31:0] adr;
reg    [15:0] len;
reg           start_rd_tck;
reg           rd_tck_started;
reg           start_rd_sync1;
reg           start_wb_rd;
reg           start_wb_rd_q;
reg           start_wr_tck;
reg           start_wr_sync1;
reg           start_wb_wr;
reg           start_wb_wr_q;
 
wire          dr_read;
wire          dr_write;
wire          dr_go;
 
reg           dr_write_latched;
reg           dr_read_latched;
reg           dr_go_latched;
 
wire          status_cnt_end;
 
wire          byte, half, long;
reg           byte_q, half_q, long_q;
reg           byte_q2, half_q2, long_q2;
reg           cmd_read;
reg           cmd_write;
reg           cmd_go;
 
reg           status_cnt1, status_cnt2, status_cnt3, status_cnt4;
 
reg [`STATUS_LEN -1:0] status;
 
reg           wb_error, wb_error_sync, wb_error_tck;
reg           wb_overrun, wb_overrun_sync, wb_overrun_tck;
reg           underrun_tck;
 
reg           busy_wb;
reg           busy_tck;
reg           wb_end;
reg           wb_end_rst;
reg           wb_end_rst_sync;
reg           wb_end_sync;
reg           wb_end_tck, wb_end_tck_q;
reg           busy_sync;
reg           latch_data;
 
reg           set_addr, set_addr_sync, set_addr_wb, set_addr_wb_q;
reg           read_cycle;
reg           write_cycle;
reg     [2:0] rw_type;
wire   [31:0] input_data;
 
wire          len_eq_0;
wire          crc_cnt_31;
 
reg     [1:0] ptr;
reg     [2:0] fifo_cnt;
wire          fifo_full;
wire          fifo_empty;
reg     [7:0] mem [0:3];
reg     [2:0] mem_ptr;
reg           wishbone_ce_sync;
reg           wishbone_ce_rst;
wire          go_prelim;
 
 
 
assign enable = wishbone_ce_i & shift_dr_i;
assign crc_en_o = enable & crc_cnt_end & (~status_cnt_end);
assign shift_crc_o = enable & status_cnt_end;  // Signals dbg module to shift out the CRC
 
 
// Selecting where to take the data from 
always @ (posedge tck_i)
begin
  if (update_dr_i)
    ptr <= #1 2'h0;
  else if (read_cycle & crc_cnt_31) // first latch
    ptr <= #1 ptr + 1'b1;
  else if (read_cycle & byte & (~byte_q))
    ptr <= ptr + 1'd1;
end
 
 
// Shift register for shifting in and out the data
always @ (posedge tck_i or posedge rst_i)
begin
  if (rst_i)
    begin
      dr <= #1 51'h0;
      latch_data <= #1 1'b0;
    end
  else if (read_cycle & crc_cnt_31)
    begin
      dr[31:0] <= #1 input_data[31:0];
      latch_data <= #1 1'b1;
    end
  else if (read_cycle & crc_cnt_end)
    begin
      case (rw_type)  // synthesis parallel_case full_case
        `WB_READ8 : begin
                      if(byte & (~byte_q))
                        begin
                          case (ptr)    // synthesis parallel_case
                            2'b00 : dr[31:24] <= #1 input_data[31:24];
                            2'b01 : dr[31:24] <= #1 input_data[23:16];
                            2'b10 : dr[31:24] <= #1 input_data[15:8];
                            2'b11 : dr[31:24] <= #1 input_data[7:0];
                          endcase
                          latch_data <= #1 1'b1;
                        end
                      else
                        begin
                          dr[31:24] <= #1 {dr[30:24], 1'b0};
                          latch_data <= #1 1'b0;
                        end
                    end
        `WB_READ16: begin
                      if(half & (~half_q))
                        begin
                          if (ptr[1])
                            dr[31:16] <= #1 input_data[15:0];
                          else
                            dr[31:16] <= #1 input_data[31:16];
                          latch_data <= #1 1'b1;
                        end
                      else
                        begin
                          dr[31:16] <= #1 {dr[30:16], 1'b0};
                          latch_data <= #1 1'b0;
                        end
                    end
        `WB_READ32: begin
                      if(long & (~long_q))
                        begin
                          dr[31:0] <= #1 input_data[31:0];
                          latch_data <= #1 1'b1;
                        end
                      else
                        begin
                          dr[31:0] <= #1 {dr[30:0], 1'b0};
                          latch_data <= #1 1'b0;
                        end
                    end
      endcase
    end
  else if (enable & ((~addr_len_cnt_end) | (~cmd_cnt_end) | ((~data_cnt_end) & write_cycle)))
    begin
      dr <= #1 {dr[49:0], tdi_i};
      latch_data <= #1 1'b0;
    end
end
 
 
assign cmd_cnt_en = enable & (~cmd_cnt_end);
 
 
// Command counter
always @ (posedge tck_i or posedge rst_i)
begin
  if (rst_i)
    cmd_cnt <= #1 2'h0;
  else if (update_dr_i)
    cmd_cnt <= #1 2'h0;
  else if (cmd_cnt_en)
    cmd_cnt <= #1 cmd_cnt + 1'b1;
end
 
 
assign addr_len_cnt_en = enable & cmd_cnt_end & (~addr_len_cnt_end);
 
 
// Address/length counter
always @ (posedge tck_i or posedge rst_i)
begin
  if (rst_i)
    addr_len_cnt <= #1 6'h0;
  else if (update_dr_i)
    addr_len_cnt <= #1 6'h0;
  else if (addr_len_cnt_en)
    addr_len_cnt <= #1 addr_len_cnt + 1'b1;
end
 
 
assign data_cnt_en = enable & (~data_cnt_end) & (cmd_cnt_end & write_cycle | crc_cnt_end & read_cycle);
 
 
// Data counter
always @ (posedge tck_i or posedge rst_i)
begin
  if (rst_i)
    data_cnt <= #1 19'h0;
  else if (update_dr_i)
    data_cnt <= #1 19'h0;
  else if (data_cnt_en)
    data_cnt <= #1 data_cnt + 1'b1;
end
 
 
 
assign byte = data_cnt[2:0] == 3'd7;
assign half = data_cnt[3:0] == 4'd15;
assign long = data_cnt[4:0] == 5'd31;
 
 
always @ (posedge tck_i)
begin
  byte_q <= #1 byte;
  half_q <= #1 half;
  long_q <= #1 long;
  byte_q2 <= #1 byte_q;
  half_q2 <= #1 half_q;
  long_q2 <= #1 long_q;
end
 
 
assign dr_read = (dr[2:0] == `WB_READ8) || (dr[2:0] == `WB_READ16) || (dr[2:0] == `WB_READ32);
assign dr_write = (dr[2:0] == `WB_WRITE8) || (dr[2:0] == `WB_WRITE16) || (dr[2:0] == `WB_WRITE32);
assign dr_go = dr[2:0] == `WB_GO;
 
 
// Latching instruction
always @ (posedge tck_i)
begin
  if (update_dr_i)
    begin
      dr_cmd_latched <= #1 3'h0;
      dr_read_latched  <= #1 1'b0;
      dr_write_latched  <= #1 1'b0;
      dr_go_latched  <= #1 1'b0;
    end
  else if (cmd_cnt_end & (~cmd_cnt_end_q))
    begin
      dr_cmd_latched <= #1 dr[2:0];
      dr_read_latched <= #1 dr_read;
      dr_write_latched <= #1 dr_write;
      dr_go_latched <= #1 dr_go;
    end
end
 
 
// Upper limit. Address/length counter counts until this value is reached
always @ (posedge tck_i)
begin
  if (cmd_cnt == 2'h2)
    begin
      if ((~dr[0])  & (~tdi_i))                                   // (current command is WB_STATUS or WB_GO)
        addr_len_cnt_limit <= #1 6'd0;
      else                                                        // (current command is WB_WRITEx or WB_READx)
        addr_len_cnt_limit <= #1 6'd48;
    end
end
 
 
assign go_prelim = (cmd_cnt == 2'h2) & dr[1] & (~dr[0]) & (~tdi_i);
 
 
// Upper limit. Data counter counts until this value is reached.
always @ (posedge tck_i)
begin
  if (update_dr_i)
    data_cnt_limit <= #1 {len, 3'b000};
end
 
 
assign crc_cnt_en = enable & (~crc_cnt_end) & (cmd_cnt_end & addr_len_cnt_end  & (~write_cycle) | (data_cnt_end & write_cycle));
 
 
// crc counter
always @ (posedge tck_i or posedge rst_i)
begin
  if (rst_i)
    crc_cnt <= #1 6'h0;
  else if(crc_cnt_en)
    crc_cnt <= #1 crc_cnt + 1'b1;
  else if (update_dr_i)
    crc_cnt <= #1 6'h0;
end
 
assign cmd_cnt_end  = cmd_cnt  == 2'h3;
assign addr_len_cnt_end = addr_len_cnt == addr_len_cnt_limit;
assign crc_cnt_end  = crc_cnt  == 6'd32;
assign crc_cnt_31 = crc_cnt  == 6'd31;
assign data_cnt_end = (data_cnt == data_cnt_limit);
 
always @ (posedge tck_i)
begin
  crc_cnt_end_q  <= #1 crc_cnt_end;
  cmd_cnt_end_q  <= #1 cmd_cnt_end;
  data_cnt_end_q <= #1 data_cnt_end;
end
 
 
// Status counter is made of 4 serialy connected registers
always @ (posedge tck_i or posedge rst_i)
begin
  if (rst_i)
    status_cnt1 <= #1 1'b0;
  else if (update_dr_i)
    status_cnt1 <= #1 1'b0;
  else if (data_cnt_end & read_cycle |
           crc_cnt_end & (~read_cycle)
          )
    status_cnt1 <= #1 1'b1;
end
 
 
always @ (posedge tck_i or posedge rst_i)
begin
  if (rst_i)
    begin
      status_cnt2 <= #1 1'b0;
      status_cnt3 <= #1 1'b0;
      status_cnt4 <= #1 1'b0;
    end
  else if (update_dr_i)
    begin
      status_cnt2 <= #1 1'b0;
      status_cnt3 <= #1 1'b0;
      status_cnt4 <= #1 1'b0;
    end
  else
    begin
      status_cnt2 <= #1 status_cnt1;
      status_cnt3 <= #1 status_cnt2;
      status_cnt4 <= #1 status_cnt3;
    end
end
 
 
assign status_cnt_end = status_cnt4;
 
 
// Status register
always @ (posedge tck_i or posedge rst_i)
begin
  if (rst_i)
    begin
    status <= #1 {`STATUS_LEN{1'b0}};
    end
  else if(crc_cnt_end & (~crc_cnt_end_q) & (~read_cycle))
    begin
    status <= #1 {crc_match_i, wb_error_tck, wb_overrun_tck, busy_tck};
    end
  else if (data_cnt_end & (~data_cnt_end_q) & read_cycle)
    begin
    status <= #1 {crc_match_reg, wb_error_tck, underrun_tck, busy_tck};
    end
  else if (shift_dr_i & (~status_cnt_end))
    begin
    status <= #1 {status[0], status[`STATUS_LEN -1:1]};
    end
end
// Following status is shifted out:
// 1. bit:          1 if crc is OK, else 0
// 2. bit:          1 while WB access is in progress (busy_tck), else 0
// 3. bit:          1 if overrun occured during write (data couldn't be written fast enough)
//                    or underrun occured during read (data couldn't be read fast enough)
// 4. bit:          1 if WB error occured, else 0
 
 
// TDO multiplexer
always @ (pause_dr_i or busy_tck or crc_cnt_end or crc_cnt_end_q or crc_match_i or
          data_cnt_end or data_cnt_end_q or read_cycle or crc_match_reg or status or dr)
begin
  if (pause_dr_i)
    begin
    tdo_o = busy_tck;
    end
  else if (crc_cnt_end & (~crc_cnt_end_q) & (~(read_cycle)))
    begin
      tdo_o = crc_match_i;
    end
  else if (read_cycle & crc_cnt_end & (~data_cnt_end))
    begin
    tdo_o = dr[31];
    end
  else if (read_cycle & data_cnt_end & (~data_cnt_end_q))     // cmd is already updated
    begin
      tdo_o = crc_match_reg;
    end
  else if (crc_cnt_end & data_cnt_end)  // cmd is already updated
    begin
      tdo_o = status[0];
    end
  else
    begin
      tdo_o = 1'b0;
    end
end
 
 
 
always @ (posedge tck_i)
begin
  if(crc_cnt_end & (~crc_cnt_end_q))
    crc_match_reg <= #1 crc_match_i;
end
 
 
// Latching instruction
always @ (posedge tck_i or posedge rst_i)
begin
  if (rst_i)
    begin
      cmd <= #1 3'h0;
      cmd_old <= #1 3'h0;
      cmd_read <= #1 1'b0;
      cmd_write <= #1 1'b0;
      cmd_go <= #1 1'b0;
    end
  else if(crc_cnt_end & (~crc_cnt_end_q) & crc_match_i)
    begin
      cmd <= #1 dr_cmd_latched;
      cmd_old <= #1 cmd;
      cmd_read <= #1 dr_read_latched;
      cmd_write <= #1 dr_write_latched;
      cmd_go <= #1 dr_go_latched;
    end
end
 
 
// Latching address
always @ (posedge tck_i)
begin
  if(crc_cnt_end & (~crc_cnt_end_q) & crc_match_i)
    begin
      if (dr_write_latched | dr_read_latched)
        begin
          adr <= #1 dr[47:16];
          set_addr <= #1 1'b1;
        end
    end
  else
    set_addr <= #1 1'b0;
end
 
 
// Length counter
always @ (posedge tck_i)
begin
  if(crc_cnt_end & (~crc_cnt_end_q) & crc_match_i & (dr_write_latched | dr_read_latched))
    len <= #1 dr[15:0];
  else if (start_rd_tck)
    begin
      case (rw_type)  // synthesis parallel_case full_case
        `WB_READ8 : len <= #1 len - 1'd1;
        `WB_READ16: len <= #1 len - 2'd2;
        `WB_READ32: len <= #1 len - 3'd4;
      endcase
    end
end
 
 
assign len_eq_0 = len == 16'h0;
 
 
// Start wishbone read cycle
always @ (posedge tck_i)
begin
  if (read_cycle & (~dr_go_latched) & (~len_eq_0))              // First read after cmd is entered
    start_rd_tck <= #1 1'b1;
  else if ((~start_rd_tck) & read_cycle & (~len_eq_0) & (~fifo_full) & (~rd_tck_started))
    start_rd_tck <= #1 1'b1;
  else
    start_rd_tck <= #1 1'b0;
end
 
 
always @ (posedge tck_i)
begin
  if (update_dr_i)
    rd_tck_started <= #1 1'b0;
  else if (start_rd_tck)
    rd_tck_started <= #1 1'b1;
  else if (wb_end_tck & (~wb_end_tck_q))
    rd_tck_started <= #1 1'b0;
end
 
 
always @ (posedge tck_i)
begin
  if (update_dr_i)
    read_cycle <= #1 1'b0;
  else if (cmd_read & go_prelim)
    read_cycle <= #1 1'b1;
end
 
 
always @ (posedge tck_i or posedge rst_i)
begin
  if (rst_i)
    rw_type <= #1 3'h0;
  else if ((cmd_read | cmd_write) & go_prelim)
    rw_type <= #1 cmd;
end
 
 
always @ (posedge tck_i or posedge rst_i)
begin
  if (rst_i)
    write_cycle <= #1 1'b0;
  else if (update_dr_i)
    write_cycle <= #1 1'b0;
  else if (cmd_write & go_prelim)
    write_cycle <= #1 1'b1;
end
 
 
// Start wishbone write cycle
always @ (posedge tck_i or posedge rst_i)
begin
  if (rst_i)
    begin
      start_wr_tck <= #1 1'b0;
      wb_dat_o <= #1 32'h0;
    end
  else if (write_cycle)
    begin
      case (rw_type)  // synthesis parallel_case full_case
        `WB_WRITE8  : begin
                        if (byte_q & (~byte_q2))
                          begin
                            start_wr_tck <= #1 1'b1;
                            wb_dat_o <= #1 {4{dr[7:0]}};
                          end
                        else
                          begin
                            start_wr_tck <= #1 1'b0;
                          end
                      end
        `WB_WRITE16 : begin
                        if (half_q & (~half_q2))
                          begin
                            start_wr_tck <= #1 1'b1;
                            wb_dat_o <= #1 {2{dr[15:0]}};
                          end
                        else
                          begin
                            start_wr_tck <= #1 1'b0;
                          end
                      end
        `WB_WRITE32 : begin
                        if (long_q & (~long_q2))
                          begin
                            start_wr_tck <= #1 1'b1;
                            wb_dat_o <= #1 dr[31:0];
                          end
                        else
                          begin
                            start_wr_tck <= #1 1'b0;
                          end
                      end
      endcase
    end
  else
    start_wr_tck <= #1 1'b0;
end
 
 
always @ (posedge wb_clk_i)
begin
  start_rd_sync1  <= #1 start_rd_tck;
  start_wb_rd     <= #1 start_rd_sync1;
  start_wb_rd_q   <= #1 start_wb_rd;
 
  start_wr_sync1  <= #1 start_wr_tck;
  start_wb_wr     <= #1 start_wr_sync1;
  start_wb_wr_q   <= #1 start_wb_wr;
 
  set_addr_sync   <= #1 set_addr;
  set_addr_wb     <= #1 set_addr_sync;
  set_addr_wb_q   <= #1 set_addr_wb;
end
 
 
// wb_cyc_o
always @ (posedge wb_clk_i or posedge rst_i)
begin
  if (rst_i)
    wb_cyc_o <= #1 1'b0;
  else if ((start_wb_wr & (~start_wb_wr_q)) | (start_wb_rd & (~start_wb_rd_q)))
    wb_cyc_o <= #1 1'b1;
  else if (wb_ack_i | wb_err_i)
    wb_cyc_o <= #1 1'b0;
end
 
 
// wb_adr_o logic
always @ (posedge wb_clk_i or posedge rst_i)
begin
  if (rst_i)
    wb_adr_o <= #1 32'h0;
  else if (set_addr_wb & (~set_addr_wb_q)) // Setting starting address
    wb_adr_o <= #1 adr;
  else if (wb_ack_i)
    begin
      if ((rw_type == `WB_WRITE8) | (rw_type == `WB_READ8))
        wb_adr_o <= #1 wb_adr_o + 1'd1;
      else if ((rw_type == `WB_WRITE16) | (rw_type == `WB_READ16))
        wb_adr_o <= #1 wb_adr_o + 2'd2;
      else
        wb_adr_o <= #1 wb_adr_o + 3'd4;
    end
end
 
 
 
//    adr   byte  |  short  |  long
//     0    1000     1100      1111
//     1    0100     err       err
//     2    0010     0011      err
//     3    0001     err       err
// wb_sel_o logic
always @ (posedge wb_clk_i or posedge rst_i)
begin
  if (rst_i)
    wb_sel_o[3:0] <= #1 4'h0;
  else
    begin
      wb_sel_o[0] <= #1 (rw_type[1:0] == 2'b11) & (wb_adr_o[1:0] == 2'b00) | (rw_type[1:0] == 2'b01) & (wb_adr_o[1:0] == 2'b11) |
                        (rw_type[1:0] == 2'b10) & (wb_adr_o[1:0] == 2'b10);
      wb_sel_o[1] <= #1 (rw_type[1:0] == 2'b11) & (wb_adr_o[1:0] == 2'b00) | (rw_type[1] ^ rw_type[0]) & (wb_adr_o[1:0] == 2'b10);
      wb_sel_o[2] <= #1 (rw_type[1]) & (wb_adr_o[1:0] == 2'b00) | (rw_type[1:0] == 2'b01) & (wb_adr_o[1:0] == 2'b01);
      wb_sel_o[3] <= #1 (wb_adr_o[1:0] == 2'b00);
    end
end
 
 
assign wb_we_o = write_cycle;
assign wb_cab_o = 1'b0;
assign wb_stb_o = wb_cyc_o;
assign wb_cti_o = 3'h0;     // always performing single access
assign wb_bte_o = 2'h0;     // always performing single access
 
 
// Logic for detecting end of transaction
always @ (posedge wb_clk_i or posedge rst_i)
begin
  if (rst_i)
    wb_end <= #1 1'b0;
  else if (wb_ack_i | wb_err_i)
    wb_end <= #1 1'b1;
  else if (wb_end_rst)
    wb_end <= #1 1'b0;
end
 
 
always @ (posedge tck_i or posedge rst_i)
begin
  if (rst_i)
    begin
      wb_end_sync <= #1 1'b0;
      wb_end_tck  <= #1 1'b0;
      wb_end_tck_q<= #1 1'b0;
    end
  else
    begin
      wb_end_sync <= #1 wb_end;
      wb_end_tck  <= #1 wb_end_sync;
      wb_end_tck_q<= #1 wb_end_tck;
    end
end
 
 
always @ (posedge wb_clk_i or posedge rst_i)
begin
  if (rst_i)
    busy_wb <= #1 1'b0;
  else if (wb_end_rst)
    busy_wb <= #1 1'b0;
  else if (wb_cyc_o)
    busy_wb <= #1 1'b1;
end
 
 
always @ (posedge tck_i or posedge rst_i)
begin
  if (rst_i)
    begin
      busy_sync <= #1 1'b0;
      busy_tck <= #1 1'b0;
    end
  else
    begin
      busy_sync <= #1 busy_wb;
      busy_tck <= #1 busy_sync;
    end
end
 
 
always @ (posedge wb_clk_i)
begin
  wb_end_rst_sync <= #1 wb_end_tck;
  wb_end_rst  <= #1 wb_end_rst_sync;
end
 
 
// Detecting WB error
always @ (posedge wb_clk_i or posedge rst_i)
begin
  if (rst_i)
    wb_error <= #1 1'b0;
  else if(wb_err_i)
    wb_error <= #1 1'b1;
  else if(wb_ack_i & status_reset_en) // error remains active until STATUS read is performed
    wb_error <= #1 1'b0;
end
 
 
always @ (posedge tck_i)
begin
  wb_error_sync <= #1 wb_error;
  wb_error_tck  <= #1 wb_error_sync;
end
 
 
// Detecting overrun when write operation.
always @ (posedge wb_clk_i or posedge rst_i)
begin
  if (rst_i)
    wb_overrun <= #1 1'b0;
  else if(start_wb_wr & (~start_wb_wr_q) & wb_cyc_o)
    wb_overrun <= #1 1'b1;
  else if((wb_ack_i | wb_err_i) & status_reset_en) // error remains active until STATUS read is performed
    wb_overrun <= #1 1'b0;
end
 
always @ (posedge tck_i)
begin
  wb_overrun_sync <= #1 wb_overrun;
  wb_overrun_tck  <= #1 wb_overrun_sync;
end
 
 
// Detecting underrun when read operation
always @ (posedge tck_i or posedge rst_i)
begin
  if (rst_i)
    underrun_tck <= #1 1'b0;
  else if(latch_data & fifo_empty & (~data_cnt_end))
    underrun_tck <= #1 1'b1;
  else if(read_cycle & status_reset_en) // error remains active until STATUS read is performed
    underrun_tck <= #1 1'b0;
end
 
 
 
// wb_error is locked until WB_STATUS is performed
always @ (posedge tck_i or posedge rst_i)
begin
  if (rst_i)
    status_reset_en <= 1'b0;
  else if((cmd_old == `WB_STATUS) & (cmd !== `WB_STATUS))
    status_reset_en <= #1 1'b1;
  else
    status_reset_en <= #1 1'b0;
end
 
 
always @ (posedge wb_clk_i)
begin
  wishbone_ce_sync <= #1  wishbone_ce_i;
  wishbone_ce_rst  <= #1 ~wishbone_ce_sync;
end
 
 
// Logic for latching data that is read from wishbone
always @ (posedge wb_clk_i)
begin
  if(wishbone_ce_rst)
    mem_ptr <= #1 3'h0;
  else if (wb_ack_i)
    begin
      if (rw_type == `WB_READ8)
        mem_ptr <= #1 mem_ptr + 1'd1;
      else if (rw_type == `WB_READ16)
        mem_ptr <= #1 mem_ptr + 2'd2;
    end
end
 
 
// Logic for latching data that is read from wishbone
always @ (posedge wb_clk_i)
begin
  if (wb_ack_i)
    begin
      case (wb_sel_o)    // synthesis parallel_case full_case 
        4'b1000  :  mem[mem_ptr[1:0]] <= #1 wb_dat_i[31:24];            // byte 
        4'b0100  :  mem[mem_ptr[1:0]] <= #1 wb_dat_i[23:16];            // byte
        4'b0010  :  mem[mem_ptr[1:0]] <= #1 wb_dat_i[15:08];            // byte
        4'b0001  :  mem[mem_ptr[1:0]] <= #1 wb_dat_i[07:00];            // byte
 
        4'b1100  :                                                      // half
                    begin
                      mem[mem_ptr[1:0]]      <= #1 wb_dat_i[31:24];
                      mem[mem_ptr[1:0]+1'b1] <= #1 wb_dat_i[23:16];
                    end
        4'b0011  :                                                      // half
                    begin
                      mem[mem_ptr[1:0]]      <= #1 wb_dat_i[15:08];
                      mem[mem_ptr[1:0]+1'b1] <= #1 wb_dat_i[07:00];
                    end
        4'b1111  :                                                      // long
                    begin
                      mem[0] <= #1 wb_dat_i[31:24];
                      mem[1] <= #1 wb_dat_i[23:16];
                      mem[2] <= #1 wb_dat_i[15:08];
                      mem[3] <= #1 wb_dat_i[07:00];
                    end
      endcase
    end
end
 
 
assign input_data = {mem[0], mem[1], mem[2], mem[3]};
 
 
// Fifo counter and empty/full detection
always @ (posedge tck_i)
begin
  if (update_dr_i)
    fifo_cnt <= #1 3'h0;
  else if (wb_end_tck & (~wb_end_tck_q) & (~latch_data))  // incrementing
    begin
      case (rw_type)  // synthesis parallel_case full_case
        `WB_READ8 : fifo_cnt <= #1 fifo_cnt + 1'd1;
        `WB_READ16: fifo_cnt <= #1 fifo_cnt + 2'd2;
        `WB_READ32: fifo_cnt <= #1 fifo_cnt + 3'd4;
      endcase
    end
  else if (~(wb_end_tck & (~wb_end_tck_q)) & latch_data)  // decrementing
    begin
      case (rw_type)  // synthesis parallel_case full_case
        `WB_READ8 : fifo_cnt <= #1 fifo_cnt - 1'd1;
        `WB_READ16: fifo_cnt <= #1 fifo_cnt - 2'd2;
        `WB_READ32: fifo_cnt <= #1 fifo_cnt - 3'd4;
      endcase
    end
end
 
 
assign fifo_full = fifo_cnt == 3'h4;
assign fifo_empty = fifo_cnt == 3'h0;
 
 
 
 
endmodule
 

Line No.	Rev	Author	Line
1	82	mohor	`//////////////////////////////////////////////////////////////////////`
2			`//// ////`
3			`//// dbg_wb.v ////`
4			`//// ////`
5			`//// ////`
6			`//// This file is part of the SoC/OpenRISC Development Interface ////`
7			`//// http://www.opencores.org/projects/DebugInterface/ ////`
8			`//// ////`
9			`//// Author(s): ////`
10			`//// Igor Mohor (igorm@opencores.org) ////`
11			`//// ////`
12			`//// ////`
13			`//// All additional information is avaliable in the README.txt ////`
14			`//// file. ////`
15			`//// ////`
16			`//////////////////////////////////////////////////////////////////////`
17			`//// ////`
18			`//// Copyright (C) 2000 - 2003 Authors ////`
19			`//// ////`
20			`//// This source file may be used and distributed without ////`
21			`//// restriction provided that this copyright statement is not ////`
22			`//// removed from the file and that any derivative work contains ////`
23			`//// the original copyright notice and the associated disclaimer. ////`
24			`//// ////`
25			`//// This source file is free software; you can redistribute it ////`
26			`//// and/or modify it under the terms of the GNU Lesser General ////`
27			`//// Public License as published by the Free Software Foundation; ////`
28			`//// either version 2.1 of the License, or (at your option) any ////`
29			`//// later version. ////`
30			`//// ////`
31			`//// This source is distributed in the hope that it will be ////`
32			`//// useful, but WITHOUT ANY WARRANTY; without even the implied ////`
33			`//// warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR ////`
34			`//// PURPOSE. See the GNU Lesser General Public License for more ////`
35			`//// details. ////`
36			`//// ////`
37			`//// You should have received a copy of the GNU Lesser General ////`
38			`//// Public License along with this source; if not, download it ////`
39			`//// from http://www.opencores.org/lgpl.shtml ////`
40			`//// ////`
41			`//////////////////////////////////////////////////////////////////////`
42			`//`
43			`// CVS Revision History`
44			`//`
45			`// $Log: not supported by cvs2svn $`
46	121	mohor	`// Revision 1.16 2004/01/19 07:32:41 simons`
47			`// Reset values width added because of FV, a good sentence changed because some tools can not handle it.`
48			`//`
49	108	simons	`// Revision 1.15 2004/01/17 18:01:24 mohor`
50			`// New version.`
51			`//`
52	102	mohor	`// Revision 1.14 2004/01/16 14:51:33 mohor`
53			`// cpu registers added.`
54			`//`
55	99	mohor	`// Revision 1.13 2004/01/15 12:09:43 mohor`
56			`// Working.`
57			`//`
58	97	mohor	`// Revision 1.12 2004/01/14 22:59:18 mohor`
59			`// Temp version.`
60			`//`
61	95	mohor	`// Revision 1.11 2004/01/14 12:29:40 mohor`
62			`// temp version. Resets will be changed in next version.`
63			`//`
64	94	mohor	`// Revision 1.10 2004/01/13 11:28:14 mohor`
65			`// tmp version.`
66			`//`
67	93	mohor	`// Revision 1.9 2004/01/10 07:50:24 mohor`
68			`// temp version.`
69			`//`
70	92	mohor	`// Revision 1.8 2004/01/09 12:48:44 mohor`
71			`// tmp version.`
72			`//`
73	91	mohor	`// Revision 1.7 2004/01/08 17:53:36 mohor`
74			`// tmp version.`
75			`//`
76	90	mohor	`// Revision 1.6 2004/01/07 11:58:56 mohor`
77			`// temp4 version.`
78			`//`
79	89	mohor	`// Revision 1.5 2004/01/06 17:15:19 mohor`
80			`// temp3 version.`
81			`//`
82	88	mohor	`// Revision 1.4 2004/01/05 12:16:00 mohor`
83			`// tmp2 version.`
84			`//`
85	87	mohor	`// Revision 1.3 2003/12/23 16:22:46 mohor`
86			`// Tmp version.`
87			`//`
88	86	mohor	`// Revision 1.2 2003/12/23 15:26:26 mohor`
89			`// Small fix.`
90			`//`
91	83	mohor	`// Revision 1.1 2003/12/23 15:09:04 mohor`
92			`// New directory structure. New version of the debug interface.`
93	82	mohor	`//`
94			`//`
95	83	mohor	`//`
96	82	mohor
97			`// synopsys translate_off`
98			`include "timescale.v"
99			`// synopsys translate_on`
100			`include "dbg_wb_defines.v"
101
102			`// Top module`
103			`module dbg_wb(`
104			`// JTAG signals`
105			`tck_i,`
106			`tdi_i,`
107			`tdo_o,`
108
109			`// TAP states`
110			`shift_dr_i,`
111			`pause_dr_i,`
112			`update_dr_i,`
113
114			`wishbone_ce_i,`
115			`crc_match_i,`
116			`crc_en_o,`
117			`shift_crc_o,`
118	95	mohor	`rst_i,`
119	82	mohor
120			`// WISHBONE common signals`
121	95	mohor	`wb_clk_i,`
122	82	mohor
123			`// WISHBONE master interface`
124			`wb_adr_o, wb_dat_o, wb_dat_i, wb_cyc_o, wb_stb_o, wb_sel_o,`
125			`wb_we_o, wb_ack_i, wb_cab_o, wb_err_i, wb_cti_o, wb_bte_o`
126
127			`);`
128
129			`// JTAG signals`
130	97	mohor	`input tck_i;`
131			`input tdi_i;`
132			`output tdo_o;`
133	82	mohor
134			`// TAP states`
135	97	mohor	`input shift_dr_i;`
136			`input pause_dr_i;`
137			`input update_dr_i;`
138	82	mohor
139	97	mohor	`input wishbone_ce_i;`
140			`input crc_match_i;`
141			`output crc_en_o;`
142			`output shift_crc_o;`
143			`input rst_i;`
144	82	mohor	`// WISHBONE common signals`
145	97	mohor	`input wb_clk_i;`
146	82	mohor
147			`// WISHBONE master interface`
148			`output [31:0] wb_adr_o;`
149			`output [31:0] wb_dat_o;`
150			`input [31:0] wb_dat_i;`
151			`output wb_cyc_o;`
152			`output wb_stb_o;`
153			`output [3:0] wb_sel_o;`
154			`output wb_we_o;`
155			`input wb_ack_i;`
156			`output wb_cab_o;`
157			`input wb_err_i;`
158			`output [2:0] wb_cti_o;`
159			`output [1:0] wb_bte_o;`
160
161			`reg wb_cyc_o;`
162			`reg [31:0] wb_adr_o;`
163	88	mohor	`reg [31:0] wb_dat_o;`
164	82	mohor	`reg [3:0] wb_sel_o;`
165
166			`reg tdo_o;`
167
168	88	mohor	`reg [50:0] dr;`
169			`wire enable;`
170	90	mohor	`wire cmd_cnt_en;`
171	88	mohor	`reg [1:0] cmd_cnt;`
172			`wire cmd_cnt_end;`
173			`reg cmd_cnt_end_q;`
174	90	mohor	`wire addr_len_cnt_en;`
175	88	mohor	`reg [5:0] addr_len_cnt;`
176			`reg [5:0] addr_len_cnt_limit;`
177			`wire addr_len_cnt_end;`
178	90	mohor	`wire crc_cnt_en;`
179	88	mohor	`reg [5:0] crc_cnt;`
180			`wire crc_cnt_end;`
181			`reg crc_cnt_end_q;`
182	90	mohor	`wire data_cnt_en;`
183	88	mohor	`reg [18:0] data_cnt;`
184			`reg [18:0] data_cnt_limit;`
185			`wire data_cnt_end;`
186	90	mohor	`reg data_cnt_end_q;`
187	88	mohor	`reg status_reset_en;`
188	82	mohor
189	90	mohor	`reg crc_match_reg;`
190	82	mohor
191	92	mohor	`reg [2:0] cmd, cmd_old, dr_cmd_latched;`
192			`reg [31:0] adr;`
193			`reg [15:0] len;`
194			`reg start_rd_tck;`
195	97	mohor	`reg rd_tck_started;`
196	92	mohor	`reg start_rd_sync1;`
197			`reg start_wb_rd;`
198			`reg start_wb_rd_q;`
199			`reg start_wr_tck;`
200			`reg start_wr_sync1;`
201			`reg start_wb_wr;`
202			`reg start_wb_wr_q;`
203	88	mohor
204	92	mohor	`wire dr_read;`
205			`wire dr_write;`
206			`wire dr_go;`
207	88	mohor
208	92	mohor	`reg dr_write_latched;`
209			`reg dr_read_latched;`
210			`reg dr_go_latched;`
211	82	mohor
212	92	mohor	`wire status_cnt_end;`
213	89	mohor
214	92	mohor	`wire byte, half, long;`
215			`reg byte_q, half_q, long_q;`
216	94	mohor	`reg byte_q2, half_q2, long_q2;`
217	92	mohor	`reg cmd_read;`
218			`reg cmd_write;`
219			`reg cmd_go;`
220	90	mohor
221	92	mohor	`reg status_cnt1, status_cnt2, status_cnt3, status_cnt4;`
222	90	mohor
223	92	mohor	reg [`STATUS_LEN -1:0] status;
224
225	97	mohor	`reg wb_error, wb_error_sync, wb_error_tck;`
226			`reg wb_overrun, wb_overrun_sync, wb_overrun_tck;`
227			`reg underrun_tck;`
228	92	mohor
229	97	mohor	`reg busy_wb;`
230			`reg busy_tck;`
231			`reg wb_end;`
232			`reg wb_end_rst;`
233			`reg wb_end_rst_sync;`
234			`reg wb_end_sync;`
235			`reg wb_end_tck, wb_end_tck_q;`
236			`reg busy_sync;`
237			`reg latch_data;`
238	92	mohor
239	97	mohor	`reg set_addr, set_addr_sync, set_addr_wb, set_addr_wb_q;`
240			`reg read_cycle;`
241			`reg write_cycle;`
242			`reg [2:0] rw_type;`
243			`wire [31:0] input_data;`
244	92	mohor
245	97	mohor	`wire len_eq_0;`
246			`wire crc_cnt_31;`
247	93	mohor
248	97	mohor	`reg [1:0] ptr;`
249			`reg [2:0] fifo_cnt;`
250			`wire fifo_full;`
251			`wire fifo_empty;`
252			`reg [7:0] mem [0:3];`
253			`reg [2:0] mem_ptr;`
254			`reg wishbone_ce_sync;`
255			`reg wishbone_ce_rst;`
256			`wire go_prelim;`
257
258
259
260	82	mohor	`assign enable = wishbone_ce_i & shift_dr_i;`
261	90	mohor	`assign crc_en_o = enable & crc_cnt_end & (~status_cnt_end);`
262	89	mohor	`assign shift_crc_o = enable & status_cnt_end; // Signals dbg module to shift out the CRC`
263	82	mohor
264
265	97	mohor	`// Selecting where to take the data from`
266	82	mohor	`always @ (posedge tck_i)`
267			`begin`
268	93	mohor	`if (update_dr_i)`
269			`ptr <= #1 2'h0;`
270	95	mohor	`else if (read_cycle & crc_cnt_31) // first latch`
271	93	mohor	`ptr <= #1 ptr + 1'b1;`
272	95	mohor	`else if (read_cycle & byte & (~byte_q))`
273	93	mohor	`ptr <= ptr + 1'd1;`
274			`end`
275
276
277	97	mohor	`// Shift register for shifting in and out the data`
278	121	mohor	`always @ (posedge tck_i or posedge rst_i)`
279	93	mohor	`begin`
280	121	mohor	`if (rst_i)`
281	90	mohor	`begin`
282	121	mohor	`dr <= #1 51'h0;`
283			`latch_data <= #1 1'b0;`
284			`end`
285			`else if (read_cycle & crc_cnt_31)`
286			`begin`
287	93	mohor	`dr[31:0] <= #1 input_data[31:0];`
288	97	mohor	`latch_data <= #1 1'b1;`
289	93	mohor	`end`
290			`else if (read_cycle & crc_cnt_end)`
291			`begin`
292	95	mohor	`case (rw_type) // synthesis parallel_case full_case`
293	90	mohor	`WB_READ8 : begin
294			`if(byte & (~byte_q))`
295	92	mohor	`begin`
296	93	mohor	`case (ptr) // synthesis parallel_case`
297			`2'b00 : dr[31:24] <= #1 input_data[31:24];`
298			`2'b01 : dr[31:24] <= #1 input_data[23:16];`
299			`2'b10 : dr[31:24] <= #1 input_data[15:8];`
300			`2'b11 : dr[31:24] <= #1 input_data[7:0];`
301			`endcase`
302	97	mohor	`latch_data <= #1 1'b1;`
303	92	mohor	`end`
304	90	mohor	`else`
305	92	mohor	`begin`
306	93	mohor	`dr[31:24] <= #1 {dr[30:24], 1'b0};`
307	97	mohor	`latch_data <= #1 1'b0;`
308	92	mohor	`end`
309	90	mohor	`end`
310			`WB_READ16: begin
311			`if(half & (~half_q))`
312	92	mohor	`begin`
313	93	mohor	`if (ptr[1])`
314	97	mohor	`dr[31:16] <= #1 input_data[15:0];`
315			`else`
316	93	mohor	`dr[31:16] <= #1 input_data[31:16];`
317	97	mohor	`latch_data <= #1 1'b1;`
318	92	mohor	`end`
319	90	mohor	`else`
320	92	mohor	`begin`
321	93	mohor	`dr[31:16] <= #1 {dr[30:16], 1'b0};`
322	97	mohor	`latch_data <= #1 1'b0;`
323	92	mohor	`end`
324	90	mohor	`end`
325			`WB_READ32: begin
326			`if(long & (~long_q))`
327	92	mohor	`begin`
328	93	mohor	`dr[31:0] <= #1 input_data[31:0];`
329	97	mohor	`latch_data <= #1 1'b1;`
330	92	mohor	`end`
331	90	mohor	`else`
332	92	mohor	`begin`
333	93	mohor	`dr[31:0] <= #1 {dr[30:0], 1'b0};`
334	97	mohor	`latch_data <= #1 1'b0;`
335	92	mohor	`end`
336	90	mohor	`end`
337			`endcase`
338			`end`
339	94	mohor	`else if (enable & ((~addr_len_cnt_end) \| (~cmd_cnt_end) \| ((~data_cnt_end) & write_cycle)))`
340	92	mohor	`begin`
341	99	mohor	`dr <= #1 {dr[49:0], tdi_i};`
342			`latch_data <= #1 1'b0;`
343	92	mohor	`end`
344	82	mohor	`end`
345
346
347	90	mohor	`assign cmd_cnt_en = enable & (~cmd_cnt_end);`
348	88	mohor
349	97	mohor
350			`// Command counter`
351	95	mohor	`always @ (posedge tck_i or posedge rst_i)`
352	82	mohor	`begin`
353	95	mohor	`if (rst_i)`
354	108	simons	`cmd_cnt <= #1 2'h0;`
355	82	mohor	`else if (update_dr_i)`
356	108	simons	`cmd_cnt <= #1 2'h0;`
357	90	mohor	`else if (cmd_cnt_en)`
358	87	mohor	`cmd_cnt <= #1 cmd_cnt + 1'b1;`
359	82	mohor	`end`
360
361
362	90	mohor	`assign addr_len_cnt_en = enable & cmd_cnt_end & (~addr_len_cnt_end);`
363
364	97	mohor
365			`// Address/length counter`
366	95	mohor	`always @ (posedge tck_i or posedge rst_i)`
367	87	mohor	`begin`
368	95	mohor	`if (rst_i)`
369	108	simons	`addr_len_cnt <= #1 6'h0;`
370	88	mohor	`else if (update_dr_i)`
371	108	simons	`addr_len_cnt <= #1 6'h0;`
372	90	mohor	`else if (addr_len_cnt_en)`
373	88	mohor	`addr_len_cnt <= #1 addr_len_cnt + 1'b1;`
374			`end`
375
376
377	95	mohor	`assign data_cnt_en = enable & (~data_cnt_end) & (cmd_cnt_end & write_cycle \| crc_cnt_end & read_cycle);`
378	90	mohor
379	97	mohor
380			`// Data counter`
381	95	mohor	`always @ (posedge tck_i or posedge rst_i)`
382	88	mohor	`begin`
383	95	mohor	`if (rst_i)`
384	108	simons	`data_cnt <= #1 19'h0;`
385	87	mohor	`else if (update_dr_i)`
386	108	simons	`data_cnt <= #1 19'h0;`
387	90	mohor	`else if (data_cnt_en)`
388	87	mohor	`data_cnt <= #1 data_cnt + 1'b1;`
389			`end`
390	82	mohor
391	87	mohor
392	88	mohor
393	93	mohor	`assign byte = data_cnt[2:0] == 3'd7;`
394			`assign half = data_cnt[3:0] == 4'd15;`
395			`assign long = data_cnt[4:0] == 5'd31;`
396	88	mohor
397
398			`always @ (posedge tck_i)`
399			`begin`
400	95	mohor	`byte_q <= #1 byte;`
401			`half_q <= #1 half;`
402			`long_q <= #1 long;`
403			`byte_q2 <= #1 byte_q;`
404			`half_q2 <= #1 half_q;`
405			`long_q2 <= #1 long_q;`
406	88	mohor	`end`
407
408
409	108	simons	assign dr_read = (dr[2:0] == `WB_READ8) \|\| (dr[2:0] == `WB_READ16) \|\| (dr[2:0] == `WB_READ32);
410			assign dr_write = (dr[2:0] == `WB_WRITE8) \|\| (dr[2:0] == `WB_WRITE16) \|\| (dr[2:0] == `WB_WRITE32);
411	89	mohor	assign dr_go = dr[2:0] == `WB_GO;
412	88	mohor
413
414	97	mohor	`// Latching instruction`
415	88	mohor	`always @ (posedge tck_i)`
416			`begin`
417			`if (update_dr_i)`
418	91	mohor	`begin`
419	99	mohor	`dr_cmd_latched <= #1 3'h0;`
420	91	mohor	`dr_read_latched <= #1 1'b0;`
421			`dr_write_latched <= #1 1'b0;`
422			`dr_go_latched <= #1 1'b0;`
423			`end`
424	88	mohor	`else if (cmd_cnt_end & (~cmd_cnt_end_q))`
425	91	mohor	`begin`
426	99	mohor	`dr_cmd_latched <= #1 dr[2:0];`
427	91	mohor	`dr_read_latched <= #1 dr_read;`
428			`dr_write_latched <= #1 dr_write;`
429			`dr_go_latched <= #1 dr_go;`
430			`end`
431	88	mohor	`end`
432
433
434	97	mohor	`// Upper limit. Address/length counter counts until this value is reached`
435	88	mohor	`always @ (posedge tck_i)`
436			`begin`
437	90	mohor	`if (cmd_cnt == 2'h2)`
438	88	mohor	`begin`
439	95	mohor	`if ((~dr[0]) & (~tdi_i)) // (current command is WB_STATUS or WB_GO)`
440	99	mohor	`addr_len_cnt_limit <= #1 6'd0;`
441	90	mohor	`else // (current command is WB_WRITEx or WB_READx)`
442	99	mohor	`addr_len_cnt_limit <= #1 6'd48;`
443	88	mohor	`end`
444			`end`
445
446
447	94	mohor	`assign go_prelim = (cmd_cnt == 2'h2) & dr[1] & (~dr[0]) & (~tdi_i);`
448
449	88	mohor
450	97	mohor	`// Upper limit. Data counter counts until this value is reached.`
451	94	mohor	`always @ (posedge tck_i)`
452			`begin`
453			`if (update_dr_i)`
454	99	mohor	`data_cnt_limit <= #1 {len, 3'b000};`
455	94	mohor	`end`
456	88	mohor
457	90	mohor
458	94	mohor	`assign crc_cnt_en = enable & (~crc_cnt_end) & (cmd_cnt_end & addr_len_cnt_end & (~write_cycle) \| (data_cnt_end & write_cycle));`
459
460	97	mohor
461	82	mohor	`// crc counter`
462	95	mohor	`always @ (posedge tck_i or posedge rst_i)`
463	82	mohor	`begin`
464	95	mohor	`if (rst_i)`
465	108	simons	`crc_cnt <= #1 6'h0;`
466	90	mohor	`else if(crc_cnt_en)`
467	82	mohor	`crc_cnt <= #1 crc_cnt + 1'b1;`
468			`else if (update_dr_i)`
469	108	simons	`crc_cnt <= #1 6'h0;`
470	82	mohor	`end`
471
472	87	mohor	`assign cmd_cnt_end = cmd_cnt == 2'h3;`
473	88	mohor	`assign addr_len_cnt_end = addr_len_cnt == addr_len_cnt_limit;`
474	87	mohor	`assign crc_cnt_end = crc_cnt == 6'd32;`
475	93	mohor	`assign crc_cnt_31 = crc_cnt == 6'd31;`
476	89	mohor	`assign data_cnt_end = (data_cnt == data_cnt_limit);`
477	82	mohor
478			`always @ (posedge tck_i)`
479			`begin`
480	90	mohor	`crc_cnt_end_q <= #1 crc_cnt_end;`
481			`cmd_cnt_end_q <= #1 cmd_cnt_end;`
482			`data_cnt_end_q <= #1 data_cnt_end;`
483	82	mohor	`end`
484
485	90	mohor
486	97	mohor	`// Status counter is made of 4 serialy connected registers`
487	95	mohor	`always @ (posedge tck_i or posedge rst_i)`
488	82	mohor	`begin`
489	95	mohor	`if (rst_i)`
490	90	mohor	`status_cnt1 <= #1 1'b0;`
491	82	mohor	`else if (update_dr_i)`
492	90	mohor	`status_cnt1 <= #1 1'b0;`
493	94	mohor	`else if (data_cnt_end & read_cycle \|`
494	95	mohor	`crc_cnt_end & (~read_cycle)`
495	90	mohor	`)`
496			`status_cnt1 <= #1 1'b1;`
497	82	mohor	`end`
498
499	90	mohor
500	95	mohor	`always @ (posedge tck_i or posedge rst_i)`

Browse

Tools

Subversion Repositories dbg_interface

[/] [dbg_interface/] [trunk/] [rtl/] [verilog/] [dbg_wb.v] - Blame information for rev 121