URL https://opencores.org/ocsvn/openrisc/openrisc/trunk

Subversion Repositories openrisc

[/] [openrisc/] [trunk/] [gnu-old/] [newlib-1.17.0/] [libgloss/] [m68k/] [mvme135.ld] - Blame information for rev 842

Go to most recent revision | Details | Compare with Previous | View Log


STARTUP(crt0.o)
OUTPUT_ARCH(m68k)
/* Uncomment this if you want srecords. This is needed for a.out
 * if you plan to use GDB.
OUTPUT_FORMAT(srec)
 */
SEARCH_DIR(.)
GROUP(-lmvme135 -lc -lgcc)
__DYNAMIC  =  0;
 
/*
 * Setup the memory map of the Motorola MVME135 Board
 * stack grows down from high memory.
 *
 * The memory map look like this:
 * +--------------------+ <- low memory
 * | .text              |
 * |        _etext      |
 * |        ctor list   | the ctor and dtor lists are for
 * |        dtor list   | C++ support
 * +--------------------+
 * | .data              | initialized data goes here
 * |        _edata      |
 * +--------------------+
 * | .bss               |
 * |        __bss_start | start of bss, cleared by crt0
 * |        _end        | start of heap, used by sbrk()
 * +--------------------+
 * .                    .
 * .                    .
 * .                    .
 * |        __stack     | top of stack
 * +--------------------+
 */
 
MEMORY
{
  ram (rwx) : ORIGIN = 0x5000, LENGTH = 1M
}
 
/*
 * Allocate the stack to be at the top of memory, since the stack
 * grows down
 */
 
PROVIDE (__stack = 1M - 8);
 
/*
 * Initalize some symbols to be zero so we can reference them in the
 * crt0 without core dumping. These functions are all optional, but
 * we do this so we can have our crt0 always use them if they exist.
 * This is so BSPs work better when using the crt0 installed gcc.
 * We have to initalize them twice, so we cover a.out (which prepends
 * an underscore) and coff object file formats.
 */
PROVIDE (hardware_init_hook = 0);
PROVIDE (_hardware_init_hook = 0);
PROVIDE (software_init_hook = 0);
PROVIDE (_software_init_hook = 0);
/*
 * stick everything in ram (of course)
 */
SECTIONS
{
  .text :
  {
    *(.text .text.*)
    . = ALIGN(0x4);
     __CTOR_LIST__ = .;
    ___CTOR_LIST__ = .;
    LONG((__CTOR_END__ - __CTOR_LIST__) / 4 - 2)
    *(.ctors)
    LONG(0)
    __CTOR_END__ = .;
    __DTOR_LIST__ = .;
    ___DTOR_LIST__ = .;
    LONG((__DTOR_END__ - __DTOR_LIST__) / 4 - 2)
    *(.dtors)
     LONG(0)
    __DTOR_END__ = .;
    *(.rodata .rodata.*)
    *(.gcc_except_table)
 
    . = ALIGN(0x2);
    __INIT_SECTION__ = . ;
    LONG (0x4e560000)   /* linkw %fp,#0 */
    *(.init)
    SHORT (0x4e5e)      /* unlk %fp */
    SHORT (0x4e75)      /* rts */
 
    __FINI_SECTION__ = . ;
    LONG (0x4e560000)   /* linkw %fp,#0 */
    *(.fini)
    SHORT (0x4e5e)      /* unlk %fp */
    SHORT (0x4e75)      /* rts */
 
    _etext = .;
    *(.lit)
  } > ram
 
  .data :
  {
    *(.got.plt) *(.got)
    *(.shdata)
    *(.data .data.*)
    _edata = .;
  } > ram
 
  .bss :
  {
    . = ALIGN(0x4);
    __bss_start = . ;
    *(.shbss)
    *(.bss .bss.*)
    *(COMMON)
    _end =  ALIGN (0x8);
    __end = _end;
  } > ram
 
  .stab 0 (NOLOAD) :
  {
    *(.stab)
  }
 
  .stabstr 0 (NOLOAD) :
  {
    *(.stabstr)
  }
}

