URL https://opencores.org/ocsvn/eco32/eco32/trunk

Subversion Repositories eco32

[/] [eco32/] [trunk/] [stdalone/] [twotasks-1/] [os/] [start.s] - Blame information for rev 136

Go to most recent revision | Details | Compare with Previous | View Log


;
; start.s -- startup code
;
 
        .import main
        .import task0StkTop
        .import currentStkTop
        .import _ecode
        .import _edata
        .import _ebss
 
        .export _bcode
        .export _bdata
        .export _bbss
 
        .export enable
        .export disable
        .export orMask
        .export andMask
        .export getISR
        .export setISR
        .export startTask
        .export setTLB
 
        .code
_bcode:
 
        .data
_bdata:
 
        .bss
_bbss:
 
        .code
 
        ; reset arrives here
reset:
        j       start
 
        ; interrupts arrive here
intrpt:
        j       isr
 
        ; user TLB misses arrive here
userMiss:
        j       isr
 
isr:
        add     $26,$29,$0               ; sp -> $26
        add     $27,$1,$0                ; $1 -> $27
        ldw     $29,$0,currentStkTop     ; setup kernel mode stack
        sub     $29,$29,128             ; save registers
        stw     $2,$29,8
        stw     $3,$29,12
        stw     $4,$29,16
        stw     $5,$29,20
        stw     $6,$29,24
        stw     $7,$29,28
        stw     $8,$29,32
        stw     $9,$29,36
        stw     $10,$29,40
        stw     $11,$29,44
        stw     $12,$29,48
        stw     $13,$29,52
        stw     $14,$29,56
        stw     $15,$29,60
        stw     $16,$29,64
        stw     $17,$29,68
        stw     $18,$29,72
        stw     $19,$29,76
        stw     $20,$29,80
        stw     $21,$29,84
        stw     $22,$29,88
        stw     $23,$29,92
        stw     $24,$29,96
        stw     $25,$29,100
        stw     $26,$29,116             ; this is the task's sp
        stw     $27,$29,4               ; this is the task's $1
        stw     $30,$29,120             ; this is the task's resumption addr
        stw     $31,$29,124
        add     $5,$29,$0                ; $5 = pointer to register array
        mvfs    $4,0                     ; $4 = IRQ number
        slr     $4,$4,16
        and     $4,$4,0x1F
        sll     $26,$4,2                ; $26 = 4 * IRQ number
        ldw     $26,$26,irqsrv          ; get addr of service routine
        jalr    $26                     ; call service routine
        j       resume                  ; resume task if ISR returns
 
        ; resume a task
resume:
        ldw     $29,$0,currentStkTop     ; setup kernel mode stack
        sub     $29,$29,128             ; restore registers
        ldw     $2,$29,8
        ldw     $3,$29,12
        ldw     $4,$29,16
        ldw     $5,$29,20
        ldw     $6,$29,24
        ldw     $7,$29,28
        ldw     $8,$29,32
        ldw     $9,$29,36
        ldw     $10,$29,40
        ldw     $11,$29,44
        ldw     $12,$29,48
        ldw     $13,$29,52
        ldw     $14,$29,56
        ldw     $15,$29,60
        ldw     $16,$29,64
        ldw     $17,$29,68
        ldw     $18,$29,72
        ldw     $19,$29,76
        ldw     $20,$29,80
        ldw     $21,$29,84
        ldw     $22,$29,88
        ldw     $23,$29,92
        ldw     $24,$29,96
        ldw     $25,$29,100
        ldw     $26,$29,116             ; this is the task's sp
        ldw     $27,$29,4               ; this is the task's $1
        ldw     $30,$29,120             ; this is the task's resumption addr
        ldw     $31,$29,124
        add     $1,$27,$0                ; $27 -> $1
        add     $29,$26,$0               ; $26 -> sp
        rfx                             ; return from exception
 
