Subversion Repositories openrisc_me

/* YACC parser for Java expressions, for GDB.

   Copyright (C) 1997, 1998, 1999, 2000, 2006, 2007, 2008, 2009, 2010

   Free Software Foundation, Inc.

   This file is part of GDB.

   This program is free software; you can redistribute it and/or modify

   it under the terms of the GNU General Public License as published by

   the Free Software Foundation; either version 3 of the License, or

   (at your option) any later version.

   This program is distributed in the hope that it will be useful,

   but WITHOUT ANY WARRANTY; without even the implied warranty of

   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the

   GNU General Public License for more details.

   You should have received a copy of the GNU General Public License

   along with this program.  If not, see .  */

/* Parse a Java expression from text in a string,

   and return the result as a  struct expression  pointer.

   That structure contains arithmetic operations in reverse polish,

   with constants represented by operations that are followed by special data.

   See expression.h for the details of the format.

   What is important here is that it can be built up sequentially

   during the process of parsing; the lower levels of the tree always

   come first in the result.  Well, almost always; see ArrayAccess.

   Note that malloc's and realloc's in this file are transformed to

   xmalloc and xrealloc respectively by the same sed command in the

   makefile that remaps any other malloc/realloc inserted by the parser

   generator.  Doing this with #defines and trying to control the interaction

   with include files ( and  for example) just became

   too messy, particularly when such includes can be inserted at random

   times by the parser generator.  */

%{

#include "defs.h"

#include "gdb_string.h"

#include 

#include "expression.h"

#include "value.h"

#include "parser-defs.h"

#include "language.h"

#include "jv-lang.h"

#include "bfd.h" /* Required by objfiles.h.  */

#include "symfile.h" /* Required by objfiles.h.  */

#include "objfiles.h" /* For have_full_symbols and have_partial_symbols */

#include "block.h"

#define parse_type builtin_type (parse_gdbarch)

#define parse_java_type builtin_java_type (parse_gdbarch)

/* Remap normal yacc parser interface names (yyparse, yylex, yyerror, etc),

   as well as gratuitiously global symbol names, so we can have multiple

   yacc generated parsers in gdb.  Note that these are only the variables

   produced by yacc.  If other parser generators (bison, byacc, etc) produce

   additional global names that conflict at link time, then those parser

   generators need to be fixed instead of adding those names to this list. */

#define yymaxdepth java_maxdepth

#define yyparse java_parse

#define yylex   java_lex

#define yyerror java_error

#define yylval  java_lval

#define yychar  java_char

#define yydebug java_debug

#define yypact  java_pact

#define yyr1    java_r1

#define yyr2    java_r2

#define yydef   java_def

#define yychk   java_chk

#define yypgo   java_pgo

#define yyact   java_act

#define yyexca  java_exca

#define yyerrflag java_errflag

#define yynerrs java_nerrs

#define yyps    java_ps

#define yypv    java_pv

#define yys     java_s

#define yy_yys  java_yys

#define yystate java_state

#define yytmp   java_tmp

#define yyv     java_v

#define yy_yyv  java_yyv

#define yyval   java_val

#define yylloc  java_lloc

#define yyreds  java_reds               /* With YYDEBUG defined */

#define yytoks  java_toks               /* With YYDEBUG defined */

#define yyname  java_name               /* With YYDEBUG defined */

#define yyrule  java_rule               /* With YYDEBUG defined */

#define yylhs   java_yylhs

#define yylen   java_yylen

#define yydefred java_yydefred

#define yydgoto java_yydgoto

#define yysindex java_yysindex

#define yyrindex java_yyrindex

#define yygindex java_yygindex

#define yytable  java_yytable

#define yycheck  java_yycheck

#ifndef YYDEBUG

#define YYDEBUG 1               /* Default to yydebug support */

#endif

#define YYFPRINTF parser_fprintf

int yyparse (void);

static int yylex (void);

void yyerror (char *);

static struct type *java_type_from_name (struct stoken);

static void push_expression_name (struct stoken);

static void push_fieldnames (struct stoken);

static struct expression *copy_exp (struct expression *, int);

static void insert_exp (int, struct expression *);

%}

