URL https://opencores.org/ocsvn/zipcpu/zipcpu/trunk

Subversion Repositories zipcpu

[/] [zipcpu/] [trunk/] [bench/] [asm/] [zipdhry.S] - Blame information for rev 66

Go to most recent revision | Details | Compare with Previous | View Log


;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;
; Filename:     zipdhry.S
;
; Project:      Zip CPU -- a small, lightweight, RISC CPU soft core
;
; Purpose:      Zip assembly file for running the Dhrystone benchmark in the
;               Zip CPU.
;
; Creator:      Dan Gisselquist, Ph.D.
;               Gisselquist Tecnology, LLC
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;
; Copyright (C) 2015, Gisselquist Technology, LLC
;
; This program is free software (firmware): you can redistribute it and/or
; modify it under the terms of  the GNU General Public License as published
; by the Free Software Foundation, either version 3 of the License, or (at
; your option) any later version.
;
; This program is distributed in the hope that it will be useful, but WITHOUT
; ANY WARRANTY; without even the implied warranty of MERCHANTIBILITY or
; FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
; for more details.
;
; License:      GPL, v3, as defined and found on www.gnu.org,
;               http://www.gnu.org/licenses/gpl.html
;
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;
// Under Verilator:
//      DMIPS:          28.6    100 MHz (sim)   0.29
//
//
//   with no loop unrolling nor function inlining
//      DMIPS:          24.3    100 MHz (sim)   0.24
//   with packed strings
//      DMIPS:          35.6    100 MHz (sim)   0.36
//
// For comparison:
//      uBlaze:         255     177 MHz         1.44
//      LEON3                                   1.4
//      NiOS II:        218     185 MHz         1.16
//      OpenRisk        250     250 MHz         1.00
//      LM32                                    1.14
//      ZPU             2.6      50 MHz         0.05
//
 
// Some #def's to control compilation.
//
// SKIP_SHORT_CIRCUITS determines whether or not we do internal testing and
// jump to a BUSY instruction on failure for the debugger to pick up.  Skip
// this for valid testing.
//
// #define      SKIP_SHORT_CIRCUITS
//
// NO_INLINE controls whether or not we inline certain functions.  If you
// define this, nothing will be inlined.
// #define      NO_INLINE
//
// NO_LOOP_UNROLLING controls loop unrolling.  The default is to unroll loops
// by a factor of 4x.  By defining this, all loop unrolling is removed.
// #define      NO_LOOP_UNROLLING
//
// Use PSTRS has to deal with whether or not we are processing packed strings
// or normal strings.  Packed strings are really a cheaters exception to the
// dhrystone measure, although they do get our score up.
//
// #define      USE_PSTRS
        sys.ctr.mtask   equ     0xc0000008
// int main(int argc, char **argv) {
//      dhrystone();
// }
entry:
        MOV     top_of_stack(PC),uSP
        MOV     entry(PC),uR12
        ; Store  our tick counter in R1
        LDI     sys.ctr.mtask,R1
        ; And start with our counter cleared at zero
        CLR     R0
        STO     R0,(R1)
#ifdef  SUPERVISOR_TASK
        MOV     __HERE__+3(PC),R0
        STO     R0,1(SP)
        BRA     dhrystone
#else
        MOV     dhrystone(PC),uPC
        RTU
#endif
        ; Read the tick counter back out
        LOD     (R1),R0
        HALT    ; Stop the CPU--We're done!!!!!!!
 
// typedef      enum { Ident_1, Ident_2, Ident_3, Ident_4, Ident_5 } test_enum;
// typedef      enum { false, true } bool;
 
// typedef      int     Arr_1_Dim[50];
// typedef      int     Arr_2_Dim[50][50];
#ifdef  USE_PSTRS
#define RECSIZE 12
#else
#define RECSIZE 35
#endif
#define NUMBER_OF_RUNS  (512)
        ptr_comp                        equ     0
        discr                           equ     1
        variant.var_1.enum_comp         equ     2
        variant.var_1.int_comp          equ     3
        variant.var_1.str_comp          equ     4
 
gbl_arr_1:
        fill    50,0
gbl_arr_2:
        fill    2500,0
gbl_ch:
        word    0
gbl_ch_2:
        word    0
gbl_bool:
        word    0
gbl_int:
        word    0
gbl_ptr:
        word    0
// Arr_1_Dim    gbl_arr_1;
// Arr_2_Dim    gbl_arr_2;
// char gbl_ch, gbl_ch_2;
// bool gbl_bool;
// int  gbl_int;
// RECP gbl_ptr;
 
//char  *lcl_strcpy(char *d, char *s) {
//      char    *cpd = d, ch;
//
//      do{
//              *cpd++ = ch = *s++;
//      } while(ch);
//
//}
//
lcl_strcpy:
        ; R0 = d
        ; R1 = s
        ; R3 = ch
copy_next_char:
#ifdef  NO_LOOP_UNROLLING
        LOD     (R1),R2
        STO     R2,(R0)
#ifdef  USE_PSTRS
        TST     255,R2
#else
        CMP     0,R2
#endif
        RETN.Z
        ADD     1,R0
        ADD     1,R1
        BRA     copy_next_char
 
 
 
#else
        LOD     (R1),R2
        STO     R2,(R0)
#ifdef  USE_PSTRS
        TST     255,R2
#else
        CMP     0,R2
#endif
        ; BZ    lcl_strcpy_end_of_loop
        RETN.Z
        LOD     1(R1),R2
        STO     R2,1(R0)
#ifdef  USE_PSTRS
        TST     255,R2
#else
        CMP     0,R2
#endif
        ; BZ    lcl_strcpy_end_of_loop
        RETN.Z
        LOD     2(R1),R2
        STO     R2,2(R0)
#ifdef  USE_PSTRS
        TST     255,R2
#else
        CMP     0,R2
#endif
        ; BZ    lcl_strcpy_end_of_loop
        RETN.Z
        LOD     3(R1),R2
        STO     R2,3(R0)
        ; BZ    lcl_strcpy_end_of_loop
#ifdef  USE_PSTRS
        TST     255,R2
#else
        CMP     0,R2
#endif
        RETN.Z
        ADD     4,R0
        ADD     4,R1
        BRA     copy_next_char
#endif
 
//int   lcl_strcmp(char *s1, char *s2) {
//      char    a, b;
//      do {
//              a = *s1++; b = *s2++;
//      } while((a)&&(a==b));
//
//      return a-b;
//}
 
lcl_strcmp:
        SUB     1,SP
        STO     R3,1(SP)
 
strcmp_top_of_loop:
#ifdef  NO_LOOP_UNROLLING
        ; LOD   (R0),R2
        ; LOD   (R1),R3                 ; Alternate approach:
        ; CMP   R2,R3                   ;       CMP     0,R2
        ; BNZ   strcmp_end_loop         ;       BZ      strcmp_end_loop
        ; CMP   0,R2                    ;       CMP     R2,R3
        ; BZ    strcmp_end_loop         ;       BZ      strcmp_top_of_loop
        ; CMP   0,R3                    ;
        ; BZ    strcmp_end_loop         ;
        ; ADD   1,R0
        ; ADD   1,R1
        ; BRA   strcmp_top_of_loop
        LOD     (R0),R2
        LOD     (R1),R3
#ifdef  USE_PSTRS
        TST     255,R2
#else
        CMP     0,R2
#endif
        BZ      strcmp_end_loop
        ADD     1,R0
        ADD     1,R1
        CMP     R2,R3
        BZ      strcmp_top_of_loop
#else
        LOD     (R0),R2
        LOD     (R1),R3
#ifdef  USE_PSTRS
        TST     255,R2
