OpenCores
URL https://opencores.org/ocsvn/or1k/or1k/trunk

Subversion Repositories or1k

Compare Revisions

  • This comparison shows the changes necessary to convert path 
    /or1k/trunk/rtems-20020807/aclocal
    from Rev 1026 to Rev 1765
    ↔ Reverse comparison
  •

Rev 1026 → Rev 1765

/check-bsp-cache.m4
0,0 → 1,17
dnl check-bsp-cache.m4,v 1.3 2000/11/09 17:04:53 joel Exp
 
dnl RTEMS_CHECK_BSP_CACHE(RTEMS_BSP)
AC_DEFUN(RTEMS_CHECK_BSP_CACHE,
[
AC_REQUIRE([RTEMS_CHECK_CPU])dnl sets RTEMS_CPU, target
AC_REQUIRE([RTEMS_ENV_RTEMSBSP])dnl set RTEMS_BSP
AC_REQUIRE([RTEMS_TOP])dnl sets RTEMS_TOPdir
AC_CACHE_CHECK([for RTEMS_CPU_MODEL], rtems_cv_RTEMS_CPU_MODEL,
. $RTEMS_TOPdir/c/[$]$1/make/[$]$1.cache)
RTEMS_CPU_MODEL=$rtems_cv_RTEMS_CPU_MODEL
AC_SUBST(RTEMS_CPU_MODEL)
AC_CACHE_CHECK([for RTEMS_BSP_FAMILY], rtems_cv_RTEMS_BSP_FAMILY,
. $RTEMS_TOPdir/c/[$]$1/make/[$]$1.cache)
RTEMS_BSP_FAMILY=$rtems_cv_RTEMS_BSP_FAMILY
AC_SUBST(RTEMS_BSP_FAMILY)
])dnl
/canonical-host.m4
0,0 → 1,25
dnl canonical-host.m4,v 1.6 2000/11/15 21:56:52 joel Exp
 
AC_DEFUN(RTEMS_CANONICAL_HOST,
[dnl
AC_REQUIRE([AC_CANONICAL_HOST])
RTEMS_HOST=$host_os
case "${target}" in
# hpux unix port should go here
i[[34567]]86-*linux*) # unix "simulator" port
RTEMS_HOST=Linux
;;
i[[34567]]86-*freebsd*) # unix "simulator" port
RTEMS_HOST=FreeBSD
;;
i[[34567]]86-pc-cygwin*) # Cygwin is just enough unix like :)
RTEMS_HOST=Cygwin
;;
sparc-sun-solaris*) # unix "simulator" port
RTEMS_HOST=Solaris
;;
*)
;;
esac
AC_SUBST(RTEMS_HOST)
])dnl
/check-cpu.m4
0,0 → 1,18
dnl check-cpu.m4,v 1.6 2002/07/22 10:13:20 ralf Exp
 
dnl check if RTEMS support a cpu
AC_DEFUN(RTEMS_CHECK_CPU,
[dnl
AC_REQUIRE([RTEMS_TOP])
AC_REQUIRE([RTEMS_CANONICAL_TARGET_CPU])
 
# Is this a supported CPU?
AC_MSG_CHECKING([if cpu $RTEMS_CPU is supported])
# FIXME: Temporary hack
if test -d "$srcdir/$RTEMS_TOPdir/cpukit/score/cpu/$RTEMS_CPU"; then
AC_MSG_RESULT(yes)
else
AC_MSG_ERROR(no)
fi
])dnl
 
/check-itron.m4
0,0 → 1,37
dnl check-itron.m4,v 1.4 2000/11/02 15:44:04 joel Exp
dnl
AC_DEFUN(RTEMS_CHECK_ITRON_API,
[dnl
AC_REQUIRE([RTEMS_CHECK_CPU])dnl
AC_REQUIRE([RTEMS_ENABLE_ITRON])dnl
 
AC_CACHE_CHECK([whether CPU supports libitron],
rtems_cv_HAS_ITRON_API,
[dnl
case "$RTEMS_CPU" in
unix*)
rtems_cv_HAS_ITRON_API="no"
;;
*)
if test "${RTEMS_HAS_ITRON_API}" = "yes"; then
rtems_cv_HAS_ITRON_API="yes";
else
rtems_cv_HAS_ITRON_API="disabled";
fi
;;
esac])
if test "$rtems_cv_HAS_ITRON_API" = "yes"; then
HAS_ITRON_API="yes";
else
HAS_ITRON_API="no";
fi
AC_SUBST(HAS_ITRON_API)dnl
])
 
AC_DEFUN(RTEMS_DEFINE_ITRON_API,
[AC_REQUIRE([RTEMS_CHECK_ITRON_API])dnl
if test x"${HAS_ITRON_API}" = x"yes";
then
AC_DEFINE_UNQUOTED(RTEMS_ITRON_API,1,[if itron api is supported])
fi
])
/gcc-specs.m4
0,0 → 1,20
dnl
dnl gcc-specs.m4,v 1.5 2000/11/09 17:04:53 joel Exp
dnl
dnl Check whether the target compiler accepts -specs
dnl
 
AC_DEFUN(RTEMS_GCC_SPECS,
[AC_REQUIRE([RTEMS_PROG_CC])
AC_CACHE_CHECK(whether $CC accepts -specs,rtems_cv_gcc_specs,
[
rtems_cv_gcc_specs=no
if test x"$GCC" = x"yes"; then
touch confspec
echo 'void f(){}' >conftest.c
if test -z "`${CC} -specs confspec -c conftest.c 2>&1`";then
rtems_cv_gcc_specs=yes
fi
fi
rm -f confspec conftest*
])])
/enable-multiprocessing.m4
0,0 → 1,12
dnl enable-multiprocessing.m4,v 1.5 2002/06/30 06:27:36 ralf Exp
 
AC_DEFUN(RTEMS_ENABLE_MULTIPROCESSING,
[
AC_ARG_ENABLE(multiprocessing,
AC_HELP_STRING([--enable-multiprocessing],[enable multiprocessing interface]),
[case "${enable_multiprocessing}" in
yes) ;;
no) ;;
*) AC_MSG_ERROR(bad value ${enableval} for enable-multiprocessing option) ;;
esac],[enable_multiprocessing=no])
])
/bsp-alias.m4
0,0 → 1,39
dnl
dnl bsp-alias.m4,v 1.15 2001/11/21 18:36:51 joel Exp
dnl
 
dnl _RTEMS_BSP_ALIAS(BSP_ALIAS,RTEMS_BSP_FAMILY)
dnl Internal subroutine to RTEMS_BSP_ALIAS
AC_DEFUN(_RTEMS_BSP_ALIAS,
[# account for "aliased" bsps which share source code
case $1 in
simcpu32) $2=sim68000 ;; # BSVC CPU32 variant
c3xsim) $2=c4xsim ;; # TI C3x Simulator in gdb
mcp750) $2=motorola_powerpc ;; # Motorola PPC board variant
mvme2307) $2=motorola_powerpc ;; # Motorola PPC board variant
mvme162lx) $2=mvme162 ;; # m68k - mvme162 board variant
gen68360_040) $2=gen68360 ;; # m68k - 68360 in companion mode
p4600) $2=p4000 ;; # mips64orion - p4000 board w/IDT 4600
p4650) $2=p4000 ;; # mips64orion - p4000 board w/IDT 4650
mbx8*) $2=mbx8xx ;; # MBX821/MBX860 board
pc386dx) $2=pc386 ;; # i386 - PC w/o FPU
pc486) $2=pc386 ;; # i386 - PC with i486DX
pc586) $2=pc386 ;; # i386 - PC with Pentium
pc686) $2=pc386 ;; # i386 - PC with PentiumPro
pck6) $2=pc386 ;; # i386 - PC with K6
bare*) $2=bare ;; # EXP: bare-aliases
erc32nfp) $2=erc32 ;; # erc32 without fpu
leon1) $2=leon ;; # leon without fpu
leon2) $2=leon ;; # leon with fpu
simsh7032) $2=shsim ;; # SH7032 simulator
simsh7045) $2=shsim ;; # SH7045 simulator
*) $2=$1;;
esac]
)
 