/* Although the yacc "value" of an expression is not used,

   since the result is stored in the structure being created,

   other node types do have values.  */

%union

  {

    LONGEST lval;

    struct {

      LONGEST val;

      struct type *type;

    } typed_val_int;

    struct {

      DOUBLEST dval;

      struct type *type;

    } typed_val_float;

    struct symbol *sym;

    struct type *tval;

    struct stoken sval;

    struct ttype tsym;

    struct symtoken ssym;

    struct block *bval;

    enum exp_opcode opcode;

    struct internalvar *ivar;

    int *ivec;

  }

%{

/* YYSTYPE gets defined by %union */

static int parse_number (char *, int, int, YYSTYPE *);

%}

%type  rcurly Dims Dims_opt

%type  ClassOrInterfaceType ClassType /* ReferenceType Type ArrayType */

%type  IntegralType FloatingPointType NumericType PrimitiveType ArrayType PrimitiveOrArrayType

%token  INTEGER_LITERAL

%token  FLOATING_POINT_LITERAL

%token  IDENTIFIER

%token  STRING_LITERAL

%token  BOOLEAN_LITERAL

%token  TYPENAME

%type  Name SimpleName QualifiedName ForcedName

/* A NAME_OR_INT is a symbol which is not known in the symbol table,

   but which would parse as a valid number in the current input radix.

   E.g. "c" when input_radix==16.  Depending on the parse, it will be

   turned into a name or into a number.  */

%token  NAME_OR_INT

%token ERROR

/* Special type cases, put in to allow the parser to distinguish different

   legal basetypes.  */

%token LONG SHORT BYTE INT CHAR BOOLEAN DOUBLE FLOAT

%token VARIABLE

%token  ASSIGN_MODIFY

%token SUPER NEW

%left ','

%right '=' ASSIGN_MODIFY

%right '?'

%left OROR

%left ANDAND

%left '|'

%left '^'

%left '&'

%left EQUAL NOTEQUAL

%left '<' '>' LEQ GEQ

%left LSH RSH

%left '+' '-'

%left '*' '/' '%'

%right INCREMENT DECREMENT

%right '.' '[' '('

%%

start   :       exp1

        |       type_exp

        ;

type_exp:       PrimitiveOrArrayType

                {

                  write_exp_elt_opcode(OP_TYPE);

                  write_exp_elt_type($1);

                  write_exp_elt_opcode(OP_TYPE);

                }

        ;

PrimitiveOrArrayType:

                PrimitiveType

        |       ArrayType

        ;

StringLiteral:

        STRING_LITERAL

                {

                  write_exp_elt_opcode (OP_STRING);

                  write_exp_string ($1);

                  write_exp_elt_opcode (OP_STRING);

                }

;

Literal:

        INTEGER_LITERAL

                { write_exp_elt_opcode (OP_LONG);

                  write_exp_elt_type ($1.type);

                  write_exp_elt_longcst ((LONGEST)($1.val));

                  write_exp_elt_opcode (OP_LONG); }

|       NAME_OR_INT

                { YYSTYPE val;

                  parse_number ($1.ptr, $1.length, 0, &val);

                  write_exp_elt_opcode (OP_LONG);

                  write_exp_elt_type (val.typed_val_int.type);

                  write_exp_elt_longcst ((LONGEST)val.typed_val_int.val);

                  write_exp_elt_opcode (OP_LONG);

                }

|       FLOATING_POINT_LITERAL

                { write_exp_elt_opcode (OP_DOUBLE);

                  write_exp_elt_type ($1.type);

                  write_exp_elt_dblcst ($1.dval);

                  write_exp_elt_opcode (OP_DOUBLE); }

|       BOOLEAN_LITERAL

                { write_exp_elt_opcode (OP_LONG);

                  write_exp_elt_type (parse_java_type->builtin_boolean);

                  write_exp_elt_longcst ((LONGEST)$1);

                  write_exp_elt_opcode (OP_LONG); }

|       StringLiteral

        ;