#else
        CMP     0,R2
#endif
        BZ      strcmp_end_loop
        CMP     R2,R3
        BNZ     strcmp_end_loop
        LOD     1(R0),R2
        LOD     1(R1),R3
#ifdef  USE_PSTRS
        TST     255,R2
#else
        CMP     0,R2
#endif
        BZ      strcmp_end_loop
        CMP     R2,R3
        BNZ     strcmp_end_loop
        LOD     2(R0),R2
        LOD     2(R1),R3
#ifdef  USE_PSTRS
        TST     255,R2
#else
        CMP     0,R2
#endif
        BZ      strcmp_end_loop
        CMP     R2,R3
        BNZ     strcmp_end_loop
        LOD     3(R0),R2
        LOD     3(R1),R3
#ifdef  USE_PSTRS
        TST     255,R2
#else
        CMP     0,R2
#endif
        BZ      strcmp_end_loop
        CMP     R2,R3
        BNZ     strcmp_end_loop
        ADD     4,R0
        ADD     4,R1
        BRA     strcmp_top_of_loop
#endif
 
strcmp_end_loop:
        SUB     R3,R2
        MOV     R2,R0
 
        LOD     1(SP),R3
        ADD     1,SP
        RETN
 
 
//test_enum     func_1(char ch_1, char ch_2) {
//      char    lcl_ch_1, lcl_ch_2;
//
//      lcl_ch_1 = ch_1;
//      lcl_ch_2 = lcl_ch_1;
//      if (lcl_ch_2 != ch_2)
//              return 0;
//      else {
//              gbl_ch = lcl_ch_1;
//              return 1;
//      }
 
#ifdef  NO_INLINE
func_1:
        ; On input,
        ; R0 = ch_1
        ; R1 = ch_2
        ; R2 = available
        ; On output, R0 is our return value
 
        MOV     R0,R2
        CMP     R2,R1
        CLR.NZ  R0
        STO.Z   R2,gbl_ch(R12)
        LDILO.Z 1,R0
        RETN
#endif
 
//bool  func_2(char *str_1, char *str_2) {
//      int     lcl_int;
//      char    lcl_ch;
//
//      lcl_int = 2;
//      while(lcl_int <= 2) {
//              if (func_1(str_1[lcl_int], str_2[lcl_int+1])==0) {
//                      lcl_ch = 'A';
//                      lcl_int ++;
//              }
//      }
//
//      if ((lcl_ch >= 'W')&&(lcl_ch < 'Z'))
//              lcl_int = 7;
//      if (lcl_ch == 'R')
//              return true;
//      else {
//              if (lcl_strcmp(str_1, str_2)>0) {
//                      lcl_int += 7;
//                      gbl_int = lcl_int;
//              } else
//                      return false;
//      }
//}
func_2:
        ;
        SUB     6,SP
        STO     R3,2(SP)
        STO     R4,3(SP)
        STO     R5,4(SP)
        STO     R6,5(SP)
        STO     R7,6(SP)
 
        MOV     R0,R3   ; R3 = str_1
        MOV     R1,R4   ; R4 = str_2
        LDI     2,R5    ; R5 = lcl_int
        LDI     'A',R7  ; R7 = lcl_ch
func_2_while_loop:
        CMP     2,R5
        BGT     func_2_end_while_loop
func_2_top_while_loop:
        MOV     R3,R6
        ADD     R5,R6
 
#ifdef  NO_INLINE
        LOD     (R6),R0
        MOV     R4,R6
        ADD     R5,R6
        LOD     1(R6),R1
 
        MOV     __HERE__+3(PC),R2
        STO     R2,1(SP)
        BRA     func_1
 
        CMP     0,R0
        ADD.Z   1,R5
#ifndef SKIP_SHORT_CIRCUITS
        BUSY.NZ
#endif
#else
        LOD     (R6),R2
        MOV     R4,R6
        ADD     R5,R6
        LOD     1(R6),R1
 
        CMP     R2,R1
        STO.Z   R2,gbl_ch(R12)
        LDILO.Z 1,R0
 
        ADD.NZ  1,R5
#ifndef SKIP_SHORT_CIRCUITS
        BUSY.Z
#endif
#endif
 
        CMP     3,R5
#ifndef SKIP_SHORT_CIRCUITS
        BUSY.LT
#endif
        BLT     func_2_top_while_loop
 
func_2_end_while_loop:
 
        // CMP  'W',R7                  // BUT! We know lcl_ch='A'
        // BLT  skip_if                 // So we can skip this
        // CMP  'Z',R7                  // entire  section
        // LDI.LT       7,R5
        // CMP  'R',R7
        // BNZ alt_if_case
        // LLO.Z        1,R0
        // BRA  func_2_return_and_cleanup
        //
        MOV     R3,R0
        MOV     R4,R1
        MOV     __HERE__+3(PC),R2
        STO     R2,1(SP)
        BRA     lcl_strcmp
        CMP     0,R0
        BGT     func_2_final_then
        CLR     R0
        BRA     func_2_return_and_cleanup
func_2_final_then:
        // ADD  7,R5            ; Never read, so useless code
        LDI     1,R0
#ifndef SKIP_SHORT_CIRCUITS
        BUSY
#endif
func_2_return_and_cleanup:
 
        LOD     2(SP),R3
        LOD     3(SP),R4
        LOD     4(SP),R5
        LOD     5(SP),R6
        LOD     6(SP),R7
        ADD     6,SP
        RETN
 
//bool  func_3(test_enum a) {
//      test_enum       lcl_enum;
//
//      lcl_enum = a;
//      if (lcl_enum == Ident_3)
//              return true;
//      else
//              return false;
//}
 
#ifdef  NO_INLINE
func_3:
        ; On entry,
        ;  R0 = a
        ;  R1 - available
        CMP     2,R0
        CLR             R0      ; CLR Doesn't set flags
        LDILO.Z         1,R0
        RETN
#endif
 
 
// void proc_6(test_enum ev, test_enum *ep) {
//      *ep = ev;
//      if (!func_3(ev))
//              *ep = 3;
//      switch(ev) {
//              case 0: *ep = 0; break;
//              case 1:
//                      if (gbl_int > 100)
//                              *ep = 0;
//                      else
//                              *ep = 3;
//                      break;
//              case 2:
//                      *ep = 1;
//                      break;
//              case 3:
//                      break;
//              case 4:
//                      *ep = 2;
//      }
//}
 
proc_6:
        ; On entry:
        ;       R0 = ev
        ;       R1 = ep
        ;       R2 - unassigned
        ; Since we call func_3, we have to reserve R0 and R1
        ; for other purposes.  Thus
        ;       R2 = ev
        ;       R3 = ep
        SUB     2,SP
        STO     R3,2(SP)
 
        MOV     R1,R3
        MOV     R0,R2
        ; *ep = ev
        STO     R0,(R1)
#ifndef SKIP_SHORT_CIRCUITS
        CMP     2,R0
        BUSY.NZ
#endif
 
#ifdef  NO_INLINE
        ; !func_3(ev)
        MOV     __HERE__+3(PC),R1
        STO     R1,1(SP)
        BRA     func_3
 
        TST     -1,R0
        LDI     3,R1
        STO.Z   R1,(R3)
#else
        CMP             2,R0
        LDI     3,R1
        STO.Z   R1,(R3)
#endif
 
        TST     -1,R0
        LDI     3,R1
#ifndef SKIP_SHORT_CIRCUITS
        BUSY.Z
#endif
        STO.Z   R1,(R3)
 
#ifndef SKIP_SHORT_CIRCUITS
        CMP     2,R2
        BUSY.NZ
