Subversion Repositories openrisc

# configure.in. Autoconf input file.

# Copyright (c) 1995, 1996 Cygnus Support

# Copyright (C) 2004, Jacob Bower

# Copyright (C) 2010, Embecosm Limited 

# Contributor Jeremy Bennett 

# This file is part of Newlib.

# The original work by Jacob Bower is provided as-is without any kind of

# warranty. Use it at your own risk!

# All subsequent work is bound by version 3 of the GPL as follows.

# This program is free software; you can redistribute it and/or modify it

# under the terms of the GNU General Public License as published by the Free

# Software Foundation; either version 3 of the License, or (at your option)

# any later version.

# This program is distributed in the hope that it will be useful, but WITHOUT

# ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or

# FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License for

# more details.

# You should have received a copy of the GNU General Public License along

# with this program.  If not, see .

dnl Process this file with autoconf to produce a configure script.

AC_PREREQ(2.59)

AC_INIT(libor32.a,0.2.0)

AC_CONFIG_HEADER(config.h)

# No shared libraries allowed

if test "${enable_shared}" = "yes" ; then

    echo "Shared libraries not supported for cross compiling, ignored"

fi

# Where are the auxillary tools (confg.sub etc)?

if test "$srcdir" = "." ; then

  if test "${with_target_subdir}" != "." ; then

    libgloss_topdir="${srcdir}/${with_multisrctop}../../.."

  else

    libgloss_topdir="${srcdir}/${with_multisrctop}../.."

  fi

else

  libgloss_topdir="${srcdir}/../.."

fi

AC_CONFIG_AUX_DIR($libgloss_topdir)

AC_CANONICAL_TARGET

AC_ARG_PROGRAM

AC_PROG_INSTALL

AC_DEFINE(HAVE_GNU_LD, 1, [Using GNU ld])

# We always use ELF, define various useful associated things.

AC_DEFINE(HAVE_ELF, 1, [Using ELF format])

# Sort out what the symbol prefix is (we could just fix it as '_', but let the

# script work it out.

AC_CACHE_CHECK([for symbol prefix], libc_cv_symbol_prefix, [dnl

cat > conftest.c <<\EOF

foo () { }

EOF

dnl

libc_cv_symbol_prefix=none

if AC_TRY_COMMAND([${CC-cc} -S conftest.c -o - | fgrep "\$foo" > /dev/null]);

then

  libc_cv_symbol_prefix='$'

else

  if AC_TRY_COMMAND([${CC-cc} -S conftest.c -o - | fgrep "_foo" > /dev/null]);

  then

    libc_cv_symbol_prefix=_

  fi

fi

rm -f conftest* ])

if test $libc_cv_symbol_prefix != none; then

  AC_DEFINE_UNQUOTED(__SYMBOL_PREFIX, "$libc_cv_symbol_prefix", [symbol prefix])

else

  AC_DEFINE(__SYMBOL_PREFIX, "", [symbol prefix])

fi

# Standard stuff copied from libnosys. For this we'll need an aclocal.m4

LIB_AC_PROG_CC

AS=${AS-as}

AC_SUBST(AS)

AR=${AR-ar}

AC_SUBST(AR)

LD=${LD-ld}

AC_SUBST(LD)

AC_PROG_RANLIB

LIB_AM_PROG_AS

host_makefile_frag=${srcdir}/../config/default.mh

dnl We have to assign the same value to other variables because autoconf

dnl doesn't provide a mechanism to substitute a replacement keyword with

dnl arbitrary data or pathnames.

dnl

host_makefile_frag_path=$host_makefile_frag

AC_SUBST(host_makefile_frag_path)

AC_SUBST_FILE(host_makefile_frag)

AC_CONFIG_FILES(Makefile,

                ac_file=Makefile . ${libgloss_topdir}/config-ml.in,

                srcdir=${srcdir}

                target=${target}

                with_multisubdir=${with_multisubdir}

                ac_configure_args="${ac_configure_args} --enable-multilib"

                CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}

                libgloss_topdir=${libgloss_topdir}

)

AC_OUTPUT