dnl RTEMS_BSP_ALIAS(BSP_ALIAS,RTEMS_BSP_FAMILY)
dnl convert a bsp alias $1 into its bsp directory RTEMS_BSP_FAMILY
AC_DEFUN(RTEMS_BSP_ALIAS,
[_RTEMS_BSP_ALIAS(m4_if([$1],,[$RTEMS_BSP],[$1]),
m4_if([$2],,[RTEMS_BSP_FAMILY],[$2]))]
)
/check-posix.m4
0,0 → 1,36
dnl check-posix.m4,v 1.8 2001/12/20 17:33:23 joel Exp
dnl
AC_DEFUN(RTEMS_CHECK_POSIX_API,
[dnl
AC_REQUIRE([RTEMS_CHECK_CPU])dnl
AC_REQUIRE([RTEMS_ENABLE_POSIX])dnl
 
AC_CACHE_CHECK([whether CPU supports libposix],
rtems_cv_HAS_POSIX_API,
[dnl
case "$RTEMS_CPU" in
unix*)
rtems_cv_HAS_POSIX_API="no"
;;
*)
if test "${RTEMS_HAS_POSIX_API}" = "yes"; then
rtems_cv_HAS_POSIX_API="yes";
else
rtems_cv_HAS_POSIX_API="disabled";
fi
;;
esac])
if test "$rtems_cv_HAS_POSIX_API" = "yes"; then
HAS_POSIX_API="yes";
else
HAS_POSIX_API="no";
fi
AC_SUBST(HAS_POSIX_API)dnl
])
 
AC_DEFUN(RTEMS_DEFINE_POSIX_API,
[AC_REQUIRE([RTEMS_CHECK_POSIX_API])dnl
AS_IF(
[test x"${HAS_POSIX_API}" = x"yes"],
[AC_DEFINE_UNQUOTED(RTEMS_POSIX_API,1,[if posix api is supported])])
])
/sysv-ipc.m4
0,0 → 1,133
dnl
dnl sysv-ipc.m4,v 1.8 2002/01/24 14:14:55 joel Exp
dnl
dnl Check for System V IPC calls used by Unix simulators
dnl
dnl 98/07/17 Dario Alcocer alcocer@netcom.com
dnl Ralf Corsepius corsepiu@faw.uni-ulm.de
dnl
dnl Note: $host_os should probably *not* ever be used here to
dnl determine if host supports System V IPC calls, since some
dnl (e.g. FreeBSD 2.x) are configured by default to include only
dnl a subset of the System V IPC calls. Therefore, to make sure
dnl all of the required calls are found, test for each call explicitly.
dnl
dnl All of the calls use IPC_PRIVATE, so tests will not unintentionally
dnl modify any existing key sets. See the man pages for semget, shmget,
dnl msgget, semctl, shmctl and msgctl for details.
 
AC_DEFUN(RTEMS_UNION_SEMUN,
[
AC_CACHE_CHECK([whether $host defines union semun],
rtems_cv_HAS_UNION_SEMUN,
[AC_TRY_COMPILE([
#include <sys/types.h>
#include <sys/ipc.h>
#include <sys/sem.h>],
[union semun arg ;],
[rtems_cv_HAS_UNION_SEMUN="yes"],
[rtems_cv_HAS_UNION_SEMUN="no"])
])
if test "$rtems_cv_HAS_UNION_SEMUN" = "yes"; then
AC_DEFINE(HAS_UNION_SEMUN,[1],[if having union semum])
fi
])
 
AC_DEFUN(RTEMS_SYSV_SEM,
[AC_REQUIRE([AC_PROG_CC])
# AC_REQUIRE([RTEMS_CANONICAL_HOST])
AC_CACHE_CHECK(whether $host supports System V semaphores,
rtems_cv_sysv_sem,
[
AC_TRY_RUN(
[
#include <sys/types.h>
#include <sys/ipc.h>
#include <sys/sem.h>
#if !HAS_UNION_SEMUN
union semun {
int val;
struct semid_ds *buf;
ushort *array;
} ;
#endif
int main () {
union semun arg ;
 
int id=semget(IPC_PRIVATE,1,IPC_CREAT|0400);
if (id == -1)
exit(1);
arg.val = 0; /* avoid implicit type cast to union */
if (semctl(id, 0, IPC_RMID, arg) == -1)
exit(1);
exit(0);
}
],
rtems_cv_sysv_sem="yes", rtems_cv_sysv_sem="no", :)
])
])
 
AC_DEFUN(RTEMS_SYSV_SHM,
[AC_REQUIRE([AC_PROG_CC])
# AC_REQUIRE([RTEMS_CANONICAL_HOST])
AC_CACHE_CHECK(whether $host supports System V shared memory,
rtems_cv_sysv_shm,
[
AC_TRY_RUN([
#include <sys/types.h>
#include <sys/ipc.h>
#include <sys/shm.h>
int main () {
int id=shmget(IPC_PRIVATE,1,IPC_CREAT|0400);
if (id == -1)
exit(1);
if (shmctl(id, IPC_RMID, 0) == -1)
exit(1);
exit(0);
}
],
rtems_cv_sysv_shm="yes", rtems_cv_sysv_shm="no", :)
])
])
 
AC_DEFUN(RTEMS_SYSV_MSG,
[AC_REQUIRE([AC_PROG_CC])
# AC_REQUIRE([RTEMS_CANONICAL_HOST])
AC_CACHE_CHECK(whether $host supports System V messages,
rtems_cv_sysv_msg,
[
AC_TRY_RUN([
#include <sys/types.h>
#include <sys/ipc.h>
#include <sys/msg.h>
int main () {
int id=msgget(IPC_PRIVATE,IPC_CREAT|0400);
if (id == -1)
exit(1);
if (msgctl(id, IPC_RMID, 0) == -1)
exit(1);
exit(0);
}
],
rtems_cv_sysv_msg="yes", rtems_cv_sysv_msg="no", :)
])
])
 
AC_DEFUN(RTEMS_CHECK_SYSV_UNIX,
[# AC_REQUIRE([RTEMS_CANONICAL_HOST])
if test "$RTEMS_CPU" = "unix" ; then
RTEMS_UNION_SEMUN
RTEMS_SYSV_SEM
if test "$rtems_cv_sysv_sem" != "yes" ; then
AC_MSG_ERROR([System V semaphores don't work, required by simulator])
fi
RTEMS_SYSV_SHM
if test "$rtems_cv_sysv_shm" != "yes" ; then
AC_MSG_ERROR([System V shared memory doesn't work, required by simulator])
fi
RTEMS_SYSV_MSG
if test "$rtems_cv_sysv_msg" != "yes" ; then
AC_MSG_ERROR([System V messages don't work, required by simulator])
fi
fi
])
/path-ksh.m4
0,0 → 1,14
dnl path-ksh.m4,v 1.3 2000/11/02 15:44:04 joel Exp
 
AC_DEFUN(RTEMS_PATH_KSH,
[
dnl NOTE: prefer bash over ksh over sh
AC_PATH_PROGS(KSH,bash ksh sh)
if test -z "$KSH"; then
dnl NOTE: This cannot happen -- /bin/sh must always exist
AC_MSG_ERROR(
[***]
[ Cannot determine a usable shell bash/ksh/sh]
[ Please contact your system administrator] );
fi
])
/i386-gas-code16.m4
0,0 → 1,31
dnl
dnl i386-gas-code16.m4,v 1.7 2000/11/02 15:44:04 joel Exp
dnl
 
dnl check for i386 gas supporting 16 bit mode
dnl - binutils 2.9.1.0.7 and higher
 
AC_DEFUN(RTEMS_I386_GAS_CODE16,
[ if test "${host_cpu}" = "i386"; then
AC_CACHE_CHECK([for 16 bit mode assembler support],
rtems_cv_prog_gas_code16,
[cat > conftest.s << EOF
.code16
data32
addr32
lgdt 0
EOF
if AC_TRY_COMMAND($AS -o conftest.o conftest.s); then
rtems_cv_prog_gas_code16=yes
else
rtems_cv_prog_gas_code16=no
fi])
RTEMS_GAS_CODE16="$rtems_cv_prog_gas_code16"
fi
AC_SUBST(RTEMS_GAS_CODE16)
if test x"${RTEMS_GAS_CODE16}" = x"yes";
then
AC_DEFINE_UNQUOTED(NEW_GAS,1,[if using 16 bit mode assembler support])
fi
])
 
/check-bsps.m4
0,0 → 1,45
dnl check-bsps.m4,v 1.18 2001/11/21 18:36:51 joel Exp
 
dnl Report all available bsps for a target,
dnl check if a bsp-subdirectory is present for all bsps found
dnl
dnl RTEMS_CHECK_BSPS(bsp_list)
AC_DEFUN(RTEMS_CHECK_BSPS,
[
AC_REQUIRE([RTEMS_CHECK_CPU])dnl sets RTEMS_CPU, target
AC_REQUIRE([RTEMS_TOP])dnl sets RTEMS_TOPdir
AC_MSG_CHECKING([for bsps])
files=`ls $srcdir/$RTEMS_TOPdir/c/src/lib/libbsp/$RTEMS_CPU`
for file in $files; do
if test -r $srcdir/$RTEMS_TOPdir/c/src/lib/libbsp/$RTEMS_CPU/$file/bsp_specs; then
case $file in
# Now account for BSPs with build variants
c4xsim) $1="[$]$1 c4xsim c3xsim";;
gen68360) $1="[$]$1 gen68360 gen68360_040";;
p4000) $1="[$]$1 p4600 p4650";;
mvme162) $1="[$]$1 mvme162 mvme162lx";;
mbx8xx) $1="[$]$1 mbx821_001 mbx860_002 mbx860_005b";;
motorola_powerpc) $1="[$]$1 mvme2307 mcp750";;
pc386) $1="[$]$1 pc386 pc386dx pc486 pc586 pc686 pck6";;
erc32) $1="[$]$1 erc32 erc32nfp";;
leon) $1="[$]$1 leon1 leon2";;
sim68000) $1="[$]$1 sim68000 simcpu32";;
shsim) $1="[$]$1 simsh7032 simsh7045";;
*) $1="[$]$1 $file";;
esac;
fi
done
AC_MSG_RESULT([[$]$1 .. done])
])dnl
 
