URL https://opencores.org/ocsvn/t6507lp/t6507lp/trunk

Subversion Repositories t6507lp

[/] [t6507lp/] [trunk/] [rtl/] [verilog/] [t6507lp_fsm.v] - Blame information for rev 112

Go to most recent revision | Details | Compare with Previous | View Log


////////////////////////////////////////////////////////////////////////////
////                                                                    ////
//// T6507LP IP Core                                                    ////
////                                                                    ////
//// This file is part of the T6507LP project                           ////
//// http://www.opencores.org/cores/t6507lp/                            ////
////                                                                    ////
//// Description                                                        ////
//// 6507 FSM                                                           ////
////                                                                    ////
//// TODO:                                                              ////
//// - Fix relative mode, bit 7 means negative                          ////
//// - Comment the code                                                 ////
////                                                                    ////
//// Author(s):                                                         ////
//// - Gabriel Oshiro Zardo, gabrieloshiro@gmail.com                    ////
//// - Samuel Nascimento Pagliarini (creep), snpagliarini@gmail.com     ////
////                                                                    ////
////////////////////////////////////////////////////////////////////////////
////                                                                    ////
//// Copyright (C) 2001 Authors and OPENCORES.ORG                       ////
////                                                                    ////
//// This source file may be used and distributed without               ////
//// restriction provided that this copyright statement is not          ////
//// removed from the file and that any derivative work contains        ////
//// the original copyright notice and the associated disclaimer.       ////
////                                                                    ////
//// This source file is free software; you can redistribute it         ////
//// and/or modify it under the terms of the GNU Lesser General         ////
//// Public License as published by the Free Software Foundation;       ////
//// either version 2.1 of the License, or (at your option) any         ////
//// later version.                                                     ////
////                                                                    ////
//// This source is distributed in the hope that it will be             ////
//// useful, but WITHOUT ANY WARRANTY; without even the implied         ////
//// warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR            ////
//// PURPOSE. See the GNU Lesser General Public License for more        ////
//// details.                                                           ////
////                                                                    ////
//// You should have received a copy of the GNU Lesser General          ////
//// Public License along with this source; if not, download it         ////
//// from http://www.opencores.org/lgpl.shtml                           ////
////                                                                    ////
////////////////////////////////////////////////////////////////////////////
 