/* UNUSED:

Type:

        PrimitiveType

|       ReferenceType

;

*/

PrimitiveType:

        NumericType

|       BOOLEAN

                { $$ = parse_java_type->builtin_boolean; }

;

NumericType:

        IntegralType

|       FloatingPointType

;

IntegralType:

        BYTE

                { $$ = parse_java_type->builtin_byte; }

|       SHORT

                { $$ = parse_java_type->builtin_short; }

|       INT

                { $$ = parse_java_type->builtin_int; }

|       LONG

                { $$ = parse_java_type->builtin_long; }

|       CHAR

                { $$ = parse_java_type->builtin_char; }

;

FloatingPointType:

        FLOAT

                { $$ = parse_java_type->builtin_float; }

|       DOUBLE

                { $$ = parse_java_type->builtin_double; }

;

/* UNUSED:

ReferenceType:

        ClassOrInterfaceType

|       ArrayType

;

*/

ClassOrInterfaceType:

        Name

                { $$ = java_type_from_name ($1); }

;

ClassType:

        ClassOrInterfaceType

;

ArrayType:

        PrimitiveType Dims

                { $$ = java_array_type ($1, $2); }

|       Name Dims

                { $$ = java_array_type (java_type_from_name ($1), $2); }

;

Name:

        IDENTIFIER

|       QualifiedName

;

ForcedName:

        SimpleName

|       QualifiedName

;

SimpleName:

        IDENTIFIER

|       NAME_OR_INT

;

QualifiedName:

        Name '.' SimpleName

                { $$.length = $1.length + $3.length + 1;

                  if ($1.ptr + $1.length + 1 == $3.ptr

                      && $1.ptr[$1.length] == '.')

                    $$.ptr = $1.ptr;  /* Optimization. */

                  else

                    {

                      $$.ptr = (char *) malloc ($$.length + 1);

                      make_cleanup (free, $$.ptr);

                      sprintf ($$.ptr, "%.*s.%.*s",

                               $1.length, $1.ptr, $3.length, $3.ptr);

                } }

;

/*

type_exp:       type

                        { write_exp_elt_opcode(OP_TYPE);

                          write_exp_elt_type($1);

                          write_exp_elt_opcode(OP_TYPE);}

        ;

        */

/* Expressions, including the comma operator.  */

exp1    :       Expression

        |       exp1 ',' Expression

                        { write_exp_elt_opcode (BINOP_COMMA); }

        ;

Primary:

        PrimaryNoNewArray

|       ArrayCreationExpression

;

PrimaryNoNewArray:

        Literal

|       '(' Expression ')'

|       ClassInstanceCreationExpression

|       FieldAccess

|       MethodInvocation

|       ArrayAccess

|       lcurly ArgumentList rcurly

                { write_exp_elt_opcode (OP_ARRAY);

                  write_exp_elt_longcst ((LONGEST) 0);

                  write_exp_elt_longcst ((LONGEST) $3);

                  write_exp_elt_opcode (OP_ARRAY); }

;

lcurly:

        '{'

                { start_arglist (); }

;

rcurly:

        '}'

                { $$ = end_arglist () - 1; }

;

ClassInstanceCreationExpression:

        NEW ClassType '(' ArgumentList_opt ')'

                { internal_error (__FILE__, __LINE__,

                                  _("FIXME - ClassInstanceCreationExpression")); }

;

ArgumentList:

        Expression

                { arglist_len = 1; }

|       ArgumentList ',' Expression

                { arglist_len++; }

;

ArgumentList_opt:

        /* EMPTY */

                { arglist_len = 0; }

| ArgumentList

;

ArrayCreationExpression:

        NEW PrimitiveType DimExprs Dims_opt

                { internal_error (__FILE__, __LINE__,

                                  _("FIXME - ArrayCreationExpression")); }

|       NEW ClassOrInterfaceType DimExprs Dims_opt

                { internal_error (__FILE__, __LINE__,

                                  _("FIXME - ArrayCreationExpression")); }

;

DimExprs:

        DimExpr

|       DimExprs DimExpr

;

DimExpr:

        '[' Expression ']'