AC_DEFUN(RTEMS_CHECK_CUSTOM_BSP,
[dnl
AC_REQUIRE([RTEMS_TOP])
 
AC_MSG_CHECKING([for make/custom/[$]$1.cfg])
if test -r "$srcdir/$RTEMS_TOPdir/make/custom/[$]$1.cfg"; then
AC_MSG_RESULT([yes])
else
AC_MSG_ERROR([no])
fi
])dnl
/ppc.m4
0,0 → 1,111
# ppc.m4,v 1.1 2001/11/20 18:50:12 joel Exp
#
# Some hacks for handling powerpc-exception subdirectories
#
# Note: Consider this file a temporary band-aid until a better, more general
# subdirectory handling solution is introduced to RTEMS.
 
AC_DEFUN([RTEMS_PPC_EXCEPTIONS],
[
exceptions="$1_exception_processing"
AC_SUBST(exceptions)
 
AC_CONFIG_COMMANDS_POST(
[
exceptions_subdirs="$1_exception_processing"
updir=/../support
 
if test "$no_recursion" != yes; then
 
# Remove --cache-file and --srcdir arguments so they do not pile up.
ac_sub_configure_args=
ac_prev=
for ac_arg in $ac_configure_args; do
if test -n "$ac_prev"; then
ac_prev=
continue
fi
case $ac_arg in
-cache-file | --cache-file | --cache-fil | --cache-fi \
| --cache-f | --cache- | --cache | --cach | --cac | --ca | --c)
ac_prev=cache_file ;;
-cache-file=* | --cache-file=* | --cache-fil=* | --cache-fi=* \
| --cache-f=* | --cache-=* | --cache=* | --cach=* | --cac=* | --ca=* \
| --c=*)
;;
--config-cache | -C)
;;
-srcdir | --srcdir | --srcdi | --srcd | --src | --sr)
ac_prev=srcdir ;;
-srcdir=* | --srcdir=* | --srcdi=* | --srcd=* | --src=* | --sr=*)
;;
*) ac_sub_configure_args="$ac_sub_configure_args $ac_arg" ;;
esac
done
 
for ac_subdir in : $exceptions_subdirs; do test "x$ac_subdir" = x: && continue
 
# Do not complain, so a configure script can configure whichever
# parts of a large source tree are present.
test -d $srcdir${updir}/$ac_subdir || continue
 
AC_MSG_NOTICE([configuring in $ac_subdir])
case $srcdir in
.) ;;
*) AS_MKDIR_P(["./$ac_subdir"])
if test -d ./$ac_subdir; then :;
else
AC_MSG_ERROR([cannot create `pwd`/$ac_subdir])
fi
;;
esac
 
ac_popdir=`pwd`
cd $ac_subdir
 
# A "../" for each directory in /$ac_subdir.
ac_dots=`echo $ac_subdir |
sed 's,^\./,,;s,[[^/]]$,&/,;s,[[^/]]*/,../,g'`
 
case $srcdir in
.) # No --srcdir option. We are building in place.
ac_sub_srcdir=$srcdir${updir} ;;
[[\\/]]* | ?:[[\\/]]* ) # Absolute path.
ac_sub_srcdir=$srcdir${updir}/$ac_subdir ;;
*) # Relative path.
ac_sub_srcdir=$ac_dots$srcdir${updir}/$ac_subdir ;;
esac
 
# Check for guested configure; otherwise get Cygnus style configure.
if test -f $ac_sub_srcdir/configure.gnu; then
ac_sub_configure="$SHELL '$ac_sub_srcdir/configure.gnu'"
elif test -f $ac_sub_srcdir/configure; then
ac_sub_configure="$SHELL '$ac_sub_srcdir/configure'"
elif test -f $ac_sub_srcdir/configure.in; then
ac_sub_configure=$ac_configure
else
AC_MSG_WARN([no configuration information is in $ac_subdir])
ac_sub_configure=
fi
 
# The recursion is here.
if test -n "$ac_sub_configure"; then
# Make the cache file name correct relative to the subdirectory.
case $cache_file in
[[\\/]]* | ?:[[\\/]]* ) ac_sub_cache_file=$cache_file ;;
*) # Relative path.
ac_sub_cache_file=$ac_dots$cache_file ;;
esac
 
AC_MSG_NOTICE([running $ac_sub_configure $ac_sub_configure_args --cache-file=$ac_sub_cache_file --srcdir=$ac_sub_srcdir])
# The eval makes quoting arguments work.
eval $ac_sub_configure $ac_sub_configure_args \
--cache-file=$ac_sub_cache_file --srcdir=$ac_sub_srcdir ||
AC_MSG_ERROR([$ac_sub_configure failed for $ac_subdir])
fi
 
cd $ac_popdir
done
fi
])
])
/env-rtemsbsp.m4
0,0 → 1,50
dnl env-rtemsbsp.m4,v 1.7 2002/08/06 07:31:47 ralf Exp
 
dnl Pass a single BSP via an environment variable
dnl used by per BSP configure scripts
AC_DEFUN(RTEMS_ENV_RTEMSBSP,
[dnl
AC_BEFORE([$0], [RTEMS_ENABLE_RTEMSBSP])dnl
AC_BEFORE([$0], [RTEMS_PROJECT_ROOT])dnl
AC_BEFORE([$0], [RTEMS_CHECK_CUSTOM_BSP])dnl
 
AC_ARG_VAR([RTEMS_BSP],[RTEMS_BSP to build])
AC_MSG_CHECKING([for RTEMS_BSP])
AC_CACHE_VAL(rtems_cv_RTEMS_BSP,
[dnl
test -n "${RTEMS_BSP}" && rtems_cv_RTEMS_BSP="$RTEMS_BSP";
])dnl
if test -z "$rtems_cv_RTEMS_BSP"; then
AC_MSG_ERROR([Missing RTEMS_BSP])
fi
RTEMS_BSP="$rtems_cv_RTEMS_BSP"
AC_MSG_RESULT(${RTEMS_BSP})
AC_SUBST(RTEMS_BSP)
 
RTEMS_BSP_SPECS="-specs bsp_specs -qrtems"
AC_SUBST(RTEMS_BSP_SPECS)
 
GCC_SPECS="-B\$(PROJECT_ROOT)/lib/ -B\$(PROJECT_ROOT)/$RTEMS_BSP/lib/"
AC_SUBST(GCC_SPECS)
 
PROJECT_INCLUDE="\$(PROJECT_ROOT)/$RTEMS_BSP/lib/include"
AC_SUBST(PROJECT_INCLUDE)
 
PROJECT_RELEASE="\$(PROJECT_ROOT)/$RTEMS_BSP"
AC_SUBST(PROJECT_RELEASE)
 
RTEMS_ROOT=$PROJECT_ROOT/c/$RTEMS_BSP
AC_SUBST(RTEMS_ROOT)
 
RTEMS_ENABLE_BARE
AC_SUBST(BARE_CPU_MODEL)
AC_SUBST(BARE_CPU_CFLAGS)
 
AM_CONDITIONAL([MULTILIB],[false])
 
includedir="\${exec_prefix}/${RTEMS_BSP}/lib/include"
libdir="\${exec_prefix}/${RTEMS_BSP}/lib"
 
bsplibdir="\${exec_prefix}/${RTEMS_BSP}/lib"
AC_SUBST(bsplibdir)
])
/enable-inlines.m4
0,0 → 1,21
dnl enable-inlines.m4,v 1.6 2001/09/13 13:14:30 joel Exp
 
AC_DEFUN(RTEMS_ENABLE_INLINES,
[AC_ARG_ENABLE(rtems-inlines,
AC_HELP_STRING([--enable-rtems-inlines],[enable RTEMS inline functions (default:enabled, disable to use macros)]),
[case "${enableval}" in
yes) RTEMS_USE_MACROS=no ;;
no) RTEMS_USE_MACROS=yes ;;
*) AC_MSG_ERROR(bad value ${enableval} for disable-rtems-inlines option) ;;
esac],[RTEMS_USE_MACROS=no])
AC_SUBST(RTEMS_USE_MACROS)dnl
 
