URL https://opencores.org/ocsvn/neorv32/neorv32/trunk

Subversion Repositories neorv32

[/] [neorv32/] [trunk/] [sw/] [common/] [crt0.S] - Blame information for rev 61

Go to most recent revision | Details | Compare with Previous | View Log


/* ################################################################################################# */
/* # << NEORV32 - crt0.S - Start-Up Code >>                                                        # */
/* # ********************************************************************************************* # */
/* # BSD 3-Clause License                                                                          # */
/* #                                                                                               # */
/* # Copyright (c) 2021, Stephan Nolting. All rights reserved.                                     # */
/* #                                                                                               # */
/* # Redistribution and use in source and binary forms, with or without modification, are          # */
/* # permitted provided that the following conditions are met:                                     # */
/* #                                                                                               # */
/* # 1. Redistributions of source code must retain the above copyright notice, this list of        # */
/* #    conditions and the following disclaimer.                                                   # */
/* #                                                                                               # */
/* # 2. Redistributions in binary form must reproduce the above copyright notice, this list of     # */
/* #    conditions and the following disclaimer in the documentation and/or other materials        # */
/* #    provided with the distribution.                                                            # */
/* #                                                                                               # */
/* # 3. Neither the name of the copyright holder nor the names of its contributors may be used to  # */
/* #    endorse or promote products derived from this software without specific prior written      # */
/* #    permission.                                                                                # */
/* #                                                                                               # */
/* # THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS" AND ANY EXPRESS   # */
/* # OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF               # */
/* # MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE    # */
/* # COPYRIGHT HOLDER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL,     # */
/* # EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE # */
/* # GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED    # */
/* # AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING     # */
/* # NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED  # */
/* # OF THE POSSIBILITY OF SUCH DAMAGE.                                                            # */
/* # ********************************************************************************************* # */
/* # The NEORV32 Processor - https://github.com/stnolting/neorv32              (c) Stephan Nolting # */
/* ################################################################################################# */
 
.file   "crt0.S"
.section .text.boot
.balign 4
.global _start
 
 
_start:
.cfi_startproc
.cfi_undefined ra
 
  nop
 
// ************************************************************************************************
// Setup pointers using linker script symbols
// ************************************************************************************************
__crt0_pointer_init:
  .option push
  .option norelax
 
  la sp, __crt0_stack_begin  // stack pointer
  la gp, __global_pointer$   // global pointer
 
  .option pop
 
 
// ************************************************************************************************
// Setup CPU core CSRs (some of them DO NOT have a dedicated
// reset and need to be explicitly initialized)
// ************************************************************************************************
__crt0_cpu_csr_init:
 
  la   x10,   __crt0_dummy_trap_handler // configure early trap handler
  csrw mtvec, x10
  csrw mepc,  x10                       // just to init mepc
 
  csrw mstatus, zero                    // disable global IRQ
 
  csrw mie, zero                        // absolutely no interrupts sources, thanks
 
  csrw mcounteren, zero                 // no access from less-privileged modes to counter CSRs
 
  li   x11,   ~5                        // stop all counters except for [m]cycle[h] and [m]instret[h]
  csrw 0x320, x11                       // = mcountinhibit (literal address for lagacy toolchain compatibility)
 
  csrw mcycle,    zero                  // reset cycle counters
  csrw mcycleh,   zero
  csrw minstret,  zero                  // reset instruction counters
  csrw minstreth, zero
 
#if defined(__riscv_flen)
  csrw fcsr, zero                       // reset floating-point CSR
#endif
 
 
// ************************************************************************************************
// Initialize integer register file (lower half)
// ************************************************************************************************
__crt0_reg_file_clear:
//addi  x0, x0, 0 // hardwired to zero
  addi  x1, x0, 0
//addi  x2, x0, 0 // stack pointer sp
//addi  x3, x0, 0 // gloabl pointer gp
  addi  x4, x0, 0
  addi  x5, x0, 0
  addi  x6, x0, 0
  addi  x7, x0, 0
//addi  x8, x0, 0 // initialized within crt0
//addi  x9, x0, 0 // initialized within crt0
//addi x10, x0, 0 // initialized within crt0
//addi x11, x0, 0 // initialized within crt0
//addi x12, x0, 0 // initialized within crt0
//addi x13, x0, 0 // initialized within crt0
  addi x14, x0, 0
  addi x15, x0, 0
 
 
