Subversion Repositories neo430

-- #################################################################################################

-- #  << NEO430 - Bootloader ROM >>                                                                #

-- # ********************************************************************************************* #

-- # This memory includes the in-place executable image of the NEO430 bootloader. See the          #

-- # processor's documentary to get more information.                                              #

-- # ********************************************************************************************* #

-- # BSD 3-Clause License                                                                          #

-- #                                                                                               #

-- # Copyright (c) 2020, Stephan Nolting. All rights reserved.                                     #

-- #                                                                                               #

-- # Redistribution and use in source and binary forms, with or without modification, are          #

-- # permitted provided that the following conditions are met:                                     #

-- #                                                                                               #

-- # 1. Redistributions of source code must retain the above copyright notice, this list of        #

-- #    conditions and the following disclaimer.                                                   #

-- #                                                                                               #

-- # 2. Redistributions in binary form must reproduce the above copyright notice, this list of     #

-- #    conditions and the following disclaimer in the documentation and/or other materials        #

-- #    provided with the distribution.                                                            #

-- #                                                                                               #

-- # 3. Neither the name of the copyright holder nor the names of its contributors may be used to  #

-- #    endorse or promote products derived from this software without specific prior written      #

-- #    permission.                                                                                #

-- #                                                                                               #

-- # THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS" AND ANY EXPRESS   #

-- # OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF               #

-- # MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE    #

-- # COPYRIGHT HOLDER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL,     #

-- # EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE #

-- # GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED    #

-- # AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING     #

-- # NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED  #

-- # OF THE POSSIBILITY OF SUCH DAMAGE.                                                            #

-- # ********************************************************************************************* #

-- # The NEO430 Processor - https://github.com/stnolting/neo430                                    #

-- #################################################################################################

library ieee;

use ieee.std_logic_1164.all;

use ieee.numeric_std.all;

library neo430;

use neo430.neo430_package.all;

use neo430.neo430_bootloader_image.all; -- this file is generated by the image generator

entity neo430_boot_rom is

  port (

    clk_i  : in  std_ulogic; -- global clock line

    rden_i : in  std_ulogic; -- read enable

    addr_i : in  std_ulogic_vector(15 downto 0); -- address

    data_o : out std_ulogic_vector(15 downto 0)  -- data out

  );

end neo430_boot_rom;

architecture neo430_boot_rom_rtl of neo430_boot_rom is

  -- local types --

  type boot_img_t is array (0 to boot_size_c/2-1) of std_ulogic_vector(15 downto 0);

  -- init function --

  impure function init_boot_rom(init : bootloader_init_image_t) return boot_img_t is

    variable mem_v : boot_img_t;

  begin

    for i in 0 to boot_size_c/2-1 loop

      mem_v(i) := init(i);

    end loop; -- i

    return mem_v;

  end function init_boot_rom;

  -- local signals --

  signal acc_en : std_ulogic;

  signal rden   : std_ulogic;

  signal rdata  : std_ulogic_vector(15 downto 0);

  signal addr   : natural range 0 to boot_size_c/2-1;

  -- bootloader image --

  constant boot_img : boot_img_t := init_boot_rom(bootloader_init_image);

begin

  -- Access Control -----------------------------------------------------------

  -- -----------------------------------------------------------------------------

  acc_en <= '1' when (addr_i >= boot_base_c) and (addr_i < std_ulogic_vector(unsigned(boot_base_c) + boot_size_c)) else '0';

  addr <= to_integer(unsigned(addr_i(index_size_f(boot_size_c/2) downto 1))); -- word aligned

  -- Memory Access ------------------------------------------------------------

  -- -----------------------------------------------------------------------------

  mem_file_access: process(clk_i)

  begin

    -- check max size --

    if (boot_size_c > boot_max_size_c) then

      assert false report "Boot ROM size out of range! Max 2kB!" severity error;

    end if;

    if rising_edge(clk_i) then

      rden <= rden_i and acc_en;

      if (acc_en = '1') then -- reduce switching activity when not accessed

        rdata <= boot_img(addr);

      end if;

    end if;

  end process mem_file_access;

  -- output gate --

  data_o <= rdata when (rden = '1') else (others => '0');

end neo430_boot_rom_rtl;