#endif
        CMP     0,R2
        BNZ     proc_6_case_not_zero
#ifndef SKIP_SHORT_CIRCUITS
        BUSY
#endif
        LDI     0,R1
        STO     R1,(R3)
        BRA     proc_6_end_of_case
proc_6_case_not_zero:
        CMP     1,R2
        BNZ     proc_6_case_not_one
#ifndef SKIP_SHORT_CIRCUITS
        BUSY
#endif
        LDI     3,R0
        LOD     gbl_int(R12),R1
        CMP     100,R1
        CLR.GT  R0
        STO     R0,(R3)
        BRA     proc_6_end_of_case
proc_6_case_not_one:
        CMP     2,R2
        BNZ     proc_6_case_not_two
        LDI     1,R1                            // Executed, if done properly
        STO     R1,(R3)
        BRA     proc_6_end_of_case
proc_6_case_not_two:
#ifndef SKIP_SHORT_CIRCUITS
        BUSY
#endif
        CMP     4,R2
        BNZ     proc_6_case_not_four
        LDI     2,R1
        STO     R1,(R3)
        // BRA  proc_6_end_of_case
proc_6_case_not_four:
proc_6_end_of_case:
        LOD     2(SP),R3
        ADD     2,SP
        RETN
 
// void proc_7(int a, int b, int *c) {
//      int     lcl;
//
//      lcl = a + 2;
//      *c = b + a;
//}
 
#ifdef  NO_INLINE
proc_7:
        ADD 2+R0,R1
        STO R1,(R2)
 
        RETN
#endif
 
//      int     a[50];
//      int     b[50][50];
//
// void proc_8(Arr_1_Dim a, Arr_2_Dim b, int c, int d) {
//      int     idx, loc;
//
//      loc = c+5;
//      a[loc] = d;
//      a[loc+1] = a[loc];
//      a[loc+30] = loc;
//      for(idx=loc; idx<= loc+1; idx++)
//              b[loc][idx] = loc;
//      b[loc][loc-1] += 1;
//      b[loc+20][loc] = a[loc];
//      gbl_int = 5;
//}
proc_8:
        ; R0 = a
        ; R1 = b
        ; R2 = c
        ; R3 = d
        ; R4 - unassigned
        ; Makes no function/procedure calls, so these can keep
        ; R2 = loc = c+5, replaces c
        ; R4 = idx
        SUB     2,SP
        STO     R5,1(SP)
        STO     R6,2(SP)
 
        ADD     5,R2    ; loc = c+5
        MOV     R0,R5
        ADD     R2,R5
        STO     R3,(R5)
        STO     R3,1(R5)
        STO     R2,30(R5)
        MOV     R2,R5
        MPYU    50,R5   ; R5 = 50 * R2 = 50 * loc
        ADD     R1,R5   ; R5 = &b[loc][0]
        MOV     R5,R6   ; R6 = &b[loc][0]
        ADD     R2,R5   ; R5 = &b[loc][loc]
        MOV     R2,R4   ; R4 = loc = index
proc_8_top_of_loop:
        CMP     1(R2),R4
        BGT     proc_8_end_of_loop
proc_8_loop_after_condition:
        STO     R2,(R5)
        ADD     1,R5
        ADD     1,R4
        CMP     2(R2),R4
        BLT     proc_8_loop_after_condition
proc_8_end_of_loop:
 
        ; b[loc][loc-1] += 1
        ADD     R2,R6           ; R6 = &b[loc][loc]
        LOD     -1(R6),R5
        ADD     1,R5
        STO     R5,-1(R6)
        ; b[loc+20][loc] = a[loc]
        MOV     R0,R4
        ADD     R2,R4
        LOD     (R4),R3
        STO     R3,20*50(R6)
        LDI     5,R3
        STO     R3,gbl_int(R12)
 
        LOD     1(SP),R5
        LOD     2(SP),R6
        ADD     2,SP
        RETN
 
// void proc_5(void) {
//      gbl_ch = 'A';
//      gbl_bool = false;
//}
#ifdef  NO_INLINE
proc_5:
        LDI     'A',R0
        STO     R0,gbl_ch(R12)
        CLR     R0
        STO     R0,gbl_bool(R12)
        ;
        RETN
#endif
 
// void proc_4(void) {
//      bool    lcl_bool;
//      lcl_bool = (gbl_ch == 'A');
//      gbl_ch_2 = 'B';
// }
#ifdef  NO_INLINE
proc_4:
        //
        ; LDI   GBL,R12 // Already in R12
        ; Setting lcl_bool is irrelevant, so the optimizer should remove it.
        ; R0 doesn't need to be saved, since it's already trashed by the
        ; subroutine call.
        ;
        ; LOD   gbl_ch(R12),R0
        ; CLR   R1
        ; CMP   'A',R0
        ; ADD.Z 1,R1
        ;
        LDI     'B',R0
        STO     R0,gbl_ch_2(R12)
        ;
        RETN
#endif
 
// void proc_3(RECP *a) {
//      if (gbl_ptr != NULL)
//              *a = gbl_ptr->ptr_comp;
//      proc_7(10,gbl_int, &gbl_ptr->variant.var_1.int_comp); // ??
//}
proc_3:
        SUB     3,SP
        STO     R3,2(SP)
        STO     R2,3(SP)
        ; Save one for the return address from our JSR "instruction"
        ;
        LOD     gbl_ptr(R12),R2
        TST     -1,R2
#ifndef SKIP_SHORT_CIRCUITS
        BUSY.Z
#endif
        LOD.NZ  ptr_comp(R2),R3
        STO.NZ  R3,(R0)
#ifdef  NO_INLINE
        LDI     10,R0
        LOD     gbl_int(R12),R1
        MOV     variant.var_1.int_comp(R2),R2
        MOV     __HERE__+3(PC),R3
        STO     R3,1(SP)
        BRA     proc_7
#else
        LOD     gbl_int(R12),R1
        ADD      12,R1
        STO      R1,variant.var_1.int_comp(R2)
#endif
        ;
        LOD     2(SP),R3
        LOD     3(SP),R2
        ADD     3,SP
        RETN
 
 
// void proc_2(int *a) {
//      int             lcl_int;
//      test_enum       lcl_enum;
//
//      lcl_int = *a + 10;
//      do {
//              if (gbl_ch == 'A') {
//                      lcl_int -= 1;
//                      *a = lcl_int - gbl_int;
//                      lcl_enum = Ident_1;
//              }
//      } while(lcl_enum != Ident_1);
//}
proc_2:
        SUB     5,SP
        STO     R6,1(SP)
        STO     R5,2(SP)
        STO     R4,3(SP)
        STO     R3,4(SP)
        STO     R2,5(SP)
        // R1 doesn't need to be stored, it was used in the subroutine
        // call calculation
 
        LOD     (R0),R1
        MOV     10(R1),R2       ; R2 = lcl_int
        LOD     gbl_ch(R12),R4  ; R4 = gbl_ch
#ifdef  NO_CHEATING
proc_2_loop:
        CMP     'A',R4
        SUB.Z   1,R2
        LOD.Z   gbl_int(R12),R5 ; R5 = gbl_int
        MOV.Z   R2,R6           ; R6 = lcl_int
        SUB.Z   R5,R6           ; lcl_int - gbl_int
        STO.Z   R6,(R0)         ; *a = R6
        CLR.Z   R3              ; lcl_enum = 0
// #ifndef      SKIP_SHORT_CIRCUITS
        // BUSY.NZ
// #endif
 
        TST     -1,R3
// #ifndef      SKIP_SHORT_CIRCUITS
        // BUSY.NZ
// #endif
        BNZ     proc_2_loop
