URL https://opencores.org/ocsvn/rf6809/rf6809/trunk

Subversion Repositories rf6809

[/] [rf6809/] [trunk/] [software/] [boot/] [boot_rom.asm] - Blame information for rev 15

Go to most recent revision | Details | Compare with Previous | View Log


; ============================================================================
;        __
;   \\__/ o\    (C) 2013-2022  Robert Finch, Waterloo
;    \  __ /    All rights reserved.
;     \/_//     robfinch@opencores.org
;       ||
;
;
; BSD 3-Clause License
; Redistribution and use in source and binary forms, with or without
; modification, are permitted provided that the following conditions are met:
;
; 1. Redistributions of source code must retain the above copyright notice, this
;    list of conditions and the following disclaimer.
;
; 2. Redistributions in binary form must reproduce the above copyright notice,
;    this list of conditions and the following disclaimer in the documentation
;    and/or other materials provided with the distribution.
;
; 3. Neither the name of the copyright holder nor the names of its
;    contributors may be used to endorse or promote products derived from
;    this software without specific prior written permission.
;
; THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS"
; AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
; IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE
; DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT HOLDER OR CONTRIBUTORS BE LIABLE
; FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
; DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR
; SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER
; CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY,
; OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
; OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
;
; ============================================================================
;
OPT include "d:\cores2022\rf6809\software\boot\mon_equates.asm"
OPT include "d:\cores2022\rf6809\software\boot\io_equates.asm"
 
OPC_SWI                         EQU             $03F
ScreenLocation          EQU             $10
ColorCodeLocation       EQU             $14
ScreenLocation2         EQU             $18
BlkcpySrc                       EQU             $1C
BlkcpyDst                       EQU             $20
Strptr                          EQU             $24
PICptr                          EQU             $28
; Forth Area
; 0x30-0x60
 
; Task control blocks, room for 256 tasks
TCB_NxtRdy              EQU             $00     ; next task on ready / timeout list
TCB_PrvRdy              EQU             $04     ; previous task on ready / timeout list
TCB_NxtTCB              EQU             $08
TCB_Timeout             EQU             $0C
TCB_Priority    EQU             $10
TCB_MSGPTR_D1   EQU             $14
TCB_MSGPTR_D2   EQU             $18
TCB_hJCB                        EQU             $1C
TCB_Status              EQU             $1E
TCB_CursorRow   EQU             $20
TCB_CursorCol   EQU             $21
TCB_hWaitMbx    EQU             $22     ; handle of mailbox task is waiting at
TCB_mbq_next    EQU             $24     ; mailbox queue next
TCB_mbq_prev    EQU             $28     ; mailbox queue previous
TCB_iof_next    EQU             $2C
TCB_iof_prev    EQU             $30
TCB_SPSave              EQU             $34     ; TCB_SPSave area
TCB_mmu_map             EQU             $38
 
KeybdHead               EQU             $FFFFFC800
KeybdTail               EQU             $FFFFFC900
KeybdEcho               EQU             $FFFFFCA00
KeybdBad                EQU             $FFFFFCB00
KeybdAck                EQU             $FFFFFCC00
KeybdLocks              EQU             $FFFFFCD00
KeybdBuffer             EQU             $FFFFFC000      ; buffer is 16 chars
 
BIOS_SCREENS    EQU     $17000000       ; $17000000 to $171FFFFF
 
; EhBASIC vars:
;
NmiBase         EQU             $FFC013
IrqBase         EQU             $FFC014
 
IOFocusNdx      EQU             $100
 
; These variables in global OS storage area
 
IOFocusList     EQU             $FFC000 ; to $FF000F
IOFocusID               EQU             $FFC010
IrqSource               EQU             $FFC011
IRQFlag                 EQU             $FFC012
RunningID               EQU             $FFC013
 
; These variables use direct page access
CursorRow       EQU             $110
CursorCol       EQU             $111
CharColor       EQU             $112
ScreenColor     EQU             $113
CursorFlash     EQU             $114
KeyState1       EQU     $120
KeyState2       EQU     $121
KeyLED          EQU     $122
KeybdID         EQU     $124
KeybdBlock      EQU     $126
kbdHeadRcv      EQU     $127
kbdTailRcv      EQU     $128
kbdFifo                 EQU     $40                             ; in local RAM
kbdFifoAlias    EQU     $C00040 ; to $C0007F    ; alias for $40 to $7F
SerhZero                EQU     $130
SerHeadRcv      EQU     $131
SertZero                EQU     $132
SerTailRcv      EQU     $133
SerHeadXmit     EQU     $136
SerTailXmit     EQU     $138
SerRcvXon               EQU     $139
SerRcvXoff      EQU     $140
SerRcvBuf               EQU     $BFF000 ; 4kB serial recieve buffer
 
farflag EQU             $15F
asmbuf  EQU             $160    ; to $17F
 
QNdx0           EQU             $780
QNdx1           EQU             QNdx0+2
QNdx2           EQU             QNdx1+2
QNdx3           EQU             QNdx2+2
QNdx4           EQU             QNdx3+2
FreeTCB         EQU             QNdx4+2
TimeoutList     EQU             FreeTCB+2
FreeMbx         EQU             RunningTCB + 2
nMailbox        EQU             FreeMbx + 2
FreeMsg         EQU             nMailbox + 2
nMsgBlk         EQU             FreeMsg + 2
 
 
CharOutVec      EQU             $800
CharInVec       EQU             $804
CmdPromptJI     EQU     $808
MonErrVec       EQU             $80C
BreakpointFlag  EQU             $810
NumSetBreakpoints       EQU     $811
Breakpoints                     EQU             $820    ; to $82F
BreakpointBytes EQU             $830    ; to $83F
mon_vectb                               EQU             $880
 
; Register save area for monitor
mon_DSAVE       EQU             $900
mon_XSAVE       EQU             $902
mon_YSAVE       EQU             $904
mon_USAVE       EQU             $906
mon_SSAVE       EQU             $908
mon_PCSAVE      EQU             $90A
mon_DPRSAVE     EQU             $90E
mon_CCRSAVE     EQU             $90F
 
mon_numwka      EQU             $910
mon_r1          EQU             $920
mon_r2          EQU             $924
jmpvec          EQU             $928
 
; The ORG directive must set an address a multiple of 4 in order for the Verilog
; output to work correctly.
 
        org             $FFD0AC
        nop
        nop
        nop
XBLANK
        ldb             #' '
        lbsr    OUTCH
        rts
 
        org             $FFD0D0
        nop
        nop
CRLF
CRLF1:
        ldb             #CR
        lbsr    OUTCH
        ldb             #LF
        lbsr    OUTCH
        rts
 
        org             $FFD0F0
        nop
        bra             CRLF1
 
        org             $FFD1DC
ONEKEY
        jmp             [CharInVec]
 
        org             $FFD2C0
        nop
LETTER
        lbsr    OUTCH
        rts
 
        org             $FFD2CC
        nop
        nop
HEX2
        lbsr    DispByteAsHex
        rts
HEX4
        lbsr    DispWordAsHex
        rts
 
        org             $FFD300
ClearScreenJmp
        lbra    ClearScreen
        org             $FFD308
HomeCursorJmp
        lbra    HomeCursor
 
        org             $FFD400
 
; Local RAM test routine
; Checkerboard testing.
; There is 70kB of local RAM
; Does not use any RAM including no stack
 
ramtest:
        ldy             #0
        lda             #1
        sta             LEDS
        ldd             #$AAA555
ramtest1:
        std             ,y++
        cmpy    #$8000
        blo             ramtest1
        ; now readback values and compare
        ldy             #0
ramtest3:
        ldd             ,y++
        cmpd    #$AAA555
        bne             ramerr
        cmpy    #$8000
        blo             ramtest3
        lda             #2
        sta             LEDS
        jmp             ,u
ramerr:
        lda             #$80
        sta             LEDS
        ldx             #TEXTSCR
        ldb             COREID
        abx
        lda             #'F'
        sta             ,x
        sync
        jmp             ,u
 
dramtest:
        ldy             #$10000                 ; DRAM starts here
        lda             #1
        sta             LEDS
        ldu             #$AAA555
        lbsr    CRLF
dramtest1:
        deca
        bne             dramtest4
        tfr             y,d
        lbsr    DispWordAsHex
        ldb             #CR
        lbsr    OUTCH
dramtest4:
        stu             ,y++
        cmpy    #$E00000                ; DRAM ends here
        blo             dramtest1
        ; now readback values and compare
        ldy             #$10000
        lda             #1
        lbsr    CRLF
dramtest3:
        deca
        bne             dramtest5
        tfr             y,d
        lbsr    DispWordAsHex
        ldb             #CR
        lbsr    OUTCH
dramtest5:
        cmpu    ,y++
        bne             dramerr
        cmpy    #$E00000
        blo             dramtest3
        lda             #2
        sta             LEDS
        lbra    Monitor
dramerr:
        lda             #$80
        sta             LEDS
        ldx             #TEXTSCR
        ldb             COREID
        abx
        lda             #'F'
        sta             ,x
        lbra    Monitor
 
        org             $FFE000
        FDB Monitor
        FDB DumRts      ;       NEXTCMD
        FDB INCH
        FDB INCHE
        FDB INCHEK
        FDB OUTCH
        FDB PDATA
        FDB PCRLF
        FDB PSTRNG
        FDB DumRts                      ; LRA
        FDB DumRts
        FDB DumRts
        FDB DumRts
        FDB DumRts                      ; VINIZ
        FDB DisplayChar ;       VOUTCH
        FDB DumRts                      ; ACINIZ
        FDB DumRts                      ; AOUTCH
 
DumRts:
        rts
 
;------------------------------------------------------------------------------
;------------------------------------------------------------------------------
 
start:
        lda             #$FFF                   ; all cores can do this
        sta             VIA+VIA_DDRA
        lda             #$55                    ; see if we can at least set LEDs
        sta             LEDS
        lda             #1                              ; prime OS semaphore
        sta             OSSEMA+$1000
        sta             OUTSEMA+$1000
        ldu             #st6                    ; U = return address
        jmp             ramtest         ; JMP dont JSR
st6:
        lds             #$6FFF          ; boot up stack area
        lda             COREID
        cmpa    #FIRST_CORE