Line No.	Rev	Author	Line
1	148	jeremybenn	`STARTUP(crt0.o)`
2			`OUTPUT_ARCH(m68k)`
3			`/* Uncomment this if you want srecords. This is needed for a.out`
4			`* if you plan to use GDB.`
5			`OUTPUT_FORMAT(srec)`
6			`*/`
7			`SEARCH_DIR(.)`
8			`GROUP(-lmvme135 -lc -lgcc)`
9			`__DYNAMIC = 0;`
10
11			`/*`
12			`* Setup the memory map of the Motorola MVME135 Board`
13			`* stack grows down from high memory.`
14			`*`
15			`* The memory map look like this:`
16			`* +--------------------+ <- low memory`
17			`* \| .text \|`
18			`* \| _etext \|`
19			`* \| ctor list \| the ctor and dtor lists are for`
20			`* \| dtor list \| C++ support`
21			`* +--------------------+`
22			`* \| .data \| initialized data goes here`
23			`* \| _edata \|`
24			`* +--------------------+`
25			`* \| .bss \|`
26			`* \| __bss_start \| start of bss, cleared by crt0`
27			`* \| _end \| start of heap, used by sbrk()`
28			`* +--------------------+`
29			`* . .`
30			`* . .`
31			`* . .`
32			`* \| __stack \| top of stack`
33			`* +--------------------+`
34			`*/`
35
36			`MEMORY`
37			`{`
38			`ram (rwx) : ORIGIN = 0x5000, LENGTH = 1M`
39			`}`
40
41			`/*`
42			`* Allocate the stack to be at the top of memory, since the stack`
43			`* grows down`
44			`*/`
45
46			`PROVIDE (__stack = 1M - 8);`
47
48			`/*`
49			`* Initalize some symbols to be zero so we can reference them in the`
50			`* crt0 without core dumping. These functions are all optional, but`
51			`* we do this so we can have our crt0 always use them if they exist.`
52			`* This is so BSPs work better when using the crt0 installed gcc.`
53			`* We have to initalize them twice, so we cover a.out (which prepends`
54			`* an underscore) and coff object file formats.`
55			`*/`
56			`PROVIDE (hardware_init_hook = 0);`
57			`PROVIDE (_hardware_init_hook = 0);`
58			`PROVIDE (software_init_hook = 0);`
59			`PROVIDE (_software_init_hook = 0);`
60			`/*`
61			`* stick everything in ram (of course)`
62			`*/`
63			`SECTIONS`
64			`{`
65			`.text :`
66			`{`
67			`(.text .text.)`
68			`. = ALIGN(0x4);`
69			`__CTOR_LIST__ = .;`
70			`___CTOR_LIST__ = .;`
71			`LONG((__CTOR_END__ - __CTOR_LIST__) / 4 - 2)`
72			`*(.ctors)`
73			`LONG(0)`
74			`__CTOR_END__ = .;`
75			`__DTOR_LIST__ = .;`
76			`___DTOR_LIST__ = .;`
77			`LONG((__DTOR_END__ - __DTOR_LIST__) / 4 - 2)`
78			`*(.dtors)`
79			`LONG(0)`
80			`__DTOR_END__ = .;`
81			`(.rodata .rodata.)`
82			`*(.gcc_except_table)`
83
84			`. = ALIGN(0x2);`
85			`__INIT_SECTION__ = . ;`
86			`LONG (0x4e560000) /* linkw %fp,#0 */`
87			`*(.init)`
88			`SHORT (0x4e5e) /* unlk %fp */`
89			`SHORT (0x4e75) /* rts */`
90
91			`__FINI_SECTION__ = . ;`
92			`LONG (0x4e560000) /* linkw %fp,#0 */`
93			`*(.fini)`
94			`SHORT (0x4e5e) /* unlk %fp */`
95			`SHORT (0x4e75) /* rts */`
96
97			`_etext = .;`
98			`*(.lit)`
99			`} > ram`
100
101			`.data :`
102			`{`
103			`(.got.plt) (.got)`
104			`*(.shdata)`
105			`(.data .data.)`
106			`_edata = .;`
107			`} > ram`
108
109			`.bss :`
110			`{`
111			`. = ALIGN(0x4);`
112			`__bss_start = . ;`
113			`*(.shbss)`
114			`(.bss .bss.)`
115			`*(COMMON)`
116			`_end = ALIGN (0x8);`
117			`__end = _end;`
118			`} > ram`
119
120			`.stab 0 (NOLOAD) :`
121			`{`
122			`*(.stab)`
123			`}`
124
125			`.stabstr 0 (NOLOAD) :`
126			`{`
127			`*(.stabstr)`
128			`}`
129			`}`

Browse

Tools

Subversion Repositories openrisc

[/] [openrisc/] [trunk/] [gnu-old/] [newlib-1.17.0/] [libgloss/] [m68k/] [mvme135.ld] - Blame information for rev 842