if test x"${RTEMS_USE_MACROS}" = x"yes";
then
AC_DEFINE_UNQUOTED(USE_MACROS,1,[if using macros])
else
AC_DEFINE_UNQUOTED(USE_INLINES,1,[if using inlines])
fi
 
 
])
/version.m4
0,0 → 1,2
AC_DEFUN([RTEMS_VERSIONING],
m4_define([_RTEMS_VERSION],[ss-20020807]))
/enable-tests.m4
0,0 → 1,15
dnl enable-tests.m4,v 1.5 2001/09/13 13:14:30 joel Exp
 
AC_DEFUN(RTEMS_ENABLE_TESTS,
[
# If the tests are enabled, then find all the test suite Makefiles
AC_MSG_CHECKING([if the test suites are enabled? ])
AC_ARG_ENABLE(tests,
AC_HELP_STRING([--enable-tests],[enable tests (default:disabled)]),
[case "${enableval}" in
yes) tests_enabled=yes ;;
no) tests_enabled=no ;;
*) AC_MSG_ERROR(bad value ${enableval} for tests option) ;;
esac], [tests_enabled=no])
AC_MSG_RESULT([$tests_enabled])
])
/enable-cxx.m4
0,0 → 1,13
dnl enable-cxx.m4,v 1.3 2001/09/13 13:14:30 joel Exp
 
AC_DEFUN(RTEMS_ENABLE_CXX,
[
AC_ARG_ENABLE(cxx,
AC_HELP_STRING([--enable-cxx],[enable C++ support and build the rtems++
library]),
[case "${enableval}" in
yes) RTEMS_HAS_CPLUSPLUS=yes ;;
no) RTEMS_HAS_CPLUSPLUS=no ;;
*) AC_MSG_ERROR(bad value ${enableval} for enable-cxx option) ;;
esac], [RTEMS_HAS_CPLUSPLUS=no])
])
/rtems-cpu-subdirs.m4
0,0 → 1,31
AC_DEFUN([_RTEMS_CPU_SUBDIR],
[
$1 ) if test -d ${srcdir}/ifelse([$2],,[$1],[$2/$1]) ; then
AC_CONFIG_SUBDIRS(ifelse([$2],,[$1],[$2/$1]))
fi
])
 
## RTEMS_CPU_SUBDIRS([PREFIX])
AC_DEFUN([RTEMS_CPU_SUBDIRS],
[
## EDIT: If adding a new cpu to RTEMS, add it to the case block below.
case $RTEMS_CPU in
_RTEMS_CPU_SUBDIR([a29k],[$1]);;
_RTEMS_CPU_SUBDIR([arm],[$1]);;
_RTEMS_CPU_SUBDIR([c4x],[$1]);;
_RTEMS_CPU_SUBDIR([h8300],[$1]);;
_RTEMS_CPU_SUBDIR([hppa1.1],[$1]);;
_RTEMS_CPU_SUBDIR([i386],[$1]);;
_RTEMS_CPU_SUBDIR([i960],[$1]);;
_RTEMS_CPU_SUBDIR([m68k],[$1]);;
_RTEMS_CPU_SUBDIR([mips],[$1]);;
_RTEMS_CPU_SUBDIR([mips64orion],[$1]);;
_RTEMS_CPU_SUBDIR([no_cpu],[$1]);;
_RTEMS_CPU_SUBDIR([or32],[$1]);;
_RTEMS_CPU_SUBDIR([powerpc],[$1]);;
_RTEMS_CPU_SUBDIR([sh],[$1]);;
_RTEMS_CPU_SUBDIR([sparc],[$1]);;
_RTEMS_CPU_SUBDIR([unix],[$1]);;
*) AC_MSG_ERROR([Invalid RTEMS_CPU])
esac
])
/check-rdbg.m4
0,0 → 1,41
dnl check-rdbg.m4,v 1.9 2001/10/17 20:30:38 joel Exp
dnl
AC_DEFUN(RTEMS_CHECK_RDBG,
[dnl
AC_REQUIRE([RTEMS_TOP])dnl
AC_REQUIRE([RTEMS_CHECK_CPU])dnl
AC_REQUIRE([RTEMS_CHECK_NETWORKING])dnl
AC_REQUIRE([RTEMS_ENABLE_RDBG])dnl
AC_CACHE_CHECK([whether BSP supports librdbg],
rtems_cv_HAS_RDBG,
[
if test -d "$srcdir/${RTEMS_TOPdir}/c/src/librdbg/src/${RTEMS_CPU}/${$1}";
then
rtems_cv_HAS_RDBG="yes" ;
elif test -d "$srcdir/${RTEMS_TOPdir}/c/src/librdbg/src/${RTEMS_CPU}/any";
then
rtems_cv_HAS_RDBG="yes" ;
elif test "${RTEMS_CPU}" = "powerpc";
then
A=`grep -l RTEMS_PPC_EXCEPTION_PROCESSING_MODEL $srcdir/${RTEMS_TOPdir}/make/custom/* 2>/dev/null`;
C=""
for i in ${A} ;
do
B=`basename ${i} .cfg`;
C="${C} ${B}";
done
rtems_cv_HAS_RDBG="no";
for j in ${C} ;
do
if test "${$1}" = "${j}" ;
then
rtems_cv_HAS_RDBG="yes";
fi
done
else
rtems_cv_HAS_RDBG="no";
fi
])
HAS_RDBG="$rtems_cv_HAS_RDBG"
AC_SUBST(HAS_RDBG)
])
/canonical-target-name.m4
0,0 → 1,38
dnl
dnl canonical-target-name.m4,v 1.12 2001/09/14 17:30:22 joel Exp
dnl
 
dnl canonicalize target cpu
dnl NOTE: Most rtems targets do not fullfil autoconf's
dnl target naming conventions "processor-vendor-os"
dnl Therefore autoconf's AC_CANONICAL_TARGET will fail for them
dnl and we have to fix it for rtems ourselves
 
AC_DEFUN(RTEMS_CANONICAL_TARGET_CPU,
[
AC_CANONICAL_TARGET
AC_MSG_CHECKING(rtems target cpu)
case "${target}" in
# hpux unix port should go here
i[[34567]]86-*linux*) # unix "simulator" port
RTEMS_CPU=unix
;;
i[[34567]]86-*freebsd*) # unix "simulator" port
RTEMS_CPU=unix
;;
i[[34567]]86-pc-cygwin*) # Cygwin is just enough unix like :)
RTEMS_CPU=unix
;;
no_cpu-*rtems*)
RTEMS_CPU=no_cpu
;;
sparc-sun-solaris*) # unix "simulator" port
RTEMS_CPU=unix
;;
*)
RTEMS_CPU=`echo $target | sed 's%^\([[^-]]*\)-\(.*\)$%\1%'`
;;
esac
AC_SUBST(RTEMS_CPU)
AC_MSG_RESULT($RTEMS_CPU)
])
/bspopts.m4
0,0 → 1,66
dnl bspopts.m4,v 1.1 2001/11/14 18:57:26 joel Exp
dnl
 
dnl RTEMS_BSPOPTS_* - some autoconf voodoo to handle default values and
dnl help-strings for per-BSP-environment variables.
 
dnl To be used in bsp-configure scripts
 
 
dnl Example:
dnl
dnl RTEMS_BSPOPTS_SET([foo],[bar],[0])
dnl RTEMS_BSPOPTS_SET([foo],[baz*],[hello])
dnl RTEMS_BSPOPTS_SET([foo],[*],[])
dnl RTEMS_BSPOPTS_HELP([foo],[env. variable foo])
dnl -> Add "0" as default value of variable "foo" for BSP "bar"
dnl -> Add "hello" as default value of variable "foo" for all BSPs starting
dnl with "baz" in their name.
dnl -> Undefine foo as default clause for all BSP's.
dnl
dnl All this basically expands to a /bin/shell "case"-statement with
dnl accompanying autoconf magic to propagate VAR to bspopts.h.
 
 
dnl RTEMS_BSPOPTS_HELP(VAR,HELP-STRING)
dnl Set up printing the HELP-STRING for bspopts.h's variable VAR and add
dnl appropriate /bin/sh-magic to "configure" to have VAR set up.
 
AC_DEFUN([RTEMS_BSPOPTS_HELP],[
RTEMS_ARG_VAR([$1],[$2])
m4_ifdef([_$1],[
case ${RTEMS_BSP} in
_$1[]dnl
esac],[])
if test -n "[$]{$1}"; then[]dnl
AC_DEFINE_UNQUOTED([$1],
[[$]$1],
[$2])dnl
fi
])
 
