Subversion Repositories openrisc_2011-10-31

dnl This is the newlib/libc/sys configure.in file.
dnl Process this file with autoconf to produce a configure script.

AC_PREREQ(2.59)
AC_INIT([newlib],[NEWLIB_VERSION])
AC_CONFIG_SRCDIR([a29khif])

dnl Can't be done in NEWLIB_CONFIGURE because that confuses automake. 
AC_CONFIG_AUX_DIR(../../..)

NEWLIB_CONFIGURE(../..)

dnl We have to enable libtool after NEWLIB_CONFIGURE because if we try and
dnl add it into NEWLIB_CONFIGURE, executable tests are made before the first
dnl line of the macro which fail because appropriate LDFLAGS are not set.
_LT_DECL_SED
if test "${use_libtool}" = "yes"; then
AC_LIBTOOL_WIN32_DLL
AM_PROG_LIBTOOL
fi

if test -n "${sys_dir}"; then
  case ${sys_dir} in
        a29khif) AC_CONFIG_SUBDIRS(a29khif) ;;
        arc) AC_CONFIG_SUBDIRS(arc) ;;
        arm) AC_CONFIG_SUBDIRS(arm) ;;
        d10v) AC_CONFIG_SUBDIRS(d10v) ;;
        decstation) AC_CONFIG_SUBDIRS(decstation) ;;
        h8300hms) AC_CONFIG_SUBDIRS(h8300hms) ;;
        h8500hms) AC_CONFIG_SUBDIRS(h8500hms) ;;
        linux) AC_CONFIG_SUBDIRS(linux) ;;
        m88kbug) AC_CONFIG_SUBDIRS(m88kbug) ;;
        mmixware) AC_CONFIG_SUBDIRS(mmixware) ;;
        netware) AC_CONFIG_SUBDIRS(netware) ;;
        rdos) AC_CONFIG_SUBDIRS(rdos) ;;
        rtems) AC_CONFIG_SUBDIRS(rtems) ;;
        sh) AC_CONFIG_SUBDIRS(sh) ;;
        sparc64) AC_CONFIG_SUBDIRS(sparc64) ;;
        sun4) AC_CONFIG_SUBDIRS(sun4) ;;
        sysmec) AC_CONFIG_SUBDIRS(sysmec) ;;
        sysnec810) AC_CONFIG_SUBDIRS(sysnec810) ;;
        sysnecv850) AC_CONFIG_SUBDIRS(sysnecv850) ;;
        sysvi386) AC_CONFIG_SUBDIRS(sysvi386) ;;
        sysvnecv70) AC_CONFIG_SUBDIRS(sysvnecv70) ;;
        tic80) AC_CONFIG_SUBDIRS(tic80) ;;
        w65) AC_CONFIG_SUBDIRS(w65) ;;
        z8ksim) AC_CONFIG_SUBDIRS(z8ksim) ;;
  esac;
fi

CRT0=
if test "x${have_crt0}" = "xyes"; then
  CRT0=crt0.o
fi
AC_SUBST(CRT0)

AM_CONDITIONAL(HAVE_SYS_DIR, test x${sys_dir} != x)

AC_CONFIG_FILES([Makefile])
AC_OUTPUT