URL https://opencores.org/ocsvn/openmsp430/openmsp430/trunk

Subversion Repositories openmsp430

[/] [openmsp430/] [trunk/] [fpga/] [xilinx_diligent_s3board/] [software/] [ta_uart/] [swuart.s] - Blame information for rev 143

Go to most recent revision | Details | Compare with Previous | View Log


 
#include "hardware.h"
 
;variables
.data
        .comm   rxdata,1,1              ;char var
        .comm   rxshift,1,1             ;char var
        .comm   rxbit,2,2               ;short var, aligned
 
.text
 
vector_0x0012:
;interrupt(TIMERA0_VECTOR)               ;register interrupt vector
;interrupt handler to receive as Timer_A UART
.global ccr0                            ;place a label afterwards so
ccr0:                                   ;that it is used in the listing
        add     &rxbit, r0
        jmp     .Lrxstart               ;start bit
        jmp     .Lrxdatabit             ;D0
        jmp     .Lrxdatabit             ;D1
        jmp     .Lrxdatabit             ;D2
        jmp     .Lrxdatabit             ;D3
        jmp     .Lrxdatabit             ;D4
        jmp     .Lrxdatabit             ;D5
        jmp     .Lrxdatabit             ;D6
;        jmp     .Lrxlastbit             ;D7 that one is following anyway
 
.Lrxlastbit:                            ;last bit, handle byte
        bit     #SCCI, &CCTL0           ;read last bit
        rrc.b   &rxshift                 ;and save it
        clr     &rxbit                   ;reset state
        mov     #CCIE|CAP|CM_2|CCIS_1|SCS, &CCTL0   ;restore capture mode
        mov.b   &rxshift, &rxdata         ;copy received data
        bic     #CPUOFF|OSCOFF|SCG0|SCG1, 0(r1) ;exit all lowpower modes
        ;here you might do other things too, like setting a flag
        ;that the wakeup comes from the Timer_A UART. however
        ;it should not take longer than one bit time, otherwise
        ;charcetrs will be lost.
        reti
 
.Lrxstart:                              ;startbit, init
        clr     &rxshift                 ;clear input buffer
        add     #(BAUD/2), &CCR0        ;startbit + 1.5 bits -> first bit
        mov     #CCIE|CCIS_1|SCS, &CCTL0;set compare mode, sample bits
        jmp     .Lrxex                  ;set state,...
 
.Lrxdatabit:                            ;save databit
        bit     #SCCI, &CCTL0           ;measure databit
        rrc.b   &rxshift                 ;rotate in databit
 
.Lrxex: add     #BAUD, &CCR0            ;one bit delay
        incd    &rxbit                   ;setup next state
        reti
 
; void serPutc(char)
;use an other Capture/Compare than for receiving (full duplex).
;this one is without interrupts and OUTMOD, because only
;this way P1.1 can be used. P1.1 is prefered because the
;BSL is on that pin too.
.global putchar
        .type putchar, @function
putchar:                                ;send a byte
        mov     #0, &CCTL1              ;select compare mode
        mov     #10, r13                ;ten bits: Start, 8 Data, Stop
        rla     r15                     ;shift in start bit (0)
        bis     #0x0200, r15            ;set tenth bit (1), thats the stop bit
        mov     &TAR, &CCR1             ;set up start time
.Lt1lp: add     #BAUD, &CCR1            ;set up for one bit
        rrc     r15                     ;shift data trough carry
        jc      .Lt1                    ;test carry bit
.Lt0:   bic.b   #TX, &P1OUT             ;generate pulse
        jmp     .Ltc                    ;
.Lt1:   bis.b   #TX, &P1OUT             ;just use the same amount of time as for a zero
        jmp     .Ltc                    ;
.Ltc:   bit     #CCIFG, &CCTL1          ;wait for compare
        jz      .Ltc                    ;loop until the bit is set
        bic     #CCIFG, &CCTL1          ;clear for next loop
        dec     r13                     ;decrement bit counter
        jnz     .Lt1lp                  ;loop until all bits are transmitted
        ret