#else
        LOD     gbl_int(R12),R5
        SUB     1(R5),R2
        STO     R2,(R0)
#endif
        ;
        LOD     1(SP),R6
        LOD     2(SP),R5
        LOD     3(SP),R4
        LOD     4(SP),R3
        LOD     5(SP),R2
        ADD     5,SP
        RETN
 
//void  proc_1 (RECP a) {
//      RECP    nxt = a->ptr_comp;
//
//      // structassign(a->ptr_comp, gbl_ptr);
//      *(a->ptr_comp) = *(gbl_ptr);
//
//      a->variant.var_1.int_comp = 5;
//      nxt->variant.var_1.int_comp = a->variant.var_1.int_comp;
//      proc_3(&nxt->ptr_comp);
//
//      if (nxt->discr == 0) {
//              nxt->variant.var_1.int_comp = 6;
//              proc_6(a->variant.var_1.enum_comp, &nxt->variant.var_1.enum_comp);
//              nxt->ptr_comp = gbl_ptr->ptr_comp;
//              proc_7(nxt->variant.var_1.int_comp, 10, &nxt->variant.var_1.int_comp);
//      } else
//              // structassign(a, a->ptr_comp);
//              *a = *(a->ptr_comp);
//}
proc_1:
        SUB     9,SP
        STO     R2,2(SP)
        STO     R3,3(SP)
        STO     R4,4(SP)
        STO     R5,5(SP)
        STO     R6,6(SP)
        STO     R7,7(SP)
        STO     R8,8(SP)
        STO     R9,9(SP)
 
        ; R9 = a
        ; R4 = nxt
        ; R12 = GBL
        ; R13 = SP
        MOV     R0,R9
        LOD     ptr_comp(R9),R4
#ifndef SKIP_SHORT_CIRCUITS
        TST     -1,R4
        BUSY.Z
#endif
        LDI     35,R5
        MOV     R9,R6
        LOD     gbl_ptr(R12),R7
proc_1_assign_loop_1:
        LOD     (R6),R8
        ADD     1,R6
        STO     R8,(R7)
        ADD     1,R7
        SUB     1,R5
        BNZ     proc_1_assign_loop_1;
 
#ifndef SKIP_SHORT_CIRCUITS
        LOD     gbl_ptr(R12),R2
        TST     -1,R2
        BUSY.Z
#endif
 
        LDI     5,R5
        STO     R5,variant.var_1.int_comp(R9)
        STO     R5,variant.var_1.int_comp(R4)
        MOV     ptr_comp(R4),R0
        MOV     __HERE__+3(PC),R1
        STO     R1,1(SP)
        BRA     proc_3          ; Uses R0 and R1
 
        LOD     discr(R4),R5
        CMP     0,R5
        BNZ     proc_1_last_struct_assign
        ; This is the juncture that is "supposed" to be taken
        LDI     6,R5
 
        STO     R5,variant.var_1.int_comp(R4)
        LOD     variant.var_1.enum_comp(R9), R0
#ifndef SKIP_SHORT_CIRCUITS
        CMP     2,R0
        BUSY.NZ
#endif
        MOV     variant.var_1.enum_comp+R4, R1
        MOV     __HERE__+3(PC),R2
        STO     R2,1(SP)
        BRA     proc_6
        ;
        LOD     gbl_ptr(R12),R5
        LOD     ptr_comp(R5),R5
        STO     R5,ptr_comp(R4)
        ;
#ifdef  NO_INLINE
        LOD     variant.var_1.int_comp(R4),R0
        LDI     10,R1
        MOV     variant.var_1.int_comp(R4),R2
        MOV     proc_1_return_closeout(PC),R3
        STO     R3,1(SP)
        BRA     proc_7
#else
        LOD     variant.var_1.int_comp(R4),R0
        ADD     12,R0
        STO     R0,variant.var_1.int_comp(R4)
        BRA     proc_1_return_closeout
#endif
        ;
proc_1_last_struct_assign:
#ifndef SKIP_SHORT_CIRCUITS
        BUSY
#endif
        LDI     35,R4
        MOV     R2,R5
        LOD     gbl_ptr(R12),R6
proc_1_assign_loop_2:
        LOD     (R6),R8
        STO     R8,(R7)
        ADD     1,R6
        ADD     1,R7
        SUB     1,R5
        BNZ     proc_1_assign_loop_2
        //
proc_1_return_closeout:
        //
        LOD     2(SP),R2
        LOD     3(SP),R3
        LOD     4(SP),R4
        LOD     5(SP),R5
        LOD     6(SP),R6
        LOD     7(SP),R7
        LOD     8(SP),R8
        LOD     9(SP),R9
        ADD     9,SP
        RETN
 
// void dhrystone(void) {
//      int     lcl_int_1, lcl_int_2, lcl_int_3, index, number_of_runs = 500;
//      test_enum       lcl_enum;
//      char    lcl_str_1[30], lcl_str_2[30], ch_index;
//      REC_T   a, b, *nxt = &a;
//
//      gbl_ptr = &b;
//      gbl_ptr->ptr_comp = nxt;
//      gbl_ptr->variant.var_1.enum_comp = 2;
//      gbl_ptr->variant.var_1.int_comp = 40;
//      lcl_strcpy(gbl_ptr->variant.var_1.str_comp, "DHRYSTONE PROGRAM, SOME STRING");
//      lcl_strcpy(lcl_str_1, "DHRYSTONE PROGRAM, 1\'ST STRING");
//
//      gbl_arr_2[8][7] = 10;
//
//      for(index=0; index < number_of_runs; index++) {
//              proc_5();
//              proc_4();
//              lcl_int_1 = 2;
//              lcl_int_2 = 3;
//              lcl_strcpy(lcl_str_2, "DHRYSTONE PROGRAM, 2\'ND STRING");
//              lcl_enum = Ident_2;
//              gbl_bool = !func_2(lcl_str_1, lcl_str_2);
//              while(lcl_int_1 < lcl_int_2) {
//                      lcl_int_3 = 5 * lcl_int_1 - lcl_int_2;
//                      proc_7(lcl_int_1, lcl_int_2, &lcl_int_3);
//                      lcl_int_1 += 1;
//              }
//
//              proc_8(gbl_arr_1, gbl_arr_2, lcl_int_1, lcl_int_3);
//              proc_1(gbl_ptr);
//
//              for(ch_index='A'; ch_index <= gbl_ch_2; ch_index++) {
//                      if (lcl_enum == func_1(ch_index, 'C')) {
//                              // Then not executed??
//                              proc_6(0, &lcl_enum);
//                              lcl_strcpy(lcl_str_2, "DHRYSTONE PROGRAM, 3\'RD STRING");
//                              lcl_int_2 = index;
//                              gbl_int = index;
//                      }
//              }
//
//              lcl_int_2 = lcl_int_2 * lcl_int_1;
//              lcl_int_1 = lcl_int_2 / lcl_int_3;
//              lcl_int_2 = 7 * ( lcl_int_2 - lcl_int_3) - lcl_int_1;
//              proc_2(&lcl_int_1);
//      }
//}
 
some_string:
#ifdef  USE_PSTRS
        word    'DHRY','STON','E PR','OGRA','M, S','OME '
        word    'STRI','NG\0\0'
#else
        word    'D','H','R','Y','S','T','O','N','E',' '
        word    'P','R','O','G','R','A','M',',',' '
        word    'S','O','M','E',' ','S','T','R','I','N','G'
        word    0
#endif
 
first_string:
#ifdef  USE_PSTRS
        word    'DHRY','STON','E PR','OGRA'
        word    'M, 1','\'ST ','STRI','NG\0\0'