dnl RTEMS_BSPOPTS_SET(VAR,BSP,DEFAULT)
dnl Set up a value DEFAULT to be used as default value for variable VAR for
dnl BSP in RTEMS_BSPOPTS_HELP.
 
dnl MUST be use in front of exactly _one_ corresponding RTEMS_BSPOPTS_HELP
 
AC_DEFUN([RTEMS_BSPOPTS_SET],[dnl
m4_append([_$1],
[$2 )
$1=[$]{$1-$3} ;;
])
])
 
 
dnl RTEMS_ARG_VAR(VAR,HELP-STRING)
dnl An internal macros to have RTEMS_BSPOPTS_HELP's help string pretty
dnl printed with configure --help.
dnl Stripped down version of autoconf-2.52's AC_ARG_VAR.
 
AC_DEFUN([RTEMS_ARG_VAR],
[
m4_expand_once([m4_divert_once([HELP_VAR],
[AC_HELP_STRING([$1], [$2], [ ])])],
[$0($1)])dnl
])
/rtems-top.m4
0,0 → 1,52
dnl rtems-top.m4,v 1.14 2002/03/28 13:53:19 joel Exp
 
dnl
dnl RTEMS_TOP($1)
dnl
dnl $1 .. relative path from this configure.in to the toplevel configure.in
dnl
AC_DEFUN(RTEMS_TOP,
[dnl
AC_REQUIRE([RTEMS_VERSIONING])
AC_CHECK_PROGS(MAKE, gmake make)
AC_BEFORE([$0], [AC_CONFIG_AUX_DIR])dnl
AC_BEFORE([$0], [AM_INIT_AUTOMAKE])dnl
 
AC_PREFIX_DEFAULT([/opt/rtems])
 
## HACK to allow gnu-make conditionals in automake-Makefiles.
ENDIF=endif
AC_SUBST(ENDIF)
 
RTEMS_TOPdir="$1";
AC_SUBST(RTEMS_TOPdir)
 
## with_target_subdirs is handled implicitly by autoconf
test -n "$with_target_subdir" || with_target_subdir="."
 
if test "$with_target_subdir" = "." ; then
# Native
PROJECT_TOPdir=${RTEMS_TOPdir}/'$(top_builddir)'
else
# Cross
dots=`echo $with_target_subdir|\
sed -e 's%^\./%%' -e 's%[[^/]]$%&/%' -e 's%[[^/]]*/%../%g'`
PROJECT_TOPdir=${dots}${RTEMS_TOPdir}/'$(top_builddir)'
fi
AC_SUBST(PROJECT_TOPdir)
 
if test "$with_target_subdir" = "." ; then
# Native
PROJECT_ROOT="${RTEMS_TOPdir}/\$(top_builddir)"
else
# Cross
PROJECT_ROOT="${RTEMS_TOPdir}/\$(top_builddir)"
fi
AC_SUBST(PROJECT_ROOT)
 
AC_MSG_CHECKING([for RTEMS Version])
AS_IF([test -r "${srcdir}/${RTEMS_TOPdir}/aclocal/version.m4"],
[],
[AC_MSG_ERROR([Unable to find ${RTEMS_TOPdir}/aclocal/version.m4])])
AC_MSG_RESULT([_RTEMS_VERSION])
])dnl
/enable-rdbg.m4
0,0 → 1,15
dnl enable-rdbg.m4,v 1.5 2001/09/13 13:14:30 joel Exp
 
AC_DEFUN(RTEMS_ENABLE_RDBG,
[
AC_BEFORE([$0], [RTEMS_CHECK_RDBG])dnl
 
AC_ARG_ENABLE(rdbg,
AC_HELP_STRING([--enable-rdbg],[enable remote debugger]),
[case "${enableval}" in
yes) RTEMS_HAS_RDBG=yes ;;
no) RTEMS_HAS_RDBG=no ;;
*) AC_MSG_ERROR(bad value ${enableval} for enable-rdbg option) ;;
esac],[RTEMS_HAS_RDBG=no])
AC_SUBST(RTEMS_HAS_RDBG)dnl
])
/check-multiprocessing.m4
0,0 → 1,42
dnl
dnl check-multiprocessing.m4,v 1.11 2002/06/30 06:27:36 ralf Exp
dnl
 
AC_DEFUN(RTEMS_CHECK_MULTIPROCESSING,
[dnl
AC_REQUIRE([RTEMS_ENABLE_MULTILIB])dnl
AC_REQUIRE([RTEMS_ENV_RTEMSBSP])dnl
AC_REQUIRE([RTEMS_TOP])dnl
AC_REQUIRE([RTEMS_CHECK_CPU])dnl
AC_REQUIRE([RTEMS_ENABLE_MULTIPROCESSING])dnl
AC_REQUIRE([RTEMS_BSP_ALIAS])dnl
 
AC_CACHE_CHECK([if wanting multiprocessing],
[rtems_cv_want_multiprocessing],
[
AS_IF([test x"$multilib" = x"no"],
[# no cpukit
rtems_cv_want_multiprocessing="$enable_multiprocessing"
],[
#HACK: Should check for RTEMS_MULTIPROCESSING in cpuopts.h, instead
rtems_cv_want_multiprocessing="$enable_multiprocessing"
])
])
 
AS_IF([test "$rtems_cv_want_multiprocessing" = "yes"],
[
AC_CACHE_CHECK([whether BSP supports multiprocessing],
[rtems_cv_HAS_MP],[
if test -d "$srcdir/${RTEMS_TOPdir}/c/src/lib/libbsp/${RTEMS_CPU}/${RTEMS_BSP_FAMILY}/shmsupp"; then
rtems_cv_HAS_MP="yes" ;
else
rtems_cv_HAS_MP="no";
fi
])
if test $rtems_cv_HAS_MP = "no"; then
AC_MSG_ERROR([multiprocessing requested but not supported])
fi
],[rtems_cv_HAS_MP="no";])
 
AC_SUBST(HAS_MP,[$rtems_cv_HAS_MP])
])
/check-networking.m4
0,0 → 1,29
dnl check-networking.m4,v 1.4 2000/11/02 15:44:04 joel Exp
dnl
AC_DEFUN(RTEMS_CHECK_NETWORKING,
[dnl
AC_REQUIRE([RTEMS_CHECK_CPU])dnl
AC_REQUIRE([RTEMS_ENABLE_NETWORKING])dnl
 
AC_CACHE_CHECK([whether BSP supports networking],
rtems_cv_HAS_NETWORKING,
[dnl
case "$RTEMS_CPU" in
unix*)
rtems_cv_HAS_NETWORKING="no"
;;
*)
if test "${RTEMS_HAS_NETWORKING}" = "yes"; then
rtems_cv_HAS_NETWORKING="yes";
else
rtems_cv_HAS_NETWORKING="disabled";
fi
;;
esac])
if test "$rtems_cv_HAS_NETWORKING" = "yes"; then
HAS_NETWORKING="yes";
else
HAS_NETWORKING="no";
fi
AC_SUBST(HAS_NETWORKING)dnl
])
/bsp-configure.m4
0,0 → 1,19
dnl bsp-configure.m4,v 1.2 2002/07/22 09:17:40 ralf Exp
 
dnl RTEMS_BSP_CONFIGURE
dnl Commom macro to be included by all bsp-configure.acs
AC_DEFUN([RTEMS_BSP_CONFIGURE],
[
AC_PREREQ([2.52])
AM_MAINTAINER_MODE
RTEMS_ENV_RTEMSBSP
 
RTEMS_CHECK_CUSTOM_BSP(RTEMS_BSP)
RTEMS_CHECK_BSP_CACHE(RTEMS_BSP)
 
RTEMS_CANONICAL_HOST
AM_CONFIG_HEADER([include/bspopts.h])
RTEMS_PROJECT_ROOT
 
RTEMS_CHECK_MULTIPROCESSING
])
/prog-cxx.m4
0,0 → 1,30
dnl
dnl prog-cxx.m4,v 1.12 2002/04/17 13:27:29 joel Exp
dnl
dnl Check for target g++
dnl
 
AC_DEFUN(RTEMS_PROG_CXX,
[
AC_BEFORE([$0], [AC_PROG_CXXCPP])dnl
AC_BEFORE([$0], [RTEMS_CANONICALIZE_TOOLS])dnl
 
dnl Only accept g++
dnl NOTE: This might be too restrictive
RTEMS_CHECK_TOOL(CXX,g++)
AC_PROG_CXX
test -z "$CXX" \
&& AC_MSG_ERROR([no acceptable c++ found in \$PATH])
])
 