;       beq             st8
;       sync                                            ; halt cores other than 2
st8:
;       bne             skip_init
;       bsr             romToRam
;       ldd             #st7 & $FFFF
;       tfr             d,x
;       jmp             ,x                              ; jump to the BIOS now in local RAM
st7:
        bsr             Delay3s         ; give some time for devices to reset
        clr             BreakpointFlag
        clr             NumSetBreakpoints
        lda             #$AA
        sta             LEDS
        lda             #FIRST_CORE
        sta             IOFocusID       ; core #2 has focus
        sta             RunningID
        ; Clear IO focus list
        ldx             #0
st9:
        clr             IOFocusList,x
        inx
        cmpx    #16
        blo             st9
        lda             #24
        sta             IOFocusList+FIRST_CORE
 
        lda             #$0CE
        sta             ScreenColor
        sta             CharColor
        bsr             ClearScreen
        ldd             #DisplayChar
        std             CharOutVec
        ldd             #SerialPeekCharDirect
        std             CharInVec
;       swi
;       fcb             MF_OSCALL
;       fcb             24                                      ; request IO focus
        ldb             COREID
        cmpb    #FIRST_CORE
        beq             init
        bra             skip_init
        bra             multi_sieve
st3:
        lda             #$FF
        sta             LEDS
        bra             st3
 
        ; initialize interrupt controller
        ; first, zero out all the vectors
init:
        lbsr    rtc_read        ; get clock values
        ldx             #kbdHeadRcv
        ldb             #32                             ; number of bytes to zero out
init1:
        clr             ,x+
        decb
        bne             init1
        lbsr    TimerInit
        lbsr    InitSerial
        ldx             #128
        lda             #1                      ; set irq(bit0), clear firq (bit1), disable int (bit 6), clear edge sense(bit 7)
        ldb             #FIRST_CORE                     ; serving core id
st1:
        clr             PIC,x                   ; cause code
        sta             PIC+1,x
        stb             PIC+2,x
        leax    4,x
        cmpx    #256
        blo             st1
;       lda             #4                              ; make the timer interrupt edge sensitive
;       sta             PIC+4                   ; reg #4 is the edge sensitivity setting
;       sta             PIC                             ; reg #0 is interrupt enable
        lda             #$81                    ; make irq edge sensitive
        sta             PIC+$FD
        lda             #31                             ; enable timer interrupt
        sta             PIC+9
        ldb             #1
        stb             OUTSEMA+SEMAABS ; set semaphore to 1 available slot
skip_init:
        andcc   #$EF                    ; unmask irq
        lda             #COLS
        sta             TEXTREG+TEXT_COLS
        lda             #ROWS
        sta             TEXTREG+TEXT_ROWS
        bsr             ClearScreen
        bsr             HomeCursor
        lda             #5
        sta             LEDS
        ldd             #msgStartup
        bsr             DisplayString
        ldx             #0
        ldd             #0
        lbsr    ShowSprites
        lbsr    KeybdInit
        ldd             KeybdID
        bsr             DispWordAsHex
        jmp             MonitorStart
 
msgStartup
        fcb             "rf6809 12-bit System Starting.",CR,LF,0
 
;------------------------------------------------------------------------------
; The checkpoint register must be cleared within 1 second or a NMI interrupt
; will occur. checkpoint should be called with a JSR so that the global ROM
; routine is called.
;
; Modifies:
;               none
;------------------------------------------------------------------------------
 
checkpoint:
        clr             $FFFFFFFE1      ; writing any value will do
        rts
 
;------------------------------------------------------------------------------
; Copy the system ROM to local RAM
; Running the code from local RAM is probably an order of magnitude faster
; then running from the global ROM. It also reduces the network traffic to
; run from local RAM.
;
; Modifies:
;               d,x,y
;------------------------------------------------------------------------------
 
romToRam:
        ldx             #$FFC000
        ldy             #$00C000
romToRam1:
        ldd             ,x++
        std             ,y++
        cmpx    #0
        bne             romToRam1
        rts
 
;------------------------------------------------------------------------------
; Multi-core sieve program.
;------------------------------------------------------------------------------
 
; First fill screen chars with 'P' indicating prime positions
; Each core is responsible for the Nth position where N is the
; core number minus two.
;
multi_sieve:
        lda             #'P'                                    ; indicate prime
        ldb             COREID                          ; find out which core we are
        subb    #FIRST_CORE
        ldx             #0                                              ; start at first char of screen
        abx
multi_sieve3:
        sta             TEXTSCR,x                       ; store 'P'
        leax    8,x                                             ; advance to next position
        cmpx    #4095
        blo             multi_sieve3
        jsr             checkpoint
        addb    #2                                              ; start sieve at 2 (core id)
        lda             #'N'                                    ; flag position value of 'N' for non-prime
multi_sieve2:
        ldx             #0
        abx                                                                     ; skip the first position - might be prime
multi_sieve1:
        abx                                                                     ; increment
        sta             TEXTSCR,x
        cmpx    #4095
        blo             multi_sieve1
        jsr             checkpoint
        addb    #8                                              ; number of cores working on it
        cmpb    #4080
        blo             multi_sieve2
multi_sieve4:                                   ; hang machine
        sync
        lbra    Monitor
 
;------------------------------------------------------------------------------
; Single core sieve.
;------------------------------------------------------------------------------
 
sieve:
        lda             #'P'                                    ; indicate prime
        ldx             #0                                              ; start at first char of screen
sieve3:
        sta             TEXTSCR,x                       ; store 'P'
        inx                                                                     ; advance to next position
        cmpx    #4095
        blo             sieve3
        ldb             #2                                              ; start sieve at 2
        lda             #'N'                                    ; flag position value of 'N' for non-prime
sieve2:
        ldx             #0
        abx                                                                     ; skip the first position - might be prime
sieve1:
        abx                                                                     ; increment
        sta             TEXTSCR,x
        cmpx    #4095
        blo             multi_sieve1
        incb                                                            ; number of cores working on it
        cmpb    #4080
        blo             sieve2
sieve4:                                                         ; hang machine
        rts
 
;------------------------------------------------------------------------------
; Three second delay for user convenience and to allow some devices time to
; reset.
;------------------------------------------------------------------------------
 
Delay3s:
        ldd             #9000000
dly3s1:
        cmpb    #$FF
        bne             dly3s2
dly3s2:
        sta             LEDS
        subd    #1
        bne             dly3s1
        rts
 
;------------------------------------------------------------------------------
;------------------------------------------------------------------------------
ShiftLeft5:
        aslb
        rola
        aslb
        rola
        aslb
        rola
        aslb
        rola
        aslb
        rola
        rts
 
;------------------------------------------------------------------------------
; Parameters:
;               b = core id of core to copy
;------------------------------------------------------------------------------
;
CopyVirtualScreenToScreen:
        pshs    d,x,y,u
        ; Compute virtual screen location for core passed in accb.
        tfr             b,a
        asla
        asla
        asla
        asla
        ora             #$C00
        clrb
        tfr             d,x
        pshs    d
        ldy             #TEXTSCR
        ldu             #COLS*ROWS/2
cv2s1:
        ldd             ,x++
        std             ,y++
        leau    -1,u
        cmpu    #0
        bne             cv2s1
        ; reset the cursor position in the text controller
        puls    x
        ldb             CursorRow,x
        lda             #COLS
        mul
        tfr             d,y
        ldb             CursorCol,x
        tfr             y,x
        abx
        stx             TEXTREG+TEXT_CURPOS
        puls    d,x,y,u,pc
 
;------------------------------------------------------------------------------
;------------------------------------------------------------------------------
;
CopyScreenToVirtualScreen:
        pshs    d,x,y,u
        bsr             GetScreenLocation
        tfr             d,y
        ldx             #TEXTSCR
        ldu             #COLS*ROWS/2
cs2v1:
        ldd             ,x++
        std             ,y++
        leau    -1,u
        cmpu    #0
        bne             cs2v1
        puls    d,x,y,u,pc
 
;------------------------------------------------------------------------------
;------------------------------------------------------------------------------
        fcb             "TEXTSCR "
        fcw             TextOpen
        fcw             TextClose
        fcw             TextRead
        fcw             TextWrite
        fcw             TextSeek
 
TextOpen:
        rts
TextClose:
        rts
TextRead:
        rts
TextWrite:
        rts
TextSeek:
        rts
 
;------------------------------------------------------------------------------
; Clear the screen and the screen color memory
; We clear the screen to give a visual indication that the system
; is working at all.
;
; Modifies:
;               none
;------------------------------------------------------------------------------
 
ClearScreen:
        pshs    d,x,y,u
        ldx             #COLS*ROWS
        tfr             x,u
        bsr             GetScreenLocation
        tfr             d,y
        ldb             #' '                            ; space char
cs1:
        stb             ,y+                                     ; set text to space
        leax    -1,x                            ; decrement x
        bne             cs1
        ldb             COREID                  ; update colors only if we have focus
        cmpb    IOFocusID
        bra             cs3
        ldy             #TEXTSCR+$2000
;       lda             CharColor
        lda             #$0CE
        tfr             u,x                                     ; get back count
cs2:
        sta             ,y+
        dex                                                             ; decrement x
        bne             cs2
cs3:
        puls    d,x,y,u,pc
 
;------------------------------------------------------------------------------
; Scroll text on the screen upwards
;
; Modifies:
;               none
;------------------------------------------------------------------------------
 
ScrollUp:
        pshs    d,x,y,u
        ldy             #(COLS*ROWS-1)/2        ; y = num chars/2 to move
        bsr             GetScreenLocation
        tfr             d,x
        tfr             d,u
        leax    COLS,x          ; x = index to source row
scrup1:
        ldd             ,x++                    ; move 2 characters
        std             ,u++
        dey
        bne             scrup1
        lda             #ROWS-1
        bsr             BlankLine
        puls    d,x,y,u,pc
 
;------------------------------------------------------------------------------
; Blank out a line on the display
;
; Modifies:
;               none
; Parameters:
;       acca = line number to blank
;------------------------------------------------------------------------------
 