#else
        word    'D','H','R','Y','S','T','O','N','E',' '
        word    'P','R','O','G','R','A','M',','
        word    ' ','1','\'','S','T'
        word    ' ','S','T','R','I','N','G'
        word    0
#endif
 
second_string:
#ifdef  USE_PSTRS
        word    'DHRY','STON','E PR','OGRA'
        word    'M, 2','\'ND ','STRI','NG\0\0'
#else
        word    'D','H','R','Y','S','T','O','N','E',' '
        word    'P','R','O','G','R','A','M',',',' '
        word    '2','\'','N','D',' ','S','T','R','I','N','G'
        word    0
#endif
 
third_string:
#ifdef  USE_PSTRS
        word    'DHRY','STON','E PR','OGRA'
        word    'M, 3','\'RD ','STRI','NG\0\0'
#else
        word    'D','H','R','Y','S','T','O','N','E',' '
        word    'P','R','O','G','R','A','M',',',' '
        word    '3','\'','R','D',' ','S','T','R','I','N','G'
        word    0
#endif
 
dhrystone:
#ifdef  SUPERVISOR_TASK
        SUB     12+RECSIZE+RECSIZE+30+30+3,SP
        ; Leave a space on the top of the stack for calling
        ; subroutines.
        STO     R1,2(SP)
        STO     R2,3(SP)
        STO     R3,4(SP)
        STO     R4,5(SP)
        STO     R5,6(SP)
        STO     R6,7(SP)
        STO     R7,8(SP)
        STO     R8,9(SP)
        STO     R9,10(SP)
        STO     R10,11(SP)
        STO     R11,12(SP)
        lcl_int_1       equ     12                      ; plus SP
#else
        lcl_int_1       equ     2                       ; plus SP
        SUB     2+RECSIZE+RECSIZE+30+30+3,SP
#endif
        // 12 is the global variable pointer
        // 13 is our stack
        // 14 is our condition code register
        // 15 is the program counter
        ;
        lcl_int_3       equ     lcl_int_1+1             ; plus SP
        lcl_enum        equ     lcl_int_3+1             ; plus SP
        lcl_str_1       equ     lcl_enum+1              ; plus SP
        lcl_str_2       equ     lcl_str_1+30            ; plus SP
        rec_a           equ     lcl_str_2+30            ; plus SP
        rec_b           equ     rec_a+RECSIZE           ; plus SP
 
//      int     lcl_int_1, lcl_int_2, lcl_int_3, index, number_of_runs = 500;
//      test_enum       lcl_enum;
//      char    lcl_str_1[30], lcl_str_2[30], ch_index;
//      REC_T   a, b, *nxt = &a;
//
//      gbl_ptr = &b;
        MOV     rec_b(SP),R0            ; R0 = &b
        STO     R0,gbl_ptr(PC)
//      gbl_ptr->ptr_comp = nxt;
        MOV     rec_a(SP),R1            ; R1 = &a = nxt
        STO     R1,ptr_comp(R0)         ; gbp_ptr->ptr.comp=b->ptr.comp=R1=nxt
//      gbl_ptr->variant.var_1.enum_comp = 2;
        LDI     2,R2
        STO     R2,variant.var_1.enum_comp(R0)
//      gbl_ptr->variant.var_1.int_comp = 40;
        LDI     40,R2
        STO     R2,variant.var_1.int_comp(R0)
//      lcl_strcpy(gbl_ptr->variant.var_1.str_comp, "DHRYSTONE PROGRAM, SOME STRING");
        MOV     variant.var_1.str_comp(R0),R0
        MOV     some_string(PC),R1
        MOV     __HERE__+3(PC),R2
        STO     R2,1(SP)
        BRA     lcl_strcpy
 
//      lcl_strcpy(lcl_str_1, "DHRYSTONE PROGRAM, 1\'ST STRING");
        MOV     lcl_str_1(SP),R0
        MOV     first_string(PC),R1
        MOV     __HERE__+3(PC),R2
        STO     R2,1(SP)
        BRA     lcl_strcpy
 
//      gbl_arr_2[8][7] = 10;
        LDI     10,R0
        STO     R0,8*50+7+gbl_arr_2(R12)
//
//      for(index=0; index < number_of_runs; index++) {
        ; Let R11 be our index
        CLR     R11
dhrystone_main_loop:
        ;; Start of Dhrystone main loop
        ; proc_5();
#ifdef  NO_INLINE
        MOV     __HERE__+3(PC),R0
        STO     R0,1(SP)
        BRA     proc_5
#else
        LDI     'A',R0
        STO     R0,gbl_ch(R12)
        CLR     R0
        STO     R0,gbl_bool(R12)
#endif
        ; proc_4();
#ifdef  NO_INLINE
        MOV     __HERE__+3(PC),R0
        STO     R0,1(SP)
        BRA     proc_4
#else
        LDI     'B',R0
        STO     R0,gbl_ch_2(R12)
#endif
//              lcl_int_1 = 2;
        LDI     2,R5
        STO     R5,lcl_int_1(SP)
//              lcl_int_2 = 3;
        LDI     3,R6
//              lcl_strcpy(lcl_str_2, "DHRYSTONE PROGRAM, 2\'ND STRING");
        MOV     lcl_str_2(SP),R0
        MOV     second_string(PC),R1
        MOV     __HERE__+3(PC),R2
        STO     R2,1(SP)
        BRA     lcl_strcpy
//              lcl_enum = Ident_2;
        LDI     2,R0
        STO     R0,lcl_enum(SP)
//              gbl_bool = !func_2(lcl_str_1, lcl_str_2);
        MOV     lcl_str_1(SP),R0
        MOV     lcl_str_2(SP),R1
        MOV     __HERE__+3(PC),R2
        STO     R2,1(SP)
        BRA     func_2
        CLR     R1
        TST     -1,R0
        LDILO.Z 1,R1
        STO     R1,gbl_bool(PC)
 
//              while(lcl_int_1 < lcl_int_2) {
        ; R5 = lcl_int_1 = 2 on entry
        ; R6 = lcl_int_2 = 3 on entry, so no entry test is required
        LOD     lcl_int_1(SP),R5
        // The 'while' comparison
        CMP     R6,R5
        BGE     dhrystone_end_while_loop
dhrystone_while_loop:
//                      lcl_int_3 = 5 * lcl_int_1 - lcl_int_2;
        MOV     R5,R7
        MPYS    5,R7
        SUB     R6,R7
        STO     R7,lcl_int_3(SP)
//                      proc_7(lcl_int_1, lcl_int_2, &lcl_int_3);
#ifdef  NO_INLINE
        MOV     R5,R0
        MOV     R6,R1
        MOV     lcl_int_3(SP),R2
        MOV     __HERE__+3(PC),R3
        STO     R3,1(SP)
        BRA     proc_7
#else
        MOV     R6,R1
        ADD     2+R5,R1
        STO     R1,lcl_int_3(SP)
#endif
//                      lcl_int_1 += 1;
        LOD     lcl_int_1(SP),R5
        ADD     1,R5
        STO     R5,lcl_int_1(SP)
;
        ; BRA   dhrystone_while_loop    ; We'll unroll the loop, and put an
        CMP     R6,R5                   ; additional comparison at the bottom
        BLT     dhrystone_while_loop
dhrystone_end_while_loop:
//              }
//
//              proc_8(gbl_arr_1, gbl_arr_2, lcl_int_1, lcl_int_3);
        MOV     gbl_arr_1(PC),R0
        MOV     gbl_arr_2(PC),R1
        MOV     R5,R2
        MOV     R6,R3
        MOV     __HERE__+3(PC),R4
        STO     R4,1(SP)
        BRA     proc_8
