URL https://opencores.org/ocsvn/openrisc_me/openrisc_me/trunk

Subversion Repositories openrisc_me

[/] [openrisc/] [trunk/] [rtos/] [rtems/] [c/] [src/] [lib/] [libbsp/] [m68k/] [mvme136/] [startup/] [linkcmds] - Blame information for rev 173

Details | Compare with Previous | View Log


/*
 *  This file contains directives for the GNU linker which are specific
 *  to the Motorola MVME136/MVME135 boards.
 *
 *  COPYRIGHT (c) 1989-1999.
 *  On-Line Applications Research Corporation (OAR).
 *
 *  The license and distribution terms for this file may be
 *  found in the file LICENSE in this distribution or at
 *  http://www.OARcorp.com/rtems/license.html.
 *
 *  $Id: linkcmds,v 1.2 2001-09-27 12:00:14 chris Exp $
 */
 
/*
 * Declare some sizes.
 */
_RamBase = DEFINED(_RamBase) ? _RamBase : 0x0;
_RamSize = DEFINED(_RamSize) ? _RamSize : 1M;
_HeapSize = DEFINED(_HeapSize) ? _HeapSize : 0x10000;
_StackSize = DEFINED(_StackSize) ? _StackSize : 0x1000;
 
MEMORY
{
        ram : org = 0x0, l = 1M
}
 
SECTIONS
{
        ram : {
                . = 0x3000;
        } >ram
 
        /*
         * Text, data and bss segments
         */
        .text : {
                *(.text)
 
                /*
                 * C++ constructors/destructors
                 *
                 * Various files can provide initialization and finalization
                 * functions.  crtbegin.o and crtend.o are two instances. The
                 * body of these functions are in .init and .fini sections. We
                 * accumulate the bodies here, and prepend function prologues
                 * from crti.o and function epilogues from crtn.o. crti.o must
                 * be linked first; crtn.o must be linked last.  Because these
                 * are wildcards, it doesn't matter if the user does not
                 * actually link against crti.o and crtn.o; the linker won't
                 * look for a file to match a wildcard.  The wildcard also
                 * means that it doesn't matter which directory crti.o and
                 * crtn.o are in.
                 */
                *(.gnu.linkonce.t.*)
 
                /*
                 * Initialization and finalization code.
                 *
                 * gcc uses crtbegin.o to find the start of the constructors
                 * and destructors so we make sure it is first.  Because this
                 * is a wildcard, it doesn't matter if the user does not
                 * actually link against crtbegin.o; the linker won't look for
                 * a file to match a wildcard.  The wildcard also means that
                 * it doesn't matter which directory crtbegin.o is in. The
                 * constructor and destructor list are terminated in
                 * crtend.o.  The same comments apply to it.
                 */
                PROVIDE (_init = .);
                *crti.o(.init)
                *(.init)
                *crtn.o(.init)
                PROVIDE (_fini = .);
                *crti.o(.fini)
                *(.fini)
                *crtn.o(.fini)
 
                /*
                 * C++ constructors/destructors
                 */
                . = ALIGN (16);
                *crtbegin.o(.ctors)
                *(.ctors)
                *crtend.o(.ctors)
                *crtbegin.o(.dtors)
                *(.dtors)
                *crtend.o(.dtors)
 
                /*
                 * Exception frame info
                 */
                . = ALIGN (16);
                *(.eh_frame)
 
                /*
                 * Read-only data
                 */
                . = ALIGN (16);
                _rodata_start = . ;
                *(.rodata)
                *(.gnu.linkonce.r*)
 
                 . = ALIGN (16);
                PROVIDE (_etext = .);
        } >ram
        .data : {
                PROVIDE (_copy_start = .);
                *(.data)
                *(.gnu.linkonce.d*)
                *(.gcc_except_table)
                . = ALIGN (16);
                PROVIDE (_edata = .);
                PROVIDE (_copy_end = .);
        } >ram
        .bss : {
                _clear_start = .;
                *(.bss)
                *(COMMON)
                . = ALIGN (16);
                PROVIDE (end = .);
 
                . += _StackSize;
                . = ALIGN (16);
                _stack_init = .;
                _clear_end = .;
 
                _WorkspaceBase = .;
        } >ram
}