Line No.	Rev	Author	Line
1	143	olivier.gi
2	2	olivier.gi	`#include "hardware.h"`
3
4			`;variables`
5			`.data`
6			`.comm rxdata,1,1 ;char var`
7			`.comm rxshift,1,1 ;char var`
8			`.comm rxbit,2,2 ;short var, aligned`
9
10			`.text`
11
12	143	olivier.gi	`vector_0x0012:`
13			`;interrupt(TIMERA0_VECTOR) ;register interrupt vector`
14	2	olivier.gi	`;interrupt handler to receive as Timer_A UART`
15			`.global ccr0 ;place a label afterwards so`
16			`ccr0: ;that it is used in the listing`
17	143	olivier.gi	`add &rxbit, r0`
18	2	olivier.gi	`jmp .Lrxstart ;start bit`
19			`jmp .Lrxdatabit ;D0`
20			`jmp .Lrxdatabit ;D1`
21			`jmp .Lrxdatabit ;D2`
22			`jmp .Lrxdatabit ;D3`
23			`jmp .Lrxdatabit ;D4`
24			`jmp .Lrxdatabit ;D5`
25			`jmp .Lrxdatabit ;D6`
26			`; jmp .Lrxlastbit ;D7 that one is following anyway`
27
28			`.Lrxlastbit: ;last bit, handle byte`
29			`bit #SCCI, &CCTL0 ;read last bit`
30	143	olivier.gi	`rrc.b &rxshift ;and save it`
31			`clr &rxbit ;reset state`
32	2	olivier.gi	`mov #CCIE\|CAP\|CM_2\|CCIS_1\|SCS, &CCTL0 ;restore capture mode`
33	143	olivier.gi	`mov.b &rxshift, &rxdata ;copy received data`
34	2	olivier.gi	`bic #CPUOFF\|OSCOFF\|SCG0\|SCG1, 0(r1) ;exit all lowpower modes`
35			`;here you might do other things too, like setting a flag`
36			`;that the wakeup comes from the Timer_A UART. however`
37			`;it should not take longer than one bit time, otherwise`
38			`;charcetrs will be lost.`
39			`reti`
40
41			`.Lrxstart: ;startbit, init`
42	143	olivier.gi	`clr &rxshift ;clear input buffer`
43	2	olivier.gi	`add #(BAUD/2), &CCR0 ;startbit + 1.5 bits -> first bit`
44			`mov #CCIE\|CCIS_1\|SCS, &CCTL0;set compare mode, sample bits`
45			`jmp .Lrxex ;set state,...`
46
47			`.Lrxdatabit: ;save databit`
48			`bit #SCCI, &CCTL0 ;measure databit`
49	143	olivier.gi	`rrc.b &rxshift ;rotate in databit`
50	2	olivier.gi
51			`.Lrxex: add #BAUD, &CCR0 ;one bit delay`
52	143	olivier.gi	`incd &rxbit ;setup next state`
53	2	olivier.gi	`reti`
54
55			`; void serPutc(char)`
56			`;use an other Capture/Compare than for receiving (full duplex).`
57			`;this one is without interrupts and OUTMOD, because only`
58			`;this way P1.1 can be used. P1.1 is prefered because the`
59			`;BSL is on that pin too.`
60			`.global putchar`
61			`.type putchar, @function`
62			`putchar: ;send a byte`
63			`mov #0, &CCTL1 ;select compare mode`
64			`mov #10, r13 ;ten bits: Start, 8 Data, Stop`
65			`rla r15 ;shift in start bit (0)`
66			`bis #0x0200, r15 ;set tenth bit (1), thats the stop bit`
67			`mov &TAR, &CCR1 ;set up start time`
68			`.Lt1lp: add #BAUD, &CCR1 ;set up for one bit`
69			`rrc r15 ;shift data trough carry`
70			`jc .Lt1 ;test carry bit`
71			`.Lt0: bic.b #TX, &P1OUT ;generate pulse`
72			`jmp .Ltc ;`
73			`.Lt1: bis.b #TX, &P1OUT ;just use the same amount of time as for a zero`
74			`jmp .Ltc ;`
75			`.Ltc: bit #CCIFG, &CCTL1 ;wait for compare`
76			`jz .Ltc ;loop until the bit is set`
77			`bic #CCIFG, &CCTL1 ;clear for next loop`
78			`dec r13 ;decrement bit counter`
79			`jnz .Lt1lp ;loop until all bits are transmitted`
80			`ret`

Browse

Tools

Subversion Repositories openmsp430

[/] [openmsp430/] [trunk/] [fpga/] [xilinx_diligent_s3board/] [software/] [ta_uart/] [swuart.s] - Blame information for rev 143