Subversion Repositories or1k_soc_on_altera_embedded_dev_kit

/*
 *  linux/arch/arm/lib/memcpy.S
 *
 *  Author:     Nicolas Pitre
 *  Created:    Sep 28, 2005
 *  Copyright:  MontaVista Software, Inc.
 *
 *  This program is free software; you can redistribute it and/or modify
 *  it under the terms of the GNU General Public License version 2 as
 *  published by the Free Software Foundation.
 */

#include <linux/linkage.h>
#include <asm/assembler.h>

        .macro ldr1w ptr reg abort
        ldr \reg, [\ptr], #4
        .endm

        .macro ldr4w ptr reg1 reg2 reg3 reg4 abort
        ldmia \ptr!, {\reg1, \reg2, \reg3, \reg4}
        .endm

        .macro ldr8w ptr reg1 reg2 reg3 reg4 reg5 reg6 reg7 reg8 abort
        ldmia \ptr!, {\reg1, \reg2, \reg3, \reg4, \reg5, \reg6, \reg7, \reg8}
        .endm

        .macro ldr1b ptr reg cond=al abort
        ldr\cond\()b \reg, [\ptr], #1
        .endm

        .macro str1w ptr reg abort
        str \reg, [\ptr], #4
        .endm

        .macro str8w ptr reg1 reg2 reg3 reg4 reg5 reg6 reg7 reg8 abort
        stmia \ptr!, {\reg1, \reg2, \reg3, \reg4, \reg5, \reg6, \reg7, \reg8}
        .endm

        .macro str1b ptr reg cond=al abort
        str\cond\()b \reg, [\ptr], #1
        .endm

        .macro enter reg1 reg2
        stmdb sp!, {r0, \reg1, \reg2}
        .endm

        .macro exit reg1 reg2
        ldmfd sp!, {r0, \reg1, \reg2}
        .endm

        .text

/* Prototype: void *memcpy(void *dest, const void *src, size_t n); */

ENTRY(memcpy)

#include "copy_template.S"