start:
        add     $8,$0,0xA8003FFF
        add     $9,$0,0xC0000000
        stw     $8,$9,0          ; 0xC0000000: j 0xC0010000
        stw     $8,$9,4         ; 0xC0000004: j 0xC0010004
        stw     $8,$9,8         ; 0xC0000008: j 0xC0010008
        mvfs    $8,0
        or      $8,$8,1 << 27           ; let vector point to RAM
        mvts    $8,0
        add     $10,$0,_bdata            ; copy data segment
        add     $8,$0,_edata
        sub     $9,$8,$10
        add     $9,$9,_ecode
        j       cpytest
cpyloop:
        ldw     $11,$9,0
        stw     $11,$8,0
cpytest:
        sub     $8,$8,4
        sub     $9,$9,4
        bgeu    $8,$10,cpyloop
        add     $8,$0,_bbss              ; clear bss
        add     $9,$0,_ebss
        j       clrtest
clrloop:
        stw     $0,$8,0
        add     $8,$8,4
clrtest:
        bltu    $8,$9,clrloop
        ldw     $29,$0,task0StkTop       ; setup kernel mode stack for task 0
        jal     main                    ; call 'main'
start1:
        j       start1                  ; loop
 
enable:
        mvfs    $8,0
        or      $8,$8,1 << 23
        mvts    $8,0
        jr      $31
 
disable:
        mvfs    $8,0
        and     $8,$8,~(1 << 23)
        mvts    $8,0
        jr      $31
 
orMask:
        mvfs    $8,0
        and     $4,$4,0x0000FFFF        ; use lower 16 bits only
        or      $8,$8,$4
        mvts    $8,0
        jr      $31
 
andMask:
        mvfs    $8,0
        or      $4,$4,0xFFFF0000        ; use lower 16 bits only
        and     $8,$8,$4
        mvts    $8,0
        jr      $31
 
getISR:
        sll     $4,$4,2
        ldw     $2,$4,irqsrv
        jr      $31
 
setISR:
        sll     $4,$4,2
        stw     $5,$4,irqsrv
        jr      $31
 
startTask:
        ldw     $29,$0,currentStkTop     ; setup kernel mode stack
        sub     $29,$29,128
        stw     $0,$29,0          ; preset registers
        stw     $0,$29,4
        stw     $0,$29,8
        stw     $0,$29,12
        stw     $0,$29,16
        stw     $0,$29,20
        stw     $0,$29,24
        stw     $0,$29,28
        stw     $0,$29,32
        stw     $0,$29,36
        stw     $0,$29,40
        stw     $0,$29,44
        stw     $0,$29,48
        stw     $0,$29,52
        stw     $0,$29,56
        stw     $0,$29,60
        stw     $0,$29,64
        stw     $0,$29,68
        stw     $0,$29,72
        stw     $0,$29,76
        stw     $0,$29,80
        stw     $0,$29,84
        stw     $0,$29,88
        stw     $0,$29,92
        stw     $0,$29,96
        stw     $0,$29,100
        stw     $0,$29,104
        stw     $0,$29,108
        stw     $0,$29,112
        add     $8,$0,0x80000000
        stw     $8,$29,116              ; sp
        stw     $0,$29,120               ; task starts at virtual addr 0
        stw     $0,$29,124
        mvfs    $8,0
        or      $8,$8,1 << 25           ; set previous mode to 'user'
        or      $8,$8,1 << 22           ; and enable interrupts
        mvts    $8,0
        j       resume
 
setTLB:
        mvts    $4,1                    ; set index
        mvts    $5,2                    ; set entryHi
        mvts    $6,3                    ; set entryLo
        tbwi                            ; write TLB entry at index
        jr      $31
 
        .data
 
; interrupt service routine table
 
        .align  4
 
