Subversion Repositories openmsp430

/*===========================================================================*/
/* Copyright (C) 2001 Authors                                                */
/*                                                                           */
/* This source file may be used and distributed without restriction provided */
/* that this copyright statement is not removed from the file and that any   */
/* derivative work contains the original copyright notice and the associated */
/* disclaimer.                                                               */
/*                                                                           */
/* This source file is free software; you can redistribute it and/or modify  */
/* it under the terms of the GNU Lesser General Public License as published  */
/* by the Free Software Foundation; either version 2.1 of the License, or    */
/* (at your option) any later version.                                       */
/*                                                                           */
/* This source is distributed in the hope that it will be useful, but WITHOUT*/
/* ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or     */
/* FITNESS FOR A PARTICULAR PURPOSE. See the GNU Lesser General Public       */
/* License for more details.                                                 */
/*                                                                           */
/* You should have received a copy of the GNU Lesser General Public License  */
/* along with this source; if not, write to the Free Software Foundation,    */
/* Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA        */
/*                                                                           */
/*===========================================================================*/
/*                 SINGLE-OPERAND ARITHMETIC: CALL  INSTRUCTION              */
/*---------------------------------------------------------------------------*/
/* Test the CALL  instruction.                                               */
/*                                                                           */
/* Author(s):                                                                */
/*             - Olivier Girard,    olgirard@gmail.com                       */
/*                                                                           */
/*---------------------------------------------------------------------------*/
/* $Rev: 111 $                                                                */
/* $LastChangedBy: olivier.girard $                                          */
/* $LastChangedDate: 2011-05-20 22:39:02 +0200 (Fri, 20 May 2011) $          */
/*===========================================================================*/

.set    DMEM_BASE, (__data_start     )
.set    DMEM_200,  (__data_start+0x00)
.set    DMEM_212,  (__data_start+0x12)
.set    DMEM_216,  (__data_start+0x16)
.set    DMEM_21A,  (__data_start+0x1A)
.set    DMEM_21E,  (__data_start+0x1E)
.set    DMEM_220,  (__data_start+0x20)
.set    DMEM_250,  (__data_start+0x50)
.set    DMEM_252,  (__data_start+0x52)
.set    DMEM_300,  (__data_start+0x100)

.global main

main:
        # Initialization
        #------------------------

        mov   #DMEM_252, r1        ;# Initialize stack pointer
        mov     #0x0000, r5        ;# Initialize R5


        mov     #0x1000, r15


        # Addressing mode: Rn
        #------------------------

        mov     #0x0000, r5
        mov  #TEST_ROUTINE_RN, r4
        mov     #0x5555, &0x0300
        call         r4            ;# CALL TEST_ROUTINE_RN

        mov     #0x2000, r15


        # Addressing mode: @Rn
        #------------------------

        mov   #DMEM_212, r4
        mov     #0x0000, r5
        mov   #TEST_ROUTINE_aRN, &DMEM_212
        mov     #0x5555, &DMEM_300
        call        @r4           ;# CALL TEST_ROUTINE_aRN

        mov     #0x3000, r15


        # Addressing mode: @Rn+
        #------------------------

        mov     #DMEM_216, r4
        mov     #0x0000, r5
        mov   #TEST_ROUTINE_aRNi, &DMEM_216
        mov     #0x5555, &DMEM_300
        call       @r4+           ;# CALL TEST_ROUTINE_aRNi

        mov     #0x4000, r15


        # Addressing mode: #N
        #------------------------

        mov     #0x0000, r5
        mov     #0x5555, &DMEM_300
        call    #TEST_ROUTINE_N   ;# CALL TEST_ROUTINE_N

        mov     #0x5000, r15


        # Addressing mode: X(Rn)
        #------------------------

        mov     #DMEM_200, r4
        mov     #0x0000, r5
        mov  #TEST_ROUTINE_xRN, &DMEM_21A
        mov     #0x5555, &DMEM_300
        call      26(r4)           ;# CALL TEST_ROUTINE_xRN

        mov     #0x6000, r15


        # Addressing mode: EDE
        #------------------------
.set   EDE_21E,  DMEM_21E

        mov     #0x0000, r5
        mov  #TEST_ROUTINE_EDE, &DMEM_21E
        mov     #0x5555, &DMEM_300
        call    EDE_21E            ;# CALL TEST_ROUTINE_EDE

        mov     #0x7000, r15


        # Addressing mode: &EDE
        #------------------------
.set   aEDE_220,  DMEM_220

        mov     #0x0000, r5
        mov  #TEST_ROUTINE_aEDE, &aEDE_220
        mov     #0x5555, &DMEM_300
        call  &aEDE_220            ;# CALL TEST_ROUTINE_aEDE

        mov     #0x8000, r15


        /* ----------------------         END OF TEST        --------------- */
end_of_test:
        nop
        br #0xffff



        /* ----------------------         TEST FUNCTIONS     --------------- */

TEST_ROUTINE_RN:
        mov #0x1234, r5
        ret

TEST_ROUTINE_aRN:
        mov #0x5678, r5
        ret

TEST_ROUTINE_aRNi:
        mov #0x9abc, r5
        ret

TEST_ROUTINE_N:
        mov #0xabcd, r5
        ret

TEST_ROUTINE_xRN:
        mov #0xef01, r5
        ret

TEST_ROUTINE_EDE:
        mov #0x2345, r5
        ret

TEST_ROUTINE_aEDE:
        mov #0x6789, r5
        ret



        /* ----------------------         INTERRUPT VECTORS  --------------- */

.section .vectors, "a"
.word end_of_test  ; Interrupt  0 (lowest priority)    <unused>
.word end_of_test  ; Interrupt  1                      <unused>
.word end_of_test  ; Interrupt  2                      <unused>
.word end_of_test  ; Interrupt  3                      <unused>
.word end_of_test  ; Interrupt  4                      <unused>
.word end_of_test  ; Interrupt  5                      <unused>
.word end_of_test  ; Interrupt  6                      <unused>
.word end_of_test  ; Interrupt  7                      <unused>
.word end_of_test  ; Interrupt  8                      <unused>
.word end_of_test  ; Interrupt  9                      <unused>
.word end_of_test  ; Interrupt 10                      Watchdog timer
.word end_of_test  ; Interrupt 11                      <unused>
.word end_of_test  ; Interrupt 12                      <unused>
.word end_of_test  ; Interrupt 13                      <unused>
.word end_of_test  ; Interrupt 14                      NMI
.word main         ; Interrupt 15 (highest priority)   RESET