// ************************************************************************************************
// Initialize integer register file (upper half, if no E extension)
// ************************************************************************************************
#ifndef __riscv_32e
// do not do this if compiling bootloader (to save some program space)
#ifndef make_bootloader
  addi x16, x0, 0
  addi x17, x0, 0
  addi x18, x0, 0
  addi x19, x0, 0
  addi x20, x0, 0
  addi x21, x0, 0
  addi x22, x0, 0
  addi x23, x0, 0
  addi x24, x0, 0
  addi x25, x0, 0
  addi x26, x0, 0
  addi x27, x0, 0
  addi x28, x0, 0
  addi x29, x0, 0
  addi x30, x0, 0
  addi x31, x0, 0
#endif
#endif
 
 
// ************************************************************************************************
// Reset/deactivate IO/peripheral devices
// Devices, that are not implemented, will cause a store bus access fault
// which is captured (but actually ignored) by the dummy trap handler.
// ************************************************************************************************
__crt0_reset_io:
  la   x8,   __ctr0_io_space_begin         // start of processor-internal IO region
  la   x9,   __ctr0_io_space_end           // end of processor-internal IO region
 
__crt0_reset_io_loop:
  sw   zero, 0(x8)
  addi x8,   x8, 4
  bne  x8,   x9, __crt0_reset_io_loop
 
 
// ************************************************************************************************
// Clear .bss section (byte-wise) using linker script symbols
// ************************************************************************************************
__crt0_clear_bss:
  la   x11,  __crt0_bss_start
  la   x12,  __crt0_bss_end
 
__crt0_clear_bss_loop:
  bge  x11,  x12, __crt0_clear_bss_loop_end
  sb   zero, 0(x11)
  addi x11,  x11, 1
  j    __crt0_clear_bss_loop
 
__crt0_clear_bss_loop_end:
 
 
// ************************************************************************************************
// Copy initialized .data section from ROM to RAM (byte-wise) using linker script symbols
// ************************************************************************************************
__crt0_copy_data:
  la   x11, __crt0_copy_data_src_begin        // start of data area (copy source)
  la   x12, __crt0_copy_data_dst_begin        // start of data area (copy destination)
  la   x13, __crt0_copy_data_dst_end          // last address of destination data area
 
__crt0_copy_data_loop:
  bge  x12, x13,  __crt0_copy_data_loop_end
  lb   x14, 0(x11)
  sb   x14, 0(x12)
  addi x11, x11, 1
  addi x12, x12, 1
  j    __crt0_copy_data_loop
 
__crt0_copy_data_loop_end:
 
 
// ************************************************************************************************
// Setup arguments and call main function
// ************************************************************************************************
__crt0_main_entry:
  addi x10, zero, 0 // a0 = argc = 0
  addi x11, zero, 0 // a1 = argv = 0
  jal  ra,  main    // call actual app's main function, this "should" not return
 
 
// ************************************************************************************************
// call "after main" handler (if there is any) if main really returns
// ************************************************************************************************
__crt0_main_aftermath:
  csrw  mscratch, a0                 // copy main's return code in mscratch for debugger
 
#ifndef make_bootloader              // after_main handler not supported for bootloader
  .weak __neorv32_crt0_after_main
  la   ra, __neorv32_crt0_after_main
  beqz ra, __crt0_main_aftermath_end // check if an aftermath handler has been specified
  jalr ra                            // execute handler, main's return code in a0
#endif
 
 
// ************************************************************************************************
// go to endless sleep mode
// ************************************************************************************************
__crt0_main_aftermath_end:
  csrci mstatus,  8                  // mstatus: disable global IRQs (mstatus.mie)
__crt0_main_aftermath_end_loop:
  wfi                                // try to go to sleep mode
  j __crt0_main_aftermath_end_loop   // endless loop
 
 
// ************************************************************************************************
// dummy trap handler (for exceptions & IRQs during very early boot stage)
// does nothing but tries to move on to next instruction
// ************************************************************************************************
.balign 4
__crt0_dummy_trap_handler:
 
  addi  sp,   sp, -8
  sw      x8,   0(sp)
  sw      x9,   4(sp)
 
  csrr  x8,   mcause
  blt   x8,   zero, __crt0_dummy_trap_handler_irq  // skip mepc modification if interrupt
 
  csrr  x8,   mepc
 
__crt0_dummy_trap_handler_exc_c_check:             // is compressed instruction?
  lh    x9,   0(x8)                                // get compressed instruction or lower 16 bits of uncompressed instruction that caused exception
  andi  x9,   x9, 3                                // mask: isolate lowest 2 opcode bits (= 11 for uncompressed instructions)
 
  addi  x8,   x8, +2                               // only this for compressed instructions
  csrw  mepc, x8                                   // set return address when compressed instruction
 
  addi  x8,   zero, 3
  bne   x8,   x9, __crt0_dummy_trap_handler_irq    // jump if compressed instruction
 