//              proc_1(gbl_ptr);
        LOD     gbl_ptr(PC),R0
        MOV     __HERE__+3(PC),R2
        STO     R2,1(SP)
        BRA     proc_1
//
//              for(ch_index='A'; ch_index <= gbl_ch_2; ch_index++) {
        LDI     'A',R7
        LOD     gbl_ch_2(SP),R8
        CMP     R7,R8
        BLT     dhrystone_end_of_for_loop
dhrystone_top_of_for_loop:
//                      if (lcl_enum == func_1(ch_index, 'C')) {
#ifdef  NO_INLINE
        MOV     R7,R0
        LDI     'C',R1
        MOV     __HERE__+3(PC),R2
        STO     R2,1(SP)
        BRA     func_1
#else
        CMP     'C',R7
        CLR.NZ  R0
        STO.Z   R7,gbl_ch(R12)
        LDILO.Z 1,R0
#endif
 
        ; Result is now in R0
        LOD     lcl_enum(SP),R1
        CMP     R0,R1
        BNZ     dhrystone_skip_then_clause
//                              // Then not executed??
//                              proc_6(0, &lcl_enum);
 
#ifndef SKIP_SHORT_CIRCUITS
        BUSY
#endif
 
        CLR     R0
        MOV     lcl_enum(SP),R1
        MOV     __HERE__+3(PC),R2
        STO     R2,1(SP)
        BRA     proc_6
 
//                              lcl_strcpy(lcl_str_2, "DHRYSTONE PROGRAM, 3\'RD STRING");
        MOV     lcl_str_2(SP),R0
        MOV     third_string(PC),R1
        MOV     __HERE__+3(PC),R2
        STO     R2,1(SP)
        BRA     lcl_strcpy
//                              lcl_int_2 = index;
        MOV     R11,R6
//                              gbl_int = index;
        STO     R11,gbl_int(PC)
//                      }
dhrystone_skip_then_clause:
        ADD     1,R7
        LOD     gbl_ch_2(SP),R8
        CMP     R8,R7
        BGE     dhrystone_top_of_for_loop
dhrystone_end_of_for_loop:
//              }
//
//              lcl_int_2 = lcl_int_2 * lcl_int_1;
        LOD     lcl_int_1(SP),R5
        MPYS    R5,R6   ; lcl_int_2 =
//              lcl_int_1 = lcl_int_2 / lcl_int_3;
#ifndef SKIP_DIVIDE
        MOV     R6,R0
        LOD     lcl_int_3(SP),R1
        MOV     __HERE__+3(PC),R2
        STO     R2,1(SP)
        BRA     divs
#else
        LDI     9,R0
#endif
        STO     R0,lcl_int_1(SP)
//              lcl_int_2 = 7 * ( lcl_int_2 - lcl_int_3) - lcl_int_1;
        LOD     lcl_int_3(SP),R2
        SUB     R2,R6
        MPYS    7,R6
        SUB     R0,R6
//              proc_2(&lcl_int_1);
        MOV     lcl_int_1(SP),R0
        MOV     __HERE__+3(PC),R1
        STO     R1,1(SP)
        BRA     proc_2
 
        ;; Bottom of (and return from) Dhrystone main loop
        ADD     1,R11
        CMP     NUMBER_OF_RUNS,R11
        BLT     dhrystone_main_loop
//      }
 
#ifdef  SUPERVISOR_TASK
        LOD     2(SP),R1
        LOD     3(SP),R2
        LOD     4(SP),R3
        LOD     5(SP),R4
        LOD     6(SP),R5
        LOD     7(SP),R6
        LOD     8(SP),R7
        LOD     9(SP),R8
        LOD     10(SP),R9
        LOD     11(SP),R10
        LOD     12(SP),R11
        ;
        ADD     12+RECSIZE+RECSIZE+30+30+3,SP
        ; Return from subroutine
        RETN
#else
        LDI     0,CC
        NOP
        NOP
        BUSY
#endif