;

Dims:

        '[' ']'

                { $$ = 1; }

|       Dims '[' ']'

        { $$ = $1 + 1; }

;

Dims_opt:

        Dims

|       /* EMPTY */

                { $$ = 0; }

;

FieldAccess:

        Primary '.' SimpleName

                { push_fieldnames ($3); }

|       VARIABLE '.' SimpleName

                { push_fieldnames ($3); }

/*|     SUPER '.' SimpleName { FIXME } */

;

FuncStart:

        Name '('

                { push_expression_name ($1); }

;

MethodInvocation:

        FuncStart

                { start_arglist(); }

        ArgumentList_opt ')'

                { write_exp_elt_opcode (OP_FUNCALL);

                  write_exp_elt_longcst ((LONGEST) end_arglist ());

                  write_exp_elt_opcode (OP_FUNCALL); }

|       Primary '.' SimpleName '(' ArgumentList_opt ')'

                { error (_("Form of method invocation not implemented")); }

|       SUPER '.' SimpleName '(' ArgumentList_opt ')'

                { error (_("Form of method invocation not implemented")); }

;

ArrayAccess:

        Name '[' Expression ']'

                {

                  /* Emit code for the Name now, then exchange it in the

                     expout array with the Expression's code.  We could

                     introduce a OP_SWAP code or a reversed version of

                     BINOP_SUBSCRIPT, but that makes the rest of GDB pay

                     for our parsing kludges.  */

                  struct expression *name_expr;

                  push_expression_name ($1);

                  name_expr = copy_exp (expout, expout_ptr);

                  expout_ptr -= name_expr->nelts;

                  insert_exp (expout_ptr-length_of_subexp (expout, expout_ptr),

                              name_expr);

                  free (name_expr);

                  write_exp_elt_opcode (BINOP_SUBSCRIPT);

                }

|       VARIABLE '[' Expression ']'

                { write_exp_elt_opcode (BINOP_SUBSCRIPT); }

|       PrimaryNoNewArray '[' Expression ']'

                { write_exp_elt_opcode (BINOP_SUBSCRIPT); }

;

PostfixExpression:

        Primary

|       Name

                { push_expression_name ($1); }

|       VARIABLE

                /* Already written by write_dollar_variable. */

|       PostIncrementExpression

|       PostDecrementExpression

;

PostIncrementExpression:

        PostfixExpression INCREMENT

                { write_exp_elt_opcode (UNOP_POSTINCREMENT); }

;

PostDecrementExpression:

        PostfixExpression DECREMENT

                { write_exp_elt_opcode (UNOP_POSTDECREMENT); }

;

UnaryExpression:

        PreIncrementExpression

|       PreDecrementExpression

|       '+' UnaryExpression

|       '-' UnaryExpression

                { write_exp_elt_opcode (UNOP_NEG); }

|       '*' UnaryExpression

                { write_exp_elt_opcode (UNOP_IND); } /*FIXME not in Java  */

|       UnaryExpressionNotPlusMinus

;

PreIncrementExpression:

        INCREMENT UnaryExpression

                { write_exp_elt_opcode (UNOP_PREINCREMENT); }

;

PreDecrementExpression:

        DECREMENT UnaryExpression

                { write_exp_elt_opcode (UNOP_PREDECREMENT); }

;

UnaryExpressionNotPlusMinus:

        PostfixExpression

|       '~' UnaryExpression

                { write_exp_elt_opcode (UNOP_COMPLEMENT); }

|       '!' UnaryExpression

                { write_exp_elt_opcode (UNOP_LOGICAL_NOT); }

|       CastExpression

        ;

CastExpression:

        '(' PrimitiveType Dims_opt ')' UnaryExpression

                { write_exp_elt_opcode (UNOP_CAST);

                  write_exp_elt_type (java_array_type ($2, $3));

                  write_exp_elt_opcode (UNOP_CAST); }