AC_DEFUN(RTEMS_PROG_CXX_FOR_TARGET,
[
RTEMS_PROG_CXX
if test "$ac_cv_prog_cc_cross" != "$ac_cv_prog_cxx_cross"; then
AC_MSG_ERROR([***]
[Inconsistency in compiler configuration:]
[Target C compiler and target C++ compiler]
[must both either be cross compilers or native compilers]
[Hint: If building a posix bsp: LD_LIBRARY_PATH?] )
fi
])
/enable-networking.m4
0,0 → 1,15
dnl enable-networking.m4,v 1.6 2001/09/13 13:14:30 joel Exp
 
AC_DEFUN(RTEMS_ENABLE_NETWORKING,
[
## AC_BEFORE([$0], [RTEMS_CHECK_NETWORKING])dnl
 
AC_ARG_ENABLE(networking,
AC_HELP_STRING([--enable-networking],[enable TCP/IP stack]),
[case "${enableval}" in
yes) RTEMS_HAS_NETWORKING=yes ;;
no) RTEMS_HAS_NETWORKING=no ;;
*) AC_MSG_ERROR(bad value ${enableval} for enable-networking option) ;;
esac],[RTEMS_HAS_NETWORKING=yes])
AC_SUBST(RTEMS_HAS_NETWORKING)dnl
])
/check-cxx.m4
0,0 → 1,26
dnl check-cxx.m4,v 1.4 2000/11/02 15:44:04 joel Exp
dnl
AC_DEFUN(RTEMS_CHECK_CXX,
[dnl
AC_REQUIRE([RTEMS_CHECK_CPU])dnl
AC_REQUIRE([RTEMS_PROG_CC_FOR_TARGET])dnl
AC_REQUIRE([RTEMS_PROG_CXX_FOR_TARGET])dnl
AC_CACHE_CHECK([whether to build rtems++],
rtems_cv_HAS_CPLUSPLUS,
[ if test "$RTEMS_HAS_CPLUSPLUS" = "yes"; then
if test -n "$CXX"; then
rtems_cv_HAS_CPLUSPLUS="yes"
else
rtems_cv_HAS_CPLUSPLUS="no"
fi
else
rtems_cv_HAS_CPLUSPLUS="no"
fi])
HAS_CPLUSPLUS="$rtems_cv_HAS_CPLUSPLUS";
AC_SUBST(HAS_CPLUSPLUS)dnl
 
if test "$HAS_CPLUSPLUS" = "yes"; then
CPLUS_LD_LIBS='$(PROJECT_RELEASE)/lib/librtems++$(LIBSUFFIX_VA)'
fi
AC_SUBST(CPLUS_LD_LIBS)
])
/config-subdirs.m4
0,0 → 1,34
dnl config-subdirs.m4,v 1.6 2002/01/06 20:12:13 joel Exp
 
dnl
dnl Misc utility macros for subdir handling to work around missing abilities
dnl in autoconf, automake and structural issues with RTEMS
dnl
dnl Contains parts derived from autoconf-2.13 AC_OUTPUT_SUBDIRS and Cygnus'
dnl configure.in.
dnl
 
dnl
dnl _AC_DOTS(PATH)
dnl
AC_DEFUN(_AC_DOTS,[
# A "../" for each directory in $1.
ac_dots=`echo $1 | \
sed -e 's%^\./%%' -e 's%[[^/]]$%&/%' -e 's%[[^/]]*/%../%g'`
])
 
dnl
dnl _RTEMS_ADJUST_SRCDIR(REVAR,CONFIG_DIR[,TARGET_SUBDIR])
dnl
AC_DEFUN(_RTEMS_ADJUST_SRCDIR,[
_AC_DOTS(ifelse([$3], ,[$2],[$3/$2]))
 
case "$srcdir" in
.) # No --srcdir option. We are building in place.
$1=$srcdir ;;
[[\\/]]* | ?:[[\\/]]*) # Absolute path.
$1=$srcdir/$2 ;;
*) # Relative path.
$1=$ac_dots$srcdir/$2 ;;
esac
])
/rtems-debug.m4
0,0 → 1,19
## rtems-debug.m4,v 1.6 2001/12/20 17:33:23 joel Exp
 
AC_DEFUN(RTEMS_ENABLE_RTEMS_DEBUG,
[
AC_ARG_ENABLE(rtems-debug,
AC_HELP_STRING([--enable-rtems-debug],[enable RTEMS_DEBUG]),
[case "${enable_rtems_debug}" in
yes) enable_rtems_debug=yes ;;
no) enable_rtems_debug=no ;;
*) AC_MSG_ERROR([bad value ${enable_rtems_debug} for RTEMS_DEBUG]) ;;
esac],[enable_rtems_debug=no])
])
 
AC_DEFUN(RTEMS_CHECK_RTEMS_DEBUG,
[AC_REQUIRE([RTEMS_ENABLE_RTEMS_DEBUG])
AS_IF([test x"${enable_rtems_debug}" = x"yes"]
[AC_DEFINE_UNQUOTED(RTEMS_DEBUG,1,[if RTEMS_DEBUG is enabled])])
])
 
/enable-itron.m4
0,0 → 1,33
dnl enable-itron.m4,v 1.8 2001/09/13 13:14:30 joel Exp
 
AC_DEFUN(RTEMS_ENABLE_ITRON,
[
## AC_BEFORE([$0], [RTEMS_CHECK_ITRON_API])dnl
 
AC_ARG_ENABLE(itron,
AC_HELP_STRING([--enable-itron],[enable itron interface]),
[case "${enableval}" in
yes) RTEMS_HAS_ITRON_API=yes ;;
no) RTEMS_HAS_ITRON_API=no ;;
*) AC_MSG_ERROR(bad value ${enableval} for enable-itron option) ;;
esac],[RTEMS_HAS_ITRON_API=yes])
 
case "${host}" in
# hpux unix port should go here
i[[34567]]86-pc-linux*) # unix "simulator" port
RTEMS_HAS_ITRON_API=no
;;
i[[34567]]86-*freebsd*) # unix "simulator" port
RTEMS_HAS_ITRON_API=no
;;
no_cpu-*rtems*)
RTEMS_HAS_ITRON_API=no
;;
sparc-sun-solaris*) # unix "simulator" port
RTEMS_HAS_ITRON_API=no
;;
*)
;;
esac
AC_SUBST(RTEMS_HAS_ITRON_API)
])
/bsp-arg-enable.m4
0,0 → 1,18
dnl bsp-arg-enable.m4,v 1.2 2001/02/02 18:30:42 joel Exp
dnl
dnl RTEMS_BSP_ARG_ENABLE(FEATURE, HELP-STRING, ACTION-IF-TRUE [, ACTION-IF-FALSE])
dnl
dnl Accept --enable-FEATURE=<RTEMS_BSP>:<bsp-value> and
dnl --enable-FEATURE=<value> in BSP-configure scripts.
dnl
dnl Configure scripts will receive <bsp-value> if <RTEMS_BSP> matches the
dnl actual value of the shell variable RTEMS_BSP (cf. RTEMS_ENV_RTEMSBSP),
dnl and the raw value passed to --enable-FEATURE otherwise.
dnl
AC_DEFUN(RTEMS_BSP_ARG_ENABLE,
[AC_REQUIRE([RTEMS_ENV_RTEMSBSP])
AC_ARG_ENABLE([$1],[$2],
[enableval=`echo "[$enable_]patsubst([$1], -, _)" | sed -e "s%^${RTEMS_BSP}:%%"`
eval "[enable_]patsubst([$1], -, _)='$enableval'"
$3],[$4])
])
/multilib.m4
0,0 → 1,17
dnl This provides configure definitions used for multilib support
 
dnl parts of these macros are derived from newlib-1.8.2's multilib support
 
AC_DEFUN(RTEMS_ENABLE_MULTILIB,
[
AC_ARG_ENABLE(multilib,
AC_HELP_STRING([--enable-multilib],
[build many library versions (default=no)]),
[case "${enableval}" in
yes) multilib=yes ;;
no) multilib=no ;;
*) AC_MSG_ERROR(bad value ${enableval} for multilib option) ;;
esac], [multilib=no])dnl
 
AM_CONDITIONAL(MULTILIB,test x"${multilib}" = x"yes")
])
/enable-rtemsbsp.m4
0,0 → 1,16
dnl enable-rtemsbsp.m4,v 1.10 2001/09/13 13:14:30 joel Exp
 
dnl Override the set of BSPs to be built.
dnl used by the toplevel configure script
dnl RTEMS_ENABLE_RTEMSBSP(rtems_bsp_list)
AC_DEFUN(RTEMS_ENABLE_RTEMSBSP,
[
AC_BEFORE([$0], [RTEMS_ENV_RTEMSBSP])dnl
AC_ARG_ENABLE(rtemsbsp,
AC_HELP_STRING([--enable-rtemsbsp="bsp1 bsp2 .."],
[BSPs to include in build]),
[case "${enableval}" in
yes|no) AC_MSG_ERROR([missing argument to --enable-rtemsbsp=\"bsp1 bsp2\"]);;
*) $1=$enableval;;
esac],[$1=""])
])
/enable-posix.m4
0,0 → 1,33
dnl enable-posix.m4,v 1.11 2001/09/13 13:14:30 joel Exp
 