Line No.	Rev	Author	Line
1	50	dgisselq	`;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;`
2			`;`
3			`; Filename: zipdhry.S`
4			`;`
5			`; Project: Zip CPU -- a small, lightweight, RISC CPU soft core`
6			`;`
7			`; Purpose: Zip assembly file for running the Dhrystone benchmark in the`
8			`; Zip CPU.`
9			`;`
10			`; Creator: Dan Gisselquist, Ph.D.`
11			`; Gisselquist Tecnology, LLC`
12			`;`
13			`;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;`
14			`;`
15			`; Copyright (C) 2015, Gisselquist Technology, LLC`
16			`;`
17			`; This program is free software (firmware): you can redistribute it and/or`
18			`; modify it under the terms of the GNU General Public License as published`
19			`; by the Free Software Foundation, either version 3 of the License, or (at`
20			`; your option) any later version.`
21			`;`
22			`; This program is distributed in the hope that it will be useful, but WITHOUT`
23			`; ANY WARRANTY; without even the implied warranty of MERCHANTIBILITY or`
24			`; FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License`
25			`; for more details.`
26			`;`
27			`; License: GPL, v3, as defined and found on www.gnu.org,`
28			`; http://www.gnu.org/licenses/gpl.html`
29			`;`
30			`;`
31			`;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;`
32			`;`
33	41	dgisselq	`// Under Verilator:`
34	57	dgisselq	`// DMIPS: 28.6 100 MHz (sim) 0.29`
35			`//`
36			`//`
37			`// with no loop unrolling nor function inlining`
38			`// DMIPS: 24.3 100 MHz (sim) 0.24`
39			`// with packed strings`
40			`// DMIPS: 35.6 100 MHz (sim) 0.36`
41			`//`
42	41	dgisselq	`// For comparison:`
43			`// uBlaze: 255 177 MHz 1.44`
44			`// LEON3 1.4`
45			`// NiOS II: 218 185 MHz 1.16`
46			`// OpenRisk 250 250 MHz 1.00`
47			`// LM32 1.14`
48			`// ZPU 2.6 50 MHz 0.05`
49			`//`
50
51	57	dgisselq	`// Some #def's to control compilation.`
52			`//`
53			`// SKIP_SHORT_CIRCUITS determines whether or not we do internal testing and`
54			`// jump to a BUSY instruction on failure for the debugger to pick up. Skip`
55			`// this for valid testing.`
56			`//`
57			`// #define SKIP_SHORT_CIRCUITS`
58			`//`
59			`// NO_INLINE controls whether or not we inline certain functions. If you`
60			`// define this, nothing will be inlined.`
61			`// #define NO_INLINE`
62			`//`
63			`// NO_LOOP_UNROLLING controls loop unrolling. The default is to unroll loops`
64			`// by a factor of 4x. By defining this, all loop unrolling is removed.`
65	41	dgisselq	`// #define NO_LOOP_UNROLLING`
66	57	dgisselq	`//`
67			`// Use PSTRS has to deal with whether or not we are processing packed strings`
68			`// or normal strings. Packed strings are really a cheaters exception to the`
69			`// dhrystone measure, although they do get our score up.`
70			`//`
71			`// #define USE_PSTRS`
72	41	dgisselq	`sys.ctr.mtask equ 0xc0000008`
73			`// int main(int argc, char **argv) {`
74			`// dhrystone();`
75			`// }`
76			`entry:`
77			`MOV top_of_stack(PC),uSP`
78			`MOV entry(PC),uR12`
79			`; Store our tick counter in R1`
80			`LDI sys.ctr.mtask,R1`
81			`; And start with our counter cleared at zero`
82			`CLR R0`
83			`STO R0,(R1)`
84			`#ifdef SUPERVISOR_TASK`
85			`MOV __HERE__+3(PC),R0`
86			`STO R0,1(SP)`
87			`BRA dhrystone`
88			`#else`
89			`MOV dhrystone(PC),uPC`
90			`RTU`
91			`#endif`
92			`; Read the tick counter back out`
93			`LOD (R1),R0`
94			`HALT ; Stop the CPU--We're done!!!!!!!`
95
96			`// typedef enum { Ident_1, Ident_2, Ident_3, Ident_4, Ident_5 } test_enum;`
97			`// typedef enum { false, true } bool;`
98
99			`// typedef int Arr_1_Dim[50];`
100			`// typedef int Arr_2_Dim[50][50];`
101	57	dgisselq	`#ifdef USE_PSTRS`
102			`#define RECSIZE 12`
103			`#else`
104	41	dgisselq	`#define RECSIZE 35`
105	57	dgisselq	`#endif`
106	41	dgisselq	`#define NUMBER_OF_RUNS (512)`
107			`ptr_comp equ 0`
108			`discr equ 1`
109			`variant.var_1.enum_comp equ 2`
110			`variant.var_1.int_comp equ 3`
111			`variant.var_1.str_comp equ 4`
112
113			`gbl_arr_1:`
114			`fill 50,0`
115			`gbl_arr_2:`
116			`fill 2500,0`
117			`gbl_ch:`
118			`word 0`
119			`gbl_ch_2:`
120			`word 0`
121			`gbl_bool:`
122			`word 0`
123			`gbl_int:`
124			`word 0`
125			`gbl_ptr:`
126			`word 0`
127			`// Arr_1_Dim gbl_arr_1;`
128			`// Arr_2_Dim gbl_arr_2;`
129			`// char gbl_ch, gbl_ch_2;`
130			`// bool gbl_bool;`
131			`// int gbl_int;`
132			`// RECP gbl_ptr;`
133
134			`//char lcl_strcpy(char d, char *s) {`
135			`// char *cpd = d, ch;`
136			`//`
137			`// do{`
138			`// cpd++ = ch = s++;`
139			`// } while(ch);`
140			`//`
141			`//}`
142			`//`
143			`lcl_strcpy:`
144			`; R0 = d`
145			`; R1 = s`
146			`; R3 = ch`
147	57	dgisselq	`copy_next_char:`
148	41	dgisselq	`#ifdef NO_LOOP_UNROLLING`
149			`LOD (R1),R2`
150			`STO R2,(R0)`
151	57	dgisselq	`#ifdef USE_PSTRS`
152			`TST 255,R2`
153			`#else`
154			`CMP 0,R2`
155			`#endif`
156			`RETN.Z`
157	41	dgisselq	`ADD 1,R0`
158			`ADD 1,R1`
159	57	dgisselq	`BRA copy_next_char`
160
161
162
163	41	dgisselq	`#else`
164			`LOD (R1),R2`
165	57	dgisselq	`STO R2,(R0)`
166			`#ifdef USE_PSTRS`
167			`TST 255,R2`
168			`#else`
169	41	dgisselq	`CMP 0,R2`
170	57	dgisselq	`#endif`
171			`; BZ lcl_strcpy_end_of_loop`
172			`RETN.Z`
173	41	dgisselq	`LOD 1(R1),R2`
174	57	dgisselq	`STO R2,1(R0)`
175			`#ifdef USE_PSTRS`
176			`TST 255,R2`
177			`#else`
178	41	dgisselq	`CMP 0,R2`
179	57	dgisselq	`#endif`
180			`; BZ lcl_strcpy_end_of_loop`
181			`RETN.Z`
182	41	dgisselq	`LOD 2(R1),R2`
183	57	dgisselq	`STO R2,2(R0)`
184			`#ifdef USE_PSTRS`
185			`TST 255,R2`
186			`#else`
187	41	dgisselq	`CMP 0,R2`
188	57	dgisselq	`#endif`
189			`; BZ lcl_strcpy_end_of_loop`
190			`RETN.Z`
191	41	dgisselq	`LOD 3(R1),R2`
192	57	dgisselq	`STO R2,3(R0)`
193			`; BZ lcl_strcpy_end_of_loop`
194			`#ifdef USE_PSTRS`
195			`TST 255,R2`
196			`#else`
197	41	dgisselq	`CMP 0,R2`
198	57	dgisselq	`#endif`
199			`RETN.Z`
200	41	dgisselq	`ADD 4,R0`
201			`ADD 4,R1`
202	57	dgisselq	`BRA copy_next_char`
203	41	dgisselq	`#endif`
204
205			`//int lcl_strcmp(char s1, char s2) {`
206			`// char a, b;`
207			`// do {`
208			`// a = s1++; b = s2++;`
209			`// } while((a)&&(a==b));`
210			`//`
211			`// return a-b;`
212			`//}`
213
214			`lcl_strcmp:`
215			`SUB 1,SP`
216			`STO R3,1(SP)`
217
218			`strcmp_top_of_loop:`
219			`#ifdef NO_LOOP_UNROLLING`
220	57	dgisselq	`; LOD (R0),R2`
221			`; LOD (R1),R3 ; Alternate approach:`
222	41	dgisselq	`; CMP R2,R3 ; CMP 0,R2`
223			`; BNZ strcmp_end_loop ; BZ strcmp_end_loop`
224			`; CMP 0,R2 ; CMP R2,R3`
225			`; BZ strcmp_end_loop ; BZ strcmp_top_of_loop`
226			`; CMP 0,R3 ;`
227			`; BZ strcmp_end_loop ;`
228			`; ADD 1,R0`
229			`; ADD 1,R1`
230			`; BRA strcmp_top_of_loop`
231			`LOD (R0),R2`
232			`LOD (R1),R3`
233	57	dgisselq	`#ifdef USE_PSTRS`
234			`TST 255,R2`
235			`#else`
236	41	dgisselq	`CMP 0,R2`
237	57	dgisselq	`#endif`
238	41	dgisselq	`BZ strcmp_end_loop`
239	57	dgisselq	`ADD 1,R0`
240			`ADD 1,R1`
241	41	dgisselq	`CMP R2,R3`
242			`BZ strcmp_top_of_loop`
243			`#else`
244			`LOD (R0),R2`
245			`LOD (R1),R3`
246	57	dgisselq	`#ifdef USE_PSTRS`
247			`TST 255,R2`
248			`#else`
249	41	dgisselq	`CMP 0,R2`
250	57	dgisselq	`#endif`
251	41	dgisselq	`BZ strcmp_end_loop`
252			`CMP R2,R3`
253			`BNZ strcmp_end_loop`
254			`LOD 1(R0),R2`
255			`LOD 1(R1),R3`
256	57	dgisselq	`#ifdef USE_PSTRS`
257			`TST 255,R2`
258			`#else`
259	41	dgisselq	`CMP 0,R2`
260	57	dgisselq	`#endif`
261	41	dgisselq	`BZ strcmp_end_loop`
262			`CMP R2,R3`
263			`BNZ strcmp_end_loop`
264			`LOD 2(R0),R2`
265			`LOD 2(R1),R3`
266	57	dgisselq	`#ifdef USE_PSTRS`
267			`TST 255,R2`
268			`#else`
269	41	dgisselq	`CMP 0,R2`
270	57	dgisselq	`#endif`
271	41	dgisselq	`BZ strcmp_end_loop`
272			`CMP R2,R3`
273			`BNZ strcmp_end_loop`
274			`LOD 3(R0),R2`
275			`LOD 3(R1),R3`
276	57	dgisselq	`#ifdef USE_PSTRS`
277			`TST 255,R2`
278			`#else`
279	41	dgisselq	`CMP 0,R2`
280	57	dgisselq	`#endif`
281	41	dgisselq	`BZ strcmp_end_loop`
282			`CMP R2,R3`
283			`BNZ strcmp_end_loop`
284			`ADD 4,R0`
285			`ADD 4,R1`
286			`BRA strcmp_top_of_loop`
287			`#endif`
288
289			`strcmp_end_loop:`
290			`SUB R3,R2`
291			`MOV R2,R0`
292
293			`LOD 1(SP),R3`
294			`ADD 1,SP`
295			`RETN`
296
297
298			`//test_enum func_1(char ch_1, char ch_2) {`
299			`// char lcl_ch_1, lcl_ch_2;`
300			`//`
301			`// lcl_ch_1 = ch_1;`
302			`// lcl_ch_2 = lcl_ch_1;`
303			`// if (lcl_ch_2 != ch_2)`
304			`// return 0;`
305			`// else {`
306			`// gbl_ch = lcl_ch_1;`
307			`// return 1;`
308			`// }`
309
310			`#ifdef NO_INLINE`
311			`func_1:`
312			`; On input,`
313			`; R0 = ch_1`
314			`; R1 = ch_2`
315			`; R2 = available`
316			`; On output, R0 is our return value`
317
318			`MOV R0,R2`
319			`CMP R2,R1`
320			`CLR.NZ R0`
321			`STO.Z R2,gbl_ch(R12)`
322			`LDILO.Z 1,R0`
323			`RETN`
324			`#endif`
325
326			`//bool func_2(char str_1, char str_2) {`
327			`// int lcl_int;`
328			`// char lcl_ch;`
329			`//`
330			`// lcl_int = 2;`
331			`// while(lcl_int <= 2) {`
332			`// if (func_1(str_1[lcl_int], str_2[lcl_int+1])==0) {`
333			`// lcl_ch = 'A';`
334			`// lcl_int ++;`
335			`// }`
336			`// }`
337			`//`
338			`// if ((lcl_ch >= 'W')&&(lcl_ch < 'Z'))`
339			`// lcl_int = 7;`
340			`// if (lcl_ch == 'R')`
341			`// return true;`
342			`// else {`
343			`// if (lcl_strcmp(str_1, str_2)>0) {`
344			`// lcl_int += 7;`
345			`// gbl_int = lcl_int;`
346			`// } else`
347			`// return false;`
348			`// }`
349			`//}`
350			`func_2:`
351			`;`
352			`SUB 6,SP`
353			`STO R3,2(SP)`
354			`STO R4,3(SP)`
355			`STO R5,4(SP)`
356			`STO R6,5(SP)`
357			`STO R7,6(SP)`
358
359			`MOV R0,R3 ; R3 = str_1`
360			`MOV R1,R4 ; R4 = str_2`
361			`LDI 2,R5 ; R5 = lcl_int`
362			`LDI 'A',R7 ; R7 = lcl_ch`
363			`func_2_while_loop:`
364			`CMP 2,R5`
365			`BGT func_2_end_while_loop`
366			`func_2_top_while_loop:`
367			`MOV R3,R6`
368			`ADD R5,R6`
369
370			`#ifdef NO_INLINE`
371			`LOD (R6),R0`
372			`MOV R4,R6`
373			`ADD R5,R6`
374			`LOD 1(R6),R1`
375
376			`MOV __HERE__+3(PC),R2`
377			`STO R2,1(SP)`
378			`BRA func_1`
379
380			`CMP 0,R0`
381			`ADD.Z 1,R5`
382	57	dgisselq	`#ifndef SKIP_SHORT_CIRCUITS`
383			`BUSY.NZ`
384			`#endif`
385	41	dgisselq	`#else`
386			`LOD (R6),R2`
387			`MOV R4,R6`
388			`ADD R5,R6`
389			`LOD 1(R6),R1`
390
391			`CMP R2,R1`
392			`STO.Z R2,gbl_ch(R12)`
393			`LDILO.Z 1,R0`
394
395			`ADD.NZ 1,R5`
396	57	dgisselq	`#ifndef SKIP_SHORT_CIRCUITS`
397			`BUSY.Z`
398	41	dgisselq	`#endif`
399	57	dgisselq	`#endif`
400	41	dgisselq
401			`CMP 3,R5`
402			`#ifndef SKIP_SHORT_CIRCUITS`
403			`BUSY.LT`
404			`#endif`
405			`BLT func_2_top_while_loop`
406
407			`func_2_end_while_loop:`
408
409			`// CMP 'W',R7 // BUT! We know lcl_ch='A'`
410			`// BLT skip_if // So we can skip this`
411			`// CMP 'Z',R7 // entire section`
412			`// LDI.LT 7,R5`
413			`// CMP 'R',R7`
414			`// BNZ alt_if_case`
415			`// LLO.Z 1,R0`
416			`// BRA func_2_return_and_cleanup`
417			`//`
418			`MOV R3,R0`
419			`MOV R4,R1`
420			`MOV __HERE__+3(PC),R2`
421			`STO R2,1(SP)`
422			`BRA lcl_strcmp`
423			`CMP 0,R0`
424			`BGT func_2_final_then`
425			`CLR R0`
426			`BRA func_2_return_and_cleanup`
427			`func_2_final_then:`
428			`// ADD 7,R5 ; Never read, so useless code`
429			`LDI 1,R0`
430			`#ifndef SKIP_SHORT_CIRCUITS`
431			`BUSY`
432			`#endif`
433			`func_2_return_and_cleanup:`
434
435			`LOD 2(SP),R3`
436			`LOD 3(SP),R4`
437			`LOD 4(SP),R5`
438			`LOD 5(SP),R6`
439			`LOD 6(SP),R7`
440			`ADD 6,SP`
441			`RETN`
442
443			`//bool func_3(test_enum a) {`
444			`// test_enum lcl_enum;`
445			`//`
446			`// lcl_enum = a;`
447			`// if (lcl_enum == Ident_3)`
448			`// return true;`
449			`// else`
450			`// return false;`
451			`//}`
452
453			`#ifdef NO_INLINE`
454			`func_3:`
455			`; On entry,`
456			`; R0 = a`
457			`; R1 - available`
458			`CMP 2,R0`
459			`CLR R0 ; CLR Doesn't set flags`
460			`LDILO.Z 1,R0`
461			`RETN`
462			`#endif`
463
464
465			`// void proc_6(test_enum ev, test_enum *ep) {`
466			`// *ep = ev;`
467			`// if (!func_3(ev))`
468			`// *ep = 3;`
469			`// switch(ev) {`
470			`// case 0: *ep = 0; break;`
471			`// case 1:`
472			`// if (gbl_int > 100)`
473			`// *ep = 0;`
474			`// else`
475			`// *ep = 3;`
476			`// break;`
477			`// case 2:`
478			`// *ep = 1;`
479			`// break;`
480			`// case 3:`
481			`// break;`
482			`// case 4:`
483			`// *ep = 2;`
484			`// }`
485			`//}`
486
487			`proc_6:`
488			`; On entry:`
489			`; R0 = ev`
490			`; R1 = ep`
491			`; R2 - unassigned`
492			`; Since we call func_3, we have to reserve R0 and R1`
493			`; for other purposes. Thus`
494			`; R2 = ev`
495			`; R3 = ep`
496			`SUB 2,SP`
497			`STO R3,2(SP)`
498
499			`MOV R1,R3`
500			`MOV R0,R2`

Browse

Tools

Subversion Repositories zipcpu

[/] [zipcpu/] [trunk/] [bench/] [asm/] [zipdhry.S] - Blame information for rev 66