URL https://opencores.org/ocsvn/s6soc/s6soc/trunk

Subversion Repositories s6soc

[/] [s6soc/] [trunk/] [rtl/] [llqspi.v] - Blame information for rev 47

Go to most recent revision | Details | Compare with Previous | View Log


///////////////////////////////////////////////////////////////////////////
//
// Filename:    llqspi.v
//
// Project:     Wishbone Controlled Quad SPI Flash Controller
//
// Purpose:     Reads/writes a word (user selectable number of bytes) of data
//              to/from a Quad SPI port.  The port is understood to be 
//              a normal SPI port unless the driver requests four bit mode.
//              When not in use, unlike our previous SPI work, no bits will
//              toggle.
//
// Creator:     Dan Gisselquist
//              Gisselquist Technology, LLC
//
///////////////////////////////////////////////////////////////////////////
//
// Copyright (C) 2015, Gisselquist Technology, LLC
//
// This program is free software (firmware): you can redistribute it and/or
// modify it under the terms of  the GNU General Public License as published
// by the Free Software Foundation, either version 3 of the License, or (at
// your option) any later version.
//
// This program is distributed in the hope that it will be useful, but WITHOUT
// ANY WARRANTY; without even the implied warranty of MERCHANTIBILITY or
// FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
// for more details.
//
// You should have received a copy of the GNU General Public License along
// with this program.  (It's in the $(ROOT)/doc directory, run make with no
// target there if the PDF file isn't present.)  If not, see
// <http://www.gnu.org/licenses/> for a copy.
//
// License:     GPL, v3, as defined and found on www.gnu.org,
//              http://www.gnu.org/licenses/gpl.html
//
//
///////////////////////////////////////////////////////////////////////////
`define QSPI_IDLE       3'h0
`define QSPI_START      3'h1
`define QSPI_BITS       3'h2
`define QSPI_READY      3'h3
`define QSPI_HOLDING    3'h4
`define QSPI_STOP       3'h5
`define QSPI_STOP_B     3'h6
 
// Modes
`define QSPI_MOD_SPI    2'b00
`define QSPI_MOD_QOUT   2'b10
`define QSPI_MOD_QIN    2'b11
 