|       '(' Expression ')' UnaryExpressionNotPlusMinus

                {

                  int last_exp_size = length_of_subexp(expout, expout_ptr);

                  struct type *type;

                  int i;

                  int base = expout_ptr - last_exp_size - 3;

                  if (base < 0 || expout->elts[base+2].opcode != OP_TYPE)

                    error (_("Invalid cast expression"));

                  type = expout->elts[base+1].type;

                  /* Remove the 'Expression' and slide the

                     UnaryExpressionNotPlusMinus down to replace it. */

                  for (i = 0;  i < last_exp_size;  i++)

                    expout->elts[base + i] = expout->elts[base + i + 3];

                  expout_ptr -= 3;

                  if (TYPE_CODE (type) == TYPE_CODE_STRUCT)

                    type = lookup_pointer_type (type);

                  write_exp_elt_opcode (UNOP_CAST);

                  write_exp_elt_type (type);

                  write_exp_elt_opcode (UNOP_CAST);

                }

|       '(' Name Dims ')' UnaryExpressionNotPlusMinus

                { write_exp_elt_opcode (UNOP_CAST);

                  write_exp_elt_type (java_array_type (java_type_from_name ($2), $3));

                  write_exp_elt_opcode (UNOP_CAST); }

;

MultiplicativeExpression:

        UnaryExpression

|       MultiplicativeExpression '*' UnaryExpression

                { write_exp_elt_opcode (BINOP_MUL); }

|       MultiplicativeExpression '/' UnaryExpression

                { write_exp_elt_opcode (BINOP_DIV); }

|       MultiplicativeExpression '%' UnaryExpression

                { write_exp_elt_opcode (BINOP_REM); }

;

AdditiveExpression:

        MultiplicativeExpression

|       AdditiveExpression '+' MultiplicativeExpression

                { write_exp_elt_opcode (BINOP_ADD); }

|       AdditiveExpression '-' MultiplicativeExpression

                { write_exp_elt_opcode (BINOP_SUB); }

;

ShiftExpression:

        AdditiveExpression

|       ShiftExpression LSH AdditiveExpression

                { write_exp_elt_opcode (BINOP_LSH); }

|       ShiftExpression RSH AdditiveExpression

                { write_exp_elt_opcode (BINOP_RSH); }

/* |    ShiftExpression >>> AdditiveExpression { FIXME } */

;

RelationalExpression:

        ShiftExpression

|       RelationalExpression '<' ShiftExpression

                { write_exp_elt_opcode (BINOP_LESS); }

|       RelationalExpression '>' ShiftExpression

                { write_exp_elt_opcode (BINOP_GTR); }

|       RelationalExpression LEQ ShiftExpression

                { write_exp_elt_opcode (BINOP_LEQ); }

|       RelationalExpression GEQ ShiftExpression

                { write_exp_elt_opcode (BINOP_GEQ); }

/* | RelationalExpresion INSTANCEOF ReferenceType { FIXME } */

;

EqualityExpression:

        RelationalExpression

|       EqualityExpression EQUAL RelationalExpression

                { write_exp_elt_opcode (BINOP_EQUAL); }

|       EqualityExpression NOTEQUAL RelationalExpression

                { write_exp_elt_opcode (BINOP_NOTEQUAL); }

;

AndExpression:

        EqualityExpression

|       AndExpression '&' EqualityExpression

                { write_exp_elt_opcode (BINOP_BITWISE_AND); }

;

ExclusiveOrExpression:

        AndExpression

|       ExclusiveOrExpression '^' AndExpression

                { write_exp_elt_opcode (BINOP_BITWISE_XOR); }

;

InclusiveOrExpression:

        ExclusiveOrExpression

|       InclusiveOrExpression '|' ExclusiveOrExpression

                { write_exp_elt_opcode (BINOP_BITWISE_IOR); }

;

ConditionalAndExpression:

        InclusiveOrExpression

|       ConditionalAndExpression ANDAND InclusiveOrExpression

                { write_exp_elt_opcode (BINOP_LOGICAL_AND); }

;

ConditionalOrExpression:

        ConditionalAndExpression

|       ConditionalOrExpression OROR ConditionalAndExpression

                { write_exp_elt_opcode (BINOP_LOGICAL_OR); }

;

