URL https://opencores.org/ocsvn/qspiflash/qspiflash/trunk

Subversion Repositories qspiflash

[/] [qspiflash/] [trunk/] [rtl/] [wbqspiflash.v] - Blame information for rev 16

Go to most recent revision | Details | Compare with Previous | View Log


////////////////////////////////////////////////////////////////////////////////
//
// Filename:    wbspiflash.v
//
// Project:     Wishbone Controlled Quad SPI Flash Controller
//
// Purpose:     Access a Quad SPI flash via a WISHBONE interface.  This
//              includes both read and write (and erase) commands to the SPI
//              flash.  All read/write commands are accomplished using the
//              high speed (4-bit) interface.  Further, the device will be
//              left/kept in the 4-bit read interface mode between accesses,
//              for a minimum read latency.
//
//      Wishbone Registers (See spec sheet for more detail):
//      0: local config(r) / erase commands(w) / deep power down cmds / etc.
//      R: (Write in Progress), (dirty-block), (spi_port_busy), 1'b0, 9'h00,
//              { last_erased_sector, 14'h00 } if (WIP)
//              else { current_sector_being_erased, 14'h00 }
//              current if write in progress, last if written
//      W: (1'b1 to erase), (12'h ignored), next_erased_block, 14'h ignored)
//      1: Configuration register
//      2: Status register (R/w)
//      3: Read ID (read only)
//      (19 bits): Data (R/w, but expect writes to take a while)
//              
//
// Creator:     Dan Gisselquist, Ph.D.
//              Gisselquist Technology, LLC
//
////////////////////////////////////////////////////////////////////////////////
//
// Copyright (C) 2015,2017, Gisselquist Technology, LLC
//
// This program is free software (firmware): you can redistribute it and/or
// modify it under the terms of  the GNU General Public License as published
// by the Free Software Foundation, either version 3 of the License, or (at
// your option) any later version.
//
// This program is distributed in the hope that it will be useful, but WITHOUT
// ANY WARRANTY; without even the implied warranty of MERCHANTIBILITY or
// FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
// for more details.
//
// You should have received a copy of the GNU General Public License along
// with this program.  (It's in the $(ROOT)/doc directory.  Run make with no
// target there if the PDF file isn't present.)  If not, see
// <http://www.gnu.org/licenses/> for a copy.
//
// License:     GPL, v3, as defined and found on www.gnu.org,
//              http://www.gnu.org/licenses/gpl.html
//
//
////////////////////////////////////////////////////////////////////////////////
//
`include "flash_config.v"
`default_nettype        none
//
`define WBQSPI_RESET            5'd0
`define WBQSPI_RESET_QUADMODE   5'd1
`define WBQSPI_IDLE             5'd2
`define WBQSPI_RDIDLE           5'd3    // Idle, but in fast read mode
`define WBQSPI_WBDECODE         5'd4
`define WBQSPI_RD_DUMMY         5'd5
`define WBQSPI_QRD_ADDRESS      5'd6
`define WBQSPI_QRD_DUMMY        5'd7
`define WBQSPI_READ_CMD         5'd8
`define WBQSPI_READ_DATA        5'd9
`define WBQSPI_WAIT_TIL_RDIDLE  5'd10
`define WBQSPI_READ_ID_CMD      5'd11
`define WBQSPI_READ_ID          5'd12
`define WBQSPI_READ_STATUS      5'd13
`define WBQSPI_READ_CONFIG      5'd14
`define WBQSPI_WAIT_TIL_IDLE    5'd15
//
//
`ifndef READ_ONLY
//
`define WBQSPI_WAIT_WIP_CLEAR   5'd16
`define WBQSPI_CHECK_WIP_CLEAR  5'd17
`define WBQSPI_CHECK_WIP_DONE   5'd18
`define WBQSPI_WEN              5'd19
`define WBQSPI_PP               5'd20   // Program page
`define WBQSPI_QPP              5'd21   // Program page, 4 bit mode
`define WBQSPI_WR_DATA          5'd22
`define WBQSPI_WR_BUS_CYCLE     5'd23
`define WBQSPI_WRITE_STATUS     5'd24
`define WBQSPI_WRITE_CONFIG     5'd25
`define WBQSPI_ERASE_WEN        5'd26
`define WBQSPI_ERASE_CMD        5'd27
`define WBQSPI_ERASE_BLOCK      5'd28
`define WBQSPI_CLEAR_STATUS     5'd29
`define WBQSPI_IDLE_CHECK_WIP   5'd30
//
`endif
 
module  wbqspiflash(i_clk,
                // Internal wishbone connections
                i_wb_cyc, i_wb_data_stb, i_wb_ctrl_stb, i_wb_we,
                i_wb_addr, i_wb_data,
                // Wishbone return values
                o_wb_ack, o_wb_stall, o_wb_data,
                // Quad Spi connections to the external device
                o_qspi_sck, o_qspi_cs_n, o_qspi_mod, o_qspi_dat, i_qspi_dat,
                o_interrupt);
        parameter       ADDRESS_WIDTH=22;
        localparam      AW = ADDRESS_WIDTH-2;
        input   wire            i_clk;
        // Wishbone, inputs first
        input   wire            i_wb_cyc, i_wb_data_stb, i_wb_ctrl_stb, i_wb_we;
        input   wire    [(AW-1):0]       i_wb_addr;
        input   wire    [31:0]   i_wb_data;
        // then outputs
        output  reg             o_wb_ack;
        output  reg             o_wb_stall;
        output  reg     [31:0]   o_wb_data;
        // Quad SPI control wires
        output  wire            o_qspi_sck, o_qspi_cs_n;
        output  wire    [1:0]    o_qspi_mod;
        output  wire    [3:0]    o_qspi_dat;
        input   wire    [3:0]    i_qspi_dat;
        // Interrupt line
        output  reg             o_interrupt;
        // output       wire    [31:0]  o_debug;
 
        reg             spi_wr, spi_hold, spi_spd, spi_dir;
        reg     [31:0]   spi_in;
        reg     [1:0]    spi_len;
        wire    [31:0]   spi_out;
        wire            spi_valid, spi_busy;
        wire            w_qspi_sck, w_qspi_cs_n;
        wire    [3:0]    w_qspi_dat;
        wire    [1:0]    w_qspi_mod;
        // wire [22:0]  spi_dbg;
        llqspi  lldriver(i_clk,
                        spi_wr, spi_hold, spi_in, spi_len, spi_spd, spi_dir,
                                spi_out, spi_valid, spi_busy,
                        w_qspi_sck, w_qspi_cs_n, w_qspi_mod, w_qspi_dat,
                                i_qspi_dat);
 
        // Erase status tracking
        reg             write_in_progress, write_protect;
        reg     [(ADDRESS_WIDTH-17):0]   erased_sector;
        reg             dirty_sector;
        initial begin
                write_in_progress = 1'b0;
                erased_sector = 0;
                dirty_sector  = 1'b1;
                write_protect = 1'b1;
        end
 
        wire    [23:0]   w_wb_addr;
        generate
        if (ADDRESS_WIDTH>=24)
                assign w_wb_addr = { i_wb_addr[21:0], 2'b00 };
        else
                assign w_wb_addr = { {(24-ADDRESS_WIDTH){1'b0}}, i_wb_addr, 2'b00 };
        endgenerate
 
        // Repeat for spif_addr
        reg     [(ADDRESS_WIDTH-3):0]    spif_addr;
        wire    [23:0]   w_spif_addr;
        generate
        if (ADDRESS_WIDTH>=24)
                assign w_spif_addr = { spif_addr[21:0], 2'b00 };
        else
                assign w_spif_addr = { {(24-ADDRESS_WIDTH){1'b0}}, spif_addr, 2'b00 };
        endgenerate
 
        reg     [7:0]    last_status;
        reg     [9:0]    reset_counter;
        reg             quad_mode_enabled;
        reg             spif_cmd, spif_override;
        reg     [31:0]   spif_data;
        reg     [4:0]    state;
        reg             spif_ctrl, spif_req;
        reg             alt_cmd, alt_ctrl;
        wire    [(ADDRESS_WIDTH-17):0]   spif_sector;
        assign  spif_sector = spif_addr[(AW-1):14];
 
        // assign       o_debug = { spi_wr, spi_spd, spi_hold, state, spi_dbg };
 
        initial state = `WBQSPI_RESET;
        initial o_wb_ack   = 1'b0;
        initial o_wb_stall = 1'b1;
        initial spi_wr     = 1'b0;
        initial spi_len    = 2'b00;
        initial quad_mode_enabled = 1'b0;
        initial o_interrupt = 1'b0;
        initial spif_override = 1'b1;
        initial spif_ctrl     = 1'b0;
        always @(posedge i_clk)
        begin
        spif_override <= 1'b0;
        alt_cmd  <= (reset_counter[9:8]==2'b10)?reset_counter[3]:1'b1; // Toggle CS_n
        alt_ctrl <= (reset_counter[9:8]==2'b10)?reset_counter[0]:1'b1; // Toggle clock too
        if (state == `WBQSPI_RESET)
        begin
                // From a reset, we should
                //      Enable the Quad I/O mode
                //      Disable the Write protection bits in the status register
                //      Chip should already be up and running, so we can start
                //      immediately ....
                o_wb_ack <= 1'b0;
                o_wb_stall <= 1'b1;
                spi_wr   <= 1'b0;
                spi_hold <= 1'b0;
                spi_spd  <= 1'b0;
                spi_dir  <= 1'b0;
                last_status <= 8'h00;
                state <= `WBQSPI_RESET_QUADMODE;
                spif_req <= 1'b0;
                spif_override <= 1'b1;
                last_status   <= 8'h00; //
                reset_counter <= 10'h3fc; //
                        // This guarantees that we aren't starting in quad
                        // I/O mode, where the FPGA configuration scripts may
                        // have left us.
        end else if (state == `WBQSPI_RESET_QUADMODE)
        begin
                // Okay, so here's the problem: we don't know whether or not
                // the Xilinx loader started us up in Quad Read I/O idle mode.
                // So, thus we need to toggle the clock and CS_n, with fewer
                // clocks than are necessary to transmit a word.
                //
                // Not ready to handle the bus yet, so stall any requests
                o_wb_ack   <= 1'b0;
                o_wb_stall <= 1'b1;
 
                // Do something ...
                if (reset_counter == 10'h00)
                begin
                        spif_override <= 1'b0;
                        state <= `WBQSPI_IDLE;
 
                        // Find out if we can use Quad I/O mode ...
                        state <= `WBQSPI_READ_CONFIG;
                        spi_wr <= 1'b1;
                        spi_len <= 2'b01;
                        spi_in <= { 8'h35, 24'h00};
 
                end else begin
                        reset_counter <= reset_counter - 10'h1;
                        spif_override <= 1'b1;
                end
        end else if (state == `WBQSPI_IDLE)
        begin
                o_interrupt <= 1'b0;
                o_wb_stall <= 1'b0;
                o_wb_ack <= 1'b0;
                spif_cmd   <= i_wb_we;
                spif_addr  <= i_wb_addr;
                spif_data  <= i_wb_data;
                spif_ctrl  <= (i_wb_ctrl_stb)&&(~i_wb_data_stb);
                spif_req   <= (i_wb_ctrl_stb)||(i_wb_data_stb);
                spi_wr <= 1'b0; // Keep the port idle, unless told otherwise
                spi_hold <= 1'b0;
                spi_spd  <= 1'b0;
                spi_dir <= 1'b0; // Write (for now, 'cause of cmd)
                // Data register access
                if (i_wb_data_stb)
                begin
 
                        if (i_wb_we) // Request to write a page
                        begin
`ifdef  READ_ONLY
                                o_wb_ack <= 1'b1;
                                o_wb_stall <= 1'b0;
                        end else
`else
                                if((~write_protect)&&(~write_in_progress))
                                begin // 00
                                        spi_wr <= 1'b1;
                                        spi_len <= 2'b00; // 8 bits
                                        // Send a write enable command
                                        spi_in <= { 8'h06, 24'h00 };
                                        state <= `WBQSPI_WEN;
 
                                        o_wb_ack <= 1'b0;
                                        o_wb_stall <= 1'b1;
                                end else if (write_protect)
                                begin // whether or not write-in_progress ...
                                        // Do nothing on a write protect
                                        // violation
                                        //
                                        o_wb_ack <= 1'b1;
                                        o_wb_stall <= 1'b0;
                                end else begin // write is in progress, wait
                                        // for it to complete
                                        state <= `WBQSPI_WAIT_WIP_CLEAR;
                                        o_wb_ack <= 1'b0;
                                        o_wb_stall <= 1'b1;
                                end
                        end else if (~write_in_progress)
`endif
                        begin // Read access, normal mode(s)
                                o_wb_ack   <= 1'b0;
                                o_wb_stall <= 1'b1;
                                spi_wr     <= 1'b1;     // Write cmd to device
                                if (quad_mode_enabled)
                                begin
                                        spi_in <= { 8'heb, w_wb_addr };
                                        state <= `WBQSPI_QRD_ADDRESS;
                                        spi_len    <= 2'b00; // single byte, cmd only
                                end else begin
                                        spi_in <= { 8'h0b, w_wb_addr };
                                        state <= `WBQSPI_RD_DUMMY;
                                        spi_len    <= 2'b11; // cmd+addr,32bits
                                end
`ifndef READ_ONLY
                        end else begin
                                // A write is in progress ... need to stall
                                // the bus until the write is complete.
                                state <= `WBQSPI_WAIT_WIP_CLEAR;
                                o_wb_ack   <= 1'b0;
                                o_wb_stall <= 1'b1;
`endif
                        end
                end else if ((i_wb_ctrl_stb)&&(i_wb_we))
                begin
`ifdef  READ_ONLY
                        o_wb_ack   <= 1'b1;
                        o_wb_stall <= 1'b0;
`else
                        o_wb_stall <= 1'b1;
                        case(i_wb_addr[1:0])
                        2'b00: begin // Erase command register
                                write_protect <= !i_wb_data[28];
                                o_wb_stall <= 1'b0;
 
                                if((i_wb_data[31])&&(!write_in_progress))
                                begin
                                        // Command an erase--ack it immediately
 
                                        o_wb_ack <= 1'b1;
                                        o_wb_stall <= 1'b0;
 
                                        if ((i_wb_data[31])&&(~write_protect))
                                        begin
                                                spi_wr <= 1'b1;
                                                spi_len <= 2'b00;
                                                // Send a write enable command
                                                spi_in <= { 8'h06, 24'h00 };
                                                state <= `WBQSPI_ERASE_CMD;
                                                o_wb_stall <= 1'b1;
                                        end
                                end else if (i_wb_data[31])
                                begin
                                        state <= `WBQSPI_WAIT_WIP_CLEAR;
                                        o_wb_ack   <= 1'b1;
                                        o_wb_stall <= 1'b1;
                                end else
                                        o_wb_ack   <= 1'b1;
                                        o_wb_stall <= 1'b0;
                                end
                        2'b01: begin
                                // Write the configuration register
                                o_wb_ack <= 1'b1;
                                o_wb_stall <= 1'b1;
 
                                // Need to send a write enable command first
                                spi_wr <= 1'b1;
                                spi_len <= 2'b00; // 8 bits
                                // Send a write enable command
                                spi_in <= { 8'h06, 24'h00 };
                                state <= `WBQSPI_WRITE_CONFIG;
                                end
                        2'b10: begin
                                // Write the status register
                                o_wb_ack <= 1'b1; // Ack immediately
                                o_wb_stall <= 1'b1; // Stall other cmds
                                // Need to send a write enable command first
                                spi_wr <= 1'b1;
                                spi_len <= 2'b00; // 8 bits
                                // Send a write enable command
                                spi_in <= { 8'h06, 24'h00 };
                                state <= `WBQSPI_WRITE_STATUS;
                                end
                        2'b11: begin // Write the ID register??? makes no sense
                                o_wb_ack <= 1'b1;
                                o_wb_stall <= 1'b0;
                                end
                        endcase
`endif
                end else if (i_wb_ctrl_stb) // &&(!i_wb_we))
                begin
                        case(i_wb_addr[1:0])
                        2'b00: begin // Read local register
                                if (write_in_progress) // Read status
                                begin// register, is write still in progress?
                                        state <= `WBQSPI_READ_STATUS;
                                        spi_wr <= 1'b1;
                                        spi_len <= 2'b01;// 8 bits out, 8 bits in
                                        spi_in <= { 8'h05, 24'h00};
 
                                        o_wb_ack <= 1'b0;
                                        o_wb_stall <= 1'b1;
                                end else begin // Return w/o talking to device
                                        o_wb_ack <= 1'b1;
                                        o_wb_stall <= 1'b0;
                                        o_wb_data <= { write_in_progress,
                                                dirty_sector, spi_busy,
                                                ~write_protect,
                                                quad_mode_enabled,
                                                {(29-ADDRESS_WIDTH){1'b0}},
                                                erased_sector, 14'h000 };
                                end end
                        2'b01: begin // Read configuration register
                                state <= `WBQSPI_READ_CONFIG;
                                spi_wr <= 1'b1;
                                spi_len <= 2'b01;
                                spi_in <= { 8'h35, 24'h00};
 
                                o_wb_ack <= 1'b0;
                                o_wb_stall <= 1'b1;
                                end
                        2'b10: begin // Read status register
                                state <= `WBQSPI_READ_STATUS;
                                spi_wr <= 1'b1;
                                spi_len <= 2'b01; // 8 bits out, 8 bits in
                                spi_in <= { 8'h05, 24'h00};
 
                                o_wb_ack <= 1'b0;
                                o_wb_stall <= 1'b1;
                                end
                        2'b11: begin // Read ID register
                                state <= `WBQSPI_READ_ID_CMD;
                                spi_wr <= 1'b1;
                                spi_len <= 2'b00;
                                spi_in <= { 8'h9f, 24'h00};
 
                                o_wb_ack <= 1'b0;
                                o_wb_stall <= 1'b1;
                                end
                        endcase
`ifndef READ_ONLY
                end else if ((~i_wb_cyc)&&(write_in_progress))
                begin
                        state <= `WBQSPI_IDLE_CHECK_WIP;
                        spi_wr <= 1'b1;
                        spi_len <= 2'b01; // 8 bits out, 8 bits in
                        spi_in <= { 8'h05, 24'h00};
 
                        o_wb_ack <= 1'b0;
                        o_wb_stall <= 1'b1;
`endif
                end
        end else if (state == `WBQSPI_RDIDLE)
        begin
                spi_wr <= 1'b0;
                o_wb_stall <= 1'b0;
                o_wb_ack <= 1'b0;
                spif_cmd   <= i_wb_we;
                spif_addr  <= i_wb_addr;
                spif_data  <= i_wb_data;
                spif_ctrl  <= (i_wb_ctrl_stb)&&(~i_wb_data_stb);
                spif_req   <= (i_wb_ctrl_stb)||(i_wb_data_stb);
                spi_hold <= 1'b0;
                spi_spd<= 1'b1;
                spi_dir <= 1'b0; // Write (for now)
                if ((i_wb_data_stb)&&(!i_wb_we))
                begin // Continue our read ... send the new address / mode
                        o_wb_stall <= 1'b1;
                        spi_wr <= 1'b1;
                        spi_len <= 2'b10; // Write address, but not mode byte
                        spi_in <= { w_wb_addr, 8'ha0 };
                        state <= `WBQSPI_QRD_DUMMY;
                end else if((i_wb_ctrl_stb)&&(!i_wb_we)&&(i_wb_addr[1:0] == 2'b00))
                begin
                        // A local read that doesn't touch the device, so leave
                        // the device in its current state
                        o_wb_stall <= 1'b0;
                        o_wb_ack <= 1'b1;
                        o_wb_data <= { write_in_progress,
                                        dirty_sector, spi_busy,
                                        ~write_protect,
                                        quad_mode_enabled,
                                        {(29-ADDRESS_WIDTH){1'b0}},
                                        erased_sector, 14'h000 };
                end else if(((i_wb_ctrl_stb)||(i_wb_data_stb)))
                begin // Need to release the device from quad mode for all else
                        o_wb_ack   <= 1'b0;
                        o_wb_stall <= 1'b1;
                        spi_wr <= 1'b1;
                        spi_len <= 2'b11;
                        spi_in <= 32'h00;
                        state <= `WBQSPI_WBDECODE;
                end
        end else if (state == `WBQSPI_WBDECODE)
        begin
                // We were in quad SPI read mode, and had to get out.
                // Now we've got a command (not data read) to read and
                // execute.  Accomplish what we would've done while in the
                // IDLE state here, save only that we don't have to worry
                // about data reads, and we need to operate on a stored
                // version of the bus command
                o_wb_stall <= 1'b1;
                o_wb_ack <= 1'b0;
                spi_wr <= 1'b0; // Keep the port idle, unless told otherwise
                spi_hold <= 1'b0;
                spi_spd <= 1'b0;
                spi_dir <= 1'b0;
                spif_req<= (spif_req) && (i_wb_cyc);
                if ((~spi_busy)&&(o_qspi_cs_n)&&(~spi_wr)) // only in full idle ...
                begin
                        // Data register access
                        if (~spif_ctrl)
                        begin
                                if (spif_cmd) // Request to write a page
                                begin
`ifdef  READ_ONLY
                                        o_wb_ack <= spif_req;
                                        o_wb_stall <= 1'b0;
                                        state <= `WBQSPI_IDLE;
`else
                                        if((~write_protect)&&(~write_in_progress))
                                        begin // 00
                                                spi_wr <= 1'b1;
                                                spi_len <= 2'b00; // 8 bits
                                                // Send a write enable command
                                                spi_in <= { 8'h06, 24'h00 };
                                                state <= `WBQSPI_WEN;
 
                                                o_wb_ack <= 1'b0;
                                                o_wb_stall <= 1'b1;
                                        end else if (write_protect)
                                        begin // whether or not write-in_progress ...
                                                // Do nothing on a write protect
                                                // violation
                                                //
                                                o_wb_ack <= spif_req;
                                                o_wb_stall <= 1'b0;
                                                state <= `WBQSPI_IDLE;
                                        end else begin // write is in progress, wait
                                                // for it to complete
                                                state <= `WBQSPI_WAIT_WIP_CLEAR;
                                                o_wb_ack <= 1'b0;
                                                o_wb_stall <= 1'b1;
                                        end
                                // end else if (~write_in_progress) // always true
                                // but ... we wouldn't get here on a normal read access
`endif
                                end else begin
                                        // Something's wrong, we should never
                                        //   get here
                                        // Attempt to go to idle to recover
                                        state <= `WBQSPI_IDLE;
                                end
                        end else if ((spif_ctrl)&&(spif_cmd))
                        begin
`ifdef  READ_ONLY
                                o_wb_ack   <= spif_req;
                                o_wb_stall <= 1'b0;
                                state <= `WBQSPI_IDLE;
`else
                                o_wb_stall <= 1'b1;
                                case(spif_addr[1:0])
                                2'b00: begin // Erase command register
                                        o_wb_ack   <= spif_req;
                                        o_wb_stall <= 1'b0;
                                        state <= `WBQSPI_IDLE;
                                        write_protect <= ~spif_data[28];
                                        // Are we commanding an erase?
                                        // We're in read mode, writes cannot
                                        // be in progress, so ...
                                        if (spif_data[31]) // Command an erase
                                        begin
                                                // Since we're not going back
                                                // to IDLE, we must stall the
                                                // bus here
                                                o_wb_stall <= 1'b1;
                                                spi_wr <= 1'b1;
                                                spi_len <= 2'b00;
                                                // Send a write enable command
                                                spi_in <= { 8'h06, 24'h00 };
                                                state <= `WBQSPI_ERASE_CMD;
                                        end end
                                2'b01: begin
                                        // Write the configuration register
                                        o_wb_ack <= spif_req;
                                        o_wb_stall <= 1'b1;
 
                                        // Need to send a write enable command first
                                        spi_wr <= 1'b1;
                                        spi_len <= 2'b00; // 8 bits
                                        // Send a write enable command
                                        spi_in <= { 8'h06, 24'h00 };
                                        state <= `WBQSPI_WRITE_CONFIG;
                                        end
                                2'b10: begin
                                        // Write the status register
                                        o_wb_ack <= spif_req; // Ack immediately
                                        o_wb_stall <= 1'b1; // Stall other cmds
                                        // Need to send a write enable command first
                                        spi_wr <= 1'b1;
                                        spi_len <= 2'b00; // 8 bits
                                        // Send a write enable command
                                        spi_in <= { 8'h06, 24'h00 };
                                        state <= `WBQSPI_WRITE_STATUS;
                                        end
                                2'b11: begin // Write the ID register??? makes no sense
                                        o_wb_ack <= spif_req;
                                        o_wb_stall <= 1'b0;
                                        state <= `WBQSPI_IDLE;
                                        end
                                endcase
`endif
                        end else begin // on (~spif_we)
                                case(spif_addr[1:0])
                                2'b00: begin // Read local register
                                        // Nonsense case--would've done this
                                        // already
                                        state <= `WBQSPI_IDLE;
                                        o_wb_ack <= spif_req;
                                        o_wb_stall <= 1'b0;
                                        end
                                2'b01: begin // Read configuration register
                                        state <= `WBQSPI_READ_CONFIG;
                                        spi_wr <= 1'b1;
                                        spi_len <= 2'b01;
                                        spi_in <= { 8'h35, 24'h00};
 
                                        o_wb_ack <= 1'b0;
                                        o_wb_stall <= 1'b1;
                                        end
                                2'b10: begin // Read status register
                                        state <= `WBQSPI_READ_STATUS;
                                        spi_wr <= 1'b1;
                                        spi_len <= 2'b01; // 8 bits out, 8 bits in
                                        spi_in <= { 8'h05, 24'h00};
 
                                        o_wb_ack <= 1'b0;
                                        o_wb_stall <= 1'b1;
                                        end
                                2'b11: begin // Read ID register
                                        state <= `WBQSPI_READ_ID_CMD;
                                        spi_wr <= 1'b1;
                                        spi_len <= 2'b00;
                                        spi_in <= { 8'h9f, 24'h00};
 
                                        o_wb_ack <= 1'b0;
                                        o_wb_stall <= 1'b1;
                                        end
                                endcase
                        end
                end
//
//
//      READ DATA section: for both data and commands
//
        end else if (state == `WBQSPI_RD_DUMMY)
        begin
                o_wb_ack   <= 1'b0;
                o_wb_stall <= 1'b1;
 
                spi_wr <= 1'b1; // Non-stop
                // Need to read one byte of dummy data,
                // just to consume 8 clocks
                spi_in <= { 8'h00, 24'h00 };
                spi_len <= 2'b00; // Read 8 bits
                spi_spd <= 1'b0;
                spi_hold <= 1'b0;
                spif_req<= (spif_req) && (i_wb_cyc);
 
                if ((~spi_busy)&&(~o_qspi_cs_n))
                        // Our command was accepted
                        state <= `WBQSPI_READ_CMD;
        end else if (state == `WBQSPI_QRD_ADDRESS)
        begin
                // We come in here immediately upon issuing a QRD read
                // command (8-bits), but we have to pause to give the
                // address (24-bits) and mode (8-bits) in quad speed.
                o_wb_ack   <= 1'b0;
                o_wb_stall <= 1'b1;
 
                spi_wr <= 1'b1; // Non-stop
                spi_in <= { w_spif_addr, 8'ha0 };
                spi_len <= 2'b10; // Write address, not mode byte
                spi_spd <= 1'b1;
                spi_dir <= 1'b0; // Still writing
                spi_hold <= 1'b0;
                spif_req<= (spif_req) && (i_wb_cyc);
 
                if ((~spi_busy)&&(spi_spd))
                        // Our command was accepted
                        state <= `WBQSPI_QRD_DUMMY;
        end else if (state == `WBQSPI_QRD_DUMMY)
        begin
                o_wb_ack   <= 1'b0;
                o_wb_stall <= 1'b1;
 
                spi_wr <= 1'b1; // Non-stop
                spi_in <= { 8'ha0, 24'h00 }; // Mode byte, then 2 bytes dummy
                spi_len <= 2'b10; // Write 24 bits
                spi_spd <= 1'b1;
                spi_dir <= 1'b0; // Still writing
                spi_hold <= 1'b0;
                spif_req<= (spif_req) && (i_wb_cyc);
 
                if ((~spi_busy)&&(spi_in[31:28] == 4'ha))
                        // Our command was accepted
                        state <= `WBQSPI_READ_CMD;
        end else if (state == `WBQSPI_READ_CMD)
        begin // Issue our first command to read 32 bits.
                o_wb_ack   <= 1'b0;
                o_wb_stall <= 1'b1;
 
                spi_wr <= 1'b1;
                spi_in <= { 8'hff, 24'h00 }; // Empty
                spi_len <= 2'b11; // Read 32 bits
                spi_dir <= 1'b1; // Now reading
                spi_hold <= 1'b0;
                spif_req<= (spif_req) && (i_wb_cyc);
                if ((spi_valid)&&(spi_len == 2'b11))
                        state <= `WBQSPI_READ_DATA;
        end else if (state == `WBQSPI_READ_DATA)
        begin
                // Pipelined read support
                spi_wr <=((i_wb_data_stb)&&(~i_wb_we)&&(i_wb_addr== (spif_addr+1)));
                spi_in <= 32'h00;
                spi_len <= 2'b11;
                // Don't adjust the speed here, it was set in the setup
                spi_dir <= 1'b1;        // Now we get to read
                // Don't let the device go to idle until the bus cycle ends.
                //      This actually prevents a *really* nasty race condition,
                //      where the strobe comes in after the lower level device
                //      has decided to stop waiting.  The write is then issued,
                //      but no one is listening.  By leaving the device open,
                //      the device is kept in a state where a valid strobe
                //      here will be useful.  Of course, we don't accept
                //      all commands, just reads.  Further, the strobe needs
                //      to be high for two clocks cycles without changing
                //      anything on the bus--one for us to notice it and pull
                //      our head out of the sand, and a second for whoever
                //      owns the bus to realize their command went through.
                spi_hold <= 1'b1;
                spif_req<= (spif_req) && (i_wb_cyc);
                if ((spi_valid)&&(~spi_in[31]))
                begin // Single pulse acknowledge and write data out
                        o_wb_ack <= spif_req;
                        o_wb_stall <= (~spi_wr);
                        // adjust endian-ness to match the PC
                        o_wb_data <= spi_out;
                        state <= (spi_wr)?`WBQSPI_READ_DATA
                                : ((spi_spd) ? `WBQSPI_WAIT_TIL_RDIDLE : `WBQSPI_WAIT_TIL_IDLE);
                        spif_req <= spi_wr;
                        spi_hold <= (~spi_wr);
                        if (spi_wr)
                                spif_addr <= i_wb_addr;
                end else if (~i_wb_cyc)
                begin // FAIL SAFE: If the bus cycle ends, forget why we're
                        // here, just go back to idle
                        state <= ((spi_spd) ? `WBQSPI_WAIT_TIL_RDIDLE : `WBQSPI_WAIT_TIL_IDLE);
                        spi_hold <= 1'b0;
                        o_wb_ack <= 1'b0;
                        o_wb_stall <= 1'b1;
                end else begin
                        o_wb_ack <= 1'b0;
                        o_wb_stall <= 1'b1;
                end
        end else if (state == `WBQSPI_WAIT_TIL_RDIDLE)
        begin // Wait 'til idle, but then go to fast read idle instead of full
                spi_wr     <= 1'b0;     // idle
                spi_hold   <= 1'b0;
                o_wb_stall <= 1'b1;
                o_wb_ack   <= 1'b0;
                spif_req   <= 1'b0;
                if ((~spi_busy)&&(o_qspi_cs_n)&&(~spi_wr)) // Wait for a full
                begin // clearing of the SPI port before moving on
                        state <= `WBQSPI_RDIDLE;
                        o_wb_stall <= 1'b0;
                        o_wb_ack   <= 1'b0;// Shouldn't be acking anything here
                end
        end else if (state == `WBQSPI_READ_ID_CMD)
        begin // We came into here immediately after issuing a 0x9f command
                // Now we need to read 32 bits of data.  Result should be
                // 0x0102154d (8'h manufacture ID, 16'h device ID, followed
                // by the number of extended bytes available 8'h4d).
                o_wb_ack <= 1'b0;
                o_wb_stall<= 1'b1;
 
                spi_wr <= 1'b1; // No data to send, but need four bytes, since
                spi_len <= 2'b11; // 32 bits of data are ... useful
                spi_in <= 32'h00; // Irrelevant
                spi_spd <= 1'b0; // Slow speed
                spi_dir <= 1'b1; // Reading
                spi_hold <= 1'b0;
                spif_req <= (spif_req) && (i_wb_cyc);
                if ((~spi_busy)&&(~o_qspi_cs_n)&&(spi_len == 2'b11))
                        // Our command was accepted, now go read the result
                        state <= `WBQSPI_READ_ID;
        end else if (state == `WBQSPI_READ_ID)
        begin
                o_wb_ack <= 1'b0; // Assuming we're still waiting
                o_wb_stall <= 1'b1;
 
                spi_wr <= 1'b0; // No more writes, we've already written the cmd
                spi_hold <= 1'b0;
                spif_req <= (spif_req) && (i_wb_cyc);
 
                // Here, we just wait until the result comes back
                // The problem is, the result may be the previous result.
                // So we use spi_len as an indicator
                spi_len <= 2'b00;
                if((spi_valid)&&(spi_len==2'b00))
                begin // Put the results out as soon as possible
                        o_wb_data <= spi_out[31:0];
                        o_wb_ack <= spif_req;
                        spif_req <= 1'b0;
                end else if ((~spi_busy)&&(o_qspi_cs_n))
                begin
                        state <= `WBQSPI_IDLE;
                        o_wb_stall <= 1'b0;
                end
        end else if (state == `WBQSPI_READ_STATUS)
        begin // We enter after the command has been given, for now just
                // read and return
                spi_wr <= 1'b0;
                o_wb_ack <= 1'b0;
                spi_hold <= 1'b0;
                spif_req <= (spif_req) && (i_wb_cyc);
                if (spi_valid)
                begin
                        o_wb_ack <= spif_req;
                        o_wb_stall <= 1'b1;
                        spif_req <= 1'b0;
                        last_status <= spi_out[7:0];
                        write_in_progress <= spi_out[0];
                        if (spif_addr[1:0] == 2'b00) // Local read, checking
                        begin // status, 'cause we're writing
                                o_wb_data <= { spi_out[0],
                                        dirty_sector, spi_busy,
                                        ~write_protect,
                                        quad_mode_enabled,
                                        {(29-ADDRESS_WIDTH){1'b0}},
                                        erased_sector, 14'h000 };
                        end else begin
                                o_wb_data <= { 24'h00, spi_out[7:0] };
                        end
                end
 
                if ((~spi_busy)&&(~spi_wr))
                        state <= `WBQSPI_IDLE;
        end else if (state == `WBQSPI_READ_CONFIG)
        begin // We enter after the command has been given, for now just
                // read and return
                spi_wr <= 1'b0;
                o_wb_ack <= 1'b0;
                o_wb_stall <= 1'b1;
                spi_hold <= 1'b0;
                spif_req <= (spif_req) && (i_wb_cyc);
 
                if (spi_valid)
                begin
                        o_wb_data <= { 24'h00, spi_out[7:0] };
                        quad_mode_enabled <= spi_out[1];
                end
 
                if ((~spi_busy)&&(~spi_wr))
                begin
                        state <= `WBQSPI_IDLE;
                        o_wb_ack   <= spif_req;
                        o_wb_stall <= 1'b0;
                        spif_req <= 1'b0;
                end
 
//
//
//      Write/erase data section
//
`ifndef READ_ONLY
        end else if (state == `WBQSPI_WAIT_WIP_CLEAR)
        begin
                o_wb_stall <= 1'b1;
                o_wb_ack   <= 1'b0;
                spi_wr <= 1'b0;
                spif_req<= (spif_req) && (i_wb_cyc);
                if (~spi_busy)
                begin
                        spi_wr   <= 1'b1;
                        spi_in   <= { 8'h05, 24'h0000 };
                        spi_hold <= 1'b1;
                        spi_len  <= 2'b01; // 16 bits write, so we can read 8
                        state <= `WBQSPI_CHECK_WIP_CLEAR;
                        spi_spd  <= 1'b0; // Slow speed
                        spi_dir  <= 1'b0;
                end
        end else if (state == `WBQSPI_CHECK_WIP_CLEAR)
        begin
                o_wb_stall <= 1'b1;
                o_wb_ack   <= 1'b0;
                // Repeat as often as necessary until we are clear
                spi_wr <= 1'b1;
                spi_in <= 32'h0000; // Values here are actually irrelevant
                spi_hold <= 1'b1;
                spi_len <= 2'b00; // One byte at a time
                spi_spd  <= 1'b0; // Slow speed
                spi_dir  <= 1'b0;
                spif_req<= (spif_req) && (i_wb_cyc);
                if ((spi_valid)&&(~spi_out[0]))
                begin
                        state <= `WBQSPI_CHECK_WIP_DONE;
                        spi_wr   <= 1'b0;
                        spi_hold <= 1'b0;
                        write_in_progress <= 1'b0;
                        last_status <= spi_out[7:0];
                end
        end else if (state == `WBQSPI_CHECK_WIP_DONE)
        begin
                o_wb_stall <= 1'b1;
                o_wb_ack   <= 1'b0;
                // Let's let the SPI port come back to a full idle,
                // and the chip select line go low before continuing
                spi_wr   <= 1'b0;
                spi_len  <= 2'b00;
                spi_hold <= 1'b0;
                spi_spd  <= 1'b0; // Slow speed
                spi_dir  <= 1'b0;
                spif_req<= (spif_req) && (i_wb_cyc);
                if ((o_qspi_cs_n)&&(~spi_busy)) // Chip select line is high, we can continue
                begin
                        spi_wr   <= 1'b0;
                        spi_hold <= 1'b0;
 
                        casez({ spif_cmd, spif_ctrl, spif_addr[1:0] })
                        4'b00??: begin // Read data from ... somewhere
                                spi_wr     <= 1'b1;     // Write cmd to device
                                if (quad_mode_enabled)
                                begin
                                        spi_in <= { 8'heb, w_spif_addr };
                                        state <= `WBQSPI_QRD_ADDRESS;
                                        // spi_len    <= 2'b00; // single byte, cmd only
                                end else begin
                                        spi_in <= { 8'h0b, w_spif_addr };
                                        state <= `WBQSPI_RD_DUMMY;
                                        spi_len    <= 2'b11; // Send cmd and addr
                                end end
                        4'b10??: begin // Write data to ... anywhere
                                spi_wr <= 1'b1;
                                spi_len <= 2'b00; // 8 bits
                                // Send a write enable command
                                spi_in <= { 8'h06, 24'h00 };
                                state <= `WBQSPI_WEN;
                                end
                        4'b0110: begin // Read status register
                                state <= `WBQSPI_READ_STATUS;
                                spi_wr <= 1'b1;
                                spi_len <= 2'b01; // 8 bits out, 8 bits in
                                spi_in <= { 8'h05, 24'h00};
                                end
                        4'b0111: begin
                                state <= `WBQSPI_READ_ID_CMD;
                                spi_wr <= 1'b1;
                                spi_len <= 2'b00;
                                spi_in <= { 8'h9f, 24'h00};
                                end
                        default: begin //
                                o_wb_stall <= 1'b1;
                                o_wb_ack <= spif_req;
                                state <= `WBQSPI_WAIT_TIL_IDLE;
                                end
                        endcase
                // spif_cmd   <= i_wb_we;
                // spif_addr  <= i_wb_addr;
                // spif_data  <= i_wb_data;
                // spif_ctrl  <= (i_wb_ctrl_stb)&&(~i_wb_data_stb);
                // spi_wr <= 1'b0; // Keep the port idle, unless told otherwise
                end
        end else if (state == `WBQSPI_WEN)
        begin // We came here after issuing a write enable command
                spi_wr <= 1'b0;
                o_wb_ack <= 1'b0;
                o_wb_stall <= 1'b1;
                spif_req<= (spif_req) && (i_wb_cyc);
                if ((~spi_busy)&&(o_qspi_cs_n)&&(~spi_wr)) // Let's come to a full stop
                        state <= (quad_mode_enabled)?`WBQSPI_QPP:`WBQSPI_PP;
                        // state <= `WBQSPI_PP;
        end else if (state == `WBQSPI_PP)
        begin // We come here under a full stop / full port idle mode
                // Issue our command immediately
                spi_wr <= 1'b1;
                spi_in <= { 8'h02, w_spif_addr };
                spi_len <= 2'b11;
                spi_hold <= 1'b1;
                spi_spd  <= 1'b0;
                spi_dir  <= 1'b0; // Writing
                spif_req<= (spif_req) && (i_wb_cyc);
 
                // Once we get busy, move on
                if (spi_busy)
                        state <= `WBQSPI_WR_DATA;
                if (spif_sector == erased_sector)
                        dirty_sector <= 1'b1;
        end else if (state == `WBQSPI_QPP)
        begin // We come here under a full stop / full port idle mode
                // Issue our command immediately
                spi_wr <= 1'b1;
                spi_in <= { 8'h32, w_spif_addr };
                spi_len <= 2'b11;
                spi_hold <= 1'b1;
                spi_spd  <= 1'b0;
                spi_dir  <= 1'b0; // Writing
                spif_req<= (spif_req) && (i_wb_cyc);
 
                // Once we get busy, move on
                if (spi_busy)
                begin
                        // spi_wr is irrelevant here ...
                        // Set the speed value once, but wait til we get busy
                        // to do so.
                        spi_spd <= 1'b1;
                        state <= `WBQSPI_WR_DATA;
                end
                if (spif_sector == erased_sector)
                        dirty_sector <= 1'b1;
        end else if (state == `WBQSPI_WR_DATA)
        begin
                o_wb_stall <= 1'b1;
                o_wb_ack   <= 1'b0;
                spi_wr   <= 1'b1; // write without waiting
                spi_in   <= spif_data;
                spi_len  <= 2'b11; // Write 4 bytes
                spi_hold <= 1'b1;
                if (~spi_busy)
                begin
                        o_wb_ack <= spif_req; // Ack when command given
                        state <= `WBQSPI_WR_BUS_CYCLE;
                end
                spif_req<= (spif_req) && (i_wb_cyc);
        end else if (state == `WBQSPI_WR_BUS_CYCLE)
        begin
                o_wb_ack <= 1'b0; // Turn off our ack and stall flags
                o_wb_stall <= 1'b1;
                spi_wr <= 1'b0;
                spi_hold <= 1'b1;
                write_in_progress <= 1'b1;
                spif_req<= (spif_req) && (i_wb_cyc);
                if (~i_wb_cyc)
                begin
                        state <= `WBQSPI_WAIT_TIL_IDLE;
                        spi_hold <= 1'b0;
                end else if (spi_wr)
                begin // Give the SPI a chance to get busy on the last write
                        // Do nothing here.
                end else if ((i_wb_data_stb)&&(i_wb_we)
                                &&(i_wb_addr == (spif_addr+1))
                                &&(i_wb_addr[(AW-1):6]==spif_addr[(AW-1):6]))
                begin
                        spif_cmd  <= 1'b1;
                        spif_data <= i_wb_data;
                        spif_addr <= i_wb_addr;
                        spif_ctrl  <= 1'b0;
                        spif_req<= 1'b1;
                        // We'll keep the bus stalled on this request
                        // for a while
                        state <= `WBQSPI_WR_DATA;
                        o_wb_ack   <= 1'b0;
                        o_wb_stall <= 1'b0;
                end else if ((i_wb_data_stb|i_wb_ctrl_stb)&&(~o_wb_ack)) // Writing out of bounds
                begin
                        spi_hold <= 1'b0;
                        spi_wr   <= 1'b0;
                        state <= `WBQSPI_WAIT_TIL_IDLE;
                end // Otherwise we stay here
        end else if (state == `WBQSPI_WRITE_CONFIG)
        begin // We enter immediately after commanding a WEN
                o_wb_ack   <= 1'b0;
                o_wb_stall <= 1'b1;
 
                spi_len <= 2'b10;
                spi_in <= { 8'h01, last_status, spif_data[7:0], 8'h00 };
                spi_wr <= 1'b0;
                spi_hold <= 1'b0;
                spif_req <= (spif_req) && (i_wb_cyc);
                if ((~spi_busy)&&(~spi_wr))
                begin
                        spi_wr <= 1'b1;
                        state <= `WBQSPI_WAIT_TIL_IDLE;
                        write_in_progress <= 1'b1;
                        quad_mode_enabled <= spif_data[1];
                end
        end else if (state == `WBQSPI_WRITE_STATUS)
        begin // We enter immediately after commanding a WEN
                o_wb_ack   <= 1'b0;
                o_wb_stall <= 1'b1;
 
                spi_len <= 2'b01;
                spi_in <= { 8'h01, spif_data[7:0], 16'h00 };
                // last_status <= i_wb_data[7:0]; // We'll read this in a moment
                spi_wr <= 1'b0;
                spi_hold <= 1'b0;
                spif_req <= (spif_req) && (i_wb_cyc);
                if ((~spi_busy)&&(~spi_wr))
                begin
                        spi_wr <= 1'b1;
                        last_status <= spif_data[7:0];
                        write_in_progress <= 1'b1;
                        if(((last_status[6])||(last_status[5]))
                                &&((~spif_data[6])&&(~spif_data[5])))
                                state <= `WBQSPI_CLEAR_STATUS;
                        else
                                state <= `WBQSPI_WAIT_TIL_IDLE;
                end
        end else if (state == `WBQSPI_ERASE_CMD)
        begin // Know that WIP is clear on entry, WEN has just been commanded
                spi_wr     <= 1'b0;
                o_wb_ack   <= 1'b0;
                o_wb_stall <= 1'b1;
                spi_hold   <= 1'b0;
                spi_spd <= 1'b0;
                spi_dir <= 1'b0;
                spif_req <= (spif_req) && (i_wb_cyc);
 
                // Here's the erase command
                spi_in <= { 8'hd8, 2'h0, spif_data[19:14], 14'h000, 2'b00 };
                spi_len <= 2'b11; // 32 bit write
                // together with setting our copy of the WIP bit
                write_in_progress <= 1'b1;
                // keeping track of which sector we just erased
                erased_sector <= spif_data[(AW-1):14];
                // and marking this erase sector as no longer dirty
                dirty_sector <= 1'b0;
 
                // Wait for a full stop before issuing this command
                if ((~spi_busy)&&(~spi_wr)&&(o_qspi_cs_n))
                begin // When our command is accepted, move to the next state
                        spi_wr <= 1'b1;
                        state <= `WBQSPI_ERASE_BLOCK;
                end
        end else if (state == `WBQSPI_ERASE_BLOCK)
        begin
                spi_wr     <= 1'b0;
                spi_hold   <= 1'b0;
                o_wb_stall <= 1'b1;
                o_wb_ack   <= 1'b0;
                spif_req <= (spif_req) && (i_wb_cyc);
                // When the port clears, we can head back to idle
                //      No ack necessary, we ackd before getting
                //      here.
                if ((~spi_busy)&&(~spi_wr))
                        state <= `WBQSPI_IDLE;
        end else if (state == `WBQSPI_CLEAR_STATUS)
        begin // Issue a clear status command
                spi_wr <= 1'b1;
                spi_hold <= 1'b0;
                spi_len <= 2'b00; // 8 bit command
                spi_in <= { 8'h30, 24'h00 };
                spi_spd <= 1'b0;
                spi_dir <= 1'b0;
                last_status[6:5] <= 2'b00;
                spif_req <= (spif_req) && (i_wb_cyc);
                if ((spi_wr)&&(~spi_busy))
                        state <= `WBQSPI_WAIT_TIL_IDLE;
        end else if (state == `WBQSPI_IDLE_CHECK_WIP)
        begin // We are now in read status register mode
 
                // No bus commands have (yet) been given
                o_wb_stall <= 1'b1;
                o_wb_ack   <= 1'b0;
                spif_req <= (spif_req) && (i_wb_cyc);
 
                // Stay in this mode unless/until we get a command, or
                //      the write is over
                spi_wr <= (((~i_wb_cyc)||((~i_wb_data_stb)&&(~i_wb_ctrl_stb)))
                                &&(write_in_progress));
                spi_len <= 2'b00; // 8 bit reads
                spi_spd <= 1'b0;  // SPI, not quad
                spi_dir <= 1'b1;  // Read
                if (spi_valid)
                begin
                        write_in_progress <= spi_out[0];
                        if ((~spi_out[0])&&(write_in_progress))
                                o_interrupt <= 1'b1;
                end else
                        o_interrupt <= 1'b0;
 
                if ((~spi_wr)&&(~spi_busy)&&(o_qspi_cs_n))
                begin // We can now go to idle and process a command
                        o_wb_stall <= 1'b0;
                        o_wb_ack   <= 1'b0;
                        state <= `WBQSPI_IDLE;
                end
`endif //       !READ_ONLY
        end else // if (state == `WBQSPI_WAIT_TIL_IDLE) or anything else
        begin
                spi_wr     <= 1'b0;
                spi_hold   <= 1'b0;
                o_wb_stall <= 1'b1;
                o_wb_ack   <= 1'b0;
                spif_req   <= 1'b0;
                if ((~spi_busy)&&(o_qspi_cs_n)&&(~spi_wr)) // Wait for a full
                begin // clearing of the SPI port before moving on
                        state <= `WBQSPI_IDLE;
                        o_wb_stall <= 1'b0;
                        o_wb_ack   <= 1'b0; // Shouldn't be acking anything here
                end
        end
        end
 
        // Command and control during the reset sequence
        assign  o_qspi_cs_n = (spif_override)?alt_cmd :w_qspi_cs_n;
        assign  o_qspi_sck  = (spif_override)?alt_ctrl:w_qspi_sck;
        assign  o_qspi_mod  = (spif_override)?  2'b01 :w_qspi_mod;
        assign  o_qspi_dat  = (spif_override)?  4'b00 :w_qspi_dat;
endmodule

Line No.	Rev	Author	Line
1	14	dgisselq	`////////////////////////////////////////////////////////////////////////////////`
2	2	dgisselq	`//`
3			`// Filename: wbspiflash.v`
4			`//`
5	3	dgisselq	`// Project: Wishbone Controlled Quad SPI Flash Controller`
6	2	dgisselq	`//`
7			`// Purpose: Access a Quad SPI flash via a WISHBONE interface. This`
8			`// includes both read and write (and erase) commands to the SPI`
9			`// flash. All read/write commands are accomplished using the`
10			`// high speed (4-bit) interface. Further, the device will be`
11			`// left/kept in the 4-bit read interface mode between accesses,`
12			`// for a minimum read latency.`
13			`//`
14	3	dgisselq	`// Wishbone Registers (See spec sheet for more detail):`
15	2	dgisselq	`// 0: local config(r) / erase commands(w) / deep power down cmds / etc.`
16			`// R: (Write in Progress), (dirty-block), (spi_port_busy), 1'b0, 9'h00,`
17			`// { last_erased_sector, 14'h00 } if (WIP)`
18			`// else { current_sector_being_erased, 14'h00 }`
19			`// current if write in progress, last if written`
20			`// W: (1'b1 to erase), (12'h ignored), next_erased_block, 14'h ignored)`
21	3	dgisselq	`// 1: Configuration register`
22			`// 2: Status register (R/w)`
23			`// 3: Read ID (read only)`
24	2	dgisselq	`// (19 bits): Data (R/w, but expect writes to take a while)`
25			`//`
26			`//`
27	14	dgisselq	`// Creator: Dan Gisselquist, Ph.D.`
28	8	dgisselq	`// Gisselquist Technology, LLC`
29	2	dgisselq	`//`
30	14	dgisselq	`////////////////////////////////////////////////////////////////////////////////`
31	2	dgisselq	`//`
32	14	dgisselq	`// Copyright (C) 2015,2017, Gisselquist Technology, LLC`
33	2	dgisselq	`//`
34	3	dgisselq	`// This program is free software (firmware): you can redistribute it and/or`
35			`// modify it under the terms of the GNU General Public License as published`
36			`// by the Free Software Foundation, either version 3 of the License, or (at`
37			`// your option) any later version.`
38			`//`
39			`// This program is distributed in the hope that it will be useful, but WITHOUT`
40			`// ANY WARRANTY; without even the implied warranty of MERCHANTIBILITY or`
41			`// FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License`
42			`// for more details.`
43			`//`
44			`// You should have received a copy of the GNU General Public License along`
45	14	dgisselq	`// with this program. (It's in the $(ROOT)/doc directory. Run make with no`
46	3	dgisselq	`// target there if the PDF file isn't present.) If not, see`
47			`// <http://www.gnu.org/licenses/> for a copy.`
48			`//`
49			`// License: GPL, v3, as defined and found on www.gnu.org,`
50			`// http://www.gnu.org/licenses/gpl.html`
51			`//`
52			`//`
53	14	dgisselq	`////////////////////////////////////////////////////////////////////////////////`
54	7	dgisselq	`//`
55			`include "flash_config.v"
56	14	dgisselq	`default_nettype none
57	7	dgisselq	`//`
58	16	dgisselq	`define WBQSPI_RESET 5'd0
59			`define WBQSPI_RESET_QUADMODE 5'd1
60			`define WBQSPI_IDLE 5'd2
61			`define WBQSPI_RDIDLE 5'd3 // Idle, but in fast read mode
62			`define WBQSPI_WBDECODE 5'd4
63			`define WBQSPI_RD_DUMMY 5'd5
64			`define WBQSPI_QRD_ADDRESS 5'd6
65			`define WBQSPI_QRD_DUMMY 5'd7
66			`define WBQSPI_READ_CMD 5'd8
67			`define WBQSPI_READ_DATA 5'd9
68			`define WBQSPI_WAIT_TIL_RDIDLE 5'd10
69			`define WBQSPI_READ_ID_CMD 5'd11
70			`define WBQSPI_READ_ID 5'd12
71			`define WBQSPI_READ_STATUS 5'd13
72			`define WBQSPI_READ_CONFIG 5'd14
73			`define WBQSPI_WAIT_TIL_IDLE 5'd15
74	7	dgisselq	`//`
75			`//`
76			`ifndef READ_ONLY
77			`//`
78	16	dgisselq	`define WBQSPI_WAIT_WIP_CLEAR 5'd16
79			`define WBQSPI_CHECK_WIP_CLEAR 5'd17
80			`define WBQSPI_CHECK_WIP_DONE 5'd18
81			`define WBQSPI_WEN 5'd19
82			`define WBQSPI_PP 5'd20 // Program page
83			`define WBQSPI_QPP 5'd21 // Program page, 4 bit mode
84			`define WBQSPI_WR_DATA 5'd22
85			`define WBQSPI_WR_BUS_CYCLE 5'd23
86			`define WBQSPI_WRITE_STATUS 5'd24
87			`define WBQSPI_WRITE_CONFIG 5'd25
88			`define WBQSPI_ERASE_WEN 5'd26
89			`define WBQSPI_ERASE_CMD 5'd27
90			`define WBQSPI_ERASE_BLOCK 5'd28
91			`define WBQSPI_CLEAR_STATUS 5'd29
92			`define WBQSPI_IDLE_CHECK_WIP 5'd30
93	7	dgisselq	`//`
94			`endif
95	2	dgisselq
96	16	dgisselq	`module wbqspiflash(i_clk,`
97	2	dgisselq	`// Internal wishbone connections`
98			`i_wb_cyc, i_wb_data_stb, i_wb_ctrl_stb, i_wb_we,`
99			`i_wb_addr, i_wb_data,`
100			`// Wishbone return values`
101			`o_wb_ack, o_wb_stall, o_wb_data,`
102			`// Quad Spi connections to the external device`
103			`o_qspi_sck, o_qspi_cs_n, o_qspi_mod, o_qspi_dat, i_qspi_dat,`
104	3	dgisselq	`o_interrupt);`
105	7	dgisselq	`parameter ADDRESS_WIDTH=22;`
106	16	dgisselq	`localparam AW = ADDRESS_WIDTH-2;`
107			`input wire i_clk;`
108	2	dgisselq	`// Wishbone, inputs first`
109	14	dgisselq	`input wire i_wb_cyc, i_wb_data_stb, i_wb_ctrl_stb, i_wb_we;`
110	16	dgisselq	`input wire [(AW-1):0] i_wb_addr;`
111	14	dgisselq	`input wire [31:0] i_wb_data;`
112	2	dgisselq	`// then outputs`
113			`output reg o_wb_ack;`
114			`output reg o_wb_stall;`
115			`output reg [31:0] o_wb_data;`
116			`// Quad SPI control wires`
117			`output wire o_qspi_sck, o_qspi_cs_n;`
118			`output wire [1:0] o_qspi_mod;`
119			`output wire [3:0] o_qspi_dat;`
120	14	dgisselq	`input wire [3:0] i_qspi_dat;`
121	2	dgisselq	`// Interrupt line`
122			`output reg o_interrupt;`
123	7	dgisselq	`// output wire [31:0] o_debug;`
124	2	dgisselq
125			`reg spi_wr, spi_hold, spi_spd, spi_dir;`
126			`reg [31:0] spi_in;`
127			`reg [1:0] spi_len;`
128			`wire [31:0] spi_out;`
129			`wire spi_valid, spi_busy;`
130	4	dgisselq	`wire w_qspi_sck, w_qspi_cs_n;`
131			`wire [3:0] w_qspi_dat;`
132			`wire [1:0] w_qspi_mod;`
133	7	dgisselq	`// wire [22:0] spi_dbg;`
134	16	dgisselq	`llqspi lldriver(i_clk,`
135	2	dgisselq	`spi_wr, spi_hold, spi_in, spi_len, spi_spd, spi_dir,`
136			`spi_out, spi_valid, spi_busy,`
137	4	dgisselq	`w_qspi_sck, w_qspi_cs_n, w_qspi_mod, w_qspi_dat,`
138	3	dgisselq	`i_qspi_dat);`
139	2	dgisselq
140			`// Erase status tracking`
141			`reg write_in_progress, write_protect;`
142	7	dgisselq	`reg [(ADDRESS_WIDTH-17):0] erased_sector;`
143	2	dgisselq	`reg dirty_sector;`
144			`initial begin`
145			`write_in_progress = 1'b0;`
146	7	dgisselq	`erased_sector = 0;`
147	2	dgisselq	`dirty_sector = 1'b1;`
148			`write_protect = 1'b1;`
149			`end`
150
151	14	dgisselq	`wire [23:0] w_wb_addr;`
152			`generate`
153			`if (ADDRESS_WIDTH>=24)`
154			`assign w_wb_addr = { i_wb_addr[21:0], 2'b00 };`
155			`else`
156			`assign w_wb_addr = { {(24-ADDRESS_WIDTH){1'b0}}, i_wb_addr, 2'b00 };`
157			`endgenerate`
158
159			`// Repeat for spif_addr`
160			`reg [(ADDRESS_WIDTH-3):0] spif_addr;`
161			`wire [23:0] w_spif_addr;`
162			`generate`
163			`if (ADDRESS_WIDTH>=24)`
164			`assign w_spif_addr = { spif_addr[21:0], 2'b00 };`
165			`else`
166			`assign w_spif_addr = { {(24-ADDRESS_WIDTH){1'b0}}, spif_addr, 2'b00 };`
167			`endgenerate`
168
169	2	dgisselq	`reg [7:0] last_status;`
170	16	dgisselq	`reg [9:0] reset_counter;`
171	2	dgisselq	`reg quad_mode_enabled;`
172	4	dgisselq	`reg spif_cmd, spif_override;`
173	2	dgisselq	`reg [31:0] spif_data;`
174	14	dgisselq	`reg [4:0] state;`
175	2	dgisselq	`reg spif_ctrl, spif_req;`
176	16	dgisselq	`reg alt_cmd, alt_ctrl;`
177	7	dgisselq	`wire [(ADDRESS_WIDTH-17):0] spif_sector;`
178	16	dgisselq	`assign spif_sector = spif_addr[(AW-1):14];`
179	2	dgisselq
180	7	dgisselq	`// assign o_debug = { spi_wr, spi_spd, spi_hold, state, spi_dbg };`
181
182	2	dgisselq	initial state = `WBQSPI_RESET;
183			`initial o_wb_ack = 1'b0;`
184			`initial o_wb_stall = 1'b1;`
185			`initial spi_wr = 1'b0;`
186			`initial spi_len = 2'b00;`
187			`initial quad_mode_enabled = 1'b0;`
188			`initial o_interrupt = 1'b0;`
189	16	dgisselq	`initial spif_override = 1'b1;`
190			`initial spif_ctrl = 1'b0;`
191			`always @(posedge i_clk)`
192	4	dgisselq	`begin`
193			`spif_override <= 1'b0;`
194	16	dgisselq	`alt_cmd <= (reset_counter[9:8]==2'b10)?reset_counter[3]:1'b1; // Toggle CS_n`
195			`alt_ctrl <= (reset_counter[9:8]==2'b10)?reset_counter[0]:1'b1; // Toggle clock too`
196	2	dgisselq	if (state == `WBQSPI_RESET)
197			`begin`
198			`// From a reset, we should`
199			`// Enable the Quad I/O mode`
200			`// Disable the Write protection bits in the status register`
201			`// Chip should already be up and running, so we can start`
202			`// immediately ....`
203			`o_wb_ack <= 1'b0;`
204			`o_wb_stall <= 1'b1;`
205	4	dgisselq	`spi_wr <= 1'b0;`
206	2	dgisselq	`spi_hold <= 1'b0;`
207			`spi_spd <= 1'b0;`
208			`spi_dir <= 1'b0;`
209			`last_status <= 8'h00;`
210	4	dgisselq	state <= `WBQSPI_RESET_QUADMODE;
211	2	dgisselq	`spif_req <= 1'b0;`
212	4	dgisselq	`spif_override <= 1'b1;`
213	16	dgisselq	`last_status <= 8'h00; //`
214			`reset_counter <= 10'h3fc; //`
215	4	dgisselq	`// This guarantees that we aren't starting in quad`
216			`// I/O mode, where the FPGA configuration scripts may`
217			`// have left us.`
218			end else if (state == `WBQSPI_RESET_QUADMODE)
219	2	dgisselq	`begin`
220	4	dgisselq	`// Okay, so here's the problem: we don't know whether or not`
221			`// the Xilinx loader started us up in Quad Read I/O idle mode.`
222	14	dgisselq	`// So, thus we need to toggle the clock and CS_n, with fewer`
223			`// clocks than are necessary to transmit a word.`
224			`//`
225	4	dgisselq	`// Not ready to handle the bus yet, so stall any requests`
226			`o_wb_ack <= 1'b0;`
227			`o_wb_stall <= 1'b1;`
228
229			`// Do something ...`
230	16	dgisselq	`if (reset_counter == 10'h00)`
231	2	dgisselq	`begin`
232	4	dgisselq	`spif_override <= 1'b0;`
233			state <= `WBQSPI_IDLE;
234	16	dgisselq
235			`// Find out if we can use Quad I/O mode ...`
236			state <= `WBQSPI_READ_CONFIG;
237			`spi_wr <= 1'b1;`
238			`spi_len <= 2'b01;`
239			`spi_in <= { 8'h35, 24'h00};`
240
241	4	dgisselq	`end else begin`
242	16	dgisselq	`reset_counter <= reset_counter - 10'h1;`
243	4	dgisselq	`spif_override <= 1'b1;`
244	2	dgisselq	`end`
245			end else if (state == `WBQSPI_IDLE)
246			`begin`
247			`o_interrupt <= 1'b0;`
248			`o_wb_stall <= 1'b0;`
249			`o_wb_ack <= 1'b0;`
250			`spif_cmd <= i_wb_we;`
251			`spif_addr <= i_wb_addr;`
252			`spif_data <= i_wb_data;`
253			`spif_ctrl <= (i_wb_ctrl_stb)&&(~i_wb_data_stb);`
254			`spif_req <= (i_wb_ctrl_stb)\|\|(i_wb_data_stb);`
255			`spi_wr <= 1'b0; // Keep the port idle, unless told otherwise`
256			`spi_hold <= 1'b0;`
257			`spi_spd <= 1'b0;`
258			`spi_dir <= 1'b0; // Write (for now, 'cause of cmd)`
259			`// Data register access`
260	14	dgisselq	`if (i_wb_data_stb)`
261	2	dgisselq	`begin`
262
263			`if (i_wb_we) // Request to write a page`
264			`begin`
265	7	dgisselq	`ifdef READ_ONLY
266			`o_wb_ack <= 1'b1;`
267			`o_wb_stall <= 1'b0;`
268			`end else`
269			`else
270	2	dgisselq	`if((~write_protect)&&(~write_in_progress))`
271			`begin // 00`
272			`spi_wr <= 1'b1;`
273			`spi_len <= 2'b00; // 8 bits`
274			`// Send a write enable command`
275			`spi_in <= { 8'h06, 24'h00 };`
276			state <= `WBQSPI_WEN;
277
278			`o_wb_ack <= 1'b0;`
279			`o_wb_stall <= 1'b1;`
280			`end else if (write_protect)`
281			`begin // whether or not write-in_progress ...`
282			`// Do nothing on a write protect`
283			`// violation`
284			`//`
285			`o_wb_ack <= 1'b1;`
286			`o_wb_stall <= 1'b0;`
287			`end else begin // write is in progress, wait`
288			`// for it to complete`
289			state <= `WBQSPI_WAIT_WIP_CLEAR;
290			`o_wb_ack <= 1'b0;`
291			`o_wb_stall <= 1'b1;`
292			`end`
293			`end else if (~write_in_progress)`
294	7	dgisselq	`endif
295	2	dgisselq	`begin // Read access, normal mode(s)`
296			`o_wb_ack <= 1'b0;`
297			`o_wb_stall <= 1'b1;`
298			`spi_wr <= 1'b1; // Write cmd to device`
299			`if (quad_mode_enabled)`
300			`begin`
301	14	dgisselq	`spi_in <= { 8'heb, w_wb_addr };`
302	2	dgisselq	state <= `WBQSPI_QRD_ADDRESS;
303			`spi_len <= 2'b00; // single byte, cmd only`
304			`end else begin`
305	14	dgisselq	`spi_in <= { 8'h0b, w_wb_addr };`
306	2	dgisselq	state <= `WBQSPI_RD_DUMMY;
307			`spi_len <= 2'b11; // cmd+addr,32bits`
308			`end`
309	7	dgisselq	`ifndef READ_ONLY
310	2	dgisselq	`end else begin`
311			`// A write is in progress ... need to stall`
312			`// the bus until the write is complete.`
313			state <= `WBQSPI_WAIT_WIP_CLEAR;
314			`o_wb_ack <= 1'b0;`
315			`o_wb_stall <= 1'b1;`
316	7	dgisselq	`endif
317	2	dgisselq	`end`
318	14	dgisselq	`end else if ((i_wb_ctrl_stb)&&(i_wb_we))`
319	2	dgisselq	`begin`
320	7	dgisselq	`ifdef READ_ONLY
321			`o_wb_ack <= 1'b1;`
322			`o_wb_stall <= 1'b0;`
323			`else
324	2	dgisselq	`o_wb_stall <= 1'b1;`
325			`case(i_wb_addr[1:0])`
326			`2'b00: begin // Erase command register`
327	16	dgisselq	`write_protect <= !i_wb_data[28];`
328	2	dgisselq	`o_wb_stall <= 1'b0;`
329
330	16	dgisselq	`if((i_wb_data[31])&&(!write_in_progress))`
331	2	dgisselq	`begin`
332			`// Command an erase--ack it immediately`
333
334			`o_wb_ack <= 1'b1;`
335			`o_wb_stall <= 1'b0;`
336
337			`if ((i_wb_data[31])&&(~write_protect))`
338			`begin`
339			`spi_wr <= 1'b1;`
340			`spi_len <= 2'b00;`
341			`// Send a write enable command`
342			`spi_in <= { 8'h06, 24'h00 };`
343			state <= `WBQSPI_ERASE_CMD;
344			`o_wb_stall <= 1'b1;`
345			`end`
346			`end else if (i_wb_data[31])`
347			`begin`
348			state <= `WBQSPI_WAIT_WIP_CLEAR;
349			`o_wb_ack <= 1'b1;`
350			`o_wb_stall <= 1'b1;`
351			`end else`
352			`o_wb_ack <= 1'b1;`
353			`o_wb_stall <= 1'b0;`
354			`end`
355			`2'b01: begin`
356			`// Write the configuration register`
357			`o_wb_ack <= 1'b1;`
358			`o_wb_stall <= 1'b1;`
359
360			`// Need to send a write enable command first`
361			`spi_wr <= 1'b1;`
362			`spi_len <= 2'b00; // 8 bits`
363			`// Send a write enable command`
364			`spi_in <= { 8'h06, 24'h00 };`
365			state <= `WBQSPI_WRITE_CONFIG;
366			`end`
367			`2'b10: begin`
368			`// Write the status register`
369			`o_wb_ack <= 1'b1; // Ack immediately`
370			`o_wb_stall <= 1'b1; // Stall other cmds`
371			`// Need to send a write enable command first`
372			`spi_wr <= 1'b1;`
373			`spi_len <= 2'b00; // 8 bits`
374			`// Send a write enable command`
375			`spi_in <= { 8'h06, 24'h00 };`
376			state <= `WBQSPI_WRITE_STATUS;
377			`end`
378			`2'b11: begin // Write the ID register??? makes no sense`
379			`o_wb_ack <= 1'b1;`
380			`o_wb_stall <= 1'b0;`
381			`end`
382			`endcase`
383	7	dgisselq	`endif
384	16	dgisselq	`end else if (i_wb_ctrl_stb) // &&(!i_wb_we))`
385	2	dgisselq	`begin`
386			`case(i_wb_addr[1:0])`
387			`2'b00: begin // Read local register`
388			`if (write_in_progress) // Read status`
389			`begin// register, is write still in progress?`
390			state <= `WBQSPI_READ_STATUS;
391			`spi_wr <= 1'b1;`
392			`spi_len <= 2'b01;// 8 bits out, 8 bits in`
393			`spi_in <= { 8'h05, 24'h00};`
394
395			`o_wb_ack <= 1'b0;`
396			`o_wb_stall <= 1'b1;`
397			`end else begin // Return w/o talking to device`
398			`o_wb_ack <= 1'b1;`
399			`o_wb_stall <= 1'b0;`
400			`o_wb_data <= { write_in_progress,`
401			`dirty_sector, spi_busy,`
402			`~write_protect,`
403			`quad_mode_enabled,`
404	7	dgisselq	`{(29-ADDRESS_WIDTH){1'b0}},`
405	2	dgisselq	`erased_sector, 14'h000 };`
406			`end end`
407			`2'b01: begin // Read configuration register`
408			state <= `WBQSPI_READ_CONFIG;
409			`spi_wr <= 1'b1;`
410			`spi_len <= 2'b01;`
411			`spi_in <= { 8'h35, 24'h00};`
412
413			`o_wb_ack <= 1'b0;`
414			`o_wb_stall <= 1'b1;`
415			`end`
416			`2'b10: begin // Read status register`
417			state <= `WBQSPI_READ_STATUS;
418			`spi_wr <= 1'b1;`
419			`spi_len <= 2'b01; // 8 bits out, 8 bits in`
420			`spi_in <= { 8'h05, 24'h00};`
421
422			`o_wb_ack <= 1'b0;`
423			`o_wb_stall <= 1'b1;`
424			`end`
425			`2'b11: begin // Read ID register`
426			state <= `WBQSPI_READ_ID_CMD;
427			`spi_wr <= 1'b1;`
428			`spi_len <= 2'b00;`
429			`spi_in <= { 8'h9f, 24'h00};`
430
431			`o_wb_ack <= 1'b0;`
432			`o_wb_stall <= 1'b1;`
433			`end`
434			`endcase`
435	7	dgisselq	`ifndef READ_ONLY
436	2	dgisselq	`end else if ((~i_wb_cyc)&&(write_in_progress))`
437			`begin`
438			state <= `WBQSPI_IDLE_CHECK_WIP;
439			`spi_wr <= 1'b1;`
440			`spi_len <= 2'b01; // 8 bits out, 8 bits in`
441			`spi_in <= { 8'h05, 24'h00};`
442
443			`o_wb_ack <= 1'b0;`
444			`o_wb_stall <= 1'b1;`
445	7	dgisselq	`endif
446	2	dgisselq	`end`
447			end else if (state == `WBQSPI_RDIDLE)
448			`begin`
449			`spi_wr <= 1'b0;`
450			`o_wb_stall <= 1'b0;`
451			`o_wb_ack <= 1'b0;`
452			`spif_cmd <= i_wb_we;`
453			`spif_addr <= i_wb_addr;`
454			`spif_data <= i_wb_data;`
455			`spif_ctrl <= (i_wb_ctrl_stb)&&(~i_wb_data_stb);`
456			`spif_req <= (i_wb_ctrl_stb)\|\|(i_wb_data_stb);`
457			`spi_hold <= 1'b0;`
458			`spi_spd<= 1'b1;`
459			`spi_dir <= 1'b0; // Write (for now)`
460	16	dgisselq	`if ((i_wb_data_stb)&&(!i_wb_we))`
461	2	dgisselq	`begin // Continue our read ... send the new address / mode`
462			`o_wb_stall <= 1'b1;`
463			`spi_wr <= 1'b1;`
464	4	dgisselq	`spi_len <= 2'b10; // Write address, but not mode byte`
465	14	dgisselq	`spi_in <= { w_wb_addr, 8'ha0 };`
466	2	dgisselq	state <= `WBQSPI_QRD_DUMMY;
467	16	dgisselq	`end else if((i_wb_ctrl_stb)&&(!i_wb_we)&&(i_wb_addr[1:0] == 2'b00))`
468	2	dgisselq	`begin`
469			`// A local read that doesn't touch the device, so leave`
470			`// the device in its current state`
471			`o_wb_stall <= 1'b0;`
472			`o_wb_ack <= 1'b1;`
473			`o_wb_data <= { write_in_progress,`
474			`dirty_sector, spi_busy,`
475			`~write_protect,`
476			`quad_mode_enabled,`
477	7	dgisselq	`{(29-ADDRESS_WIDTH){1'b0}},`
478	2	dgisselq	`erased_sector, 14'h000 };`
479	14	dgisselq	`end else if(((i_wb_ctrl_stb)\|\|(i_wb_data_stb)))`
480	2	dgisselq	`begin // Need to release the device from quad mode for all else`
481			`o_wb_ack <= 1'b0;`
482			`o_wb_stall <= 1'b1;`
483			`spi_wr <= 1'b1;`
484			`spi_len <= 2'b11;`
485			`spi_in <= 32'h00;`
486			state <= `WBQSPI_WBDECODE;
487			`end`
488			end else if (state == `WBQSPI_WBDECODE)
489			`begin`
490			`// We were in quad SPI read mode, and had to get out.`
491			`// Now we've got a command (not data read) to read and`
492			`// execute. Accomplish what we would've done while in the`
493			`// IDLE state here, save only that we don't have to worry`
494			`// about data reads, and we need to operate on a stored`
495			`// version of the bus command`
496			`o_wb_stall <= 1'b1;`
497			`o_wb_ack <= 1'b0;`
498			`spi_wr <= 1'b0; // Keep the port idle, unless told otherwise`
499			`spi_hold <= 1'b0;`
500			`spi_spd <= 1'b0;`

Browse

Tools

Subversion Repositories qspiflash

[/] [qspiflash/] [trunk/] [rtl/] [wbqspiflash.v] - Blame information for rev 16