AC_DEFUN(RTEMS_ENABLE_POSIX,
[
## AC_BEFORE([$0], [RTEMS_CHECK_POSIX_API])dnl
 
AC_ARG_ENABLE(posix,
AC_HELP_STRING([--enable-posix],[enable posix interface]),
[case "${enableval}" in
yes) RTEMS_HAS_POSIX_API=yes ;;
no) RTEMS_HAS_POSIX_API=no ;;
*) AC_MSG_ERROR(bad value ${enableval} for enable-posix option) ;;
esac],[RTEMS_HAS_POSIX_API=yes])
 
case "${host}" in
# hpux unix port should go here
i[[34567]]86-pc-linux*) # unix "simulator" port
RTEMS_HAS_POSIX_API=no
;;
i[[34567]]86-*freebsd*) # unix "simulator" port
RTEMS_HAS_POSIX_API=no
;;
no_cpu-*rtems*)
RTEMS_HAS_POSIX_API=no
;;
sparc-sun-solaris*) # unix "simulator" port
RTEMS_HAS_POSIX_API=no
;;
*)
;;
esac
AC_SUBST(RTEMS_HAS_POSIX_API)
])
/target.m4
0,0 → 1,153
dnl target.m4,v 1.9 2002/01/06 20:12:13 joel Exp
 
## HACK: Work-around to structural issue with RTEMS
## The macros below violate most autoconf and canonicalization standards
AC_DEFUN(RTEMS_CONFIG_BUILD_SUBDIRS,
[AC_REQUIRE([_RTEMS_OUTPUT_BUILD_SUBDIRS])
RTEMS_BUILD_SUBDIRS="$RTEMS_BUILD_SUBDIRS [$1]"
])
 
dnl Derived from automake-1.4's AC_OUTPUT_SUBDIRS
AC_DEFUN([_RTEMS_OUTPUT_BUILD_SUBDIRS],
[AC_CONFIG_COMMANDS([bsp-tools],
[
# HACK: This is a blantant hack and breaks Canadian crosses
build_alias="$build_alias"
host_alias="$build_alias"
if test "$no_recursion" != yes; then
if test x"$build_alias" != x"$host_alias"; then
target_subdir="$host_alias"
else
target_subdir="."
fi
# Remove --cache-file and --srcdir arguments so they do not pile up.
ac_sub_configure_args=
rtems_prev=
for rtems_arg in $rtems_configure_args; do
if test -n "$rtems_prev"; then
rtems_prev=
continue
fi
case "$rtems_arg" in
-cache-file | --cache-file | --cache-fil | --cache-fi \
| --cache-f | --cache- | --cache | --cach | --cac | --ca | --c)
rtems_prev=cache_file ;;
-cache-file=* | --cache-file=* | --cache-fil=* | --cache-fi=* \
| --cache-f=* | --cache-=* | --cache=* | --cach=* | --cac=* | --ca=* | --c=*)
;;
-srcdir | --srcdir | --srcdi | --srcd | --src | --sr)
rtems_prev=srcdir ;;
-srcdir=* | --srcdir=* | --srcdi=* | --srcd=* | --src=* | --sr=*)
;;
--target*) ;;
--build*) ;;
--host*) ;;
*_alias* ) ;; # HACK: Workaround to autoconf passing *_alias
*) ac_sub_configure_args="$ac_sub_configure_args $rtems_arg" ;;
esac
done
 
for rtems_config_dir in $RTEMS_BUILD_SUBDIRS; do
# Do not complain, so a configure script can configure whichever
# parts of a large source tree are present.
if test ! -d $srcdir/$rtems_config_dir; then
continue
fi
 
_RTEMS_PUSH_BUILDDIR([$rtems_config_dir])
 
_RTEMS_SUB_SRCDIR([$rtems_config_dir])
 
# The recursion is here.
if test -n "$ac_sub_configure"; then
# ac_sub_cache_file=./config.cache
ac_sub_cache_file=/dev/null
_RTEMS_GIVEN_INSTALL
 
echo "[running ${CONFIG_SHELL-/bin/sh} $ac_sub_configure $ac_sub_configure_args --cache-file=$ac_sub_cache_file] --srcdir=$ac_sub_srcdir"
# The eval makes quoting arguments work.
if eval ${CONFIG_SHELL-/bin/sh} $ac_sub_configure \
$ac_sub_configure_args \
--srcdir=$ac_sub_srcdir \
--with-target-subdir=$target_subdir \
--cache-file=$ac_sub_cache_file
then :
else
AC_MSG_ERROR([$ac_sub_configure failed for $rtems_config_dir])
fi
fi
 
_RTEMS_POP_BUILDDIR
done
fi],
[
RTEMS_BUILD_SUBDIRS="$RTEMS_BUILD_SUBDIRS"
rtems_configure_args="$ac_configure_args"
])
])
 
## FIXME: This is obsolete. Only kept for backward compatibility
AU_DEFUN([RTEMS_OUTPUT_BUILD_SUBDIRS],[])
 
 
dnl
dnl Misc utility macros for subdir handling to work around missing abilities
dnl in autoconf, automake and structural issues with RTEMS
dnl
dnl Contains parts derived from autoconf-2.13 AC_OUTPUT_SUBDIRS and Cygnus'
dnl configure.in.
dnl
 
dnl
dnl _RTEMS_PUSH_BUILDDIR(SUBDIR)
dnl
AC_DEFUN(_RTEMS_PUSH_BUILDDIR,
[
# _RTEMS_PUSH_BUILDDIR
echo configuring in $1
case "$srcdir" in
.) ;;
*) AS_MKDIR_P([$1])
;;
esac
 
ac_popdir=`pwd`
cd $1
])
 
dnl
dnl _RTEMS_POP_BUILDDIR
dnl
AC_DEFUN(_RTEMS_POP_BUILDDIR,
[
cd $ac_popdir
])
 
dnl
dnl _RTEMS_GIVEN_INSTALL
dnl
AC_DEFUN(_RTEMS_GIVEN_INSTALL,
[
ifdef([AC_PROVIDE_AC_PROG_INSTALL],[
case "$ac_given_INSTALL" in
[[\\/]]* | ?:[[\\/]]*) INSTALL="$ac_given_INSTALL" ;;
*) INSTALL="$ac_dots$ac_given_INSTALL" ;;
esac
])dnl
])
 
dnl
dnl _RTEMS_SUB_SRCDIR(AC_CONFIG_DIR[,TARGET_SUBDIR])
dnl
AC_DEFUN(_RTEMS_SUB_SRCDIR,[
# _RTEMS_SUB_SRCDIR
_RTEMS_ADJUST_SRCDIR(ac_sub_srcdir,$1,$2)
 
# Check for configure
if test -f $ac_sub_srcdir/configure; then
ac_sub_configure=$ac_sub_srcdir/configure
else
AC_MSG_WARN([no configuration information is in $1])
ac_sub_configure=
fi
])
/gcc-pipe.m4
0,0 → 1,21
dnl
dnl gcc-pipe.m4,v 1.8 2000/11/09 17:04:53 joel Exp
dnl
dnl Check whether the target compiler accepts -pipe
dnl
 
AC_DEFUN(RTEMS_GCC_PIPE,
[AC_REQUIRE([RTEMS_PROG_CC])
AC_REQUIRE([AC_CANONICAL_HOST])
AC_CACHE_CHECK(whether $CC accepts --pipe,rtems_cv_gcc_pipe,
[
rtems_cv_gcc_pipe=no
if test x"$GCC" = x"yes"; then
echo 'void f(){}' >conftest.c
if test -z "`${CC} --pipe -c conftest.c 2>&1`";then
rtems_cv_gcc_pipe=yes
fi
rm -f conftest*
fi
])
])
/project-root.m4
0,0 → 1,22
dnl
dnl project-root.m4,v 1.6 2001/12/20 17:33:23 joel Exp
dnl
 
