URL https://opencores.org/ocsvn/openrisc_me/openrisc_me/trunk

Subversion Repositories openrisc_me

[/] [openrisc/] [trunk/] [gnu-src/] [newlib-1.17.0/] [libgloss/] [m68k/] [mvme162.ld] - Blame information for rev 262

Go to most recent revision | Details | Compare with Previous | View Log


STARTUP(crt0.o)
OUTPUT_ARCH(m68k)
/* Uncomment this if you want srecords. This is needed for a.out
 * if you plan to use GDB.
OUTPUT_FORMAT(srec)
 */
SEARCH_DIR(.)
GROUP(-lmvme162 -lc -lgcc)
__DYNAMIC  =  0;
 
/*
 * Setup the memory map of the Motorola MVME135 Board
 * stack grows down from high memory.
 *
 * The memory map look like this:
 * +--------------------+ <- low memory
 * | .text              |
 * |        _etext      |
 * |        ctor list   | the ctor and dtor lists are for
 * |        dtor list   | C++ support
 * +--------------------+
 * | .data              | initialized data goes here
 * |        _edata      |
 * +--------------------+
 * | .bss               |
 * |        __bss_start | start of bss, cleared by crt0
 * |        _end        | start of heap, used by sbrk()
 * +--------------------+
 * .                    .
 * .                    .
 * .                    .
 * |        __stack     | top of stack
 * +--------------------+
 */
 
MEMORY
{
  monitor   : ORIGIN = 0x0000, LENGTH = 64K
  ram (rwx) : ORIGIN = 0x10000, LENGTH = 16M
}
 
/*
 * allocate the stack to be at the top of memory, since the stack
 * grows down
 */
 
PROVIDE (__stack = 16M - 8);
 
/*
 * Initalize some symbols to be zero so we can reference them in the
 * crt0 without core dumping. These functions are all optional, but
 * we do this so we can have our crt0 always use them if they exist.
 * This is so BSPs work better when using the crt0 installed with gcc.
 * We have to initalize them twice, so we cover a.out (which prepends
 * an underscore) and coff object file formats.
 */
PROVIDE (hardware_init_hook = 0);
PROVIDE (_hardware_init_hook = 0);
PROVIDE (software_init_hook = 0);
PROVIDE (_software_init_hook = 0);
/*
 * stick everything in ram (of course)
 */
SECTIONS
{
  .text :
  {
    *(.text .text.*)
    . = ALIGN(0x4);
     __CTOR_LIST__ = .;
    ___CTOR_LIST__ = .;
    LONG((__CTOR_END__ - __CTOR_LIST__) / 4 - 2)
    *(.ctors)
    LONG(0)
    __CTOR_END__ = .;
    __DTOR_LIST__ = .;
    ___DTOR_LIST__ = .;
    LONG((__DTOR_END__ - __DTOR_LIST__) / 4 - 2)
    *(.dtors)
     LONG(0)
    __DTOR_END__ = .;
    *(.rodata .rodata.*)
    *(.gcc_except_table)
 
    . = ALIGN(0x2);
    __INIT_SECTION__ = . ;
    LONG (0x4e560000)   /* linkw %fp,#0 */
    *(.init)
    SHORT (0x4e5e)      /* unlk %fp */
    SHORT (0x4e75)      /* rts */
 
    __FINI_SECTION__ = . ;
    LONG (0x4e560000)   /* linkw %fp,#0 */
    *(.fini)
    SHORT (0x4e5e)      /* unlk %fp */
    SHORT (0x4e75)      /* rts */
 
    _etext = .;
    *(.lit)
  } > ram
 
  .data :
  {
    *(.got.plt) *(.got)
    *(.shdata)
    *(.data .data.*)
    _edata = .;
  } > ram
 
  .bss :
  {
    . = ALIGN(0x4);
    __bss_start = . ;
    *(.shbss)
    *(.bss .bss.*)
    *(COMMON)
    _end =  ALIGN (0x8);
    __end = _end;
  } > ram
 
  .stab 0 (NOLOAD) :
  {
    *(.stab)
  }
 
  .stabstr 0 (NOLOAD) :
  {
    *(.stabstr)
  }
}

