Subversion Repositories or1k

dnl

dnl Configure script for the OpenRISC 1000 simulator

dnl

dnl report bugs to jrydberg@phx.pp.se

dnl

dnl Process this file with autoconf to produce a configure script.

AC_INIT(cpu/or32/execute.c)

AC_CANONICAL_SYSTEM

AM_INIT_AUTOMAKE(or1ksim, 1.3)

AM_CONFIG_HEADER(config.h)

AC_REVISION([for or1ksim-1.2, version 2.14, from autoconf version] AC_ACVERSION)

SIMVERSION=1.2

dnl make sure we are using a recent autoconf version

AC_PREREQ(2.10)

AC_CANONICAL_HOST

dnl yuck

case "$target_cpu" in

or32*)  CPU_ARCH=or32;

        ARCH_ISA=OR32;;

or16*)  CPU_ARCH=or16;

        ARCH_ISA=OR16;;

dlx*)   CPU_ARCH=dlx;

        ARCH_ISA=DLX;;

esac

AC_SUBST(CPU_ARCH)

# We want these before the checks, so the checks can modify their values.

test -z "$CFLAGS" && CFLAGS=-g auto_cflags=1

AC_PROG_CC

AC_MINIX

AC_PROG_MAKE_SET

# If we're using gcc and the user hasn't specified CFLAGS, add -O2 to CFLAGS.

test -n "$GCC" && test -n "$auto_cflags" && CFLAGS="$CFLAGS -O2 -D$ARCH_ISA"

AC_PROG_GCC_TRADITIONAL

AC_PROG_INSTALL

AC_CHECK_PROG(AR, ar, ar)

dnl Set default for ARFLAGS, since autoconf does not have a macro for it.

dnl This allows people to set it when running configure or make

test -n "$ARFLAGS" || ARFLAGS="cr"

AC_PROG_RANLIB

MAKE_SHELL=/bin/sh

AC_SUBST(MAKE_SHELL)

AC_TYPE_SIGNAL

AC_HEADER_STAT

AC_HEADER_DIRENT

AC_CHECK_FUNCS(strcasecmp select setenv putenv tcgetattr setlocale lstat)

AC_FUNC_STRCOLL

AC_CHECK_HEADERS(unistd.h stdlib.h varargs.h stdarg.h string.h \

                sys/ptem.h sys/pte.h sys/stream.h sys/select.h \

                termcap.h termios.h termio.h sys/file.h locale.h)

dnl check for "long long" (added by Erez)

AC_TRY_COMPILE(,[long long ll; unsigned long long ull;],AC_DEFINE(CC_HAS_LONG_LONG))

dnl check for GNU readline

AC_ARG_ENABLE(readline,

  [  --enable-readline       Use GNU readline], AC_CHECK_LIB(readline, add_history))

dnl yuck

case "$host_os" in

aix*)   prefer_curses=yes ;;

esac

case "$host_cpu" in

*cray*) LOCAL_CFLAGS=-DCRAY ;;

esac

case "$host_os" in

isc*)   LOCAL_CFLAGS=-Disc386 ;;

esac

case "$host_os" in

solaris*) LIBS="-lsocket -lnsl" ;;

esac

dnl define options

AC_MSG_CHECKING(whether to enable profiling)

AC_ARG_ENABLE(profiling,

    [  --enable-profiling      generate profiling code], [

    case "$enableval" in

        yes) profile="-pg" ;;

    esac

])

AC_MSG_RESULT(${enable_profiling-no})

AC_MSG_CHECKING(whether to disable CPU debugging module)

AC_ARG_ENABLE(debugmod,

    [  --disable-debugmod      turns off debug module], [

    case "$enableval" in

        no) debugmod="-DDEBUGMOD_OFF" ;;

    esac

])

AC_MSG_RESULT(${disable_debugmod-no})

AC_SUBST(FPM)

AC_MSG_CHECKING(for implementation-specific data)

AC_ARG_ENABLE(impl,

    [  --enable-impl=     use -specific environment

                          (one of: bender, mp3, default)], [

    case "$enableval" in

        no|default)        IMPL="DEFAULT" ;;

        mp3)               IMPL="MP3"     ;;

        bender)            IMPL="BENDER"  ;;

        *)

            AC_MSG_RESULT(failed)

            AC_MSG_ERROR([bad --enable-impl option])

            ;;

    esac

])

AC_MSG_RESULT(${IMPL=DEFAULT})

if test "$IMPL" = "DEFAULT"

then

    AC_MSG_WARN([using default environment])

fi

IMPL="-DIMPL_$IMPL"

BUILD_DIR=`pwd`

AC_SUBST(BUILD_DIR)

AC_SUBST(CFLAGS)

AC_SUBST(LOCAL_CFLAGS)

AC_SUBST(LOCAL_LDFLAGS)

AC_SUBST(LOCAL_DEFS)

AC_SUBST(AR)

AC_SUBST(ARFLAGS)

AC_SUBST(host_cpu)

AC_SUBST(host_os)

AC_SUBST(host)

AC_SUBST(SUMVERSION)

AC_SUBST(TERMCAP_LIB)

AC_DEFINE(HAS_EXECUTION)

dnl yuck

INCLUDES="-I\${top_srcdir}/cpu/common -I\${top_srcdir}/cpu/or1k \

-I\${top_srcdir}/cpu/$CPU_ARCH -I\${top_srcdir}/cache -I\${top_srcdir}/mmu \

-I\${top_srcdir}/bpb -I\${top_srcdir}/peripheral -I\${top_srcdir}/tick \

-I\${top_srcdir}/pm -I\${top_srcdir}/pic -I\${top_srcdir}/debug -I\${top_srcdir}/vapi"

AC_SUBST(INCLUDES)

test -n "$profile"  && CFLAGS="$CFLAGS $profile" LDFLAGS="$LDFLAGS $profile"

test -n "$debugmod" && CFLAGS="$CFLAGS $debugmod"

CFLAGS="$CFLAGS $IMPL"

AC_OUTPUT([Makefile bpb/Makefile cache/Makefile cpu/Makefile

        cpu/common/Makefile cpu/or32/Makefile cpu/or16/Makefile

        cpu/or1k/Makefile cpu/dlx/Makefile debug/Makefile

        support/Makefile mmu/Makefile peripheral/Makefile tick/Makefile

        pm/Makefile pic/Makefile debug/Makefile vapi/Makefile],

[

# Makefile uses this timestamp file to record whether config.h is up to date.

echo > stamp-h

])