dnl
dnl PROJECT_TOPdir .. relative path to the top of the build-tree
dnl PROJECT_ROOT .. relative path to the top of the temporary
dnl installation directory inside the build-tree
dnl RTEMS_TOPdir .. relative path of a subpackage's configure.in to the
dnl toplevel configure.in of the source-tree
dnl RTEMS_ROOT .. path to the top of a bsp's build directory
dnl [Applied by custom/*.cfg, depredicated otherwise]
dnl
 
AC_DEFUN(RTEMS_PROJECT_ROOT,
[dnl
AC_REQUIRE([RTEMS_TOP])
 
PACKHEX="\$(PROJECT_TOPdir)/tools/build/packhex"
AC_SUBST(PACKHEX)
])
 
/check-tool.m4
0,0 → 1,11
dnl check-tool.m4,v 1.2 2002/01/08 12:06:18 joel Exp
 
## Check for a cross tool, similar to AC_CHECK_TOOL, but do not fall back to
## the un-prefixed version of PROG-TO-CHECK-FOR.
dnl RTEMS_CHECK_TOOL(VARIABLE, PROG-TO-CHECK-FOR[, VALUE-IF-NOT-FOUND [, PATH]])
AC_DEFUN(RTEMS_CHECK_TOOL,
[
AS_IF([test "x$build_alias" != "x$host_alias"],
[rtems_tool_prefix=${ac_tool_prefix}])
AC_CHECK_PROG($1, ${rtems_tool_prefix}$2, ${rtems_tool_prefix}$2, $3, $4)
])
/prog-cc.m4
0,0 → 1,50
dnl
dnl prog-cc.m4,v 1.15 2002/04/17 13:27:29 joel Exp
dnl
dnl Check for target gcc
dnl
 
AC_DEFUN(RTEMS_PROG_CC,
[
AC_BEFORE([$0], [AC_PROG_CPP])dnl
AC_BEFORE([$0], [AC_PROG_CC])dnl
AC_BEFORE([$0], [RTEMS_CANONICALIZE_TOOLS])dnl
 
RTEMS_CHECK_TOOL(CC,gcc)
test -z "$CC" && \
AC_MSG_ERROR([no acceptable cc found in \$PATH])
AC_PROG_CC
AC_PROG_CPP
 
AM_CONDITIONAL(RTEMS_USE_GCC,test x"$GCC" = x"yes")
])
 
AC_DEFUN(RTEMS_PROG_CC_FOR_TARGET,
[
dnl check target cc
RTEMS_PROG_CC
dnl check if the compiler supports --specs
RTEMS_GCC_SPECS
dnl check if the target compiler may use --pipe
RTEMS_GCC_PIPE
dnl check if the compiler supports --specs if gcc28 is requested
# if test "$rtems_cv_gcc_specs" = "no"; then
# AC_MSG_WARN([*** disabling --enable-gcc28])
# RTEMS_USE_GCC272=yes
# fi
test "$rtems_cv_gcc_pipe" = "yes" && CC="$CC --pipe"
 
if test "$GCC" = yes; then
]
m4_if([$1],,[],[CPPFLAGS="$CPPFLAGS $1"])
[
CFLAGS="-g -Wall"
fi
 
dnl FIXME: HACK for egcs/cygwin mixing '\\' and '/' in gcc -print-*
case $build_os in
*cygwin*) GCCSED="| sed 's%\\\\%/%g'" ;;
*) ;;
esac
AC_SUBST(GCCSED)
])
/tool-paths.m4
0,0 → 1,23
AC_DEFUN(RTEMS_TOOLPATHS,
[
# tooldir='$(exec_prefix)/'$target_alias
# Temporary work-around until building in source tree is supported
AC_REQUIRE([RTEMS_PROJECT_ROOT])
 
tooldir='$(PROJECT_ROOT)'
AC_SUBST(tooldir)
 
project_includedir='$(tooldir)'/include
AC_SUBST(project_includedir)
 
project_libdir='$(tooldir)/lib$(MULTISUBDIR)'
AC_SUBST(project_libdir)
 
project_bindir='$(tooldir)/bin'
AC_SUBST(project_bindir)
 
rtems_bspdir='$(prefix)/${RTEMS_BSP}'
AC_SUBST(rtems_bspdir)
rtems_makedir='$(prefix)/make'
AC_SUBST(rtems_makedir)
])
/check-newlib.m4
0,0 → 1,31
dnl check-newlib.m4,v 1.7 2002/01/06 20:12:13 joel Exp
 
AC_DEFUN(RTEMS_CHECK_NEWLIB,
[dnl
AC_REQUIRE([RTEMS_PROG_CC_FOR_TARGET])dnl
AC_REQUIRE([RTEMS_CANONICALIZE_TOOLS])dnl
AC_CACHE_CHECK([for RTEMS newlib],
rtems_cv_use_newlib,
[
dnl some versions of newlib provide not_required_by_rtems
AC_TRY_LINK(
[extern void not_required_by_rtems() ;],
[not_required_by_rtems()],
rtems_cv_use_newlib="yes")
 
dnl some versions of newlib provide rtems_provides_crt0()
AS_IF([test -z "$rtems_cv_use_newlib"],
[AC_TRY_LINK(
[extern void rtems_provides_crt0() ;],
[rtems_provides_crt0()],
rtems_cv_use_newlib="yes",
rtems_cv_use_newlib="no")]
)
])
RTEMS_USE_NEWLIB="$rtems_cv_use_newlib"
AC_SUBST(RTEMS_USE_NEWLIB)
 
AS_IF([test x"${RTEMS_USE_NEWLIB}" = x"yes"],
[ AC_DEFINE_UNQUOTED(RTEMS_NEWLIB,1,[if using newlib])]
)
])
/path-perl.m4
0,0 → 1,12
dnl path-perl.m4,v 1.3 2000/11/02 15:44:04 joel Exp
 
AC_DEFUN(RTEMS_PATH_PERL,
[
AC_PATH_PROG(PERL,perl)
if test -z "$PERL" ; then
AC_MSG_WARN(
[***]
[ perl was not found]
[ Note: Some tools will not be built.])
fi
])
/rtems-test-no-pause.m4
0,0 → 1,18
AC_DEFUN(RTEMS_ENABLE_RTEMS_TEST_NO_PAUSE,
[AC_ARG_ENABLE(test-no-pause,
AC_HELP_STRING([--disable-test-no-pause],[disable RTEMS_TEST_NO_PAUSE]),
[case "${enableval}" in
yes) RTEMS_TEST_NO_PAUSE=yes ;;
no) RTEMS_TEST_NO_PAUSE=no ;;
*) AC_MSG_ERROR([bad value ${enableval} for RTEMS_TEST_NO_PAUSE]) ;;
esac],[RTEMS_TEST_NO_PAUSE=yes])
])
 
AC_DEFUN(RTEMS_CHECK_RTEMS_TEST_NO_PAUSE,
[AC_REQUIRE([RTEMS_ENABLE_RTEMS_TEST_NO_PAUSE])
if test x"${RTEMS_TEST_NO_PAUSE}" = x"yes";
then
AC_DEFINE_UNQUOTED(RTEMS_TEST_NO_PAUSE,1,[if RTEMS_TEST_NO_PAUSE is enabled])
fi
])
 
/enable-bare.m4
0,0 → 1,19
AC_DEFUN(RTEMS_ENABLE_BARE,
[
AC_ARG_ENABLE(bare-cpu-cflags,
AC_HELP_STRING([--enable-bare-cpu-cflags],[specify a particular cpu cflag (bare bsp specific)]),
[case "${enableval}" in
no) BARE_CPU_CFLAGS="" ;;
*) BARE_CPU_CFLAGS="${enableval}" ;;
esac],
[BARE_CPU_CFLAGS=""])
 
AC_ARG_ENABLE(bare-cpu-model,
AC_HELP_STRING([--enable-bare-cpu-model],[specify a particular cpu model (bare bsp specific)]),
[case "${enableval}" in
no) BARE_CPU_MODEL="" ;;
*) BARE_CPU_MODEL="${enableval}" ;;
esac],
[BARE_CPU_MODEL=""])
])
 
/canonicalize-tools.m4
0,0 → 1,28
dnl
dnl canonicalize-tools.m4,v 1.15 2000/11/02 22:51:12 joel Exp
dnl
dnl Set target tools
dnl
 
AC_DEFUN(RTEMS_GCC_PRINT,
[
$1=`$CC --print-prog-name=$2`
])
 
AC_DEFUN(RTEMS_CANONICALIZE_TOOLS,
[AC_REQUIRE([RTEMS_PROG_CC])dnl
 
dnl FIXME: What shall be done if these tools are not available?
RTEMS_CHECK_TOOL(AR,ar,no)
RTEMS_CHECK_TOOL(AS,as,no)
RTEMS_CHECK_TOOL(LD,ld,no)
RTEMS_CHECK_TOOL(NM,nm,no)
 
dnl special treatment of ranlib
RTEMS_CHECK_TOOL(RANLIB,ranlib,:)
 
dnl NOTE: These may not be available if not using gnutools
RTEMS_CHECK_TOOL(OBJCOPY,objcopy,no)
RTEMS_CHECK_TOOL(SIZE,size,no)
RTEMS_CHECK_TOOL(STRIP,strip,:)
])

powered by: WebSVN 2.1.0

© copyright 1999-2024 OpenCores.org, equivalent to Oliscience, all rights reserved. OpenCores®, registered trademark.