__crt0_dummy_trap_handler_exc_uncrompressed:       // is uncompressed instruction!
  csrr  x8,   mepc
  addi  x8,   x8, +2                               // add another 2 (making +4) for uncompressed instructions
  csrw  mepc, x8
 
__crt0_dummy_trap_handler_irq:
  lw    x8,   0(sp)
  lw    x9,   4(sp)
  addi  sp,   sp, +8
 
  mret
 
.cfi_endproc
.end

Line No.	Rev	Author	Line
1	2	zero_gravi	`/* ################################################################################################# */`
2	21	zero_gravi	`/* # << NEORV32 - crt0.S - Start-Up Code >> # */`
3	2	zero_gravi	`/* # ********************************************************************************************* # */`
4			`/* # BSD 3-Clause License # */`
5			`/* # # */`
6	53	zero_gravi	`/* # Copyright (c) 2021, Stephan Nolting. All rights reserved. # */`
7	2	zero_gravi	`/* # # */`
8			`/* # Redistribution and use in source and binary forms, with or without modification, are # */`
9			`/* # permitted provided that the following conditions are met: # */`
10			`/* # # */`
11			`/* # 1. Redistributions of source code must retain the above copyright notice, this list of # */`
12			`/* # conditions and the following disclaimer. # */`
13			`/* # # */`
14			`/* # 2. Redistributions in binary form must reproduce the above copyright notice, this list of # */`
15			`/* # conditions and the following disclaimer in the documentation and/or other materials # */`
16			`/* # provided with the distribution. # */`
17			`/* # # */`
18			`/* # 3. Neither the name of the copyright holder nor the names of its contributors may be used to # */`
19			`/* # endorse or promote products derived from this software without specific prior written # */`
20			`/* # permission. # */`
21			`/* # # */`
22			`/* # THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS" AND ANY EXPRESS # */`
23			`/* # OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF # */`
24			`/* # MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE # */`
25			`/* # COPYRIGHT HOLDER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, # */`
26			`/* # EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE # */`
27			`/* # GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED # */`
28			`/* # AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING # */`
29			`/* # NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED # */`
30			`/* # OF THE POSSIBILITY OF SUCH DAMAGE. # */`
31			`/* # ********************************************************************************************* # */`
32			`/* # The NEORV32 Processor - https://github.com/stnolting/neorv32 (c) Stephan Nolting # */`
33			`/* ################################################################################################# */`
34
35	21	zero_gravi	`.file "crt0.S"`
36			`.section .text.boot`
37			`.balign 4`
38			`.global _start`
39	2	zero_gravi
40
41			`_start:`
42	21	zero_gravi	`.cfi_startproc`
43			`.cfi_undefined ra`
44	2	zero_gravi
45	59	zero_gravi	`nop`
46
47	61	zero_gravi	`// ************************************************************************************************`
48	56	zero_gravi	`// Setup pointers using linker script symbols`
49	61	zero_gravi	`// ************************************************************************************************`
50	56	zero_gravi	`__crt0_pointer_init:`
51	61	zero_gravi	`.option push`
52			`.option norelax`
53	52	zero_gravi
54	61	zero_gravi	`la sp, __crt0_stack_begin // stack pointer`
55			`la gp, __global_pointer$ // global pointer`
56	52	zero_gravi
57	61	zero_gravi	`.option pop`
58
59
60			`// ************************************************************************************************`
61			`// Setup CPU core CSRs (some of them DO NOT have a dedicated`
62			`// reset and need to be explicitly initialized)`
63			`// ************************************************************************************************`
64	56	zero_gravi	`__crt0_cpu_csr_init:`
65
66	61	zero_gravi	`la x10, __crt0_dummy_trap_handler // configure early trap handler`
67			`csrw mtvec, x10`
68			`csrw mepc, x10 // just to init mepc`
69	56	zero_gravi
70	61	zero_gravi	`csrw mstatus, zero // disable global IRQ`
71	56	zero_gravi
72	61	zero_gravi	`csrw mie, zero // absolutely no interrupts sources, thanks`
73	56	zero_gravi
74	61	zero_gravi	`csrw mcounteren, zero // no access from less-privileged modes to counter CSRs`
75	56	zero_gravi
76	61	zero_gravi	`li x11, ~5 // stop all counters except for [m]cycle[h] and [m]instret[h]`
77			`csrw 0x320, x11 // = mcountinhibit (literal address for lagacy toolchain compatibility)`
78	56	zero_gravi
79	61	zero_gravi	`csrw mcycle, zero // reset cycle counters`
80			`csrw mcycleh, zero`
81			`csrw minstret, zero // reset instruction counters`
82	56	zero_gravi	`csrw minstreth, zero`
83
84	61	zero_gravi	`#if defined(__riscv_flen)`
85			`csrw fcsr, zero // reset floating-point CSR`
86	56	zero_gravi	`#endif`
87
88
89	61	zero_gravi	`// ************************************************************************************************`
90			`// Initialize integer register file (lower half)`
91			`// ************************************************************************************************`
92			`__crt0_reg_file_clear:`
93			`//addi x0, x0, 0 // hardwired to zero`
94			`addi x1, x0, 0`
95			`//addi x2, x0, 0 // stack pointer sp`
96			`//addi x3, x0, 0 // gloabl pointer gp`
97			`addi x4, x0, 0`
98			`addi x5, x0, 0`
99			`addi x6, x0, 0`
100			`addi x7, x0, 0`
101			`//addi x8, x0, 0 // initialized within crt0`
102			`//addi x9, x0, 0 // initialized within crt0`
103			`//addi x10, x0, 0 // initialized within crt0`
104			`//addi x11, x0, 0 // initialized within crt0`
105			`//addi x12, x0, 0 // initialized within crt0`
106			`//addi x13, x0, 0 // initialized within crt0`
107			`addi x14, x0, 0`
108			`addi x15, x0, 0`
109
110
111			`// ************************************************************************************************`
112			`// Initialize integer register file (upper half, if no E extension)`
113			`// ************************************************************************************************`
114	32	zero_gravi	`#ifndef __riscv_32e`
115	61	zero_gravi	`// do not do this if compiling bootloader (to save some program space)`
116	32	zero_gravi	`#ifndef make_bootloader`
117			`addi x16, x0, 0`
118			`addi x17, x0, 0`
119			`addi x18, x0, 0`
120			`addi x19, x0, 0`
121			`addi x20, x0, 0`
122			`addi x21, x0, 0`
123			`addi x22, x0, 0`
124			`addi x23, x0, 0`
125			`addi x24, x0, 0`
126			`addi x25, x0, 0`
127			`addi x26, x0, 0`
128			`addi x27, x0, 0`
129			`addi x28, x0, 0`
130			`addi x29, x0, 0`
131			`addi x30, x0, 0`
132			`addi x31, x0, 0`
133			`#endif`
134			`#endif`
135
136
137	61	zero_gravi	`// ************************************************************************************************`
138	2	zero_gravi	`// Reset/deactivate IO/peripheral devices`
139	61	zero_gravi	`// Devices, that are not implemented, will cause a store bus access fault`
140			`// which is captured (but actually ignored) by the dummy trap handler.`
141			`// ************************************************************************************************`
142	2	zero_gravi	`__crt0_reset_io:`
143	61	zero_gravi	`la x8, __ctr0_io_space_begin // start of processor-internal IO region`
144			`la x9, __ctr0_io_space_end // end of processor-internal IO region`
145	2	zero_gravi
146			`__crt0_reset_io_loop:`
147	58	zero_gravi	`sw zero, 0(x8)`
148			`addi x8, x8, 4`
149			`bne x8, x9, __crt0_reset_io_loop`
150	2	zero_gravi
151
152	61	zero_gravi	`// ************************************************************************************************`
153	23	zero_gravi	`// Clear .bss section (byte-wise) using linker script symbols`
154	61	zero_gravi	`// ************************************************************************************************`
155	2	zero_gravi	`__crt0_clear_bss:`
156	61	zero_gravi	`la x11, __crt0_bss_start`
157			`la x12, __crt0_bss_end`
158	2	zero_gravi
159			`__crt0_clear_bss_loop:`
160	61	zero_gravi	`bge x11, x12, __crt0_clear_bss_loop_end`
161	2	zero_gravi	`sb zero, 0(x11)`
162	61	zero_gravi	`addi x11, x11, 1`
163	2	zero_gravi	`j __crt0_clear_bss_loop`
164
165			`__crt0_clear_bss_loop_end:`
166
167
168	61	zero_gravi	`// ************************************************************************************************`
169	23	zero_gravi	`// Copy initialized .data section from ROM to RAM (byte-wise) using linker script symbols`
170	61	zero_gravi	`// ************************************************************************************************`
171	2	zero_gravi	`__crt0_copy_data:`
172	61	zero_gravi	`la x11, __crt0_copy_data_src_begin // start of data area (copy source)`
173			`la x12, __crt0_copy_data_dst_begin // start of data area (copy destination)`
174			`la x13, __crt0_copy_data_dst_end // last address of destination data area`
175	2	zero_gravi
176			`__crt0_copy_data_loop:`
177			`bge x12, x13, __crt0_copy_data_loop_end`
178			`lb x14, 0(x11)`
179			`sb x14, 0(x12)`
180			`addi x11, x11, 1`
181			`addi x12, x12, 1`
182			`j __crt0_copy_data_loop`
183
184			`__crt0_copy_data_loop_end:`
185
186
187	61	zero_gravi	`// ************************************************************************************************`
188			`// Setup arguments and call main function`
189			`// ************************************************************************************************`
190	2	zero_gravi	`__crt0_main_entry:`
191	61	zero_gravi	`addi x10, zero, 0 // a0 = argc = 0`
192			`addi x11, zero, 0 // a1 = argv = 0`
193			`jal ra, main // call actual app's main function, this "should" not return`
194	2	zero_gravi
195
196	61	zero_gravi	`// ************************************************************************************************`
197			`// call "after main" handler (if there is any) if main really returns`
198			`// ************************************************************************************************`
199			`__crt0_main_aftermath:`
200			`csrw mscratch, a0 // copy main's return code in mscratch for debugger`
201	2	zero_gravi
202	61	zero_gravi	`#ifndef make_bootloader // after_main handler not supported for bootloader`
203			`.weak __neorv32_crt0_after_main`
204			`la ra, __neorv32_crt0_after_main`
205			`beqz ra, __crt0_main_aftermath_end // check if an aftermath handler has been specified`
206			`jalr ra // execute handler, main's return code in a0`
207			`#endif`
208	2	zero_gravi
209
210	61	zero_gravi	`// ************************************************************************************************`
211			`// go to endless sleep mode`
212			`// ************************************************************************************************`
213			`__crt0_main_aftermath_end:`
214			`csrci mstatus, 8 // mstatus: disable global IRQs (mstatus.mie)`
215			`__crt0_main_aftermath_end_loop:`
216			`wfi // try to go to sleep mode`
217			`j __crt0_main_aftermath_end_loop // endless loop`
218	2	zero_gravi
219	61	zero_gravi
220			`// ************************************************************************************************`
221			`// dummy trap handler (for exceptions & IRQs during very early boot stage)`
222			`// does nothing but tries to move on to next instruction`
223			`// ************************************************************************************************`
224	21	zero_gravi	`.balign 4`
225	14	zero_gravi	`__crt0_dummy_trap_handler:`
226	2	zero_gravi
227	61	zero_gravi	`addi sp, sp, -8`
228			`sw x8, 0(sp)`
229			`sw x9, 4(sp)`
230	2	zero_gravi
231	61	zero_gravi	`csrr x8, mcause`
232			`blt x8, zero, __crt0_dummy_trap_handler_irq // skip mepc modification if interrupt`
233	2	zero_gravi
234	61	zero_gravi	`csrr x8, mepc`
235	2	zero_gravi
236	61	zero_gravi	`__crt0_dummy_trap_handler_exc_c_check: // is compressed instruction?`
237			`lh x9, 0(x8) // get compressed instruction or lower 16 bits of uncompressed instruction that caused exception`
238			`andi x9, x9, 3 // mask: isolate lowest 2 opcode bits (= 11 for uncompressed instructions)`
239	2	zero_gravi
240	61	zero_gravi	`addi x8, x8, +2 // only this for compressed instructions`
241			`csrw mepc, x8 // set return address when compressed instruction`
242	2	zero_gravi
243	61	zero_gravi	`addi x8, zero, 3`
244			`bne x8, x9, __crt0_dummy_trap_handler_irq // jump if compressed instruction`
245
246			`__crt0_dummy_trap_handler_exc_uncrompressed: // is uncompressed instruction!`
247			`csrr x8, mepc`
248			`addi x8, x8, +2 // add another 2 (making +4) for uncompressed instructions`
249	14	zero_gravi	`csrw mepc, x8`
250	2	zero_gravi
251	14	zero_gravi	`__crt0_dummy_trap_handler_irq:`
252	61	zero_gravi	`lw x8, 0(sp)`
253			`lw x9, 4(sp)`
254			`addi sp, sp, +8`
255	2	zero_gravi
256			`mret`
257
258	21	zero_gravi	`.cfi_endproc`
259			`.end`

Browse

Tools

Subversion Repositories neorv32

[/] [neorv32/] [trunk/] [sw/] [common/] [crt0.S] - Blame information for rev 61