module  llqspi(i_clk,
                // Module interface
                i_wr, i_hold, i_word, i_len, i_spd, i_dir,
                        o_word, o_valid, o_busy,
                // QSPI interface
                o_sck, o_cs_n, o_mod, o_dat, i_dat);
        input                   i_clk;
        // Chip interface
        //      Can send info
        //              i_dir = 1, i_spd = 0, i_hold = 0, i_wr = 1,
        //                      i_word = { 1'b0, 32'info to send },
        //                      i_len = # of bytes in word-1
        input                   i_wr, i_hold;
        input           [31:0]   i_word;
        input           [1:0]    i_len;  // 0=>8bits, 1=>16 bits, 2=>24 bits, 3=>32 bits
        input                   i_spd; // 0 -> normal QPI, 1 -> QSPI
        input                   i_dir; // 0 -> read, 1 -> write to SPI
        output  reg     [31:0]   o_word;
        output  reg             o_valid, o_busy;
        // Interface with the QSPI lines
        output  reg             o_sck;
        output  reg             o_cs_n;
        output  reg     [1:0]    o_mod;
        output  reg     [3:0]    o_dat;
        input           [3:0]    i_dat;
 
        // output       wire    [22:0]  o_dbg;
        // assign       o_dbg = { state, spi_len,
                // o_busy, o_valid, o_cs_n, o_sck, o_mod, o_dat, i_dat };
 
        // Timing:
        //
        //      Tick    Clk     BSY/WR  CS_n    BIT/MO  STATE
        //       0      1       0/0     1        -      
        //       1      1       0/1     1        -
        //       2      1       1/0     0         -      QSPI_START
        //       3      0        1/0     0         -      QSPI_START
        //       4      0        1/0     0         0      QSPI_BITS
        //       5      1       1/0     0         0      QSPI_BITS
        //       6      0        1/0     0         1      QSPI_BITS
        //       7      1       1/0     0         1      QSPI_BITS
        //       8      0        1/0     0         2      QSPI_BITS
        //       9      1       1/0     0         2      QSPI_BITS
        //      10      0        1/0     0         3      QSPI_BITS
        //      11      1       1/0     0         3      QSPI_BITS
        //      12      0        1/0     0         4      QSPI_BITS
        //      13      1       1/0     0         4      QSPI_BITS
        //      14      0        1/0     0         5      QSPI_BITS
        //      15      1       1/0     0         5      QSPI_BITS
        //      16      0        1/0     0         6      QSPI_BITS
        //      17      1       1/1     0         6      QSPI_BITS
        //      18      0        1/1     0         7      QSPI_READY
        //      19      1       0/1     0         7      QSPI_READY
        //      20      0        1/0/V   0         8      QSPI_BITS
        //      21      1       1/0     0         8      QSPI_BITS
        //      22      0        1/0     0         9      QSPI_BITS
        //      23      1       1/0     0         9      QSPI_BITS
        //      24      0        1/0     0        10      QSPI_BITS
        //      25      1       1/0     0        10      QSPI_BITS
        //      26      0        1/0     0        11      QSPI_BITS
        //      27      1       1/0     0        11      QSPI_BITS
        //      28      0        1/0     0        12      QSPI_BITS
        //      29      1       1/0     0        12      QSPI_BITS
        //      30      0        1/0     0        13      QSPI_BITS
        //      31      1       1/0     0        13      QSPI_BITS
        //      32      0        1/0     0        14      QSPI_BITS
        //      33      1       1/0     0        14      QSPI_BITS
        //      34      0        1/0     0        15      QSPI_READY
        //      35      1       1/0     0        15      QSPI_READY
        //      36      1       1/0/V   0         -      QSPI_STOP
        //      37      1       1/0     0         -      QSPI_STOPB
        //      38      1       1/0     1        -      QSPI_IDLE
        //      39      1       0/0     1        -
        // Now, let's switch from single bit to quad mode
        //      40      1       0/0     1        -      QSPI_IDLE
        //      41      1       0/1     1        -      QSPI_IDLE
        //      42      1       1/0     0         -      QSPI_START
        //      43      0        1/0     0         -      QSPI_START
        //      44      0        1/0     0         0      QSPI_BITS
        //      45      1       1/0     0         0      QSPI_BITS
        //      46      0        1/0     0         1      QSPI_BITS
        //      47      1       1/0     0         1      QSPI_BITS
        //      48      0        1/0     0         2      QSPI_BITS
        //      49      1       1/0     0         2      QSPI_BITS
        //      50      0        1/0     0         3      QSPI_BITS
        //      51      1       1/0     0         3      QSPI_BITS
        //      52      0        1/0     0         4      QSPI_BITS
        //      53      1       1/0     0         4      QSPI_BITS
        //      54      0        1/0     0         5      QSPI_BITS
        //      55      1       1/0     0         5      QSPI_BITS
        //      56      0        1/0     0         6      QSPI_BITS
        //      57      1       1/1/QR  0         6      QSPI_BITS
        //      58      0        1/1/QR  0         7      QSPI_READY
        //      59      1       0/1/QR  0         7      QSPI_READY
        //      60      0        1/0/?/V 0         8-11   QSPI_BITS
        //      61      1       1/0/?   0         8-11   QSPI_BITS
        //      62      0        1/0/?   0         12-15  QSPI_BITS
        //      63      1       1/0/?   0         12-15  QSPI_BITS
        //      64      1       1/0/?/V 0        -       QSPI_STOP
        //      65      1       1/0/?   0        -       QSPI_STOPB
        //      66      1       1/0/?   1       -       QSPI_IDLE
        //      67      1       0/0     1       -       QSPI_IDLE
        // Now let's try something entirely in Quad read mode, from the
        // beginning
        //      68      1       0/1/QR  1       -       QSPI_IDLE
        //      69      1       1/0     0        -       QSPI_START
        //      70      0        1/0     0        -       QSPI_START
        //      71      0        1/0     0        0-3     QSPI_BITS
        //      72      1       1/0     0        0-3     QSPI_BITS
        //      73      0        1/1/QR  0        4-7     QSPI_BITS
        //      74      1       0/1/QR  0        4-7     QSPI_BITS
        //      75      0        1/?/?/V 0        8-11    QSPI_BITS
        //      76      1       1/?/?   0        8-11    QSPI_BITS
        //      77      0        1/1/QR  0        12-15   QSPI_BITS
        //      78      1       0/1/QR  0        12-15   QSPI_BITS
        //      79      0        1/?/?/V 0        16-19   QSPI_BITS
        //      80      1       1/0     0        16-19   QSPI_BITS
        //      81      0        1/0     0        20-23   QSPI_BITS
        //      82      1       1/0     0        20-23   QSPI_BITS
        //      83      1       1/0/V   0        -       QSPI_STOP
        //      84      1       1/0     0        -       QSPI_STOPB
        //      85      1       1/0     1       -       QSPI_IDLE
        //      86      1       0/0     1       -       QSPI_IDLE
 
        wire    i_miso;
        assign  i_miso = i_dat[1];
 
        reg             r_spd, r_dir;
        reg     [5:0]    spi_len;
        reg     [31:0]   r_word;
        reg     [30:0]   r_input;
        reg     [2:0]    state;
        initial state = `QSPI_IDLE;
        initial o_sck   = 1'b1;
        initial o_cs_n  = 1'b1;
        initial o_dat   = 4'hd;
        initial o_valid = 1'b0;
        initial o_busy  = 1'b0;
        initial r_input = 31'h000;
        initial o_mod   = `QSPI_MOD_SPI;
        always @(posedge i_clk)
                if ((state == `QSPI_IDLE)&&(o_sck))
                begin
                        o_cs_n <= 1'b1;
                        o_valid <= 1'b0;
                        o_busy  <= 1'b0;
                        o_mod <= `QSPI_MOD_SPI;
                        r_word <= i_word;
                        r_spd <= i_spd;
                        r_dir <= i_dir;
                        if (i_wr)
                        begin
                                state <= `QSPI_START;
                                spi_len<= { 1'b0, i_len, 3'b000 } + 6'h8;
                                o_cs_n <= 1'b0;
                                // o_sck <= 1'b1;
                                o_busy <= 1'b1;
                        end
                end else if (state == `QSPI_START)
                begin // We come in here with sck high, stay here 'til sck is low
                        o_sck <= 1'b0;
                        if (o_sck == 1'b0)
                        begin
                                state <= `QSPI_BITS;
                                spi_len<= spi_len - ( (r_spd)? 6'h4 : 6'h1 );
                                if (r_spd)
                                        r_word <= { r_word[27:0], 4'h0 };
                                else
                                        r_word <= { r_word[30:0], 1'b0 };
                        end
                        o_mod <= (r_spd) ? { 1'b1, r_dir } : `QSPI_MOD_SPI;
                        o_cs_n <= 1'b0;
                        o_busy <= 1'b1;
                        o_valid <= 1'b0;
                        if (r_spd)
                                o_dat <= r_word[31:28];
                        else
                                o_dat <= { 3'b110, r_word[31] };
                end else if (~o_sck)
                begin
                        o_sck <= 1'b1;
                        o_busy <= ((state != `QSPI_READY)||(~i_wr));
                        o_valid <= 1'b0;
                end else if (state == `QSPI_BITS)
                begin
                        // Should enter into here with at least a spi_len
                        // of one, perhaps more
                        o_sck <= 1'b0;
                        o_busy <= 1'b1;
                        if (r_spd)
                        begin
                                o_dat <= r_word[31:28];
                                r_word <= { r_word[27:0], 4'h0 };
                                spi_len <= spi_len - 6'h4;
                                if (spi_len == 6'h4)
                                        state <= `QSPI_READY;
                        end else begin
                                o_dat <= { 3'b110, r_word[31] };
                                r_word <= { r_word[30:0], 1'b0 };
                                spi_len <= spi_len - 6'h1;
                                if (spi_len == 6'h1)
                                        state <= `QSPI_READY;
                        end
 
                        o_valid <= 1'b0;
                        if (~o_mod[1])
                                r_input <= { r_input[29:0], i_miso };
                        else if (o_mod[1])
                                r_input <= { r_input[26:0], i_dat };
                end else if (state == `QSPI_READY)
                begin
                        o_valid <= 1'b0;
                        o_cs_n <= 1'b0;
                        o_busy <= 1'b1;
                        // This is the state on the last clock (both low and
                        // high clocks) of the data.  Data is valid during
                        // this state.  Here we chose to either STOP or
                        // continue and transmit more.
                        o_sck <= (i_hold); // No clocks while holding
                        r_spd <= i_spd;
                        r_dir <= i_dir;
                        if (i_spd)
                        begin
                                r_word <= { i_word[27:0], 4'h0 };
                                spi_len<= { 1'b0, i_len, 3'b000 } + 6'h8 - 6'h4;
                        end else begin
                                r_word <= { i_word[30:0], 1'b0 };
                                spi_len<= { 1'b0, i_len, 3'b000 } + 6'h8 - 6'h1;
                        end
                        if((~o_busy)&&(i_wr))// Acknowledge a new request
                        begin
                                state <= `QSPI_BITS;
                                o_busy <= 1'b1;
                                o_sck <= 1'b0;
 
                                // Read the new request off the bus
                                // Set up the first bits on the bus
                                o_mod <= (i_spd) ? { 1'b1, i_dir } : `QSPI_MOD_SPI;
                                if (i_spd)
                                        o_dat <= i_word[31:28];
                                else
                                        o_dat <= { 3'b110, i_word[31] };
 
                        end else begin
                                o_sck <= 1'b1;
                                state <= (i_hold)?`QSPI_HOLDING : `QSPI_STOP;
                                o_busy <= (~i_hold);
                        end
 
                        // Read a bit upon any transition
                        o_valid <= 1'b1;
                        if (~o_mod[1])
                        begin
                                r_input <= { r_input[29:0], i_miso };
                                o_word  <= { r_input[30:0], i_miso };
                        end else if (o_mod[1])
                        begin
                                r_input <= { r_input[26:0], i_dat };
                                o_word  <= { r_input[27:0], i_dat };
                        end
                end else if (state == `QSPI_HOLDING)
                begin
                        // We need this state so that the o_valid signal
                        // can get strobed with our last result.  Otherwise
                        // we could just sit in READY waiting for a new command.
                        //
                        // Incidentally, the change producing this state was
                        // the result of a nasty race condition.  See the
                        // commends in wbqspiflash for more details.
                        //
                        o_valid <= 1'b0;
                        o_cs_n <= 1'b0;
                        o_busy <= 1'b0;
                        r_spd <= i_spd;
                        r_dir <= i_dir;
                        if (i_spd)
                        begin
                                r_word <= { i_word[27:0], 4'h0 };
                                spi_len<= { 1'b0, i_len, 3'b100 };
                        end else begin
                                r_word <= { i_word[30:0], 1'b0 };
                                spi_len<= { 1'b0, i_len, 3'b111 };
                        end
                        if((~o_busy)&&(i_wr))// Acknowledge a new request
                        begin
                                state  <= `QSPI_BITS;
                                o_busy <= 1'b1;
                                o_sck  <= 1'b0;
 
                                // Read the new request off the bus
                                // Set up the first bits on the bus
                                o_mod<=(i_spd)?{ 1'b1, i_dir } : `QSPI_MOD_SPI;
                                if (i_spd)
                                        o_dat <= i_word[31:28];
                                else
                                        o_dat <= { 3'b110, i_word[31] };
                        end else begin
                                o_sck <= 1'b1;
                                state <= (i_hold)?`QSPI_HOLDING : `QSPI_STOP;
                                o_busy <= (~i_hold);
                        end
                end else if (state == `QSPI_STOP)
                begin
                        o_sck   <= 1'b1; // Stop the clock
                        o_valid <= 1'b0; // Output may have just been valid, but no more
                        o_busy  <= 1'b1; // Still busy till port is clear
                        state <= `QSPI_STOP_B;
                        o_mod <= `QSPI_MOD_SPI;
                end else if (state == `QSPI_STOP_B)
                begin
                        o_cs_n <= 1'b1;
                        o_sck <= 1'b1;
                        // Do I need this????
                        // spi_len <= 3; // Minimum CS high time before next cmd
                        state <= `QSPI_IDLE;
                        o_valid <= 1'b0;
                        o_busy <= 1'b1;
                        o_mod <= `QSPI_MOD_SPI;
                end else begin // Invalid states, should never get here
                        state   <= `QSPI_STOP;
                        o_valid <= 1'b0;
                        o_busy  <= 1'b1;
                        o_cs_n  <= 1'b1;
                        o_sck   <= 1'b1;
                        o_mod   <= `QSPI_MOD_SPI;
                        o_dat   <= 4'hd;
                end
 
endmodule
 

Line No.	Rev	Author	Line
1	2	dgisselq	`///////////////////////////////////////////////////////////////////////////`
2			`//`
3			`// Filename: llqspi.v`
4			`//`
5			`// Project: Wishbone Controlled Quad SPI Flash Controller`
6			`//`
7			`// Purpose: Reads/writes a word (user selectable number of bytes) of data`
8			`// to/from a Quad SPI port. The port is understood to be`
9			`// a normal SPI port unless the driver requests four bit mode.`
10			`// When not in use, unlike our previous SPI work, no bits will`
11			`// toggle.`
12			`//`
13			`// Creator: Dan Gisselquist`
14			`// Gisselquist Technology, LLC`
15			`//`
16			`///////////////////////////////////////////////////////////////////////////`
17			`//`
18			`// Copyright (C) 2015, Gisselquist Technology, LLC`
19			`//`
20			`// This program is free software (firmware): you can redistribute it and/or`
21			`// modify it under the terms of the GNU General Public License as published`
22			`// by the Free Software Foundation, either version 3 of the License, or (at`
23			`// your option) any later version.`
24			`//`
25			`// This program is distributed in the hope that it will be useful, but WITHOUT`
26			`// ANY WARRANTY; without even the implied warranty of MERCHANTIBILITY or`
27			`// FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License`
28			`// for more details.`
29			`//`
30			`// You should have received a copy of the GNU General Public License along`
31			`// with this program. (It's in the $(ROOT)/doc directory, run make with no`
32			`// target there if the PDF file isn't present.) If not, see`
33			`// <http://www.gnu.org/licenses/> for a copy.`
34			`//`
35			`// License: GPL, v3, as defined and found on www.gnu.org,`
36			`// http://www.gnu.org/licenses/gpl.html`
37			`//`
38			`//`
39			`///////////////////////////////////////////////////////////////////////////`
40			`define QSPI_IDLE 3'h0
41			`define QSPI_START 3'h1
42			`define QSPI_BITS 3'h2
43			`define QSPI_READY 3'h3
44			`define QSPI_HOLDING 3'h4
45			`define QSPI_STOP 3'h5
46			`define QSPI_STOP_B 3'h6
47
48			`// Modes`
49			`define QSPI_MOD_SPI 2'b00
50			`define QSPI_MOD_QOUT 2'b10
51			`define QSPI_MOD_QIN 2'b11
52
53			`module llqspi(i_clk,`
54			`// Module interface`
55			`i_wr, i_hold, i_word, i_len, i_spd, i_dir,`
56			`o_word, o_valid, o_busy,`
57			`// QSPI interface`
58			`o_sck, o_cs_n, o_mod, o_dat, i_dat);`
59			`input i_clk;`
60			`// Chip interface`
61			`// Can send info`
62			`// i_dir = 1, i_spd = 0, i_hold = 0, i_wr = 1,`
63			`// i_word = { 1'b0, 32'info to send },`
64			`// i_len = # of bytes in word-1`
65			`input i_wr, i_hold;`
66			`input [31:0] i_word;`
67			`input [1:0] i_len; // 0=>8bits, 1=>16 bits, 2=>24 bits, 3=>32 bits`
68			`input i_spd; // 0 -> normal QPI, 1 -> QSPI`
69			`input i_dir; // 0 -> read, 1 -> write to SPI`
70			`output reg [31:0] o_word;`
71			`output reg o_valid, o_busy;`
72			`// Interface with the QSPI lines`
73			`output reg o_sck;`
74			`output reg o_cs_n;`
75			`output reg [1:0] o_mod;`
76			`output reg [3:0] o_dat;`
77			`input [3:0] i_dat;`
78
79			`// output wire [22:0] o_dbg;`
80			`// assign o_dbg = { state, spi_len,`
81			`// o_busy, o_valid, o_cs_n, o_sck, o_mod, o_dat, i_dat };`
82
83			`// Timing:`
84			`//`
85			`// Tick Clk BSY/WR CS_n BIT/MO STATE`
86			`// 0 1 0/0 1 -`
87			`// 1 1 0/1 1 -`
88			`// 2 1 1/0 0 - QSPI_START`
89			`// 3 0 1/0 0 - QSPI_START`
90			`// 4 0 1/0 0 0 QSPI_BITS`
91			`// 5 1 1/0 0 0 QSPI_BITS`
92			`// 6 0 1/0 0 1 QSPI_BITS`
93			`// 7 1 1/0 0 1 QSPI_BITS`
94			`// 8 0 1/0 0 2 QSPI_BITS`
95			`// 9 1 1/0 0 2 QSPI_BITS`
96			`// 10 0 1/0 0 3 QSPI_BITS`
97			`// 11 1 1/0 0 3 QSPI_BITS`
98			`// 12 0 1/0 0 4 QSPI_BITS`
99			`// 13 1 1/0 0 4 QSPI_BITS`
100			`// 14 0 1/0 0 5 QSPI_BITS`
101			`// 15 1 1/0 0 5 QSPI_BITS`
102			`// 16 0 1/0 0 6 QSPI_BITS`
103			`// 17 1 1/1 0 6 QSPI_BITS`
104			`// 18 0 1/1 0 7 QSPI_READY`
105			`// 19 1 0/1 0 7 QSPI_READY`
106			`// 20 0 1/0/V 0 8 QSPI_BITS`
107			`// 21 1 1/0 0 8 QSPI_BITS`
108			`// 22 0 1/0 0 9 QSPI_BITS`
109			`// 23 1 1/0 0 9 QSPI_BITS`
110			`// 24 0 1/0 0 10 QSPI_BITS`
111			`// 25 1 1/0 0 10 QSPI_BITS`
112			`// 26 0 1/0 0 11 QSPI_BITS`
113			`// 27 1 1/0 0 11 QSPI_BITS`
114			`// 28 0 1/0 0 12 QSPI_BITS`
115			`// 29 1 1/0 0 12 QSPI_BITS`
116			`// 30 0 1/0 0 13 QSPI_BITS`
117			`// 31 1 1/0 0 13 QSPI_BITS`
118			`// 32 0 1/0 0 14 QSPI_BITS`
119			`// 33 1 1/0 0 14 QSPI_BITS`
120			`// 34 0 1/0 0 15 QSPI_READY`
121			`// 35 1 1/0 0 15 QSPI_READY`
122			`// 36 1 1/0/V 0 - QSPI_STOP`
123			`// 37 1 1/0 0 - QSPI_STOPB`
124			`// 38 1 1/0 1 - QSPI_IDLE`
125			`// 39 1 0/0 1 -`
126			`// Now, let's switch from single bit to quad mode`
127			`// 40 1 0/0 1 - QSPI_IDLE`
128			`// 41 1 0/1 1 - QSPI_IDLE`
129			`// 42 1 1/0 0 - QSPI_START`
130			`// 43 0 1/0 0 - QSPI_START`
131			`// 44 0 1/0 0 0 QSPI_BITS`
132			`// 45 1 1/0 0 0 QSPI_BITS`
133			`// 46 0 1/0 0 1 QSPI_BITS`
134			`// 47 1 1/0 0 1 QSPI_BITS`
135			`// 48 0 1/0 0 2 QSPI_BITS`
136			`// 49 1 1/0 0 2 QSPI_BITS`
137			`// 50 0 1/0 0 3 QSPI_BITS`
138			`// 51 1 1/0 0 3 QSPI_BITS`
139			`// 52 0 1/0 0 4 QSPI_BITS`
140			`// 53 1 1/0 0 4 QSPI_BITS`
141			`// 54 0 1/0 0 5 QSPI_BITS`
142			`// 55 1 1/0 0 5 QSPI_BITS`
143			`// 56 0 1/0 0 6 QSPI_BITS`
144			`// 57 1 1/1/QR 0 6 QSPI_BITS`
145			`// 58 0 1/1/QR 0 7 QSPI_READY`
146			`// 59 1 0/1/QR 0 7 QSPI_READY`
147			`// 60 0 1/0/?/V 0 8-11 QSPI_BITS`
148			`// 61 1 1/0/? 0 8-11 QSPI_BITS`
149			`// 62 0 1/0/? 0 12-15 QSPI_BITS`
150			`// 63 1 1/0/? 0 12-15 QSPI_BITS`
151			`// 64 1 1/0/?/V 0 - QSPI_STOP`
152			`// 65 1 1/0/? 0 - QSPI_STOPB`
153			`// 66 1 1/0/? 1 - QSPI_IDLE`
154			`// 67 1 0/0 1 - QSPI_IDLE`
155			`// Now let's try something entirely in Quad read mode, from the`
156			`// beginning`
157			`// 68 1 0/1/QR 1 - QSPI_IDLE`
158			`// 69 1 1/0 0 - QSPI_START`
159			`// 70 0 1/0 0 - QSPI_START`
160			`// 71 0 1/0 0 0-3 QSPI_BITS`
161			`// 72 1 1/0 0 0-3 QSPI_BITS`
162			`// 73 0 1/1/QR 0 4-7 QSPI_BITS`
163			`// 74 1 0/1/QR 0 4-7 QSPI_BITS`
164			`// 75 0 1/?/?/V 0 8-11 QSPI_BITS`
165			`// 76 1 1/?/? 0 8-11 QSPI_BITS`
166			`// 77 0 1/1/QR 0 12-15 QSPI_BITS`
167			`// 78 1 0/1/QR 0 12-15 QSPI_BITS`
168			`// 79 0 1/?/?/V 0 16-19 QSPI_BITS`
169			`// 80 1 1/0 0 16-19 QSPI_BITS`
170			`// 81 0 1/0 0 20-23 QSPI_BITS`
171			`// 82 1 1/0 0 20-23 QSPI_BITS`
172			`// 83 1 1/0/V 0 - QSPI_STOP`
173			`// 84 1 1/0 0 - QSPI_STOPB`
174			`// 85 1 1/0 1 - QSPI_IDLE`
175			`// 86 1 0/0 1 - QSPI_IDLE`
176
177			`wire i_miso;`
178			`assign i_miso = i_dat[1];`
179
180			`reg r_spd, r_dir;`
181			`reg [5:0] spi_len;`
182			`reg [31:0] r_word;`
183			`reg [30:0] r_input;`
184			`reg [2:0] state;`
185			initial state = `QSPI_IDLE;
186			`initial o_sck = 1'b1;`
187			`initial o_cs_n = 1'b1;`
188			`initial o_dat = 4'hd;`
189			`initial o_valid = 1'b0;`
190			`initial o_busy = 1'b0;`
191			`initial r_input = 31'h000;`
192	46	dgisselq	initial o_mod = `QSPI_MOD_SPI;
193	2	dgisselq	`always @(posedge i_clk)`
194			if ((state == `QSPI_IDLE)&&(o_sck))
195			`begin`
196			`o_cs_n <= 1'b1;`
197			`o_valid <= 1'b0;`
198			`o_busy <= 1'b0;`
199			o_mod <= `QSPI_MOD_SPI;
200	46	dgisselq	`r_word <= i_word;`
201			`r_spd <= i_spd;`
202			`r_dir <= i_dir;`
203	2	dgisselq	`if (i_wr)`
204			`begin`
205			state <= `QSPI_START;
206			`spi_len<= { 1'b0, i_len, 3'b000 } + 6'h8;`
207			`o_cs_n <= 1'b0;`
208	46	dgisselq	`// o_sck <= 1'b1;`
209	2	dgisselq	`o_busy <= 1'b1;`
210			`end`
211			end else if (state == `QSPI_START)
212			`begin // We come in here with sck high, stay here 'til sck is low`
213			`o_sck <= 1'b0;`
214			`if (o_sck == 1'b0)`
215			`begin`
216			state <= `QSPI_BITS;
217			`spi_len<= spi_len - ( (r_spd)? 6'h4 : 6'h1 );`
218			`if (r_spd)`
219			`r_word <= { r_word[27:0], 4'h0 };`
220			`else`
221			`r_word <= { r_word[30:0], 1'b0 };`
222			`end`
223			o_mod <= (r_spd) ? { 1'b1, r_dir } : `QSPI_MOD_SPI;
224			`o_cs_n <= 1'b0;`
225			`o_busy <= 1'b1;`
226			`o_valid <= 1'b0;`
227			`if (r_spd)`
228			`o_dat <= r_word[31:28];`
229	46	dgisselq	`else`
230	2	dgisselq	`o_dat <= { 3'b110, r_word[31] };`
231			`end else if (~o_sck)`
232			`begin`
233			`o_sck <= 1'b1;`
234			o_busy <= ((state != `QSPI_READY)\|\|(~i_wr));
235			`o_valid <= 1'b0;`
236			end else if (state == `QSPI_BITS)
237			`begin`
238			`// Should enter into here with at least a spi_len`
239			`// of one, perhaps more`
240			`o_sck <= 1'b0;`
241			`o_busy <= 1'b1;`
242			`if (r_spd)`
243			`begin`
244			`o_dat <= r_word[31:28];`
245			`r_word <= { r_word[27:0], 4'h0 };`
246			`spi_len <= spi_len - 6'h4;`
247			`if (spi_len == 6'h4)`
248			state <= `QSPI_READY;
249			`end else begin`
250			`o_dat <= { 3'b110, r_word[31] };`
251			`r_word <= { r_word[30:0], 1'b0 };`
252			`spi_len <= spi_len - 6'h1;`
253			`if (spi_len == 6'h1)`
254			state <= `QSPI_READY;
255			`end`
256
257			`o_valid <= 1'b0;`
258			`if (~o_mod[1])`
259			`r_input <= { r_input[29:0], i_miso };`
260			`else if (o_mod[1])`
261			`r_input <= { r_input[26:0], i_dat };`
262			end else if (state == `QSPI_READY)
263			`begin`
264			`o_valid <= 1'b0;`
265			`o_cs_n <= 1'b0;`
266			`o_busy <= 1'b1;`
267			`// This is the state on the last clock (both low and`
268			`// high clocks) of the data. Data is valid during`
269			`// this state. Here we chose to either STOP or`
270			`// continue and transmit more.`
271			`o_sck <= (i_hold); // No clocks while holding`
272	46	dgisselq	`r_spd <= i_spd;`
273			`r_dir <= i_dir;`
274			`if (i_spd)`
275			`begin`
276			`r_word <= { i_word[27:0], 4'h0 };`
277			`spi_len<= { 1'b0, i_len, 3'b000 } + 6'h8 - 6'h4;`
278			`end else begin`
279			`r_word <= { i_word[30:0], 1'b0 };`
280			`spi_len<= { 1'b0, i_len, 3'b000 } + 6'h8 - 6'h1;`
281			`end`
282	2	dgisselq	`if((~o_busy)&&(i_wr))// Acknowledge a new request`
283			`begin`
284			state <= `QSPI_BITS;
285			`o_busy <= 1'b1;`
286			`o_sck <= 1'b0;`
287
288			`// Read the new request off the bus`
289			`// Set up the first bits on the bus`
290			o_mod <= (i_spd) ? { 1'b1, i_dir } : `QSPI_MOD_SPI;
291			`if (i_spd)`
292			`o_dat <= i_word[31:28];`
293	46	dgisselq	`else`
294	2	dgisselq	`o_dat <= { 3'b110, i_word[31] };`
295
296			`end else begin`
297			`o_sck <= 1'b1;`
298			state <= (i_hold)?`QSPI_HOLDING : `QSPI_STOP;
299			`o_busy <= (~i_hold);`
300	46	dgisselq	`end`
301	2	dgisselq
302	46	dgisselq	`// Read a bit upon any transition`
303			`o_valid <= 1'b1;`
304			`if (~o_mod[1])`
305			`begin`
306			`r_input <= { r_input[29:0], i_miso };`
307			`o_word <= { r_input[30:0], i_miso };`
308			`end else if (o_mod[1])`
309			`begin`
310			`r_input <= { r_input[26:0], i_dat };`
311			`o_word <= { r_input[27:0], i_dat };`
312	2	dgisselq	`end`
313			end else if (state == `QSPI_HOLDING)
314			`begin`
315			`// We need this state so that the o_valid signal`
316			`// can get strobed with our last result. Otherwise`
317			`// we could just sit in READY waiting for a new command.`
318			`//`
319			`// Incidentally, the change producing this state was`
320			`// the result of a nasty race condition. See the`
321			`// commends in wbqspiflash for more details.`
322			`//`
323			`o_valid <= 1'b0;`
324			`o_cs_n <= 1'b0;`
325			`o_busy <= 1'b0;`
326	46	dgisselq	`r_spd <= i_spd;`
327			`r_dir <= i_dir;`
328			`if (i_spd)`
329			`begin`
330			`r_word <= { i_word[27:0], 4'h0 };`
331			`spi_len<= { 1'b0, i_len, 3'b100 };`
332			`end else begin`
333			`r_word <= { i_word[30:0], 1'b0 };`
334			`spi_len<= { 1'b0, i_len, 3'b111 };`
335			`end`
336	2	dgisselq	`if((~o_busy)&&(i_wr))// Acknowledge a new request`
337			`begin`
338			state <= `QSPI_BITS;
339			`o_busy <= 1'b1;`
340			`o_sck <= 1'b0;`
341
342			`// Read the new request off the bus`
343			`// Set up the first bits on the bus`
344			o_mod<=(i_spd)?{ 1'b1, i_dir } : `QSPI_MOD_SPI;
345			`if (i_spd)`
346			`o_dat <= i_word[31:28];`
347	46	dgisselq	`else`
348	2	dgisselq	`o_dat <= { 3'b110, i_word[31] };`
349			`end else begin`
350			`o_sck <= 1'b1;`
351			state <= (i_hold)?`QSPI_HOLDING : `QSPI_STOP;
352			`o_busy <= (~i_hold);`
353			`end`
354			end else if (state == `QSPI_STOP)
355			`begin`
356			`o_sck <= 1'b1; // Stop the clock`
357			`o_valid <= 1'b0; // Output may have just been valid, but no more`
358			`o_busy <= 1'b1; // Still busy till port is clear`
359			state <= `QSPI_STOP_B;
360			o_mod <= `QSPI_MOD_SPI;
361			end else if (state == `QSPI_STOP_B)
362			`begin`
363			`o_cs_n <= 1'b1;`
364			`o_sck <= 1'b1;`
365			`// Do I need this????`
366			`// spi_len <= 3; // Minimum CS high time before next cmd`
367			state <= `QSPI_IDLE;
368			`o_valid <= 1'b0;`
369			`o_busy <= 1'b1;`
370			o_mod <= `QSPI_MOD_SPI;
371			`end else begin // Invalid states, should never get here`
372			state <= `QSPI_STOP;
373			`o_valid <= 1'b0;`
374			`o_busy <= 1'b1;`
375			`o_cs_n <= 1'b1;`
376			`o_sck <= 1'b1;`
377			o_mod <= `QSPI_MOD_SPI;
378			`o_dat <= 4'hd;`
379			`end`
380
381			`endmodule`
382

Browse

Tools

Subversion Repositories s6soc

[/] [s6soc/] [trunk/] [rtl/] [llqspi.v] - Blame information for rev 47