Subversion Repositories openrisc_me

/*
 *
 *  COPYRIGHT (c) 1989-1999.
 *  On-Line Applications Research Corporation (OAR).
 *
 *  The license and distribution terms for this file may be
 *  found in found in the file LICENSE in this distribution or at
 *  http://www.OARcorp.com/rtems/license.html.
 *
 *  $Id: linkcmds,v 1.2 2001-09-27 12:01:02 chris Exp $
 */

OUTPUT_FORMAT("elf32-powerpc", "elf32-powerpc",
              "elf32-powerpc")
OUTPUT_ARCH(powerpc)
ENTRY(_start)
 /*SEARCH_DIR(/usr1/gnu/cross/powerpc-unknown-eabi//powerpc-unknown-eabi/lib); */
/* Do we need any of these for elf?
   __DYNAMIC = 0;    */
PROVIDE (PSIM_INSTRUCTIONS_PER_MICROSECOND = 100);
PROVIDE (CPU_PPC_CLICKS_PER_MS = 16667);
MEMORY
  {
        RAM : ORIGIN = 0, LENGTH = 8M
        EPROM : ORIGIN = 0xFFF00000, LENGTH = 0x20000
  }

SECTIONS
{
  .vectors 0xFFF00100 :
  {
    *(.vectors)
  } >EPROM

  /* Read-only sections, merged into text segment: */
  /* . = 0x40000 + SIZEOF_HEADERS; */
  . = 0x4000;
  .interp         : { *(.interp) } 
  .hash           : { *(.hash)          }
  .dynsym         : { *(.dynsym)                }
  .dynstr         : { *(.dynstr)                }
  .rela.text      : { *(.rela.text)     }
  .rela.data      : { *(.rela.data)     }
  .rela.rodata    : { *(.rela.rodata)   }
  .rela.got       : { *(.rela.got)      }
  .rela.got1      : { *(.rela.got1)     }
  .rela.got2      : { *(.rela.got2)     }
  .rela.ctors     : { *(.rela.ctors)    }
  .rela.dtors     : { *(.rela.dtors)    }
  .rela.init      : { *(.rela.init)     }
  .rela.fini      : { *(.rela.fini)     }
  .rela.bss       : { *(.rela.bss)      }
  .rela.plt       : { *(.rela.plt)      }
  .rela.sdata     : { *(.rela.sdata2)   }
  .rela.sbss      : { *(.rela.sbss2)    }
  .rela.sdata2    : { *(.rela.sdata2)   }
  .rela.sbss2     : { *(.rela.sbss2)    }
  .plt            : { *(.plt)           }
  .text      :
  {
    *(.text)
    *(.gnu.linkonce.t.*)
    *(.descriptors)
    /* .gnu.warning sections are handled specially by elf32.em.  */
    *(.gnu.warning)
  } >RAM
  .init           : { *(.init)          } >RAM
  .fini           : { *(.fini)          } >RAM
  .rodata         : { *(.rodata) *(.gnu.linkonce.r*) } >RAM
  .rodata1        : { *(.rodata1)       } >RAM
  PROVIDE (_etext = .);
  PROVIDE (etext = .);
  PROVIDE (__SDATA2_START__ = .);
  .sdata2         : { *(.sdata2)        } >RAM
  .sbss2          : { *(.sbss2)         } >RAM
  PROVIDE (__SBSS2_END__ = .);
  /* Adjust the address for the data segment.  We want to adjust up to
     the same address within the page on the next page up.  It would
     be more correct to do this:
       . = ALIGN(0x40000) + (ALIGN(8) & (0x40000 - 1));
     The current expression does not correctly handle the case of a
     text segment ending precisely at the end of a page; it causes the
     data segment to skip a page.  The above expression does not have
     this problem, but it will currently (2/95) cause BFD to allocate
     a single segment, combining both text and data, for this case.
     This will prevent the text segment from being shared among
     multiple executions of the program; I think that is more
     important than losing a page of the virtual address space (note
     that no actual memory is lost; the page which is skipped can not
     be referenced).  */
  /* . =  ALIGN(8) + 0x40000; */
  .data    :
  {
    *(.data)
    *(.gnu.linkonce.d.*)
    CONSTRUCTORS
  } >RAM
  PROVIDE (__EXCEPT_START__ = .);
  .gcc_except_table   : { *(.gcc_except_table) } >RAM
  PROVIDE (__EXCEPT_END__ = .);

  .data1          : { *(.data1)         } >RAM
  .got1           : { *(.got1)          } >RAM
  .dynamic        : { *(.dynamic)       } >RAM
  /* Put .ctors and .dtors next to the .got2 section, so that the pointers
     get relocated with -mrelocatable. Also put in the .fixup pointers.
     The current compiler no longer needs this, but keep it around for 2.7.2  */
   PROVIDE (__GOT2_START__ = .);
   PROVIDE (_GOT2_START_ = .);
  .got2           :  { *(.got2)         } >RAM
  PROVIDE (__GOT2_END__ = .);
  PROVIDE (_GOT2_END_ = .);

  PROVIDE (__CTOR_LIST__ = .);
  .ctors          : { *(.ctors)         } >RAM
  PROVIDE (__CTOR_END__ = .);

  PROVIDE (__DTOR_LIST__ = .);
  .dtors          : { *(.dtors)         } >RAM
  PROVIDE (__DTOR_END__ = .);

  PROVIDE (__FIXUP_START__ = .);
  PROVIDE (_FIXUP_START_ = .);
  .fixup          : { *(.fixup)         } >RAM
  PROVIDE (_FIXUP_END_ = .);
  PROVIDE (__FIXUP_END__ = .);

  PROVIDE (__GOT_START__ = .);
  PROVIDE (_GOT_START_ = .);
  s.got = .;
  .got            : { *(.got)           } >RAM
  .got.plt        : { *(.got.plt)       } >RAM
  PROVIDE (_GOT_END_ = .);
  PROVIDE (__GOT_END__ = .);

  /* We want the small data sections together, so single-instruction offsets
     can access them all, and initialized data all before uninitialized, so
     we can shorten the on-disk segment size.  */
  PROVIDE (__SDATA_START__ = .);
  .sdata          : { *(.sdata)         } >RAM
  _edata  =  .;
  PROVIDE (edata = .);

  PROVIDE (RAM_END = 0x7f0000);
  .sbss      :
  {
    PROVIDE (__sbss_start = .);
    *(.sbss)
    *(.scommon)
    PROVIDE (__sbss_end = .);
  } >RAM
  PROVIDE (__SBSS_END__ = .);

  .bss       :
  {
   PROVIDE (__bss_start = .);
   *(.dynbss)
   *(.bss)
   *(COMMON)
  } >RAM
  . =  ALIGN(8) + 0x8000;
  PROVIDE(__stack = .);
  PROVIDE(_end = .);
  PROVIDE(end = .);

  /* These are needed for ELF backends which have not yet been
     converted to the new style linker.  */
  .stab 0 : { *(.stab) }
  .stabstr 0 : { *(.stabstr) }
  /* DWARF debug sections.
     Symbols in the DWARF debugging sections are relative to the beginning
     of the section so we begin them at 0.  */
  /* DWARF 1 */
  .debug          0 : { *(.debug) }
  .line           0 : { *(.line) }
  /* GNU DWARF 1 extensions */
  .debug_srcinfo  0 : { *(.debug_srcinfo) }
  .debug_sfnames  0 : { *(.debug_sfnames) }
  /* DWARF 1.1 and DWARF 2 */
  .debug_aranges  0 : { *(.debug_aranges) }
  .debug_pubnames 0 : { *(.debug_pubnames) }
  /* DWARF 2 */
  .debug_info     0 : { *(.debug_info) }
  .debug_abbrev   0 : { *(.debug_abbrev) }
  .debug_line     0 : { *(.debug_line) }
  .debug_frame    0 : { *(.debug_frame) }
  .debug_str      0 : { *(.debug_str) }
  .debug_loc      0 : { *(.debug_loc) }
  .debug_macinfo  0 : { *(.debug_macinfo) }
  /* SGI/MIPS DWARF 2 extensions */
  .debug_weaknames 0 : { *(.debug_weaknames) }
  .debug_funcnames 0 : { *(.debug_funcnames) }
  .debug_typenames 0 : { *(.debug_typenames) }
  .debug_varnames  0 : { *(.debug_varnames) }
  /* These must appear regardless of  .  */
}