irqsrv:
        .word   0                ; 00: terminal 0 transmitter interrupt
        .word   0                ; 01: terminal 0 receiver interrupt
        .word   0                ; 02: terminal 1 transmitter interrupt
        .word   0                ; 03: terminal 1 receiver interrupt
        .word   0                ; 04: keyboard interrupt
        .word   0                ; 05: unused
        .word   0                ; 06: unused
        .word   0                ; 07: unused
        .word   0                ; 08: disk interrupt
        .word   0                ; 09: unused
        .word   0                ; 10: unused
        .word   0                ; 11: unused
        .word   0                ; 12: unused
        .word   0                ; 13: unused
        .word   0                ; 14: timer 0 interrupt
        .word   0                ; 15: timer 1 interrupt
        .word   0                ; 16: bus timeout exception
        .word   0                ; 17: illegal instruction exception
        .word   0                ; 18: privileged instruction exception
        .word   0                ; 19: divide instruction exception
        .word   0                ; 20: trap instruction exception
        .word   0                ; 21: TLB miss exception
        .word   0                ; 22: TLB write exception
        .word   0                ; 23: TLB invalid exception
        .word   0                ; 24: illegal address exception
        .word   0                ; 25: privileged address exception
        .word   0                ; 26: unused
        .word   0                ; 27: unused
        .word   0                ; 28: unused
        .word   0                ; 29: unused
        .word   0                ; 30: unused
        .word   0                ; 31: unused

Browse

Tools

Subversion Repositories eco32

[/] [eco32/] [trunk/] [stdalone/] [twotasks-1/] [os/] [start.s] - Blame information for rev 136