ConditionalExpression:

        ConditionalOrExpression

|       ConditionalOrExpression '?' Expression ':' ConditionalExpression

                { write_exp_elt_opcode (TERNOP_COND); }

;

AssignmentExpression:

        ConditionalExpression

|       Assignment

;

Assignment:

        LeftHandSide '=' ConditionalExpression

                { write_exp_elt_opcode (BINOP_ASSIGN); }

|       LeftHandSide ASSIGN_MODIFY ConditionalExpression

                { write_exp_elt_opcode (BINOP_ASSIGN_MODIFY);

                  write_exp_elt_opcode ($2);

                  write_exp_elt_opcode (BINOP_ASSIGN_MODIFY); }

;

LeftHandSide:

        ForcedName

                { push_expression_name ($1); }

|       VARIABLE

                /* Already written by write_dollar_variable. */

|       FieldAccess

|       ArrayAccess

;

Expression:

        AssignmentExpression

;

%%

/* Take care of parsing a number (anything that starts with a digit).

   Set yylval and return the token type; update lexptr.

   LEN is the number of characters in it.  */

/*** Needs some error checking for the float case ***/

static int

parse_number (char *p, int len, int parsed_float, YYSTYPE *putithere)

{

  ULONGEST n = 0;

  ULONGEST limit, limit_div_base;

  int c;

  int base = input_radix;

  struct type *type;

  if (parsed_float)

    {

      /* It's a float since it contains a point or an exponent.  */

      char c;

      int num = 0;      /* number of tokens scanned by scanf */

      char saved_char = p[len];

      p[len] = 0;       /* null-terminate the token */

      num = sscanf (p, "%" DOUBLEST_SCAN_FORMAT "%c",

                    &putithere->typed_val_float.dval, &c);

      p[len] = saved_char;      /* restore the input stream */

      if (num != 1)             /* check scanf found ONLY a float ... */

        return ERROR;

      /* See if it has `f' or `d' suffix (float or double).  */

      c = tolower (p[len - 1]);

      if (c == 'f' || c == 'F')

        putithere->typed_val_float.type = parse_type->builtin_float;

      else if (isdigit (c) || c == '.' || c == 'd' || c == 'D')

        putithere->typed_val_float.type = parse_type->builtin_double;

      else

        return ERROR;

      return FLOATING_POINT_LITERAL;

    }

  /* Handle base-switching prefixes 0x, 0t, 0d, 0 */

  if (p[0] == '0')

    switch (p[1])

      {

      case 'x':

      case 'X':

        if (len >= 3)

          {

            p += 2;

            base = 16;

            len -= 2;

          }

        break;

      case 't':

      case 'T':

      case 'd':

      case 'D':

        if (len >= 3)

          {

            p += 2;

            base = 10;

            len -= 2;

          }

        break;

      default:

        base = 8;

        break;

      }

  c = p[len-1];

  /* A paranoid calculation of (1<<64)-1. */

  limit = (ULONGEST)0xffffffff;

  limit = ((limit << 16) << 16) | limit;

  if (c == 'l' || c == 'L')

    {

      type = parse_java_type->builtin_long;

      len--;

    }

  else

    {

      type = parse_java_type->builtin_int;

    }

  limit_div_base = limit / (ULONGEST) base;

  while (--len >= 0)

    {

      c = *p++;

      if (c >= '0' && c <= '9')

        c -= '0';

      else if (c >= 'A' && c <= 'Z')

        c -= 'A' - 10;

      else if (c >= 'a' && c <= 'z')

        c -= 'a' - 10;

      else

        return ERROR;   /* Char not a digit */

      if (c >= base)

        return ERROR;

      if (n > limit_div_base

          || (n *= base) > limit - c)

        error (_("Numeric constant too large"));

      n += c;

        }

  /* If the type is bigger than a 32-bit signed integer can be, implicitly

     promote to long.  Java does not do this, so mark it as

     parse_type->builtin_uint64 rather than parse_java_type->builtin_long.

     0x80000000 will become -0x80000000 instead of 0x80000000L, because we

     don't know the sign at this point.  */

  if (type == parse_java_type->builtin_int && n > (ULONGEST)0x80000000)

    type = parse_type->builtin_uint64;

  putithere->typed_val_int.val = n;

  putithere->typed_val_int.type = type;

  return INTEGER_LITERAL;

}