Line No.	Rev	Author	Line
1	30	unneback	`/*`
2			`* This file contains directives for the GNU linker which are specific`
3			`* to the Motorola MVME136/MVME135 boards.`
4			`*`
5			`* COPYRIGHT (c) 1989-1999.`
6			`* On-Line Applications Research Corporation (OAR).`
7			`*`
8			`* The license and distribution terms for this file may be`
9			`* found in the file LICENSE in this distribution or at`
10			`* http://www.OARcorp.com/rtems/license.html.`
11			`*`
12			`* $Id: linkcmds,v 1.2 2001-09-27 12:00:14 chris Exp $`
13			`*/`
14
15			`/*`
16			`* Declare some sizes.`
17			`*/`
18			`_RamBase = DEFINED(_RamBase) ? _RamBase : 0x0;`
19			`_RamSize = DEFINED(_RamSize) ? _RamSize : 1M;`
20			`_HeapSize = DEFINED(_HeapSize) ? _HeapSize : 0x10000;`
21			`_StackSize = DEFINED(_StackSize) ? _StackSize : 0x1000;`
22
23			`MEMORY`
24			`{`
25			`ram : org = 0x0, l = 1M`
26			`}`
27
28			`SECTIONS`
29			`{`
30			`ram : {`
31			`. = 0x3000;`
32			`} >ram`
33
34			`/*`
35			`* Text, data and bss segments`
36			`*/`
37			`.text : {`
38			`*(.text)`
39
40			`/*`
41			`* C++ constructors/destructors`
42			`*`
43			`* Various files can provide initialization and finalization`
44			`* functions. crtbegin.o and crtend.o are two instances. The`
45			`* body of these functions are in .init and .fini sections. We`
46			`* accumulate the bodies here, and prepend function prologues`
47			`* from crti.o and function epilogues from crtn.o. crti.o must`
48			`* be linked first; crtn.o must be linked last. Because these`
49			`* are wildcards, it doesn't matter if the user does not`
50			`* actually link against crti.o and crtn.o; the linker won't`
51			`* look for a file to match a wildcard. The wildcard also`
52			`* means that it doesn't matter which directory crti.o and`
53			`* crtn.o are in.`
54			`*/`
55			`(.gnu.linkonce.t.)`
56
57			`/*`
58			`* Initialization and finalization code.`
59			`*`
60			`* gcc uses crtbegin.o to find the start of the constructors`
61			`* and destructors so we make sure it is first. Because this`
62			`* is a wildcard, it doesn't matter if the user does not`
63			`* actually link against crtbegin.o; the linker won't look for`
64			`* a file to match a wildcard. The wildcard also means that`
65			`* it doesn't matter which directory crtbegin.o is in. The`
66			`* constructor and destructor list are terminated in`
67			`* crtend.o. The same comments apply to it.`
68			`*/`
69			`PROVIDE (_init = .);`
70			`*crti.o(.init)`
71			`*(.init)`
72			`*crtn.o(.init)`
73			`PROVIDE (_fini = .);`
74			`*crti.o(.fini)`
75			`*(.fini)`
76			`*crtn.o(.fini)`
77
78			`/*`
79			`* C++ constructors/destructors`
80			`*/`
81			`. = ALIGN (16);`
82			`*crtbegin.o(.ctors)`
83			`*(.ctors)`
84			`*crtend.o(.ctors)`
85			`*crtbegin.o(.dtors)`
86			`*(.dtors)`
87			`*crtend.o(.dtors)`
88
89			`/*`
90			`* Exception frame info`
91			`*/`
92			`. = ALIGN (16);`
93			`*(.eh_frame)`
94
95			`/*`
96			`* Read-only data`
97			`*/`
98			`. = ALIGN (16);`
99			`_rodata_start = . ;`
100			`*(.rodata)`
101			`(.gnu.linkonce.r)`
102
103			`. = ALIGN (16);`
104			`PROVIDE (_etext = .);`
105			`} >ram`
106			`.data : {`
107			`PROVIDE (_copy_start = .);`
108			`*(.data)`
109			`(.gnu.linkonce.d)`
110			`*(.gcc_except_table)`
111			`. = ALIGN (16);`
112			`PROVIDE (_edata = .);`
113			`PROVIDE (_copy_end = .);`
114			`} >ram`
115			`.bss : {`
116			`_clear_start = .;`
117			`*(.bss)`
118			`*(COMMON)`
119			`. = ALIGN (16);`
120			`PROVIDE (end = .);`
121
122			`. += _StackSize;`
123			`. = ALIGN (16);`
124			`_stack_init = .;`
125			`_clear_end = .;`
126
127			`_WorkspaceBase = .;`
128			`} >ram`
129			`}`

Browse

Tools

Subversion Repositories openrisc_me

[/] [openrisc/] [trunk/] [rtos/] [rtems/] [c/] [src/] [lib/] [libbsp/] [m68k/] [mvme136/] [startup/] [linkcmds] - Blame information for rev 173