Line No.	Rev	Author	Line
1	18	hellwig	`;`
2			`; start.s -- startup code`
3			`;`
4
5			`.import main`
6			`.import task0StkTop`
7			`.import currentStkTop`
8			`.import _ecode`
9			`.import _edata`
10			`.import _ebss`
11
12			`.export _bcode`
13			`.export _bdata`
14			`.export _bbss`
15
16			`.export enable`
17			`.export disable`
18			`.export orMask`
19			`.export andMask`
20			`.export getISR`
21			`.export setISR`
22			`.export startTask`
23			`.export setTLB`
24
25			`.code`
26			`_bcode:`
27
28			`.data`
29			`_bdata:`
30
31			`.bss`
32			`_bbss:`
33
34			`.code`
35
36			`; reset arrives here`
37			`reset:`
38			`j start`
39
40			`; interrupts arrive here`
41			`intrpt:`
42			`j isr`
43
44			`; user TLB misses arrive here`
45			`userMiss:`
46			`j isr`
47
48			`isr:`
49			`add $26,$29,$0 ; sp -> $26`
50			`add $27,$1,$0 ; $1 -> $27`
51			`ldw $29,$0,currentStkTop ; setup kernel mode stack`
52			`sub $29,$29,128 ; save registers`
53			`stw $2,$29,8`
54			`stw $3,$29,12`
55			`stw $4,$29,16`
56			`stw $5,$29,20`
57			`stw $6,$29,24`
58			`stw $7,$29,28`
59			`stw $8,$29,32`
60			`stw $9,$29,36`
61			`stw $10,$29,40`
62			`stw $11,$29,44`
63			`stw $12,$29,48`
64			`stw $13,$29,52`
65			`stw $14,$29,56`
66			`stw $15,$29,60`
67			`stw $16,$29,64`
68			`stw $17,$29,68`
69			`stw $18,$29,72`
70			`stw $19,$29,76`
71			`stw $20,$29,80`
72			`stw $21,$29,84`
73			`stw $22,$29,88`
74			`stw $23,$29,92`
75			`stw $24,$29,96`
76			`stw $25,$29,100`
77			`stw $26,$29,116 ; this is the task's sp`
78			`stw $27,$29,4 ; this is the task's $1`
79			`stw $30,$29,120 ; this is the task's resumption addr`
80			`stw $31,$29,124`
81			`add $5,$29,$0 ; $5 = pointer to register array`
82			`mvfs $4,0 ; $4 = IRQ number`
83			`slr $4,$4,16`
84			`and $4,$4,0x1F`
85			`sll $26,$4,2 ; $26 = 4 * IRQ number`
86			`ldw $26,$26,irqsrv ; get addr of service routine`
87			`jalr $26 ; call service routine`
88			`j resume ; resume task if ISR returns`
89
90			`; resume a task`
91			`resume:`
92			`ldw $29,$0,currentStkTop ; setup kernel mode stack`
93			`sub $29,$29,128 ; restore registers`
94			`ldw $2,$29,8`
95			`ldw $3,$29,12`
96			`ldw $4,$29,16`
97			`ldw $5,$29,20`
98			`ldw $6,$29,24`
99			`ldw $7,$29,28`
100			`ldw $8,$29,32`
101			`ldw $9,$29,36`
102			`ldw $10,$29,40`
103			`ldw $11,$29,44`
104			`ldw $12,$29,48`
105			`ldw $13,$29,52`
106			`ldw $14,$29,56`
107			`ldw $15,$29,60`
108			`ldw $16,$29,64`
109			`ldw $17,$29,68`
110			`ldw $18,$29,72`
111			`ldw $19,$29,76`
112			`ldw $20,$29,80`
113			`ldw $21,$29,84`
114			`ldw $22,$29,88`
115			`ldw $23,$29,92`
116			`ldw $24,$29,96`
117			`ldw $25,$29,100`
118			`ldw $26,$29,116 ; this is the task's sp`
119			`ldw $27,$29,4 ; this is the task's $1`
120			`ldw $30,$29,120 ; this is the task's resumption addr`
121			`ldw $31,$29,124`
122			`add $1,$27,$0 ; $27 -> $1`
123			`add $29,$26,$0 ; $26 -> sp`
124			`rfx ; return from exception`
125
126			`start:`
127	101	hellwig	`add $8,$0,0xA8003FFF`
128			`add $9,$0,0xC0000000`
129			`stw $8,$9,0 ; 0xC0000000: j 0xC0010000`
130			`stw $8,$9,4 ; 0xC0000004: j 0xC0010004`
131			`stw $8,$9,8 ; 0xC0000008: j 0xC0010008`
132	18	hellwig	`mvfs $8,0`
133			`or $8,$8,1 << 27 ; let vector point to RAM`
134			`mvts $8,0`
135			`add $10,$0,_bdata ; copy data segment`
136			`add $8,$0,_edata`
137			`sub $9,$8,$10`
138			`add $9,$9,_ecode`
139			`j cpytest`
140			`cpyloop:`
141			`ldw $11,$9,0`
142			`stw $11,$8,0`
143			`cpytest:`
144			`sub $8,$8,4`
145			`sub $9,$9,4`
146			`bgeu $8,$10,cpyloop`
147			`add $8,$0,_bbss ; clear bss`
148			`add $9,$0,_ebss`
149			`j clrtest`
150			`clrloop:`
151			`stw $0,$8,0`
152			`add $8,$8,4`
153			`clrtest:`
154			`bltu $8,$9,clrloop`
155			`ldw $29,$0,task0StkTop ; setup kernel mode stack for task 0`
156			`jal main ; call 'main'`
157			`start1:`
158			`j start1 ; loop`
159
160			`enable:`
161			`mvfs $8,0`
162			`or $8,$8,1 << 23`
163			`mvts $8,0`
164			`jr $31`
165
166			`disable:`
167			`mvfs $8,0`
168			`and $8,$8,~(1 << 23)`
169			`mvts $8,0`
170			`jr $31`
171
172			`orMask:`
173			`mvfs $8,0`
174			`and $4,$4,0x0000FFFF ; use lower 16 bits only`
175			`or $8,$8,$4`
176			`mvts $8,0`
177			`jr $31`
178
179			`andMask:`
180			`mvfs $8,0`
181			`or $4,$4,0xFFFF0000 ; use lower 16 bits only`
182			`and $8,$8,$4`
183			`mvts $8,0`
184			`jr $31`
185
186			`getISR:`
187			`sll $4,$4,2`
188			`ldw $2,$4,irqsrv`
189			`jr $31`
190
191			`setISR:`
192			`sll $4,$4,2`
193			`stw $5,$4,irqsrv`
194			`jr $31`
195
196			`startTask:`
197			`ldw $29,$0,currentStkTop ; setup kernel mode stack`
198			`sub $29,$29,128`
199			`stw $0,$29,0 ; preset registers`
200			`stw $0,$29,4`
201			`stw $0,$29,8`
202			`stw $0,$29,12`
203			`stw $0,$29,16`
204			`stw $0,$29,20`
205			`stw $0,$29,24`
206			`stw $0,$29,28`
207			`stw $0,$29,32`
208			`stw $0,$29,36`
209			`stw $0,$29,40`
210			`stw $0,$29,44`
211			`stw $0,$29,48`
212			`stw $0,$29,52`
213			`stw $0,$29,56`
214			`stw $0,$29,60`
215			`stw $0,$29,64`
216			`stw $0,$29,68`
217			`stw $0,$29,72`
218			`stw $0,$29,76`
219			`stw $0,$29,80`
220			`stw $0,$29,84`
221			`stw $0,$29,88`
222			`stw $0,$29,92`
223			`stw $0,$29,96`
224			`stw $0,$29,100`
225			`stw $0,$29,104`
226			`stw $0,$29,108`
227			`stw $0,$29,112`
228			`add $8,$0,0x80000000`
229			`stw $8,$29,116 ; sp`
230			`stw $0,$29,120 ; task starts at virtual addr 0`
231			`stw $0,$29,124`
232			`mvfs $8,0`
233			`or $8,$8,1 << 25 ; set previous mode to 'user'`
234			`or $8,$8,1 << 22 ; and enable interrupts`
235			`mvts $8,0`
236			`j resume`
237
238			`setTLB:`
239			`mvts $4,1 ; set index`
240			`mvts $5,2 ; set entryHi`
241			`mvts $6,3 ; set entryLo`
242			`tbwi ; write TLB entry at index`
243			`jr $31`
244
245			`.data`
246
247			`; interrupt service routine table`
248
249			`.align 4`
250
251			`irqsrv:`
252			`.word 0 ; 00: terminal 0 transmitter interrupt`
253			`.word 0 ; 01: terminal 0 receiver interrupt`
254			`.word 0 ; 02: terminal 1 transmitter interrupt`
255			`.word 0 ; 03: terminal 1 receiver interrupt`
256			`.word 0 ; 04: keyboard interrupt`
257			`.word 0 ; 05: unused`
258			`.word 0 ; 06: unused`
259			`.word 0 ; 07: unused`
260			`.word 0 ; 08: disk interrupt`
261			`.word 0 ; 09: unused`
262			`.word 0 ; 10: unused`
263			`.word 0 ; 11: unused`
264			`.word 0 ; 12: unused`
265			`.word 0 ; 13: unused`
266	38	hellwig	`.word 0 ; 14: timer 0 interrupt`
267			`.word 0 ; 15: timer 1 interrupt`
268	18	hellwig	`.word 0 ; 16: bus timeout exception`
269			`.word 0 ; 17: illegal instruction exception`
270			`.word 0 ; 18: privileged instruction exception`
271			`.word 0 ; 19: divide instruction exception`
272			`.word 0 ; 20: trap instruction exception`
273			`.word 0 ; 21: TLB miss exception`
274			`.word 0 ; 22: TLB write exception`
275			`.word 0 ; 23: TLB invalid exception`
276			`.word 0 ; 24: illegal address exception`
277			`.word 0 ; 25: privileged address exception`
278			`.word 0 ; 26: unused`
279			`.word 0 ; 27: unused`
280			`.word 0 ; 28: unused`
281			`.word 0 ; 29: unused`
282			`.word 0 ; 30: unused`
283			`.word 0 ; 31: unused`