struct token

{

  char *operator;

  int token;

  enum exp_opcode opcode;

};

static const struct token tokentab3[] =

  {

    {">>=", ASSIGN_MODIFY, BINOP_RSH},

    {"<<=", ASSIGN_MODIFY, BINOP_LSH}

  };

static const struct token tokentab2[] =

  {

    {"+=", ASSIGN_MODIFY, BINOP_ADD},

    {"-=", ASSIGN_MODIFY, BINOP_SUB},

    {"*=", ASSIGN_MODIFY, BINOP_MUL},

    {"/=", ASSIGN_MODIFY, BINOP_DIV},

    {"%=", ASSIGN_MODIFY, BINOP_REM},

    {"|=", ASSIGN_MODIFY, BINOP_BITWISE_IOR},

    {"&=", ASSIGN_MODIFY, BINOP_BITWISE_AND},

    {"^=", ASSIGN_MODIFY, BINOP_BITWISE_XOR},

    {"++", INCREMENT, BINOP_END},

    {"--", DECREMENT, BINOP_END},

    {"&&", ANDAND, BINOP_END},

    {"||", OROR, BINOP_END},

    {"<<", LSH, BINOP_END},

    {">>", RSH, BINOP_END},

    {"==", EQUAL, BINOP_END},

    {"!=", NOTEQUAL, BINOP_END},

    {"<=", LEQ, BINOP_END},

    {">=", GEQ, BINOP_END}

  };

/* Read one token, getting characters through lexptr.  */

static int

yylex (void)

{

  int c;

  int namelen;

  unsigned int i;

  char *tokstart;

  char *tokptr;

  int tempbufindex;

  static char *tempbuf;

  static int tempbufsize;

 retry:

  prev_lexptr = lexptr;

  tokstart = lexptr;

  /* See if it is a special token of length 3.  */

  for (i = 0; i < sizeof tokentab3 / sizeof tokentab3[0]; i++)

    if (strncmp (tokstart, tokentab3[i].operator, 3) == 0)

      {

        lexptr += 3;

        yylval.opcode = tokentab3[i].opcode;

        return tokentab3[i].token;

      }

  /* See if it is a special token of length 2.  */

  for (i = 0; i < sizeof tokentab2 / sizeof tokentab2[0]; i++)

    if (strncmp (tokstart, tokentab2[i].operator, 2) == 0)

      {

        lexptr += 2;

        yylval.opcode = tokentab2[i].opcode;

        return tokentab2[i].token;

      }

  switch (c = *tokstart)

    {

    case 0:

      return 0;

    case ' ':

    case '\t':

    case '\n':

      lexptr++;

      goto retry;

    case '\'':

      /* We either have a character constant ('0' or '\177' for example)

         or we have a quoted symbol reference ('foo(int,int)' in C++

         for example). */

      lexptr++;

      c = *lexptr++;

      if (c == '\\')

        c = parse_escape (parse_gdbarch, &lexptr);

      else if (c == '\'')

        error (_("Empty character constant"));

      yylval.typed_val_int.val = c;

      yylval.typed_val_int.type = parse_java_type->builtin_char;

      c = *lexptr++;

      if (c != '\'')

        {

          namelen = skip_quoted (tokstart) - tokstart;

          if (namelen > 2)

            {

              lexptr = tokstart + namelen;

              if (lexptr[-1] != '\'')

                error (_("Unmatched single quote"));

              namelen -= 2;

              tokstart++;

              goto tryname;

            }

          error (_("Invalid character constant"));

        }

      return INTEGER_LITERAL;

    case '(':

      paren_depth++;

      lexptr++;

      return c;

    case ')':

      if (paren_depth == 0)

        return 0;

      paren_depth--;

      lexptr++;

      return c;

    case ',':

      if (comma_terminates && paren_depth == 0)