BlankLine:
        pshs    d,x
        pshs    a
        bsr             GetScreenLocation
        tfr             d,x
        puls    a
        ldb             #COLS   ; b = # chars to blank out from video controller
        mul                                     ; d = screen index (row# * #cols)
        leax    d,x
        lda             #' '
        ldb             #COLS   ; b = # chars to blank out from video controller
blnkln1:
        sta             ,x+
        decb
        bne             blnkln1
        puls    d,x,pc
 
;------------------------------------------------------------------------------
; Get the location of the screen memory. The location
; depends on whether or not the task has the output focus.
;
; Modifies:
;               d
; Retuns:
;               d = screen location
;------------------------------------------------------------------------------
 
GetScreenLocation:
        lda             COREID                  ; which core are we?
        cmpa    IOFocusID               ; do we have the IO focus
        bne             gsl1                            ; no, go pick virtual screen address
        ldd             #TEXTSCR                ; yes, we update the real screen
        rts
gsl1:
        ldd             #$7800
        rts
 
;------------------------------------------------------------------------------
; HomeCursor
; Set the cursor location to the top left of the screen.
;
; Modifies:
;               none
;------------------------------------------------------------------------------
 
HomeCursor:
        pshs    d,x
        clr             CursorRow
        clr             CursorCol
        ldb             COREID
        cmpb    IOFocusID
        bne             hc1
        clra
        sta             TEXTREG+TEXT_CURPOS
hc1:
        puls    d,x,pc
 
;------------------------------------------------------------------------------
; Update the cursor position in the text controller based on the
;  CursorRow,CursorCol.
;
; Modifies:
;               none
;------------------------------------------------------------------------------
;
UpdateCursorPos:
        pshs    d,x
        ldb             COREID                          ; update cursor position in text controller
        cmpb    IOFocusID                       ; only for the task with the output focus
        bne             ucp1
        lda             CursorRow
        anda    #$3F                                    ; limit of 63 rows
        ldb             TEXTREG+TEXT_COLS
        mul
        tfr             d,x
        ldb             CursorCol
        abx
        stx             TEXTREG+TEXT_CURPOS
ucp1:
        puls    d,x,pc
 
;------------------------------------------------------------------------------
; Calculate screen memory location from CursorRow,CursorCol.
; Also refreshes the cursor location.
;
; Modifies:
;               d
; Returns:
;       d = screen location
;------------------------------------------------------------------------------
;
CalcScreenLoc:
        pshs    x
        lda             CursorRow
        ldb             #COLS
        mul
        tfr             d,x
        ldb             CursorCol
        abx
        ldb             COREID                          ; update cursor position in text controller
        cmpb    IOFocusID                       ; only for the task with the output focus
        bne             csl1
        stx             TEXTREG+TEXT_CURPOS
csl1:
        bsr             GetScreenLocation
        leax    d,x
        tfr             x,d
        puls    x,pc
 
;------------------------------------------------------------------------------
; Display a character on the screen.
; If the task doesn't have the I/O focus then the character is written to
; the virtual screen.
;
; Modifies:
;               none
; Parameters:
;       accb = char to display
;------------------------------------------------------------------------------
;
DisplayChar:
        lbsr    SerialPutChar
        pshs    d,x
        cmpb    #CR                                     ; carriage return ?
        bne             dccr
        clr             CursorCol               ; just set cursor column to zero on a CR
        bsr             UpdateCursorPos
dcx14:
        lbra            dcx4
dccr:
        cmpb    #$91                            ; cursor right ?
        bne             dcx6
        lda             CursorCol
        cmpa    #COLS
        bhs             dcx7
        inca
        sta             CursorCol
dcx7:
        bsr             UpdateCursorPos
        puls    d,x,pc
dcx6:
        cmpb    #$90                            ; cursor up ?
        bne             dcx8
        lda             CursorRow
        beq             dcx7
        deca
        sta             CursorRow
        bra             dcx7
dcx8:
        cmpb    #$93                            ; cursor left ?
        bne             dcx9
        lda             CursorCol
        beq             dcx7
        deca
        sta             CursorCol
        bra             dcx7
dcx9:
        cmpb    #$92                            ; cursor down ?
        bne             dcx10
        lda             CursorRow
        cmpa    #ROWS
        beq             dcx7
        inca
        sta             CursorRow
        bra             dcx7
dcx10:
        cmpb    #$94                            ; cursor home ?
        bne             dcx11
        lda             CursorCol
        beq             dcx12
        clr             CursorCol
        bra             dcx7
dcx12:
        clr             CursorRow
        bra             dcx7
dcx11:
        cmpb    #$99                            ; delete ?
        bne             dcx13
        bsr             CalcScreenLoc
        tfr             d,x
        lda             CursorCol               ; acc = cursor column
        bra             dcx5
dcx13
        cmpb    #CTRLH                  ; backspace ?
        bne             dcx3
        lda             CursorCol
        beq             dcx4
        deca
        sta             CursorCol
        bsr             CalcScreenLoc
        tfr             d,x
        lda             CursorCol
dcx5:
        ldb             1,x
        stb             ,x++
        inca
        cmpa    #COLS
        blo             dcx5
        ldb             #' '
        dex
        stb             ,x
        bra             dcx4
dcx3:
        cmpb    #LF                             ; linefeed ?
        beq             dclf
        pshs    b
        bsr     CalcScreenLoc
        tfr             d,x
        puls    b
        stb             ,x
        ; ToDo character color
;       lda             CharColor
;       sta             $2000,x
        bsr             IncCursorPos
        bra             dcx4
dclf:
        bsr             IncCursorRow
dcx4:
        puls    d,x,pc
 
;------------------------------------------------------------------------------
; Increment the cursor position, scroll the screen if needed.
;
; Modifies:
;               none
;------------------------------------------------------------------------------
 
IncCursorPos:
        pshs    d,x
        lda             CursorCol
        inca
        sta             CursorCol
        cmpa    #COLS
        blo             icc1
        clr             CursorCol               ; column = 0
        bra             icr1
IncCursorRow:
        pshs    d,x
icr1:
        lda             CursorRow
        inca
        sta             CursorRow
        cmpa    #ROWS
        blo             icc1
        deca                                                    ; backup the cursor row, we are scrolling up
        sta             CursorRow
        bsr             ScrollUp
icc1:
        bsr             UpdateCursorPos
icc2:
        puls    d,x,pc
 
;------------------------------------------------------------------------------
; Display a string on the screen.
;
; Modifies:
;               none
; Parameters:
;               d = pointer to string
;------------------------------------------------------------------------------
;
DisplayString:
        pshs    d,x
        tfr             d,x
dspj2:                                          ; lock semaphore for access
        lda             OUTSEMA+1
        beq             dspj2
dspj1B:
        ldb             ,x+                             ; move string char into acc
        beq             dsretB          ; is it end of string ?
        lbsr    OUTCH                   ; display character
        bra             dspj1B
dsretB:
        clr             OUTSEMA+1       ; unlock semaphore
        puls    d,x,pc
 
DisplayStringCRLF:
        pshs    d
        bsr             DisplayString
        ldb             #CR
        lbsr    OUTCH
        ldb             #LF
        lbsr    OUTCH
        puls    d,pc
 
;
; PRINT CR, LF, STRING
;
PSTRNG
        BSR             PCRLF
        BRA             PDATA
PCRLF
        PSHS    X
        LDX             #CRLFST
        BSR             PDATA
        PULS    X
        RTS
 
PRINT
        JSR             OUTCH
PDATA
        LDB             ,X+
        CMPB    #$04
        BNE             PRINT
        RTS
 
CRLFST
        fcb     CR,LF,4
 
DispDWordAsHex:
        bsr             DispWordAsHex
        exg             d,x
        bsr             DispWordAsHex
        exg             d,x
        rts
 
DispWordAsHex:
        exg             a,b
        bsr             DispByteAsHex
        exg             a,b
        bsr             DispByteAsHex
        rts
 
DispByteAsHex:
  pshs  b
        lsrb
        lsrb
        lsrb
        lsrb
        lsrb
        lsrb
        lsrb
        lsrb
        bsr             DispNyb
        puls    b
        pshs    b
        lsrb
        lsrb
        lsrb
        lsrb
        bsr             DispNyb
        puls    b
 
DispNyb
        pshs    b
        andb    #$0F
        cmpb    #10
        blo             DispNyb1
        addb    #'A'-10
        lbsr    OUTCH
        puls    b,pc
DispNyb1
        addb    #'0'
        lbsr    OUTCH
        puls    b,pc
 
;==============================================================================
; Timer
;==============================================================================
 
OPT INCLUDE "d:\cores2022\rf6809\software\boot\timer.asm"
OPT INCLUDE "d:\cores2022\rf6809\software\boot\i2c.asm"
OPT INCLUDE "d:\cores2022\rf6809\software\boot\rtc_driver.asm"
 
;==============================================================================
; Keyboard I/O
;==============================================================================
 
OPT INCLUDE "d:\cores2022\rf6809\software\boot\scancodes.asm"
OPT INCLUDE "d:\cores2022\rf6809\software\boot\keyboard.asm"
 
        fcb             "KEYBOARD"
        fcw             KeybdOpen
        fcw             KeybdClose
        fcw             KeybdRead
        fcw             KeybdWrite
        fcw             KeybdSeek
 
; Keyboard Open:
; Initialize the keyboard buffer head and tail indexes
;
KeybdOpen:
        rts
 
; Keyboard Close:
; Nothing to do except maybe clear the keyboard buffer
;
KeybdClose:
        rts
;
KeybdRead:
        rts
;
KeybdWrite:
        rts
 
KeybdSeek:
        rts
 
;==============================================================================
; Serial I/O
;==============================================================================
 
OPT INCLUDE "d:\cores2022\rf6809\software\boot\serial.asm"
 
;------------------------------------------------------------------------------
; Check if there is a keyboard character available. If so return true (<0)
; otherwise return false (0) in accb.
;------------------------------------------------------------------------------
;
KeybdCheckForKeyDirect:
        bra             DBGCheckForKey
 
;------------------------------------------------------------------------------
;------------------------------------------------------------------------------
INCH:
        pshs    b
INCH2:
        ldb             COREID
        cmpb    IOFocusID       ; if we do not have focus, block
        bne             INCH2
;       ldb             #$800                   ; block if no key available, get scancode directly
;       bra             GetKey
;       jsr             [CharInVec]     ; vector is being overwritten somehow
        lbsr    SerialPeekCharDirect
        tsta
        bmi             INCH1                   ; block if no key available
        leas    1,s                             ; get rid of blocking status
        rts
INCH1:
        puls    b                                       ; check blocking status
        tstb
        bmi     INCH                    ; if blocking, loop
        ldd             #-1                             ; return -1 if no char available
        rts
 
INCHE:
        bsr             INCH
        bra             INCHEK3
 
INCHEK:
        bsr             INCH
        tst             KeybdEcho
        beq             INCHEK1
INCHEK3:
        cmpa    #CR
        bne             INCHEK2
        lbsr            CRLF
        bra             INCHEK1
INCHEK2:
        lbsr    DisplayChar
INCHEK1:
        rts
 
OUTCH:
        jmp             [CharOutVec]
 
;------------------------------------------------------------------------------
; r1 0=echo off, non-zero = echo on
;------------------------------------------------------------------------------
;
SetKeyboardEcho:
        stb             KeybdEcho
        rts
 
 
;------------------------------------------------------------------------------
; Parameters:
;               x,d     bitmap of sprites to enable
;------------------------------------------------------------------------------
 
ShowSprites:
        stx             SPRITE_CTRL+SPRITE_EN
        std             SPRITE_CTRL+SPRITE_EN+2
        rts
 
;==============================================================================
; Femtiki Operating System.
;==============================================================================
 
OSCallTbl:
        fcw             0
        fcw             0
        fcw             0
        fcw             0
        fcw             0
        fcw             0
        fcw             0
        fcw             0
        fcw             0
        fcw             0
        fcw             0
        fcw             0
        fcw             0
        fcw             0
        fcw             0
        fcw             0
        fcw             0
        fcw             0
        fcw             0
        fcw             0
        fcw             0
        fcw             0
        fcw             ReleaseIOFocus
        fcw             0
        fcw             RequestIOFocus
 
NumOSFuncs      EQU     (*-OSCallTbl)/2
 
RequestIOFocus:
        ldb             COREID
        ldx             #IOFocusList
        abx
        sta             ,x
        tst             IOFocusID
        lbne    oscx
        stb             IOFocusID
        lbra    oscx
 
ReleaseIOFocus:
        ldb             COREID
        ldx             #IOFocusList
        abx
        clr             ,x                                              ; clear the request indicator
        lbsr    CopyScreenToVirtualScreen
        cmpb    IOFocusID                       ; are we the one with the focus?
        lbne    oscx
        ; We had the focus, so now a new core needs the focus.
        ; Search the focus list for a requestor. If no requester
        ; is found, give focus to core #1.
        lda             #15
riof2:
        incb
        andb    #15
        abx
        tst             ,x
        bne             riof1
        deca
        bne             riof2
        ; If no focus is requested by anyone, give to core #1
        ldb             #1
        lda             #24
        sta             ,x
riof1:
        stb             IOFocusID
        lbsr    CopyVirtualScreenToScreen
        lbra    oscx
 
 
;==============================================================================
;==============================================================================
 
;------------------------------------------------------------------------------
; Seed the random number generator. All channels are seeded with the same
; value.
;
; Parameters:
;               d = 'z' part of seed
;               x = 'w' part of seed
; Returns:
;               none
;------------------------------------------------------------------------------
 
mon_srand:
        ldy     #0
mon_srand1:
        sty     PRNG+4                          ; select channel
        clr     PRNG+8
        clr PRNG+9
        std     PRNG+10                         ; update low half of value
        clr PRNG+12
        clr PRNG+13
        stx     PRNG+14                         ; update low half of value
        iny
        cmpy    #$400                           ; 1k channels
        blo             mon_srand1
        rts
 
;------------------------------------------------------------------------------
; Get a random number and generate the next one.
;
; Parameters:
;               d = channel to use
; Returns:
;               x,d = 36 bit random value
;------------------------------------------------------------------------------
 
mon_rand:
        std     PRNG+4                          ; select channel
        ldx     PRNG+0
        ldd     PRNG+2
        stb     PRNG+3                          ; trigger calc of next number
        rts
 
;==============================================================================
; System Monitor
;==============================================================================
 
; Command Tables
 
cmdTable1:
        fcb             '<','>'+$800
        fcb             'b','s'+$800
        fcb             'b','c'+$800
        fcb             'D','R'+$800
        fcb             'D'+$800
        fcb             ':'+$800
        fcb             "FI",'G'+$800
        fcb             "FI",'L'+$800
        fcb             'F','L'+$800
        fcb             'J'+$800
        fcb             "RAMTES",'T'+$800
        fcb             "SP",'D'+$800
        fcb             "TI",'R'+$800
        fcb             'U'+$800
        fcb             "exi",'t'+$800
        fcb             '?'+$800
        fcb             "CL",'S'+$800
        fcw             0
 
cmdTable2:
        fcw             Redirect
        fcw             ArmBreakpoint
        fcw             DisarmBreakpoint
        fcw             DumpRegs
        fcw             DumpMemory
        fcw             EditMemory
        fcw             $FE0000                                 ; FIG forth
        fcw             FillMemory
        fcw             DumpIOFocusList
        fcw             jump_to_code
        fcw             dramtest
        fcw             $FF8000                                 ; sprite demo
        fcw             rtc_read
        fcw             $FF8003                                 ; unassembler
        fcw             xitMonitor
        fcw             PromptHelp
        fcw             PromptClearscreen
 
CmdPrompt:
        lbsr    CRLF
        ldb             #'$'
        lbsr    OUTCH
        lbra    OUTCH
 
msgF09Starting:
        fcb             "Femtiki F09 Multi-core OS Starting",CR,LF,0
 
MonitorStart:
        clr             BreakpointFlag
        clr             NumSetBreakpoints
        ldd             #123
        ldx             #654
        lbsr    mon_srand
        ldd             #msgF09Starting
        lbsr    DisplayString
        ldd             #HelpMsg
        lbsr    DisplayString
        ldd             #CmdPrompt
        std             CmdPromptJI
        ldd             #DisplayErr
        std             MonErrVec
        ldd             #$63FF                  ; default app stack
        std             mon_SSAVE
        clr             mon_DPRSAVE     ;
        tfr             ccr,a
        sta             mon_CCRSAVE
        clr             mon_PCSAVE
        ldd             #Monitor
        std             mon_PCSAVE+1
        clr             mon_XSAVE
        clr             mon_YSAVE
        clr             mon_USAVE
Monitor:
        leas    $6FFF                           ; reset stack pointer
        clrb                                                    ; turn off keyboard echo
        lbsr    SetKeyboardEcho
        ; Reset IO vectors
        ldd             #SerialPeekCharDirect
        std             CharInVec
        ldd             #DisplayChar
        std             CharOutVec
        ldd             #CmdPrompt
        std             CmdPromptJI
;       jsr             RequestIOFocus
PromptLn:
        jsr             [CmdPromptJI]
 
; Get characters until a CR is keyed
 
Prompt3:
        ldd             #-1                                     ; block until key present
        lbsr    INCH
        cmpb    #CR                                     ; carriage return?
        beq             Prompt1
        lbsr    OUTCH                           ; spit out the character
        bra             Prompt3                 ; and keep going
 
; Process the screen line that the CR was keyed on
;
Prompt1:
        ldd             #$5050
        std             LEDS
;       ldb             RunningID
;       cmpb    #61
;       bhi             Prompt3
        clr             CursorCol                       ; go back to the start of the line
        lbsr    CalcScreenLoc   ; calc screen memory location
        tfr             d,y
skipDollar:
        bsr             MonGetNonSpace
        cmpb    #'$'
        beq             skipDollar              ; skip over '$' prompt character
 
; Dispatch based on command
;
        dey
        tfr             y,u                                                     ; save off input position
        clrb
        ldx             #cmdTable1
parseCmd1:
        lda             ,y+                                                     ; get input character
        tst             ,x                                                      ; test for end of command
        bmi             endOfWord                               ;
        cmpa    ,x+                                                     ; does input match command?
        beq             parseCmd1
scanNextWord:
        tst             ,x+
        beq             Monitor                                 ; if end of table reached, not a command
        bpl             scanNextWord
        incb
        tfr             u,y                                                     ; reset input pointer
        bra             parseCmd1                               ; try again
endOfWord:
        eora    ,x
        asla
        bne             scanNextWord
        ; we found the command in the table
        aslb                                                                    ; b = word index
        ldx             #cmdTable2
        jmp             [b,x]                                           ; execute command
 
Redirect:
        bsr             MonGetch
        cmpb    #'s'
        bne             Prompt2a
        ldd             #SerialPeekCharDirect
        std             CharInVec
        ldd             #SerialPutChar
        std             CharOutVec
        bra             Monitor
Prompt2a:
        cmpb    #'c'
        bne             Monitor
        ldd             #GetKey
        std             CharInVec
        ldd             #DisplayChar
        std             CharOutVec
        bra             Monitor
 
PromptHelp:
        ldd             #HelpMsg
        lbsr    DisplayString
        bra             Monitor
 
PromptClearscreen:
        lbsr    ClearScreen
        lbsr    HomeCursor
        bra             Monitor
 
MonGetch:
        ldb             ,y
        iny
        rts
 
MonGetNonSpace:
        bsr             MonGetCh
        cmpb    #' '
        beq             MonGetNonSpace
        rts
 
;------------------------------------------------------------------------------
; Ignore blanks in the input
; Y = text pointer
; D destroyed
;------------------------------------------------------------------------------
;
ignBlanks:
ignBlanks1:
        bsr             MonGetch
        cmpb    #' '
        beq             ignBlanks1
        dey
        rts
 
;------------------------------------------------------------------------------
; Multiply number in work area by 10.
;------------------------------------------------------------------------------
Times10:
        ldd             mon_numwka              ; make a copy of the number
        std             mon_numwka+8
        ldd             mon_numwka+2
        std             mon_numwka+10
        asl             mon_numwka+3    ; shift left = *2
        rol             mon_numwka+2
        rol             mon_numwka+1
        rol             mon_numwka+0
        asl             mon_numwka+3    ; shift left = *4
        rol             mon_numwka+2
        rol             mon_numwka+1
        rol             mon_numwka+0
        ldd             mon_numwka+2    ; add in original value
        addd    mon_numwka+10   ; = *5
        ldb             mon_numwka+1
        adcb    mon_numwka+9
        stb             mon_numwka+1
        lda             mon_numwka+0
        adca    mon_numwka+8
        sta             mon_numwka+0
        asl             mon_numwka+3    ; shift left = * 10
        rol             mon_numwka+2
        rol             mon_numwka+1
        rol             mon_numwka+0
        rts
 
;------------------------------------------------------------------------------
;------------------------------------------------------------------------------
GetTwoParams:
        bsr             ignBlanks
        bsr             GetHexNumber    ; get start address of dump
        ldd             mon_numwka
        std             mon_r1
        ldd             mon_numwka+2
        std             mon_r1+2
        bsr             ignBlanks
        bsr             GetHexNumber    ; get end address of dump
        ldd             mon_numwka
        std             mon_r2
        ldd             mon_numwka+2
        std             mon_r2+2
        rts
 
;------------------------------------------------------------------------------
; Get a range, the end must be greater or equal to the start.
;------------------------------------------------------------------------------
GetRange:
        bsr             GetTwoParams
        ldd             mon_r2+2
        subd    mon_r1+2
        ldd             mon_r2
        sbcb    mon_r1+1
        sbca    mon_r1
        lbcc    grng1
        jsr             [MonErrVec]
        lbra    Monitor
grng1:
        rts
 
shl_numwka:
        asl             mon_numwka+3
        rol             mon_numwka+2
        rol             mon_numwka+1
        rol             mon_numwka
        rts
 
;------------------------------------------------------------------------------
; Get a hexidecimal number. Maximum of twelve digits.
;
; Modifies:
;       Y = text pointer (updated)
;       D = number of digits
;       mon_numwka contains number
;------------------------------------------------------------------------------
;
GetHexNumber:
        clrd
        std             mon_numwka      ; zero out work area
        std             mon_numwka+2
        pshs    x
        ldx             #0                                      ; max 12 eight digits
gthxn2:
        bsr             MonGetch
        bsr             AsciiToHexNybble
        cmpb    #-1
        beq             gthxn1
        bsr             shl_numwka
        bsr             shl_numwka
        bsr             shl_numwka
        bsr             shl_numwka
        andb    #$0f
        orb             mon_numwka+3
        stb             mon_numwka+3
        inx
        cmpx    #12
        blo             gthxn2
gthxn1:
        tfr             x,d
        puls    x,pc
 
;GetDecNumber:
;       phx
;       push    r4
;       push    r5
;       ldx             #0
;       ld              r4,#10
;       ld              r5,#10
;gtdcn2:
;       jsr             MonGetch
;       jsr             AsciiToDecNybble
;       cmp             #-1
;       beq             gtdcn1
;       mul             r2,r2,r5
;       add             r2,r1
;       dec             r4
;       bne             gtdcn2
;gtdcn1:
;       txa
;       pop             r5
;       pop             r4
;       plx
;       rts
 
;------------------------------------------------------------------------------
; Convert ASCII character in the range '0' to '9', 'a' to 'f' or 'A' to 'F'
; to a hex nybble.
;------------------------------------------------------------------------------
;
AsciiToHexNybble:
        cmpb    #'0'
        blo             gthx3
        cmpb    #'9'
        bhi             gthx5
        subb    #'0'
        rts
gthx5:
        cmpb    #'A'
        blo             gthx3
        cmpb    #'F'
        bhi             gthx6
        subb    #'A'
        addb    #10
        rts
gthx6:
        cmpb    #'a'
        blo             gthx3
        cmpb    #'z'
        bhi             gthx3
        subb    #'a'
        addb    #10
        rts
gthx3:
        ldb             #-1             ; not a hex number
        rts
 
AsciiToDecNybble:
        cmpb    #'0'
        bcc             gtdc3
        cmpb    #'9'+1
        bcs             gtdc3
        subb    #'0'
        rts
gtdc3:
        ldb             #-1
        rts
 
DisplayErr:
        ldd             #msgErr
        lbsr    DisplayString
        jmp             Monitor
 
DisplayStringDX
        std             Strptr
        stx             Strptr+2
        jsr             DisplayString
        rts
 
msgErr:
        fcb     "**Err",CR,LF,0
 
HelpMsg:
        fcb             "? = Display help",CR,LF
        fcb     "CLS = clear screen",CR,LF
        fcb     "bs = set breakpoint",CR,LF
        fcb     "bc = clear breakpoint",CR,LF
;       db      "S = Boot from SD Card",CR,LF
        fcb     ": = Edit memory bytes",CR,LF
;       db      "L = Load sector",CR,LF
;       db      "W = Write sector",CR,LF
        fcb "DR = Dump registers",CR,LF
        fcb     "D = Dump memory",CR,LF
        fcb     "F = Fill memory",CR,LF
        fcb "FL = Dump I/O Focus List",CR,LF
        fcb "FIG = start FIG Forth",CR,LF
;       db      "KILL n = kill task #n",CR,LF
;       db      "B = start tiny basic",CR,LF
;       db      "b = start EhBasic 6502",CR,LF
        fcb     "J = Jump to code",CR,LF
        fcb "RAM = test RAM",CR,LF
;       db      "R[n] = Set register value",CR,LF
;       db      "r = random lines - test bitmap",CR,LF
;       db      "e = ethernet test",CR,LF
        fcb     "s = serial output test",CR,LF
        fcb     "SP = sprite demo",CR,LF
;       db      "T = Dump task list",CR,LF
;       db      "TO = Dump timeout list",CR,LF
        fcb     "TI = display date/time",CR,LF
;       db      "TEMP = display temperature",CR,LF
        fcb     "U = unassemble",CR,LF
;       db      "P = Piano",CR,LF
        fcb     "x = exit monitor",CR,LF
        fcb             0
 
msgRegHeadings
        fcb     CR,LF,"  D/AB     X      Y      U      S       PC    DP  CCR",CR,LF,0
 
nHEX4:
        jsr             HEX4
        rts
 
nXBLANK:
        ldb             #' '
        lbra    OUTCH
 
;------------------------------------------------------------------------------
; Dump Memory
;
; Usage:
;       $D FFFC12 FFFC20
;
; Dump formatted to look like:
;               :FFFC12 012 012 012 012 555 666 777 888
;
;------------------------------------------------------------------------------
 
DumpMemory:
        bsr             GetRange
        ldy             #0
        ldy             mon_r1+2
dmpm2:
        lbsr    CRLF
        ldb             #':'
        lbsr    OUTCH
        tfr             y,d
        ;addd   mon_r1+2                                        ; output the address
        lbsr    DispWordAsHex
        ldb             #' '
        lbsr    OUTCH
        ldx             #8                                                              ; number of bytes to display
dmpm1:
;       ldb             far [mon_r1+1],y
        ;ldb            [mon_r1+2],y
        ldb             ,y
        iny
        lbsr    DispByteAsHex                   ; display byte
        ldb             #' '                                                    ; followed by a space
        lbsr    OUTCH
        clrb
        clra
        lbsr    INCH
        cmpb    #CTRLC
        beq             dmpm3
        dex
        bne             dmpm1
        ; Now output ascii
        ldb             #' '
        lbsr    OUTCH
        ldx             #8                                                              ; 8 chars to output
        leay    -8,y                                                    ; backup pointer
dmpm5:
;       ldb             far [mon_r1+1],y        ; get the char
;       ldb             [mon_r1+2],y                    ; get the char
        ldb             ,y
        cmpb    #$20                                                    ; is it a control char?
        bhs             dmpm4
        ldb             #'.'
dmpm4:
        lbsr    OUTCH
        iny
        dex
        bne             dmpm5
        cmpy    mon_r2+2
        blo             dmpm2
dmpm3:
        lbsr    CRLF
        lbra    Monitor
 
;------------------------------------------------------------------------------
; Edit Memory
;
; Usage:
;       $$:FFFC12 8 "Hello World!" 0
;
; Dump formatted to look like:
;               :FFFC12 012 012 012 012 555 666 777 888
;
;------------------------------------------------------------------------------
 
EditMemory:
        ldu             #8                                              ; set max byte count
        lbsr    GetHexNumber    ; get the start address
        ldx             mon_numwka+2
EditMem2:
        lbsr    ignBlanks                       ; skip over blanks
        lbsr    GetHexNumber    ; get the byte value
        tstb                                                            ; check for valid value
        beq             EditMem1                        ; if invalid, quit
        ldb             mon_numwka+3    ; get value
        stb             ,x+                                             ; update memory at address
        leau    -1,u                                    ; decremeent byte count
        cmpu    #0
        bne             EditMem2                        ; go back for annother byte
EditMem1:
        lbsr    MonGetch                        ; see if a string is being entered
        cmpb    #'"'
        bne             EditMem3                        ; no string, we're done
        ldu             #40                                             ; string must be less than 40 chars
EditMem4:
        lbsr    MonGetch                        ; look for close quote
        cmpb    #'"'
        bne             EditMem6                        ; end of string?
        ldu             #8                                              ; reset the byte count
        bra             EditMem2
EditMem6:
        stb             ,x+                                             ; store the character in memory
        leau    -1,u                                    ; decrement byte count
        cmpu    #0
        bhi             EditMem4                        ; max 40 chars
EditMem3:
        lbra    Monitor
 
 
;------------------------------------------------------------------------------
; Fill Memory
;
; Usage:
;       $$F FFFC12 FFFC30 89F
;
;------------------------------------------------------------------------------
 
FillMemory:
        lbsr    GetRange                        ; get address range to fill
        lbsr    ignBlanks
        lbsr    GetHexNumber    ; get target byte to write
        ldb             mon_numwka+3
        ldx             mon_r1+2
        clra
fillm1:                                                         ; Check for a CTRL-C every page of memory
        tsta
        bne             fillm2
        clrb                                                            ; we want a non-blocking check
        clra
        lbsr    INCH
        cmpb    #CTRLC
        lbeq    Monitor
        ldb             mon_numwka+3    ; reset target byte
fillm2:
        stb             ,x+
        cmpx    mon_r2+2
        bls             fillm1
fillm3:
        lbra    Monitor
 
;------------------------------------------------------------------------------
; Dump Registers
;
;       Usage:
;               $DR
;------------------------------------------------------------------------------
 
DumpRegs:
        ldd             #msgRegHeadings
        lbsr    DisplayString
        bsr             nXBLANK
        ldd             mon_DSAVE
        bsr             nHEX4
        bsr             nXBLANK
        ldd             mon_XSAVE
        bsr             nHEX4
        bsr             nXBLANK
        ldd             mon_YSAVE
        bsr             nHEX4
        bsr             nXBLANK
        ldd             mon_USAVE
        bsr             nHEX4
        bsr             nXBLANK
        ldd             mon_SSAVE
        bsr             nHEX4
        bsr             nXBLANK
        ldb             mon_PCSAVE+1
        lbsr    DispByteAsHex
        ldd             mon_PCSAVE+2
        bsr             nHEX4
        bsr             nXBLANK
        ldd             mon_DPRSAVE
        jsr             HEX2
        bsr             nXBLANK
        lda             mon_CCRSAVE
        lbsr    HEX2
        bsr             nXBLANK
        lbra    Monitor
 
;------------------------------------------------------------------------------
; Jump to code
;
; Registers are loaded with values from the monitor register save area before
; the code is jumped to.
;
; J 
;------------------------------------------------------------------------------
 
jump_to_code:
        bsr             GetHexNumber
        sei
        lds             mon_SSAVE
        ldd             #
        pshs    d
        ldb             #>jtc_exit
        pshs    b
        ldd             mon_numwka+2    ; get the address parameter
        pshs    d
        ldb             mon_numwka+1
        pshs    b
        ldd             mon_USAVE
        pshs    d
        ldd             mon_YSAVE
        pshs    d
        ldd             mon_XSAVE
        pshs    d
        lda             mon_DPRSAVE
        pshs    a
        ldd             mon_DSAVE
        pshs    d
        lda             mon_CCRSAVE
        pshs    a
        puls    far ccr,d,dpr,x,y,u,pc
jtc_exit:
        sts             >mon_SSAVE              ; need to use extended addressing, no direct page setting
        leas    $6FFF                                   ; reset stack to system area, dont modify flags register!
        pshs    ccr                                             ; now the stack can be used
        pshs    a                                                       ; save acca register so we can use it
        tfr             dpr,a                                   ; a = outgoing dpr value
        sta             >mon_DPRSAVE    ; force extended addressing mode usage here dpr is not set
        clra                                                            ; dpg register must be set to zero before values are
        tfr             a,dpr                                   ; saved in the monitor register save area.
        puls    a                                                       ; get back acca
        std             mon_DSAVE                       ; save regsters, can use direct addressing now
        stx             mon_XSAVE
        sty             mon_YSAVE
        stu             mon_USAVE
        puls    a                                                       ; get back ccr
        sta             mon_CCRSAVE             ; and save it too
        ; Reset vectors in case they got toasted.
        ldd             #SerialPeekCharDirect
        std             CharInVec
        ldd             #DisplayChar
        std             CharOutVec
        ldd             DisplayErr
        std             MonErrVec
        ; todo set according to coreid
        lbra    DumpRegs                        ; now go do a register dump
 
;------------------------------------------------------------------------------
;------------------------------------------------------------------------------
 
DumpIOFocusList:
        ldx             #0
dfl2:
        ldb             IOFocusList,x
        cmpb    #24
        bne             dfl1
        tfr             x,d
        lbsr    DispByteAsHex
        ldb             #' '
        lbsr    OUTCH
dfl1:
        inx
        cmpx    #16
        blo             dfl2
        lbsr    CRLF
        lbra    Monitor
 
bootpg:
        fcb             $000
boot_stack:
        fcw             $006FFF
numBreakpoints:
        fcb             8
mon_rom_vectab:
        fcw             mon_rom_vecs
mon_rom_vecs:
        fcw             Monitor                                         ; enter monitor program
        fcw             INCH                                                    ; input a character
        fcw             OUTCH                                                   ; output a character
        fcw             CRLF                                                    ; output carriage-return, line feed
        fcw             DisplayString
        fcw             DispByteAsHex
        fcw             DispWordAsHex
        fcw             ShowSprites
        fcw             mon_srand
        fcw             mon_rand
        fcw             0                                                                        ; operating system call
        fcw             GetRange
 
NumFuncs        EQU     (*-mon_rom_vectab)/2
 
;------------------------------------------------------------------------------
; SWI routine.
;
; SWI is used to call ROM monitor routines and process breakpoints.
;
;       swi
;       fcb 
;------------------------------------------------------------------------------
 
swi_rout:
        ldb             bootpg,pcr                      ; reset direct page
        tfr             b,dp
swi_rout1:
        ldu             11,s                                            ; get program counter (low order 2 bytes)
        leau    -1,u                                            ; backup a byte
        tst             BreakpointFlag  ; are we in breakpoint mode?
        beq             swiNotBkpt
        ldu             #Breakpoints
        ldb             NumSetBreakpoints
        beq             swiNotBkpt
swi_rout2:
        cmpu    ,y++
        beq             processBreakpoint
        decb
        bne             swi_rout2
swiNotBkpt:
        clr             BreakpointFlag
        pulu    d                                                               ; get function #, increment PC
        cmpb    #NumFuncs
        lbhi    DisplayErr
        stu             11,s                                            ; save updated PC on stack
        cmpb    #MF_OSCALL
        beq             swiCallOS
        aslb                                                                    ; 2 bytes per vector
        ldx             mon_rom_vectab,pcr
        abx
        ldx             ,x
        stx             jmpvec
        sts             mon_SSAVE                               ; save the stack pointer
        ldd             1,s                                                     ; get back D
        ldx             4,s                                                     ; get back X
        ldy             6,s                                                     ; get back Y
        ldu             8,s                                                     ; get back U
        lds             boot_stack,pcr  ; and use our own stack
        jsr             [jmpvec]                                ; call the routine
swi_rout3:
        lds             mon_SSAVE                               ; restore stack
        rti
 
processBreakpoint:
        lda             ,s
        sta             mon_CCRSAVE
        ldd             1,s
        std             mon_DSAVE
        ldb             3,s
        stb             mon_DPRSAVE
        ldd             4,s
        std             mon_XSAVE
        ldd             6,s
        std             mon_YSAVE
        ldd             8,s
        std             mon_USAVE
        sts             mon_SSAVE
        ldd             11,s
        std             mon_PCSAVE
        lds             boot_stack,pcr
        ldd             #swi_rout3                      ; setup so monitor can return
        pshs    d
        bsr             DisarmAllBreakpoints
        lbra    DumpRegs
 
xitMonitor:
        bsr             ArmAllBreakpoints
        rts
 
swiCallOS:
        leau    1,u                                                     ; next byte is func number
        ldb             ,u+
        cmpb    #NumOSFuncs                     ; check for valid range
        lbhi    DisplayErr
        stu             11,s                                            ; save updateed PC on stack
        aslb                                                                    ; compute vector address
        ldx             #OSCallTbl
        tst             b,x                                                     ; check for non-zero vector
        beq             swi_rout3
osc1:
;       tst             OSSEMA+1                                ; wait for availability
;       beq             osc1
        jsr             [b,x]                                           ; call the OS routine
oscx:
        clr             OSSEMA+1
        bra             swi_rout3
 
DisarmAllBreakpoints:
        pshs    d,x,y
        ldy             #0
        clrb
        ldx             #BreakpointBytes        ; x = breakpoint byte table address
disarm2:
        cmpb    #numBreakpoints         ; safety check
        bhs             disarm1
        cmpb    NumSetBreakpoints
        bhs             disarm1
        lda             b,x                                                             ; get memory byte
        sta             [Breakpoints,y]         ; and store it back to memory
        leay    2,y                                                             ; increment for next address
        incb                                                                            ; increment to next byte
        bra             disarm2                                         ; loop back
disarm1:
        puls    d,x,y,pc
 
ArmAllBreakpoints:
        pshs    d,x,y
        ldy             #0
        clrb
        ldx             #BreakpointBytes        ; x = breakpoint byte table address
arm2:
        cmpb    numBreakpoints          ; safety check
        bhs             arm1
        cmpb    NumSetBreakpoints
        bhs             arm1
        lda             [Breakpoints,y]         ; load byte at memory address
        sta             b,x                                                             ; save in table
        leay    2,y                                                             ; increment for next address
        incb                                                                            ; increment to next byte
        bra             arm2                                                    ; loop back
arm1:
        puls    d,x,y,pc
 
ArmBreakpoint:
        pshs    d,x,y
        lda             NumSetBreakpoints               ; check if too many breakpoints set
        cmpa    numBreakpoints
        lbhs    DisplayErr
        lbsr    GetHexNumber                            ; get address parameter
        ldb             NumSetBreakpoints               ; bv= number of set breakpoints
        ldy             mon_numwka+2                            ; get address
        lda             ,y                                                                      ; get byte at address
        ldx             #BreakpointBytes                ; and store byte in a table
        lda             #OPC_SWI                                                ; put a SWI instruction in place
        sta             ,y
        sta             b,x
        ldx             #Breakpoints                            ; also store the address in a table
        aslb                                                                                    ; index for 2 byte values
        sty             b,x
        lsrb                                                                                    ; size back to single byte
        incb
        stb             NumSetBreakpoints
        puls    d,x,y,pc
 
DisarmBreakpoint:
        pshs    d,x,y,u
        lbsr    GetHexNumber
        clrb
        clrb
        tfr             d,x                                                                     ; x = zero too
disarm6:
        cmpb    numBreakpoints                  ; no more than this many may be set
        bhs             disarm4
        cmpb    NumSetBreakpoints               ; number actually set
        bhs             disarm4
        ldy             Breakpoints,x                           ; y = breakpoint address
        cmpy    mon_numwka+2                            ; is it the one we want?
        bne             disarm3                                                 ; if not, go increment to next
        ldx             mon_numwka+2                            ; x = memory address
        ldy             #BreakpointBytes
        lda             b,y                                                                     ; get saved byte from table
        sta             ,x                                                                      ; set the byte at the memory address
        ; compress breakpoint table by removing breakpoint
        dec             NumSetBreakpoints               ; set the new number of set breakpoints
        pshs    b                                                                               ; save the position we're removing from
disarm7:
        incb                                                                                    ; set index for next byte
        lda             b,y                                                                     ; get byte
        decb                                                                                    ; and store it back
        sta             b,y
        incb                                                                                    ; move to next position
        cmpb    numBreakpoints                  ; hit end of table?
        blo             disarm7
        puls    b                                                                               ; get back position
        aslb                                                                                    ; times two for word index
        clra
        tfr             d,y
        lsrb                                                                                    ; back to byte index value
disarm8:
        ldu             2,y                                                                     ; get next breakpoint address
        stu             ,y++                                                            ; store in current pos, increment
        incb                                                                                    ; increment count
        cmpb    numBreakpoints                  ; hit end of table?
        blo             disarm8
        puls    d,x,y,u,pc
disarm3:
        leax    2,x
        incb
        bra             disarm6
disarm4:
        puls    d,x,y,u,pc
 
;------------------------------------------------------------------------------
;------------------------------------------------------------------------------
swi3_rout:
        sei
        lda             ,s
        sta             mon_CCRSAVE
        ldd             1,s
        std             mon_DSAVE
        ldb             3,s
        stb             mon_DPRSAVE
        ldd             4,s
        std             mon_XSAVE
        ldd             6,s
        std             mon_YSAVE
        ldd             8,s
        std             mon_USAVE
        sts             mon_SSAVE
        ldd             11,s
        std             mon_PCSAVE
        sts             mon_SSAVE
        lds             #$3FFF
        ldd             #swi3_exit
        pshs    d
        cli
        jmp             DumpRegs
swi3_exit:
        lds             mon_SSAVE
        rti
 
;------------------------------------------------------------------------------
;------------------------------------------------------------------------------
firq_rout:
        rti
 
irq_rout:
;       lbsr    SerialIRQ       ; check for recieved character
        lbsr    TimerIRQ
 
        ; Reset the edge sense circuit in the PIC
;       lda             #31                                                     ; Timer is IRQ #31
;       sta             IrqSource               ; stuff a byte indicating the IRQ source for PEEK()
;       sta             PIC+16                                  ; register 16 is edge sense reset reg
;       lda             VIA+VIA_IFR
;       bpl             notTimerIRQ2
;       bita    #$800
;       beq             notTimerIRQ2
;       clr             VIA+VIA_T3LL
;       clr             VIA+VIA_T3LH
;       inc             $E00037                                 ; update timer IRQ screen flag
;notTimerIRQ2:
 
        lda             IrqBase                 ; get the IRQ flag byte
        lsra
        ora             IrqBase
        anda    #$FE0
        sta             IrqBase
 
;       inc             TEXTSCR+54              ; update IRQ live indicator on screen
 
        ; flash the cursor
        ; only bother to flash the cursor for the task with the IO focus.
;       lda             COREID
;       cmpa    IOFocusID
;       bne             tr1a
;       lda             CursorFlash             ; test if we want a flashing cursor
;       beq             tr1a
;       lbsr    CalcScreenLoc   ; compute cursor location in memory
;       tfr             d,y
;       lda             $2000,y                 ; get color code $2000 higher in memory
;       ldb             IRQFlag                 ; get counter
;       lsrb
;       lsra
;       lsra
;       lsra
;       lsra
;       lsrb
;       rola
;       lsrb
;       rola
;       lsrb
;       rola
;       lsrb
;       rola
;       sta             $E00000,y               ; store the color code back to memory
tr1a:
        rti
 
;------------------------------------------------------------------------------
;------------------------------------------------------------------------------
nmi_rout:
        ldb             COREID
        lda             #'I'
        ldx             #TEXTSCR+40
        sta             b,x
rti_insn:
        rti
 
; Special Register Area
        org             $FFFFE0
 
; Interrupt vector table
 
        org             $FFFFF0
        fcw             rti_insn                ; reserved
        fcw             swi3_rout               ; SWI3
        fcw             rti_insn                ; SWI2
        fcw             firq_rout               ; FIRQ
        fcw             irq_rout                ; IRQ
        fcw             swi_rout                ; SWI
        fcw             nmi_rout                ; NMI
        fcw             start                           ; RST

Line No.	Rev	Author	Line
1	4	robfinch	`; ============================================================================`
2			`; __`
3	13	robfinch	`; \\__/ o\ (C) 2013-2022 Robert Finch, Waterloo`
4	4	robfinch	`; \ __ / All rights reserved.`
5			`; \/_// robfinch@opencores.org`
6			`; \|\|`
7			`;`
8			`;`
9	13	robfinch	`; BSD 3-Clause License`
10			`; Redistribution and use in source and binary forms, with or without`
11			`; modification, are permitted provided that the following conditions are met:`
12			`;`
13			`; 1. Redistributions of source code must retain the above copyright notice, this`
14			`; list of conditions and the following disclaimer.`
15			`;`
16			`; 2. Redistributions in binary form must reproduce the above copyright notice,`
17			`; this list of conditions and the following disclaimer in the documentation`
18			`; and/or other materials provided with the distribution.`
19			`;`
20			`; 3. Neither the name of the copyright holder nor the names of its`
21			`; contributors may be used to endorse or promote products derived from`
22			`; this software without specific prior written permission.`
23			`;`
24			`; THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS"`
25			`; AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE`
26			`; IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE`
27			`; DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT HOLDER OR CONTRIBUTORS BE LIABLE`
28			`; FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL`
29			`; DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR`
30			`; SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER`
31			`; CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY,`
32			`; OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE`
33			`; OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.`
34	4	robfinch	`;`
35			`; ============================================================================`
36			`;`
37	15	robfinch	`OPT include "d:\cores2022\rf6809\software\boot\mon_equates.asm"`
38			`OPT include "d:\cores2022\rf6809\software\boot\io_equates.asm"`
39	4	robfinch
40	15	robfinch	`OPC_SWI EQU $03F`
41	4	robfinch	`ScreenLocation EQU $10`
42			`ColorCodeLocation EQU $14`
43			`ScreenLocation2 EQU $18`
44			`BlkcpySrc EQU $1C`
45			`BlkcpyDst EQU $20`
46			`Strptr EQU $24`
47			`PICptr EQU $28`
48			`; Forth Area`
49			`; 0x30-0x60`
50
51			`; Task control blocks, room for 256 tasks`
52			`TCB_NxtRdy EQU $00 ; next task on ready / timeout list`
53			`TCB_PrvRdy EQU $04 ; previous task on ready / timeout list`
54			`TCB_NxtTCB EQU $08`
55			`TCB_Timeout EQU $0C`
56			`TCB_Priority EQU $10`
57			`TCB_MSGPTR_D1 EQU $14`
58			`TCB_MSGPTR_D2 EQU $18`
59			`TCB_hJCB EQU $1C`
60			`TCB_Status EQU $1E`
61			`TCB_CursorRow EQU $20`
62			`TCB_CursorCol EQU $21`
63			`TCB_hWaitMbx EQU $22 ; handle of mailbox task is waiting at`
64			`TCB_mbq_next EQU $24 ; mailbox queue next`
65			`TCB_mbq_prev EQU $28 ; mailbox queue previous`
66			`TCB_iof_next EQU $2C`
67			`TCB_iof_prev EQU $30`
68			`TCB_SPSave EQU $34 ; TCB_SPSave area`
69			`TCB_mmu_map EQU $38`
70
71			`KeybdHead EQU $FFFFFC800`
72			`KeybdTail EQU $FFFFFC900`
73			`KeybdEcho EQU $FFFFFCA00`
74			`KeybdBad EQU $FFFFFCB00`
75			`KeybdAck EQU $FFFFFCC00`
76			`KeybdLocks EQU $FFFFFCD00`
77			`KeybdBuffer EQU $FFFFFC000 ; buffer is 16 chars`
78
79			`BIOS_SCREENS EQU $17000000 ; $17000000 to $171FFFFF`
80
81			`; EhBASIC vars:`
82			`;`
83	15	robfinch	`NmiBase EQU $FFC013`
84			`IrqBase EQU $FFC014`
85	4	robfinch
86			`IOFocusNdx EQU $100`
87
88	13	robfinch	`; These variables in global OS storage area`
89
90	15	robfinch	`IOFocusList EQU $FFC000 ; to $FF000F`
91			`IOFocusID EQU $FFC010`
92			`IrqSource EQU $FFC011`
93			`IRQFlag EQU $FFC012`
94			`RunningID EQU $FFC013`
95	13	robfinch
96	4	robfinch	`; These variables use direct page access`
97			`CursorRow EQU $110`
98			`CursorCol EQU $111`
99			`CharColor EQU $112`
100			`ScreenColor EQU $113`
101			`CursorFlash EQU $114`
102			`KeyState1 EQU $120`
103			`KeyState2 EQU $121`
104			`KeyLED EQU $122`
105			`KeybdID EQU $124`
106	13	robfinch	`KeybdBlock EQU $126`
107			`kbdHeadRcv EQU $127`
108			`kbdTailRcv EQU $128`
109			`kbdFifo EQU $40 ; in local RAM`
110			`kbdFifoAlias EQU $C00040 ; to $C0007F ; alias for $40 to $7F`
111			`SerhZero EQU $130`
112			`SerHeadRcv EQU $131`
113			`SertZero EQU $132`
114			`SerTailRcv EQU $133`
115			`SerHeadXmit EQU $136`
116			`SerTailXmit EQU $138`
117			`SerRcvXon EQU $139`
118			`SerRcvXoff EQU $140`
119			`SerRcvBuf EQU $BFF000 ; 4kB serial recieve buffer`
120	4	robfinch
121	14	robfinch	`farflag EQU $15F`
122	13	robfinch	`asmbuf EQU $160 ; to $17F`
123
124	4	robfinch	`QNdx0 EQU $780`
125			`QNdx1 EQU QNdx0+2`
126			`QNdx2 EQU QNdx1+2`
127			`QNdx3 EQU QNdx2+2`
128			`QNdx4 EQU QNdx3+2`
129			`FreeTCB EQU QNdx4+2`
130			`TimeoutList EQU FreeTCB+2`
131			`FreeMbx EQU RunningTCB + 2`
132			`nMailbox EQU FreeMbx + 2`
133			`FreeMsg EQU nMailbox + 2`
134			`nMsgBlk EQU FreeMsg + 2`
135
136
137			`CharOutVec EQU $800`
138			`CharInVec EQU $804`
139	13	robfinch	`CmdPromptJI EQU $808`
140	14	robfinch	`MonErrVec EQU $80C`
141	15	robfinch	`BreakpointFlag EQU $810`
142			`NumSetBreakpoints EQU $811`
143			`Breakpoints EQU $820 ; to $82F`
144			`BreakpointBytes EQU $830 ; to $83F`
145			`mon_vectb EQU $880`
146	4	robfinch
147			`; Register save area for monitor`
148			`mon_DSAVE EQU $900`
149			`mon_XSAVE EQU $902`
150			`mon_YSAVE EQU $904`
151			`mon_USAVE EQU $906`
152			`mon_SSAVE EQU $908`
153			`mon_PCSAVE EQU $90A`
154			`mon_DPRSAVE EQU $90E`
155			`mon_CCRSAVE EQU $90F`
156
157			`mon_numwka EQU $910`
158			`mon_r1 EQU $920`
159	13	robfinch	`mon_r2 EQU $924`
160	15	robfinch	`jmpvec EQU $928`
161	4	robfinch
162			`; The ORG directive must set an address a multiple of 4 in order for the Verilog`
163			`; output to work correctly.`
164
165			`org $FFD0AC`
166			`nop`
167			`nop`
168			`nop`
169			`XBLANK`
170			`ldb #' '`
171			`lbsr OUTCH`
172			`rts`
173
174			`org $FFD0D0`
175			`nop`
176			`nop`
177			`CRLF`
178			`CRLF1:`
179			`ldb #CR`
180			`lbsr OUTCH`
181			`ldb #LF`
182			`lbsr OUTCH`
183			`rts`
184
185			`org $FFD0F0`
186			`nop`
187			`bra CRLF1`
188
189			`org $FFD1DC`
190			`ONEKEY`
191			`jmp [CharInVec]`
192
193			`org $FFD2C0`
194			`nop`
195			`LETTER`
196			`lbsr OUTCH`
197			`rts`
198
199			`org $FFD2CC`
200			`nop`
201			`nop`
202			`HEX2`
203			`lbsr DispByteAsHex`
204			`rts`
205			`HEX4`
206			`lbsr DispWordAsHex`
207			`rts`
208
209			`org $FFD300`
210			`ClearScreenJmp`
211			`lbra ClearScreen`
212			`org $FFD308`
213			`HomeCursorJmp`
214			`lbra HomeCursor`
215
216	13	robfinch	`org $FFD400`
217	4	robfinch
218			`; Local RAM test routine`
219			`; Checkerboard testing.`
220			`; There is 70kB of local RAM`
221			`; Does not use any RAM including no stack`
222
223			`ramtest:`
224			`ldy #0`
225			`lda #1`
226			`sta LEDS`
227			`ldd #$AAA555`
228			`ramtest1:`
229			`std ,y++`
230	13	robfinch	`cmpy #$8000`
231	4	robfinch	`blo ramtest1`
232			`; now readback values and compare`
233			`ldy #0`
234			`ramtest3:`
235			`ldd ,y++`
236			`cmpd #$AAA555`
237			`bne ramerr`
238	13	robfinch	`cmpy #$8000`
239	4	robfinch	`blo ramtest3`
240			`lda #2`
241			`sta LEDS`
242			`jmp ,u`
243			`ramerr:`
244			`lda #$80`
245			`sta LEDS`
246			`ldx #TEXTSCR`
247			`ldb COREID`
248			`abx`
249			`lda #'F'`
250			`sta ,x`
251			`sync`
252			`jmp ,u`
253
254	15	robfinch	`dramtest:`
255			`ldy #$10000 ; DRAM starts here`
256			`lda #1`
257			`sta LEDS`
258			`ldu #$AAA555`
259			`lbsr CRLF`
260			`dramtest1:`
261			`deca`
262			`bne dramtest4`
263			`tfr y,d`
264			`lbsr DispWordAsHex`
265			`ldb #CR`
266			`lbsr OUTCH`
267			`dramtest4:`
268			`stu ,y++`
269			`cmpy #$E00000 ; DRAM ends here`
270			`blo dramtest1`
271			`; now readback values and compare`
272			`ldy #$10000`
273			`lda #1`
274			`lbsr CRLF`
275			`dramtest3:`
276			`deca`
277			`bne dramtest5`
278			`tfr y,d`
279			`lbsr DispWordAsHex`
280			`ldb #CR`
281			`lbsr OUTCH`
282			`dramtest5:`
283			`cmpu ,y++`
284			`bne dramerr`
285			`cmpy #$E00000`
286			`blo dramtest3`
287			`lda #2`
288			`sta LEDS`
289			`lbra Monitor`
290			`dramerr:`
291			`lda #$80`
292			`sta LEDS`
293			`ldx #TEXTSCR`
294			`ldb COREID`
295			`abx`
296			`lda #'F'`
297			`sta ,x`
298			`lbra Monitor`
299
300	13	robfinch	`org $FFE000`
301	4	robfinch	`FDB Monitor`
302			`FDB DumRts ; NEXTCMD`
303			`FDB INCH`
304			`FDB INCHE`
305			`FDB INCHEK`
306			`FDB OUTCH`
307			`FDB PDATA`
308			`FDB PCRLF`
309			`FDB PSTRNG`
310			`FDB DumRts ; LRA`
311			`FDB DumRts`
312			`FDB DumRts`
313			`FDB DumRts`
314			`FDB DumRts ; VINIZ`
315			`FDB DisplayChar ; VOUTCH`
316			`FDB DumRts ; ACINIZ`
317			`FDB DumRts ; AOUTCH`
318
319			`DumRts:`
320			`rts`
321
322			`;------------------------------------------------------------------------------`
323			`;------------------------------------------------------------------------------`
324
325			`start:`
326	13	robfinch	`lda #$FFF ; all cores can do this`
327			`sta VIA+VIA_DDRA`
328	4	robfinch	`lda #$55 ; see if we can at least set LEDs`
329			`sta LEDS`
330	13	robfinch	`lda #1 ; prime OS semaphore`
331			`sta OSSEMA+$1000`
332	15	robfinch	`sta OUTSEMA+$1000`
333	4	robfinch	`ldu #st6 ; U = return address`
334			`jmp ramtest ; JMP dont JSR`
335			`st6:`
336	13	robfinch	`lds #$6FFF ; boot up stack area`
337	4	robfinch	`lda COREID`
338			`cmpa #FIRST_CORE`
339			`; beq st8`
340			`; sync ; halt cores other than 2`
341			`st8:`
342			`; bne skip_init`
343			`; bsr romToRam`
344			`; ldd #st7 & $FFFF`
345			`; tfr d,x`
346			`; jmp ,x ; jump to the BIOS now in local RAM`
347			`st7:`
348			`bsr Delay3s ; give some time for devices to reset`
349	15	robfinch	`clr BreakpointFlag`
350			`clr NumSetBreakpoints`
351	4	robfinch	`lda #$AA`
352			`sta LEDS`
353	13	robfinch	`lda #FIRST_CORE`
354	4	robfinch	`sta IOFocusID ; core #2 has focus`
355			`sta RunningID`
356	14	robfinch	`; Clear IO focus list`
357			`ldx #0`
358			`st9:`
359			`clr IOFocusList,x`
360			`inx`
361			`cmpx #16`
362			`blo st9`
363			`lda #24`
364			`sta IOFocusList+FIRST_CORE`
365
366	4	robfinch	`lda #$0CE`
367			`sta ScreenColor`
368			`sta CharColor`
369			`bsr ClearScreen`
370			`ldd #DisplayChar`
371			`std CharOutVec`
372	13	robfinch	`ldd #SerialPeekCharDirect`
373	4	robfinch	`std CharInVec`
374	15	robfinch	`; swi`
375			`; fcb MF_OSCALL`
376			`; fcb 24 ; request IO focus`
377	4	robfinch	`ldb COREID`
378			`cmpb #FIRST_CORE`
379			`beq init`
380			`bra skip_init`
381			`bra multi_sieve`
382			`st3:`
383			`lda #$FF`
384			`sta LEDS`
385			`bra st3`
386
387			`; initialize interrupt controller`
388			`; first, zero out all the vectors`
389			`init:`
390	13	robfinch	`lbsr rtc_read ; get clock values`
391			`ldx #kbdHeadRcv`
392			`ldb #32 ; number of bytes to zero out`
393			`init1:`
394			`clr ,x+`
395			`decb`
396			`bne init1`
397			`lbsr TimerInit`
398			`lbsr InitSerial`
399	4	robfinch	`ldx #128`
400			`lda #1 ; set irq(bit0), clear firq (bit1), disable int (bit 6), clear edge sense(bit 7)`
401			`ldb #FIRST_CORE ; serving core id`
402			`st1:`
403	13	robfinch	`clr PIC,x ; cause code`
404	4	robfinch	`sta PIC+1,x`
405			`stb PIC+2,x`
406			`leax 4,x`
407			`cmpx #256`
408			`blo st1`
409			`; lda #4 ; make the timer interrupt edge sensitive`
410			`; sta PIC+4 ; reg #4 is the edge sensitivity setting`
411			`; sta PIC ; reg #0 is interrupt enable`
412	13	robfinch	`lda #$81 ; make irq edge sensitive`
413			`sta PIC+$FD`
414			`lda #31 ; enable timer interrupt`
415	15	robfinch	`sta PIC+9`
416	13	robfinch	`ldb #1`
417			`stb OUTSEMA+SEMAABS ; set semaphore to 1 available slot`
418	4	robfinch	`skip_init:`
419			`andcc #$EF ; unmask irq`
420	15	robfinch	`lda #COLS`
421	4	robfinch	`sta TEXTREG+TEXT_COLS`
422	15	robfinch	`lda #ROWS`
423	4	robfinch	`sta TEXTREG+TEXT_ROWS`
424			`bsr ClearScreen`
425			`bsr HomeCursor`
426			`lda #5`
427			`sta LEDS`
428			`ldd #msgStartup`
429			`bsr DisplayString`
430			`ldx #0`
431			`ldd #0`
432			`lbsr ShowSprites`
433			`lbsr KeybdInit`
434			`ldd KeybdID`
435			`bsr DispWordAsHex`
436			`jmp MonitorStart`
437
438			`msgStartup`
439			`fcb "rf6809 12-bit System Starting.",CR,LF,0`
440
441			`;------------------------------------------------------------------------------`
442			`; The checkpoint register must be cleared within 1 second or a NMI interrupt`
443			`; will occur. checkpoint should be called with a JSR so that the global ROM`
444			`; routine is called.`
445			`;`
446			`; Modifies:`
447			`; none`
448			`;------------------------------------------------------------------------------`
449
450			`checkpoint:`
451			`clr $FFFFFFFE1 ; writing any value will do`
452			`rts`
453
454			`;------------------------------------------------------------------------------`
455			`; Copy the system ROM to local RAM`
456			`; Running the code from local RAM is probably an order of magnitude faster`
457			`; then running from the global ROM. It also reduces the network traffic to`
458			`; run from local RAM.`
459			`;`
460			`; Modifies:`
461			`; d,x,y`
462			`;------------------------------------------------------------------------------`
463
464			`romToRam:`
465			`ldx #$FFC000`
466			`ldy #$00C000`
467			`romToRam1:`
468			`ldd ,x++`
469			`std ,y++`
470			`cmpx #0`
471			`bne romToRam1`
472			`rts`
473
474			`;------------------------------------------------------------------------------`
475			`; Multi-core sieve program.`
476			`;------------------------------------------------------------------------------`
477
478			`; First fill screen chars with 'P' indicating prime positions`
479			`; Each core is responsible for the Nth position where N is the`
480			`; core number minus two.`
481			`;`
482			`multi_sieve:`
483			`lda #'P' ; indicate prime`
484			`ldb COREID ; find out which core we are`
485			`subb #FIRST_CORE`
486			`ldx #0 ; start at first char of screen`
487			`abx`
488			`multi_sieve3:`
489			`sta TEXTSCR,x ; store 'P'`
490			`leax 8,x ; advance to next position`
491			`cmpx #4095`
492			`blo multi_sieve3`
493			`jsr checkpoint`
494			`addb #2 ; start sieve at 2 (core id)`
495			`lda #'N' ; flag position value of 'N' for non-prime`
496			`multi_sieve2:`
497			`ldx #0`
498			`abx ; skip the first position - might be prime`
499			`multi_sieve1:`
500			`abx ; increment`

Browse

Tools

Subversion Repositories rf6809

[/] [rf6809/] [trunk/] [software/] [boot/] [boot_rom.asm] - Blame information for rev 15