`include "timescale.v"
 
module t6507lp_fsm(clk, reset_n, alu_result, alu_status, data_in, address, control, data_out, alu_opcode, alu_a, alu_enable, alu_x, alu_y);
        parameter [3:0] DATA_SIZE = 4'd8;
        parameter [3:0] ADDR_SIZE = 4'd13;
 
        localparam [3:0] DATA_SIZE_ = DATA_SIZE - 4'b0001;
        localparam [3:0] ADDR_SIZE_ = ADDR_SIZE - 4'b0001;
 
        input clk;
        input reset_n;
        input [DATA_SIZE_:0] alu_result;
        input [DATA_SIZE_:0] alu_status;
        input [DATA_SIZE_:0] data_in;
        output reg [ADDR_SIZE_:0] address;
        output reg control; // read = 0, write = 1
        output reg [DATA_SIZE_:0] data_out;
        output reg [DATA_SIZE_:0] alu_opcode;
        output reg [DATA_SIZE_:0] alu_a;
        output reg alu_enable;
 
        input [DATA_SIZE_:0] alu_x;
        input [DATA_SIZE_:0] alu_y;
 
        // FSM states. If aiming for less power consumption try gray coding.
        localparam FETCH_OP = 5'b00000;
        //localparam FETCH_OP_CALC = 5'b00001; this was never used
        localparam FETCH_LOW = 5'b00010;
        localparam FETCH_HIGH = 5'b00011;
        localparam READ_MEM = 5'b00100;
        localparam DUMMY_WRT_CALC = 5'b00101;
        localparam WRITE_MEM = 5'b00110;
        localparam FETCH_OP_CALC_PARAM = 5'b00111;
        localparam READ_MEM_CALC_INDEX = 5'b01000;
        localparam FETCH_HIGH_CALC_INDEX = 5'b01001;
        localparam READ_MEM_FIX_ADDR = 5'b01010;
        localparam FETCH_OP_EVAL_BRANCH = 5'b01011;
        localparam FETCH_OP_FIX_PC = 5'b01100;
        localparam READ_FROM_POINTER = 5'b01101;
        localparam READ_FROM_POINTER_X = 5'b01110;
        localparam READ_FROM_POINTER_X1 = 5'b01111;
        localparam PUSH_PCH = 5'b10000;
        localparam PUSH_PCL = 5'b10001;
        localparam PUSH_STATUS = 5'b10010;
        localparam FETCH_PCL = 5'b10011;
        localparam FETCH_PCH = 5'b10100;
        localparam INCREMENT_SP = 5'b10101;
        localparam PULL_STATUS = 5'b10110;
        localparam PULL_PCL = 5'b10111;
        localparam PULL_PCH = 5'b11000;
        localparam INCREMENT_PC = 5'b11001;
        localparam PUSH_REGISTER = 5'b11010;
        localparam PULL_REGISTER = 5'b11011;
        localparam DUMMY = 5'b11100;
        localparam RESET = 5'b11111;
 
        // OPCODES TODO: verify how this get synthesised
        `include "T6507LP_Package.v"
 
        // control signals
        localparam MEM_READ = 1'b0;
        localparam MEM_WRITE = 1'b1;
 
        reg [ADDR_SIZE_:0] pc;           // program counter
        reg [DATA_SIZE:0] sp;            // stack pointer. 9 bits wide.
        reg [DATA_SIZE_:0] ir;           // instruction register
        reg [ADDR_SIZE_:0] temp_addr;    // temporary address
        reg [DATA_SIZE_:0] temp_data;    // temporary data
 
        reg [4:0] state, next_state; // current and next state registers
 
        // wiring that simplifies the FSM logic by simplifying the addressing modes
        reg absolute;
        reg absolute_indexed;
        reg accumulator;
        reg immediate;
        reg implied;
        reg indirectx;
        reg indirecty;
        reg relative;
        reg zero_page;
        reg zero_page_indexed;
        reg [DATA_SIZE_:0] index; // will be assigned with either X or Y
 
        // regs that store the type of operation. again, this simplifies the FSM a lot.
        reg read;
        reg read_modify_write;
        reg write;
        reg jump;
        reg jump_indirect;
 
        // regs for the special instructions
        reg brk;
        reg rti;
        reg rts;
        reg pha;
        reg php;
        reg pla;
        reg plp;
        reg jsr;
 
        wire [ADDR_SIZE_:0] next_pc;
        assign next_pc = pc + 13'b0000000000001;
 
        reg [ADDR_SIZE_:0] address_plus_index; // this would update more times than actually needed, consuming power.
        reg page_crossed;                       // so the simple assign was changed into a combinational always block
 
        reg branch;
 
        always @(*) begin
                address_plus_index = 8'h00;
                page_crossed = 1'b0;
 
                if (state == READ_MEM_CALC_INDEX || state == READ_MEM_FIX_ADDR || state == FETCH_HIGH_CALC_INDEX) begin
                        {page_crossed, address_plus_index[7:0]} = temp_addr[7:0] + index;
                        address_plus_index[12:8] = temp_addr[12:8] + page_crossed;
                end
                else if (branch) begin
                        if (state == FETCH_OP_FIX_PC || state == FETCH_OP_EVAL_BRANCH) begin
                                {page_crossed, address_plus_index[7:0]} = pc[7:0] + index;
                                address_plus_index[12:8] = pc[12:8] + page_crossed;// warning: pc might feed these lines twice and cause branch failure
                        end                                                             // solution: add a temp reg i guess
                end
                else if (state == READ_FROM_POINTER) begin
                        if (indirectx) begin
                                {page_crossed, address_plus_index[7:0]} = temp_data + index;
                                address_plus_index[12:8] = 5'b00000;
                        end
                        else if (jump_indirect) begin
                                address_plus_index[7:0] = temp_addr[7:0] + 8'h01; // temp_addr should be 7:0?
                                address_plus_index[12:8] = 5'b00000;
                        end
                        else begin // indirecty falls here
                                address_plus_index[7:0] = temp_data + 8'h01;
                                address_plus_index[12:8] = 5'b00000;
                        end
                end
                else if (state == READ_FROM_POINTER_X) begin
                        {page_crossed, address_plus_index[7:0]} = temp_data + index + 8'h01;
                        address_plus_index[12:8] = 5'b00000;
                end
                else if (state == READ_FROM_POINTER_X1) begin
                        {page_crossed, address_plus_index[7:0]} = temp_addr[7:0] + index;
                        address_plus_index[12:8] = temp_addr[12:8] + page_crossed;
                end
        end
 
        wire [8:0] sp_plus_one;
        assign sp_plus_one = sp + 9'b000000001;
 
        wire [8:0] sp_minus_one;
        assign sp_minus_one = sp - 9'b000000001;
 
        always @ (posedge clk or negedge reset_n) begin // sequencial always block
                if (reset_n == 1'b0) begin
                        // all registers must assume default values
                        pc <= 0; // TODO: this is written somewhere. something about a reset vector. must be checked.
                        sp <= 9'b000000000; // the default is 'h100 
                        ir <= 8'h00;
                        temp_addr <= 13'h0000;
                        temp_data <= 8'h00;
                        state <= RESET;
                        // registered outputs also receive default values
                        address <= 0;
                        control <= MEM_READ;
                        data_out <= 8'h00;
                end
                else begin
                        state <= next_state;
 
                        case (state)
                                RESET: begin    // The processor was reset
                                        sp <= 9'b100000000; // this prevents flipflops with different drivers
                                        $write("under reset");
                                end
                                /*
                                FETCH_OP: executed when the processor was reset or the last instruction could not fetch.
                                FETCH_OP_CALC_PARAM: enables the alu with an argument (alu_a) and fetchs the next instruction opcode. (pipelining)
                                */
                                FETCH_OP, FETCH_OP_CALC_PARAM: begin // this is the pipeline happening!
                                        pc <= next_pc;
                                        address <= next_pc;
                                        control <= MEM_READ;
                                        ir <= data_in;
                                end
                                /*
                                in this state the opcode is already known so truly execution begins.
                                all instruction execute this cycle.
                                */
                                FETCH_LOW: begin
                                        if (accumulator || implied) begin
                                                pc <= pc; // is this better?
                                                address <= pc;
                                                control <= MEM_READ;
                                        end
                                        else if (immediate || relative) begin
                                                pc <= next_pc;
                                                address <= next_pc;
                                                control <= MEM_READ;
                                                temp_data <= data_in; // the follow-up byte is saved in temp_data 
                                        end
                                        else if (absolute || absolute_indexed || jump_indirect) begin
                                                pc <= next_pc;
                                                address <= next_pc;
                                                control <= MEM_READ;
                                                temp_addr <= {{5{1'b0}},data_in};
                                                temp_data <= 8'h00;
                                        end
                                        else if (zero_page) begin
                                                pc <= next_pc;
                                                address <= {{5{1'b0}},data_in};
                                                temp_addr <= {{5{1'b0}},data_in};
 
                                                if (write) begin
                                                        control <= MEM_WRITE;
                                                        data_out <= alu_result;
                                                end
                                                else begin
                                                        control <= MEM_READ;
                                                        data_out <= 8'h00;
                                                end
                                        end
                                        else if (zero_page_indexed) begin
                                                pc <= next_pc;
                                                address <= {{5{1'b0}}, data_in};
                                                temp_addr <= {{5{1'b0}}, data_in};
                                                control <= MEM_READ;
                                        end
                                        else if (indirectx || indirecty) begin
                                                pc <= next_pc;
                                                address <= data_in;
                                                temp_data <= data_in;
                                                control <= MEM_READ;
                                        end
                                        else begin // the special instructions will fall here: BRK, RTI, RTS...
                                                if (brk) begin
                                                        pc <= next_pc;
                                                        address <= sp;
                                                        data_out <= {{3{1'b0}}, pc[12:8]};
                                                        control <= MEM_WRITE;
                                                end
                                                else if (rti || rts) begin
                                                        address <= sp;
                                                        control <= MEM_READ;
                                                end
                                                else if (pha || php) begin
                                                        pc <= pc;
                                                        address <= sp;
                                                        data_out <= (pha) ? alu_result : alu_status;
                                                        control <= MEM_WRITE;
                                                end
                                                else if (pla || plp) begin
                                                        pc <= pc;
                                                        address <= sp;
                                                        control <= MEM_READ;
                                                end
                                                else begin // jsr
                                                        address <= sp;
                                                        control <= MEM_READ;
                                                        temp_addr <= {{5{1'b0}}, data_in};
                                                        pc <= next_pc;
                                                end
                                        end
                                end
                                FETCH_HIGH_CALC_INDEX: begin
                                        pc <= next_pc;
                                        temp_addr[12:8] <= data_in[4:0];
                                        address <= {data_in[4:0], address_plus_index[7:0]};
                                        control <= MEM_READ;
                                        data_out <= 8'h00;
                                end
                                // this cycle fetchs the next operand while still evaluating if a branch occurred.
                                FETCH_OP_EVAL_BRANCH: begin
                                        if (branch) begin
                                                pc <= {{5{1'b0}}, address_plus_index[7:0]};
                                                address <= {{5{1'b0}}, address_plus_index[7:0]};
                                                control <= MEM_READ;
                                                data_out <= 8'h00;
                                        end
                                        else begin
                                                pc <= next_pc;
                                                address <= next_pc;
                                                control <= MEM_READ;
                                                data_out <= 8'h00;
                                                ir <= data_in;
                                        end
                                end
                                // sometimes when reading memory page crosses may occur. the pc register must be fixed, i.e., add 16'h0100
                                FETCH_OP_FIX_PC: begin
                                        if (page_crossed) begin
                                                pc[12:8] <= address_plus_index[12:8];
                                                address[12:8] <= address_plus_index[12:8];
                                        end
                                        else begin
                                                pc <= next_pc;
                                                address <= next_pc;
                                                control <= MEM_READ;
                                                ir <= data_in;
                                        end
                                end
                                // several instructions ocupy 3 bytes in memory. this cycle reads the third byte.
                                FETCH_HIGH: begin
                                        if (jump) begin
                                                pc <= {data_in[4:0], temp_addr[7:0]}; // PCL <= first byte, PCH <= second byte
                                                address <= {data_in[4:0], temp_addr[7:0]};
                                                control <= MEM_READ;
                                                data_out <= 8'h00;
                                        end
                                        else begin
                                                if (write) begin
                                                        pc <= next_pc;
                                                        temp_addr[12:8] <= data_in[4:0];
                                                        address <= {data_in[4:0],temp_addr[7:0]};
                                                        control <= MEM_WRITE;
                                                        data_out <= alu_result;
                                                end
                                                else begin // read_modify_write or just read
                                                        pc <= next_pc;
                                                        temp_addr[12:8] <= data_in[4:0];
                                                        address <= {data_in[4:0],temp_addr[7:0]};
                                                        control <= MEM_READ;
                                                        data_out <= 8'h00;
                                                end
                                        end
                                end
                                READ_MEM: begin
                                        if (read_modify_write) begin
                                                pc <= pc;
                                                address <= temp_addr;
                                                control <= MEM_WRITE;
                                                temp_data <= data_in;
                                                data_out <= data_in; // writeback the same value
                                        end
                                        else begin
                                                pc <= pc;
                                                address <= pc;
                                                temp_data <= data_in;
                                                control <= MEM_READ;
                                                data_out <= 8'h00;
                                        end
                                end
                                READ_MEM_CALC_INDEX: begin
                                                address <= address_plus_index;
                                                temp_addr <= address_plus_index;
 
                                                if (write) begin
                                                        control <= MEM_WRITE;
                                                        data_out <= alu_result;
                                                end
                                                else begin
                                                        control <= MEM_READ;
                                                        data_out <= 8'h00;
                                                end
 
                                end
                                READ_MEM_FIX_ADDR: begin
                                        if (read) begin
                                                control <= MEM_READ;
                                                data_out <= 8'h00;
 
                                                if (page_crossed) begin
                                                        address <= address_plus_index;
                                                        temp_addr <= address_plus_index;
                                                end
                                                else begin
                                                        address <= pc;
                                                        temp_data <= data_in;
                                                end
                                        end
                                        else if (write) begin
                                                control <= MEM_WRITE;
                                                data_out <= alu_result;
                                                address <= address_plus_index;
                                                temp_addr <= address_plus_index;
 
                                        end
                                        else begin // read modify write
                                                control <= MEM_READ;
                                                data_out <= 8'h00;
                                                address <= address_plus_index;
                                                temp_addr <= address_plus_index;
                                        end
                                end
                                DUMMY_WRT_CALC: begin
                                        pc <= pc;
                                        address <= temp_addr;
                                        control <= MEM_WRITE;
                                        data_out <= alu_result;
                                end
                                WRITE_MEM: begin
                                        pc <= pc;
                                        address <= pc;
                                        control <= MEM_READ;
                                        data_out <= 8'h00;
                                end
                                READ_FROM_POINTER: begin
                                        if (jump_indirect) begin
                                                pc[7:0] <= data_in;
                                                control <= MEM_READ;
                                                address <= address_plus_index;
                                        end
                                        else begin
                                                pc <= pc;
                                                control <= MEM_READ;
 
                                                if (indirectx) begin
                                                        address <= address_plus_index;
                                                end
                                                else begin // indirecty falls here
                                                        address <= address_plus_index;
                                                        temp_addr <= {{5{1'b0}}, data_in};
                                                end
                                        end
                                end
                                READ_FROM_POINTER_X: begin
                                        pc <= pc;
                                        address <= address_plus_index;
                                        temp_addr[7:0] <= data_in;
                                        control <= MEM_READ;
                                end
                                READ_FROM_POINTER_X1: begin
                                        if (jump_indirect) begin
                                                pc[12:8] <= data_in[4:0];
                                                control <= MEM_READ;
                                                address <= {data_in[4:0], pc[7:0]};
                                        end
                                        else if (indirectx) begin
                                                address <= {data_in[4:0], temp_addr[7:0]};
                                                if (write) begin
                                                        control <= MEM_WRITE;
                                                        data_out <= alu_result;
                                                end
                                                else begin
                                                        control <= MEM_READ;
                                                end
                                        end
                                        else begin // indirecty falls here
                                                address <= address_plus_index;
                                                temp_addr[12:8] <= data_in;
                                                control <= MEM_READ;
                                        end
                                end
                                PUSH_PCH: begin
                                        pc <= pc;
                                        address <= sp_minus_one;
                                        data_out <= pc[7:0];
                                        control <= MEM_WRITE;
                                        sp <= sp_minus_one;
                                end
                                PUSH_PCL: begin
                                        if (jsr) begin
                                                pc <= pc;
                                                address <= pc;
                                                control <= MEM_READ;
                                                sp <= sp_minus_one;
                                        end
                                        else begin
                                                pc <= pc;
                                                address <= sp_minus_one;
                                                data_out <= alu_status;
                                                control <= MEM_WRITE;
                                                sp <= sp_minus_one;
                                        end
                                end
                                PUSH_STATUS: begin
                                        address <= 13'hFFFE;
                                        control <= MEM_READ;
                                end
                                FETCH_PCL: begin
                                        pc[7:0] <= data_in;
                                        address <= 13'hFFFF;
                                        control <= MEM_READ;
                                end
                                FETCH_PCH: begin
                                        pc[12:8] <= data_in[4:0];
                                        address <= {data_in[4:0], pc[7:0]};
                                        control <= MEM_READ;
                                end
                                INCREMENT_SP: begin
                                        sp <= sp_plus_one;
                                        address <= sp_plus_one;
                                end
                                PULL_STATUS: begin
                                        sp <= sp_plus_one;
                                        address <= sp_plus_one;
                                        temp_data <= data_in;
                                end
                                PULL_PCL: begin
                                        sp <= sp_plus_one;
                                        address <= sp_plus_one;
                                        pc[7:0] <= data_in;
                                end
                                PULL_PCH: begin
                                        pc[12:8] <= data_in[4:0];
                                        address <= {data_in[4:0], pc[7:0]};
                                end
                                INCREMENT_PC: begin
                                        pc <= next_pc;
                                        address <= next_pc;
                                end
                                PUSH_REGISTER: begin
                                        pc <= pc;
                                        address <= pc;
                                        sp <= sp_minus_one;
                                        control <= MEM_READ;
                                        temp_data <= data_in;
                                end
                                PULL_REGISTER: begin
                                        pc <= pc;
                                        address <= pc;
                                        temp_data <= data_in;
                                end
                                DUMMY: begin
                                        address <= sp;
                                        control <= MEM_WRITE;
                                end
                                default: begin
                                        $write("unknown state"); // TODO: check if synth really ignores this 2 lines. Otherwise wrap it with a `ifdef 
                                        $finish(0);
                                end
 
                        endcase
                end
        end
 
        always @ (*) begin // this is the next_state logic and the output logic always block
                alu_opcode = 8'h00;
                alu_a = 8'h00;
                alu_enable = 1'b0;
                next_state = RESET; // these lines prevents latches
 
                case (state)
                        RESET: begin
                                next_state = FETCH_OP;
                        end
                        FETCH_OP: begin
                                next_state = FETCH_LOW;
                        end
                        FETCH_OP_CALC_PARAM: begin
                                next_state = FETCH_LOW;
                                alu_opcode = ir;
                                alu_enable = 1'b1;
                                alu_a = temp_data;
                        end
                        FETCH_LOW: begin
                                if (accumulator  || implied) begin
                                        alu_opcode = ir;
                                        alu_enable = 1'b1;
                                        next_state = FETCH_OP;
                                end
                                else if (immediate) begin
                                        next_state = FETCH_OP_CALC_PARAM;
                                end
                                else if (zero_page) begin
                                        if (read || read_modify_write) begin
                                                next_state = READ_MEM;
                                        end
                                        else if (write) begin
                                                next_state = WRITE_MEM;
                                                alu_opcode = ir;
                                                alu_enable = 1'b1;
                                                alu_a = 8'h00;
                                        end
                                        else begin
                                                $write("unknown behavior");
                                                $finish(0);
                                        end
                                end
                                else if (zero_page_indexed) begin
                                        next_state = READ_MEM_CALC_INDEX;
                                end
                                else if (absolute || jump_indirect) begin
                                        next_state = FETCH_HIGH;
                                        if (write) begin // this is being done one cycle early but i have checked and the ALU will still work properly
                                                alu_opcode = ir;
                                                alu_enable = 1'b1;
                                                alu_a = 8'h00;
                                        end
                                end
                                else if (absolute_indexed) begin
                                        next_state = FETCH_HIGH_CALC_INDEX;
                                end
                                else if (relative) begin
                                        next_state = FETCH_OP_EVAL_BRANCH;
                                end
                                else if (indirectx || indirecty) begin
                                        next_state = READ_FROM_POINTER;
                                end
                                else begin // all the special instructions will fall here
                                        if (brk) begin
                                                next_state = PUSH_PCH;
                                        end
                                        else if (rti || rts) begin
                                                next_state = INCREMENT_SP;
                                        end
                                        else if (pha) begin
                                                alu_opcode = ir;
                                                alu_enable = 1'b1;
                                                //alu_a = 8'h00;
                                                next_state = PUSH_REGISTER;
                                        end
                                        else if (php) begin
                                                next_state = PUSH_REGISTER;
                                        end
                                        else if (pla || plp) begin
                                                next_state = INCREMENT_SP;
                                        end
                                        else begin // jsr
                                                next_state = DUMMY;
                                        end
                                end
                        end
                        READ_FROM_POINTER: begin
                                if (indirectx) begin
                                        next_state = READ_FROM_POINTER_X;
                                end
                                else begin // indirecty and jump indirect falls here
                                        next_state = READ_FROM_POINTER_X1;
                                end
                        end
                        READ_FROM_POINTER_X: begin
                                next_state = READ_FROM_POINTER_X1;
                        end
                        READ_FROM_POINTER_X1: begin
                                if (jump_indirect) begin
                                        next_state = FETCH_OP;
                                end
                                else if (indirecty) begin
                                        next_state = READ_MEM_FIX_ADDR;
                                end
                                else begin
                                        if (read) begin // no instruction using pointers is from type read_modify_write
                                                next_state = READ_MEM;
                                        end
                                        else if (write) begin
                                                alu_opcode = ir;
                                                alu_enable = 1'b1;
                                                next_state = WRITE_MEM;
                                        end
                                end
                        end
                        FETCH_OP_EVAL_BRANCH: begin
                                if (branch) begin
                                        next_state = FETCH_OP_FIX_PC;
                                end
                                else begin
                                        next_state = FETCH_LOW;
                                end
                        end
                        FETCH_OP_FIX_PC: begin
                                if (page_crossed) begin
                                        next_state = FETCH_OP;
                                end
                                else begin
                                        next_state = FETCH_LOW;
                                end
                        end
                        FETCH_HIGH_CALC_INDEX: begin
                                next_state = READ_MEM_FIX_ADDR;
                        end
                        READ_MEM_FIX_ADDR: begin
                                if (read) begin
                                        if (page_crossed) begin
                                                next_state = READ_MEM;
                                        end
                                        else begin
                                                next_state = FETCH_OP_CALC_PARAM;
                                        end
                                end
                                else if (read_modify_write) begin
                                        next_state = READ_MEM;
                                end
                                else if (write) begin
                                        next_state = WRITE_MEM;
                                        alu_enable = 1'b1;
                                        alu_opcode = ir;
                                end
                                else begin
                                        $write("unknown behavior");
                                        $finish(0);
                                end
                        end
                        FETCH_HIGH: begin
                                if (jump_indirect) begin
                                        next_state = READ_FROM_POINTER;
                                end
                                else if (jump) begin
                                        next_state = FETCH_OP;
                                end
                                else if (read || read_modify_write) begin
                                        next_state = READ_MEM;
                                end
                                else if (write) begin
                                        next_state = WRITE_MEM;
                                end
                                else begin
                                        $write("unknown behavior");
                                        $finish(0);
                                end
                        end
                        READ_MEM_CALC_INDEX: begin
                                if (read || read_modify_write) begin
                                        next_state = READ_MEM;
                                end
                                else if (write) begin
                                        alu_opcode = ir;
                                        alu_enable = 1'b1;
                                        next_state = WRITE_MEM;
                                end
                                else begin
                                        $write("unknown behavior");
                                        $finish(0);
                                end
                        end
                        READ_MEM: begin
                                if (read) begin
                                        next_state = FETCH_OP_CALC_PARAM;
                                end
                                else if (read_modify_write) begin
                                        next_state = DUMMY_WRT_CALC;
                                end
                        end
                        DUMMY_WRT_CALC: begin
                                alu_opcode = ir;
                                alu_enable = 1'b1;
                                alu_a = data_in;
                                next_state = WRITE_MEM;
                        end
                        WRITE_MEM: begin
                                next_state = FETCH_OP;
                        end
                        PUSH_PCH: begin
                                next_state = PUSH_PCL;
                        end
                        PUSH_PCL: begin
                                if (jsr) begin
                                        next_state = FETCH_HIGH;
                                end
                                else begin
                                        next_state = PUSH_STATUS;
                                end
                        end
                        PUSH_STATUS: begin
                                next_state = FETCH_PCL;
                        end
                        FETCH_PCL: begin
                                next_state = FETCH_PCH;
                        end
                        FETCH_PCH: begin
                                next_state = FETCH_OP;
                        end
                        INCREMENT_SP: begin
                                if (rti) begin
                                        next_state = PULL_STATUS;
                                end
                                else if (pla || plp) begin
                                        next_state = PULL_REGISTER;
                                end
                                else begin // rts
                                        next_state = PULL_PCL;
                                end
                        end
                        PULL_STATUS: begin
                                next_state = PULL_PCL;
                        end
                        PULL_PCL: begin
                                next_state = PULL_PCH;
                                alu_opcode = ir;
                                alu_enable = 1'b1;
                                alu_a = temp_data;
                        end
                        PULL_PCH: begin
                                if (rti) begin
                                        next_state = FETCH_OP;
                                end
                                else begin // rts
                                        next_state = INCREMENT_PC;
                                end
                        end
                        INCREMENT_PC: begin
                                next_state = FETCH_OP;
                        end
                        PUSH_REGISTER: begin
                                next_state = FETCH_OP;
                        end
                        PULL_REGISTER: begin
                                next_state = FETCH_OP_CALC_PARAM;
                        end
                        DUMMY: begin
                                next_state = PUSH_PCH;
                        end
                        default: begin
                                next_state = RESET;
                        end
                endcase
        end
 
        // this always block is responsible for updating the address mode and the type of operation being done
        always @ (*) begin // 
                absolute = 1'b0;
                absolute_indexed = 1'b0;
                accumulator = 1'b0;
                immediate = 1'b0;
                implied = 1'b0;
                indirectx = 1'b0;
                indirecty = 1'b0;
                relative = 1'b0;
                zero_page = 1'b0;
                zero_page_indexed = 1'b0;
 
                index = 8'h00;
 
                read = 1'b0;
                read_modify_write = 1'b0;
                write = 1'b0;
                jump = 1'b0;
                jump_indirect = 1'b0;
                branch = 1'b0;
 
                brk = 1'b0;
                rti = 1'b0;
                rts = 1'b0;
                pha = 1'b0;
                php = 1'b0;
                pla = 1'b0;
                plp = 1'b0;
                jsr = 1'b0;
 
                case (ir)
                        CLC_IMP, CLD_IMP, CLI_IMP, CLV_IMP, DEX_IMP, DEY_IMP, INX_IMP, INY_IMP, NOP_IMP,
                        SEC_IMP, SED_IMP, SEI_IMP, TAX_IMP, TAY_IMP, TSX_IMP, TXA_IMP, TXS_IMP, TYA_IMP: begin
                                implied = 1'b1;
                        end
                        ASL_ACC, LSR_ACC, ROL_ACC, ROR_ACC: begin
                                accumulator = 1'b1;
                        end
                        ADC_IMM, AND_IMM, CMP_IMM, CPX_IMM, CPY_IMM, EOR_IMM, LDA_IMM, LDX_IMM, LDY_IMM, ORA_IMM, SBC_IMM: begin
                                immediate = 1'b1;
                        end
                        ADC_ZPG, AND_ZPG, ASL_ZPG, BIT_ZPG, CMP_ZPG, CPX_ZPG, CPY_ZPG, DEC_ZPG, EOR_ZPG, INC_ZPG, LDA_ZPG, LDX_ZPG, LDY_ZPG,
                        LSR_ZPG, ORA_ZPG, ROL_ZPG, ROR_ZPG, SBC_ZPG, STA_ZPG, STX_ZPG, STY_ZPG: begin
                                zero_page = 1'b1;
                        end
                        ADC_ZPX, AND_ZPX, ASL_ZPX, CMP_ZPX, DEC_ZPX, EOR_ZPX, INC_ZPX, LDA_ZPX, LDY_ZPX, LSR_ZPX, ORA_ZPX, ROL_ZPX, ROR_ZPX,
                        SBC_ZPX, STA_ZPX, STY_ZPX: begin
                                zero_page_indexed = 1'b1;
                                index = alu_x;
                        end
                        LDX_ZPY, STX_ZPY: begin
                                zero_page_indexed = 1'b1;
                                index = alu_y;
                        end
                        BCC_REL: begin
                                relative = 1'b1;
                                index = temp_data;
 
                                if (!alu_status[C]) begin
                                        branch = 1'b1;
                                end
                                else begin
                                        branch = 1'b0;
                                end
                        end
                        BCS_REL: begin
                                relative = 1'b1;
                                index = temp_data;
 
                                if (alu_status[C]) begin
                                        branch = 1'b1;
                                end
                                else begin
                                        branch = 1'b0;
                                end
                        end
                        BEQ_REL: begin
                                relative = 1'b1;
                                index = temp_data;
 
                                if (alu_status[Z]) begin
                                        branch = 1'b1;
                                end
                                else begin
                                        branch = 1'b0;
                                end
                        end
                        BNE_REL: begin
                                relative = 1'b1;
                                index = temp_data;
 
                                if (alu_status[Z] == 1'b0) begin
                                        branch = 1'b1;
                                end
                                else begin
                                        branch = 1'b0;
                                end
                        end
                        BPL_REL: begin
                                relative = 1'b1;
                                index = temp_data;
 
                                if (!alu_status[N]) begin
                                        branch = 1'b1;
                                end
                                else begin
                                        branch = 1'b0;
                                end
                        end
                        BMI_REL: begin
                                relative = 1'b1;
                                index = temp_data;
 
                                if (alu_status[N]) begin
                                        branch = 1'b1;
                                end
                                else begin
                                        branch = 1'b0;
                                end
                        end
                        BVC_REL: begin
                                relative = 1'b1;
                                index = temp_data;
 
                                if (!alu_status[V]) begin
                                        branch = 1'b1;
                                end
                                else begin
                                        branch = 1'b0;
                                end
                        end
                        BVS_REL: begin
                                relative = 1'b1;
                                index = temp_data;
 
                                if (alu_status[V]) begin
                                        branch = 1'b1;
                                end
                                else begin
                                        branch = 1'b0;
                                end
                        end
                        ADC_ABS, AND_ABS, ASL_ABS, BIT_ABS, CMP_ABS, CPX_ABS, CPY_ABS, DEC_ABS, EOR_ABS, INC_ABS, LDA_ABS,
                        LDX_ABS, LDY_ABS, LSR_ABS, ORA_ABS, ROL_ABS, ROR_ABS, SBC_ABS, STA_ABS, STX_ABS, STY_ABS: begin
                                absolute = 1'b1;
                        end
                        ADC_ABX, AND_ABX, ASL_ABX, CMP_ABX, DEC_ABX, EOR_ABX, INC_ABX, LDA_ABX, LDY_ABX, LSR_ABX, ORA_ABX, ROL_ABX, ROR_ABX,
                        SBC_ABX, STA_ABX: begin
                                absolute_indexed = 1'b1;
                                index = alu_x;
                        end
                        ADC_ABY, AND_ABY, CMP_ABY, EOR_ABY, LDA_ABY, LDX_ABY, ORA_ABY, SBC_ABY, STA_ABY: begin
                                absolute_indexed = 1'b1;
                                index = alu_y;
                        end
                        ADC_IDX, AND_IDX, CMP_IDX, EOR_IDX, LDA_IDX, ORA_IDX, SBC_IDX, STA_IDX: begin
                                indirectx = 1'b1;
                                index = alu_x;
                        end
                        ADC_IDY, AND_IDY, CMP_IDY, EOR_IDY, LDA_IDY, ORA_IDY, SBC_IDY, STA_IDY: begin
                                indirecty = 1'b1;
                                index = alu_y;
                        end
                        JMP_ABS: begin
                                absolute = 1'b1;
                                jump = 1'b1;
                        end
                        JMP_IND: begin
                                jump_indirect = 1'b1;
                        end
                        BRK_IMP: begin
                                brk = 1'b1;
                        end
                        RTI_IMP: begin
                                rti = 1'b1;
                        end
                        RTS_IMP: begin
                                rts = 1'b1;
                        end
                        PHA_IMP: begin
                                pha = 1'b1;
                        end
                        PHP_IMP: begin
                                php = 1'b1;
                        end
                        PLA_IMP: begin
                                pla = 1'b1;
                        end
                        PLP_IMP: begin
                                plp = 1'b1;
                        end
                        JSR_ABS: begin
                                jsr = 1'b1;
                        end
                        default: begin
                                $write("state : %b", state);
                                if (reset_n == 1'b1 && state != FETCH_OP_FIX_PC) begin // the processor is NOT being reset neither it is fixing the pc
                                        $write("\nunknown OPCODE!!!!! 0x%h\n", ir);
                                        $finish();
                                end
                        end
                endcase
 
                case (ir)
                        ASL_ACC, ASL_ZPG, ASL_ZPX, ASL_ABS, ASL_ABX, LSR_ACC, LSR_ZPG, LSR_ZPX, LSR_ABS, LSR_ABX, ROL_ACC, ROL_ZPG, ROL_ZPX, ROL_ABS,
                        ROL_ABX, ROR_ACC, ROR_ZPG, ROR_ZPX, ROR_ABS, ROR_ABX, INC_ZPG, INC_ZPX, INC_ABS, INC_ABX, DEC_ZPG, DEC_ZPX, DEC_ABS,
                        DEC_ABX: begin
                                read_modify_write = 1'b1;
                        end
                        STA_ZPG, STA_ZPX, STA_ABS, STA_ABX, STA_ABY, STA_IDX, STA_IDY, STX_ZPG, STX_ZPY, STX_ABS, STY_ZPG, STY_ZPX, STY_ABS: begin
                                write = 1'b1;
                        end
                        default: begin // this should work fine since the previous case statement will detect the unknown/undocumented/unsupported opcodes
                                read = 1'b1;
                        end
                endcase
        end
endmodule
 
 
 

Line No.	Rev	Author	Line
1	61	creep	`////////////////////////////////////////////////////////////////////////////`
2			`//// ////`
3			`//// T6507LP IP Core ////`
4			`//// ////`
5			`//// This file is part of the T6507LP project ////`
6			`//// http://www.opencores.org/cores/t6507lp/ ////`
7			`//// ////`
8			`//// Description ////`
9			`//// 6507 FSM ////`
10			`//// ////`
11			`//// TODO: ////`
12	96	creep	`//// - Fix relative mode, bit 7 means negative ////`
13	110	creep	`//// - Comment the code ////`
14	61	creep	`//// ////`
15			`//// Author(s): ////`
16			`//// - Gabriel Oshiro Zardo, gabrieloshiro@gmail.com ////`
17			`//// - Samuel Nascimento Pagliarini (creep), snpagliarini@gmail.com ////`
18			`//// ////`
19			`////////////////////////////////////////////////////////////////////////////`
20			`//// ////`
21			`//// Copyright (C) 2001 Authors and OPENCORES.ORG ////`
22			`//// ////`
23			`//// This source file may be used and distributed without ////`
24			`//// restriction provided that this copyright statement is not ////`
25			`//// removed from the file and that any derivative work contains ////`
26			`//// the original copyright notice and the associated disclaimer. ////`
27			`//// ////`
28			`//// This source file is free software; you can redistribute it ////`
29			`//// and/or modify it under the terms of the GNU Lesser General ////`
30			`//// Public License as published by the Free Software Foundation; ////`
31			`//// either version 2.1 of the License, or (at your option) any ////`
32			`//// later version. ////`
33			`//// ////`
34			`//// This source is distributed in the hope that it will be ////`
35			`//// useful, but WITHOUT ANY WARRANTY; without even the implied ////`
36			`//// warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR ////`
37			`//// PURPOSE. See the GNU Lesser General Public License for more ////`
38			`//// details. ////`
39			`//// ////`
40			`//// You should have received a copy of the GNU Lesser General ////`
41			`//// Public License along with this source; if not, download it ////`
42			`//// from http://www.opencores.org/lgpl.shtml ////`
43			`//// ////`
44			`////////////////////////////////////////////////////////////////////////////`
45
46	112	creep	`include "timescale.v"
47	61	creep
48	86	creep	`module t6507lp_fsm(clk, reset_n, alu_result, alu_status, data_in, address, control, data_out, alu_opcode, alu_a, alu_enable, alu_x, alu_y);`
49	111	creep	`parameter [3:0] DATA_SIZE = 4'd8;`
50			`parameter [3:0] ADDR_SIZE = 4'd13;`
51	68	creep
52	111	creep	`localparam [3:0] DATA_SIZE_ = DATA_SIZE - 4'b0001;`
53			`localparam [3:0] ADDR_SIZE_ = ADDR_SIZE - 4'b0001;`
54	82	creep
55	71	creep	`input clk;`
56			`input reset_n;`
57	82	creep	`input [DATA_SIZE_:0] alu_result;`
58			`input [DATA_SIZE_:0] alu_status;`
59			`input [DATA_SIZE_:0] data_in;`
60			`output reg [ADDR_SIZE_:0] address;`
61	110	creep	`output reg control; // read = 0, write = 1`
62	82	creep	`output reg [DATA_SIZE_:0] data_out;`
63			`output reg [DATA_SIZE_:0] alu_opcode;`
64			`output reg [DATA_SIZE_:0] alu_a;`
65	68	creep	`output reg alu_enable;`
66	61	creep
67	86	creep	`input [DATA_SIZE_:0] alu_x;`
68			`input [DATA_SIZE_:0] alu_y;`
69	68	creep
70	111	creep	`// FSM states. If aiming for less power consumption try gray coding.`
71	95	creep	`localparam FETCH_OP = 5'b00000;`
72	110	creep	`//localparam FETCH_OP_CALC = 5'b00001; this was never used`
73	95	creep	`localparam FETCH_LOW = 5'b00010;`
74			`localparam FETCH_HIGH = 5'b00011;`
75			`localparam READ_MEM = 5'b00100;`
76			`localparam DUMMY_WRT_CALC = 5'b00101;`
77			`localparam WRITE_MEM = 5'b00110;`
78			`localparam FETCH_OP_CALC_PARAM = 5'b00111;`
79			`localparam READ_MEM_CALC_INDEX = 5'b01000;`
80			`localparam FETCH_HIGH_CALC_INDEX = 5'b01001;`
81			`localparam READ_MEM_FIX_ADDR = 5'b01010;`
82			`localparam FETCH_OP_EVAL_BRANCH = 5'b01011;`
83			`localparam FETCH_OP_FIX_PC = 5'b01100;`
84			`localparam READ_FROM_POINTER = 5'b01101;`
85			`localparam READ_FROM_POINTER_X = 5'b01110;`
86			`localparam READ_FROM_POINTER_X1 = 5'b01111;`
87	104	creep	`localparam PUSH_PCH = 5'b10000;`
88			`localparam PUSH_PCL = 5'b10001;`
89			`localparam PUSH_STATUS = 5'b10010;`
90			`localparam FETCH_PCL = 5'b10011;`
91			`localparam FETCH_PCH = 5'b10100;`
92	105	creep	`localparam INCREMENT_SP = 5'b10101;`
93			`localparam PULL_STATUS = 5'b10110;`
94			`localparam PULL_PCL = 5'b10111;`
95			`localparam PULL_PCH = 5'b11000;`
96	107	creep	`localparam INCREMENT_PC = 5'b11001;`
97	108	creep	`localparam PUSH_REGISTER = 5'b11010;`
98	109	creep	`localparam PULL_REGISTER = 5'b11011;`
99	110	creep	`localparam DUMMY = 5'b11100;`
100	95	creep	`localparam RESET = 5'b11111;`
101
102	61	creep	`// OPCODES TODO: verify how this get synthesised`
103	112	creep	`include "T6507LP_Package.v"
104	61	creep
105			`// control signals`
106			`localparam MEM_READ = 1'b0;`
107			`localparam MEM_WRITE = 1'b1;`
108
109	82	creep	`reg [ADDR_SIZE_:0] pc; // program counter`
110	104	creep	`reg [DATA_SIZE:0] sp; // stack pointer. 9 bits wide.`
111	82	creep	`reg [DATA_SIZE_:0] ir; // instruction register`
112			`reg [ADDR_SIZE_:0] temp_addr; // temporary address`
113			`reg [DATA_SIZE_:0] temp_data; // temporary data`
114	61	creep
115	96	creep	`reg [4:0] state, next_state; // current and next state registers`
116	61	creep
117	104	creep	`// wiring that simplifies the FSM logic by simplifying the addressing modes`
118	61	creep	`reg absolute;`
119			`reg absolute_indexed;`
120			`reg accumulator;`
121			`reg immediate;`
122			`reg implied;`
123	95	creep	`reg indirectx;`
124			`reg indirecty;`
125	61	creep	`reg relative;`
126			`reg zero_page;`
127			`reg zero_page_indexed;`
128	86	creep	`reg [DATA_SIZE_:0] index; // will be assigned with either X or Y`
129	61	creep
130			`// regs that store the type of operation. again, this simplifies the FSM a lot.`
131			`reg read;`
132			`reg read_modify_write;`
133			`reg write;`
134			`reg jump;`
135	101	creep	`reg jump_indirect;`
136	61	creep
137	104	creep	`// regs for the special instructions`
138	111	creep	`reg brk;`
139	105	creep	`reg rti;`
140	107	creep	`reg rts;`
141	108	creep	`reg pha;`
142	109	creep	`reg php;`
143			`reg pla;`
144	110	creep	`reg plp;`
145			`reg jsr;`
146	104	creep
147	82	creep	`wire [ADDR_SIZE_:0] next_pc;`
148	63	creep	`assign next_pc = pc + 13'b0000000000001;`
149	61	creep
150	87	creep	`reg [ADDR_SIZE_:0] address_plus_index; // this would update more times than actually needed, consuming power.`
151			`reg page_crossed; // so the simple assign was changed into a combinational always block`
152
153	94	creep	`reg branch;`
154
155	87	creep	`always @(*) begin`
156	111	creep	`address_plus_index = 8'h00;`
157			`page_crossed = 1'b0;`
158	86	creep
159	88	creep	`if (state == READ_MEM_CALC_INDEX \|\| state == READ_MEM_FIX_ADDR \|\| state == FETCH_HIGH_CALC_INDEX) begin`
160			`{page_crossed, address_plus_index[7:0]} = temp_addr[7:0] + index;`
161			`address_plus_index[12:8] = temp_addr[12:8] + page_crossed;`
162	87	creep	`end`
163	94	creep	`else if (branch) begin`
164			`if (state == FETCH_OP_FIX_PC \|\| state == FETCH_OP_EVAL_BRANCH) begin`
165			`{page_crossed, address_plus_index[7:0]} = pc[7:0] + index;`
166			`address_plus_index[12:8] = pc[12:8] + page_crossed;// warning: pc might feed these lines twice and cause branch failure`
167			`end // solution: add a temp reg i guess`
168			`end`
169	95	creep	`else if (state == READ_FROM_POINTER) begin`
170	96	creep	`if (indirectx) begin`
171			`{page_crossed, address_plus_index[7:0]} = temp_data + index;`
172			`address_plus_index[12:8] = 5'b00000;`
173			`end`
174	101	creep	`else if (jump_indirect) begin`
175	111	creep	`address_plus_index[7:0] = temp_addr[7:0] + 8'h01; // temp_addr should be 7:0?`
176	101	creep	`address_plus_index[12:8] = 5'b00000;`
177			`end`
178	96	creep	`else begin // indirecty falls here`
179			`address_plus_index[7:0] = temp_data + 8'h01;`
180			`address_plus_index[12:8] = 5'b00000;`
181			`end`
182	95	creep	`end`
183			`else if (state == READ_FROM_POINTER_X) begin`
184			`{page_crossed, address_plus_index[7:0]} = temp_data + index + 8'h01;`
185			`address_plus_index[12:8] = 5'b00000;`
186			`end`
187	96	creep	`else if (state == READ_FROM_POINTER_X1) begin`
188			`{page_crossed, address_plus_index[7:0]} = temp_addr[7:0] + index;`
189			`address_plus_index[12:8] = temp_addr[12:8] + page_crossed;`
190			`end`
191	87	creep	`end`
192
193	103	creep	`wire [8:0] sp_plus_one;`
194			`assign sp_plus_one = sp + 9'b000000001;`
195
196			`wire [8:0] sp_minus_one;`
197			`assign sp_minus_one = sp - 9'b000000001;`
198
199	71	creep	`always @ (posedge clk or negedge reset_n) begin // sequencial always block`
200			`if (reset_n == 1'b0) begin`
201			`// all registers must assume default values`
202	68	creep	`pc <= 0; // TODO: this is written somewhere. something about a reset vector. must be checked.`
203	111	creep	`sp <= 9'b000000000; // the default is 'h100`
204	82	creep	`ir <= 8'h00;`
205	111	creep	`temp_addr <= 13'h0000;`
206	82	creep	`temp_data <= 8'h00;`
207	68	creep	`state <= RESET;`
208	71	creep	`// registered outputs also receive default values`
209			`address <= 0;`
210	82	creep	`control <= MEM_READ;`
211			`data_out <= 8'h00;`
212	61	creep	`end`
213			`else begin`
214			`state <= next_state;`
215	83	creep
216	61	creep	`case (state)`
217	104	creep	`RESET: begin // The processor was reset`
218	111	creep	`sp <= 9'b100000000; // this prevents flipflops with different drivers`
219	82	creep	`$write("under reset");`
220	68	creep	`end`
221	104	creep	`/*`
222			`FETCH_OP: executed when the processor was reset or the last instruction could not fetch.`
223			`FETCH_OP_CALC_PARAM: enables the alu with an argument (alu_a) and fetchs the next instruction opcode. (pipelining)`
224			`*/`
225	110	creep	`FETCH_OP, FETCH_OP_CALC_PARAM: begin // this is the pipeline happening!`
226	61	creep	`pc <= next_pc;`
227	71	creep	`address <= next_pc;`
228	83	creep	`control <= MEM_READ;`
229	70	creep	`ir <= data_in;`
230	61	creep	`end`
231	104	creep	`/*`
232			`in this state the opcode is already known so truly execution begins.`
233			`all instruction execute this cycle.`
234			`*/`
235			`FETCH_LOW: begin`
236	68	creep	`if (accumulator \|\| implied) begin`
237	70	creep	`pc <= pc; // is this better?`
238	71	creep	`address <= pc;`
239	83	creep	`control <= MEM_READ;`
240	61	creep	`end`
241	94	creep	`else if (immediate \|\| relative) begin`
242	68	creep	`pc <= next_pc;`
243	71	creep	`address <= next_pc;`
244	83	creep	`control <= MEM_READ;`
245	70	creep	`temp_data <= data_in; // the follow-up byte is saved in temp_data`
246	61	creep	`end`
247	101	creep	`else if (absolute \|\| absolute_indexed \|\| jump_indirect) begin`
248	71	creep	`pc <= next_pc;`
249			`address <= next_pc;`
250	83	creep	`control <= MEM_READ;`
251	87	creep	`temp_addr <= {{5{1'b0}},data_in};`
252	101	creep	`temp_data <= 8'h00;`
253	71	creep	`end`
254	77	creep	`else if (zero_page) begin`
255			`pc <= next_pc;`
256			`address <= {{5{1'b0}},data_in};`
257	78	creep	`temp_addr <= {{5{1'b0}},data_in};`
258
259	77	creep	`if (write) begin`
260			`control <= MEM_WRITE;`
261	78	creep	`data_out <= alu_result;`
262	77	creep	`end`
263	83	creep	`else begin`
264			`control <= MEM_READ;`
265			`data_out <= 8'h00;`
266			`end`
267	77	creep	`end`
268	86	creep	`else if (zero_page_indexed) begin`
269			`pc <= next_pc;`
270	94	creep	`address <= {{5{1'b0}}, data_in};`
271			`temp_addr <= {{5{1'b0}}, data_in};`
272	86	creep	`control <= MEM_READ;`
273			`end`
274	96	creep	`else if (indirectx \|\| indirecty) begin`
275	95	creep	`pc <= next_pc;`
276			`address <= data_in;`
277			`temp_data <= data_in;`
278			`control <= MEM_READ;`
279			`end`
280	102	creep	`else begin // the special instructions will fall here: BRK, RTI, RTS...`
281	111	creep	`if (brk) begin`
282	104	creep	`pc <= next_pc;`
283			`address <= sp;`
284			`data_out <= {{3{1'b0}}, pc[12:8]};`
285			`control <= MEM_WRITE;`
286			`end`
287	107	creep	`else if (rti \|\| rts) begin`
288	105	creep	`address <= sp;`
289			`control <= MEM_READ;`
290			`end`
291	108	creep	`else if (pha \|\| php) begin`
292			`pc <= pc;`
293			`address <= sp;`
294			`data_out <= (pha) ? alu_result : alu_status;`
295			`control <= MEM_WRITE;`
296			`end`
297	109	creep	`else if (pla \|\| plp) begin`
298			`pc <= pc;`
299			`address <= sp;`
300			`control <= MEM_READ;`
301			`end`
302	110	creep	`else begin // jsr`
303			`address <= sp;`
304			`control <= MEM_READ;`
305			`temp_addr <= {{5{1'b0}}, data_in};`
306			`pc <= next_pc;`
307			`end`
308	102	creep	`end`
309	61	creep	`end`
310	87	creep	`FETCH_HIGH_CALC_INDEX: begin`
311			`pc <= next_pc;`
312			`temp_addr[12:8] <= data_in[4:0];`
313			`address <= {data_in[4:0], address_plus_index[7:0]};`
314			`control <= MEM_READ;`
315			`data_out <= 8'h00;`
316			`end`
317	104	creep	`// this cycle fetchs the next operand while still evaluating if a branch occurred.`
318	94	creep	`FETCH_OP_EVAL_BRANCH: begin`
319			`if (branch) begin`
320			`pc <= {{5{1'b0}}, address_plus_index[7:0]};`
321			`address <= {{5{1'b0}}, address_plus_index[7:0]};`
322			`control <= MEM_READ;`
323			`data_out <= 8'h00;`
324			`end`
325			`else begin`
326			`pc <= next_pc;`
327			`address <= next_pc;`
328			`control <= MEM_READ;`
329			`data_out <= 8'h00;`
330	95	creep	`ir <= data_in;`
331	94	creep	`end`
332			`end`
333	104	creep	`// sometimes when reading memory page crosses may occur. the pc register must be fixed, i.e., add 16'h0100`
334	94	creep	`FETCH_OP_FIX_PC: begin`
335			`if (page_crossed) begin`
336			`pc[12:8] <= address_plus_index[12:8];`
337			`address[12:8] <= address_plus_index[12:8];`
338			`end`
339			`else begin`
340			`pc <= next_pc;`
341			`address <= next_pc;`
342			`control <= MEM_READ;`
343			`ir <= data_in;`
344			`end`
345			`end`
346	104	creep	`// several instructions ocupy 3 bytes in memory. this cycle reads the third byte.`
347	71	creep	`FETCH_HIGH: begin`
348			`if (jump) begin`
349	83	creep	`pc <= {data_in[4:0], temp_addr[7:0]}; // PCL <= first byte, PCH <= second byte`
350			`address <= {data_in[4:0], temp_addr[7:0]};`
351			`control <= MEM_READ;`
352			`data_out <= 8'h00;`
353	71	creep	`end`
354			`else begin`
355			`if (write) begin`
356			`pc <= next_pc;`
357			`temp_addr[12:8] <= data_in[4:0];`
358			`address <= {data_in[4:0],temp_addr[7:0]};`
359			`control <= MEM_WRITE;`
360	77	creep	`data_out <= alu_result;`
361	71	creep	`end`
362			`else begin // read_modify_write or just read`
363			`pc <= next_pc;`
364			`temp_addr[12:8] <= data_in[4:0];`
365			`address <= {data_in[4:0],temp_addr[7:0]};`
366	83	creep	`control <= MEM_READ;`
367			`data_out <= 8'h00;`
368	71	creep	`end`
369			`end`
370	61	creep	`end`
371	71	creep	`READ_MEM: begin`
372			`if (read_modify_write) begin`
373			`pc <= pc;`
374			`address <= temp_addr;`
375			`control <= MEM_WRITE;`
376			`temp_data <= data_in;`
377			`data_out <= data_in; // writeback the same value`
378			`end`
379			`else begin`
380			`pc <= pc;`
381			`address <= pc;`
382			`temp_data <= data_in;`
383	83	creep	`control <= MEM_READ;`
384			`data_out <= 8'h00;`
385	71	creep	`end`
386	70	creep	`end`
387	86	creep	`READ_MEM_CALC_INDEX: begin`
388			`address <= address_plus_index;`
389			`temp_addr <= address_plus_index;`
390
391			`if (write) begin`
392			`control <= MEM_WRITE;`
393			`data_out <= alu_result;`
394			`end`
395			`else begin`
396			`control <= MEM_READ;`
397			`data_out <= 8'h00;`
398			`end`
399
400			`end`
401	87	creep	`READ_MEM_FIX_ADDR: begin`
402			`if (read) begin`
403			`control <= MEM_READ;`
404			`data_out <= 8'h00;`
405
406			`if (page_crossed) begin`
407			`address <= address_plus_index;`
408			`temp_addr <= address_plus_index;`
409			`end`
410			`else begin`
411			`address <= pc;`
412			`temp_data <= data_in;`
413			`end`
414			`end`
415			`else if (write) begin`
416			`control <= MEM_WRITE;`
417			`data_out <= alu_result;`
418			`address <= address_plus_index;`
419			`temp_addr <= address_plus_index;`
420
421			`end`
422			`else begin // read modify write`
423			`control <= MEM_READ;`
424			`data_out <= 8'h00;`
425			`address <= address_plus_index;`
426			`temp_addr <= address_plus_index;`
427			`end`
428			`end`
429	71	creep	`DUMMY_WRT_CALC: begin`
430			`pc <= pc;`
431			`address <= temp_addr;`
432			`control <= MEM_WRITE;`
433			`data_out <= alu_result;`
434	70	creep	`end`
435	71	creep	`WRITE_MEM: begin`
436			`pc <= pc;`
437			`address <= pc;`
438	83	creep	`control <= MEM_READ;`
439			`data_out <= 8'h00;`
440	70	creep	`end`
441	95	creep	`READ_FROM_POINTER: begin`
442	101	creep	`if (jump_indirect) begin`
443			`pc[7:0] <= data_in;`
444			`control <= MEM_READ;`
445	96	creep	`address <= address_plus_index;`
446			`end`
447	101	creep	`else begin`
448			`pc <= pc;`
449			`control <= MEM_READ;`
450
451			`if (indirectx) begin`
452			`address <= address_plus_index;`
453			`end`
454			`else begin // indirecty falls here`
455			`address <= address_plus_index;`
456			`temp_addr <= {{5{1'b0}}, data_in};`
457			`end`
458	96	creep	`end`
459	95	creep	`end`
460			`READ_FROM_POINTER_X: begin`
461			`pc <= pc;`
462			`address <= address_plus_index;`
463			`temp_addr[7:0] <= data_in;`
464			`control <= MEM_READ;`
465			`end`
466			`READ_FROM_POINTER_X1: begin`
467	101	creep	`if (jump_indirect) begin`
468			`pc[12:8] <= data_in[4:0];`
469			`control <= MEM_READ;`
470			`address <= {data_in[4:0], pc[7:0]};`
471			`end`
472			`else if (indirectx) begin`
473			`address <= {data_in[4:0], temp_addr[7:0]};`
474	96	creep	`if (write) begin`
475			`control <= MEM_WRITE;`
476			`data_out <= alu_result;`
477			`end`
478			`else begin`
479			`control <= MEM_READ;`
480			`end`
481	95	creep	`end`
482	96	creep	`else begin // indirecty falls here`
483			`address <= address_plus_index;`
484			`temp_addr[12:8] <= data_in;`
485	95	creep	`control <= MEM_READ;`
486			`end`
487			`end`
488	104	creep	`PUSH_PCH: begin`
489			`pc <= pc;`
490	110	creep	`address <= sp_minus_one;`
491	104	creep	`data_out <= pc[7:0];`
492			`control <= MEM_WRITE;`
493			`sp <= sp_minus_one;`
494			`end`
495			`PUSH_PCL: begin`
496	110	creep	`if (jsr) begin`
497			`pc <= pc;`
498			`address <= pc;`
499			`control <= MEM_READ;`
500			`sp <= sp_minus_one;`

Browse

Tools

Subversion Repositories t6507lp

[/] [t6507lp/] [trunk/] [rtl/] [verilog/] [t6507lp_fsm.v] - Blame information for rev 112