Line No.	Rev	Author	Line
1	148	jeremybenn	`STARTUP(crt0.o)`
2			`OUTPUT_ARCH(m68k)`
3			`/* Uncomment this if you want srecords. This is needed for a.out`
4			`* if you plan to use GDB.`
5			`OUTPUT_FORMAT(srec)`
6			`*/`
7			`SEARCH_DIR(.)`
8			`GROUP(-lmvme162 -lc -lgcc)`
9			`__DYNAMIC = 0;`
10
11			`/*`
12			`* Setup the memory map of the Motorola MVME135 Board`
13			`* stack grows down from high memory.`
14			`*`
15			`* The memory map look like this:`
16			`* +--------------------+ <- low memory`
17			`* \| .text \|`
18			`* \| _etext \|`
19			`* \| ctor list \| the ctor and dtor lists are for`
20			`* \| dtor list \| C++ support`
21			`* +--------------------+`
22			`* \| .data \| initialized data goes here`
23			`* \| _edata \|`
24			`* +--------------------+`
25			`* \| .bss \|`
26			`* \| __bss_start \| start of bss, cleared by crt0`
27			`* \| _end \| start of heap, used by sbrk()`
28			`* +--------------------+`
29			`* . .`
30			`* . .`
31			`* . .`
32			`* \| __stack \| top of stack`
33			`* +--------------------+`
34			`*/`
35
36			`MEMORY`
37			`{`
38			`monitor : ORIGIN = 0x0000, LENGTH = 64K`
39			`ram (rwx) : ORIGIN = 0x10000, LENGTH = 16M`
40			`}`
41
42			`/*`
43			`* allocate the stack to be at the top of memory, since the stack`
44			`* grows down`
45			`*/`
46
47			`PROVIDE (__stack = 16M - 8);`
48
49			`/*`
50			`* Initalize some symbols to be zero so we can reference them in the`
51			`* crt0 without core dumping. These functions are all optional, but`
52			`* we do this so we can have our crt0 always use them if they exist.`
53			`* This is so BSPs work better when using the crt0 installed with gcc.`
54			`* We have to initalize them twice, so we cover a.out (which prepends`
55			`* an underscore) and coff object file formats.`
56			`*/`
57			`PROVIDE (hardware_init_hook = 0);`
58			`PROVIDE (_hardware_init_hook = 0);`
59			`PROVIDE (software_init_hook = 0);`
60			`PROVIDE (_software_init_hook = 0);`
61			`/*`
62			`* stick everything in ram (of course)`
63			`*/`
64			`SECTIONS`
65			`{`
66			`.text :`
67			`{`
68			`(.text .text.)`
69			`. = ALIGN(0x4);`
70			`__CTOR_LIST__ = .;`
71			`___CTOR_LIST__ = .;`
72			`LONG((__CTOR_END__ - __CTOR_LIST__) / 4 - 2)`
73			`*(.ctors)`
74			`LONG(0)`
75			`__CTOR_END__ = .;`
76			`__DTOR_LIST__ = .;`
77			`___DTOR_LIST__ = .;`
78			`LONG((__DTOR_END__ - __DTOR_LIST__) / 4 - 2)`
79			`*(.dtors)`
80			`LONG(0)`
81			`__DTOR_END__ = .;`
82			`(.rodata .rodata.)`
83			`*(.gcc_except_table)`
84
85			`. = ALIGN(0x2);`
86			`__INIT_SECTION__ = . ;`
87			`LONG (0x4e560000) /* linkw %fp,#0 */`
88			`*(.init)`
89			`SHORT (0x4e5e) /* unlk %fp */`
90			`SHORT (0x4e75) /* rts */`
91
92			`__FINI_SECTION__ = . ;`
93			`LONG (0x4e560000) /* linkw %fp,#0 */`
94			`*(.fini)`
95			`SHORT (0x4e5e) /* unlk %fp */`
96			`SHORT (0x4e75) /* rts */`
97
98			`_etext = .;`
99			`*(.lit)`
100			`} > ram`
101
102			`.data :`
103			`{`
104			`(.got.plt) (.got)`
105			`*(.shdata)`
106			`(.data .data.)`
107			`_edata = .;`
108			`} > ram`
109
110			`.bss :`
111			`{`
112			`. = ALIGN(0x4);`
113			`__bss_start = . ;`
114			`*(.shbss)`
115			`(.bss .bss.)`
116			`*(COMMON)`
117			`_end = ALIGN (0x8);`
118			`__end = _end;`
119			`} > ram`
120
121			`.stab 0 (NOLOAD) :`
122			`{`
123			`*(.stab)`
124			`}`
125
126			`.stabstr 0 (NOLOAD) :`
127			`{`
128			`*(.stabstr)`
129			`}`
130			`}`

Browse

Tools

Subversion Repositories openrisc_me

[/] [openrisc/] [trunk/] [gnu-src/] [newlib-1.17.0/] [libgloss/] [m68k/] [mvme162.ld] - Blame information for rev 262