Subversion Repositories qaz_libs

//////////////////////////////////////////////////////////////////////
////                                                              ////
//// Copyright (C) 2015 Authors and OPENCORES.ORG                 ////
////                                                              ////
//// This source file may be used and distributed without         ////
//// restriction provided that this copyright statement is not    ////
//// removed from the file and that any derivative work contains  ////
//// the original copyright notice and the associated disclaimer. ////
////                                                              ////
//// This source file is free software; you can redistribute it   ////
//// and/or modify it under the terms of the GNU Lesser General   ////
//// Public License as published by the Free Software Foundation; ////
//// either version 2.1 of the License, or (at your option) any   ////
//// later version.                                               ////
////                                                              ////
//// This source is distributed in the hope that it will be       ////
//// useful, but WITHOUT ANY WARRANTY; without even the implied   ////
//// warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR      ////
//// PURPOSE.  See the GNU Lesser General Public License for more ////
//// details.                                                     ////
////                                                              ////
//// You should have received a copy of the GNU Lesser General    ////
//// Public License along with this source; if not, download it   ////
//// from http://www.opencores.org/lgpl.shtml                     ////
////                                                              ////
//////////////////////////////////////////////////////////////////////


package q_pkg;

  // --------------------------------------------------------------------
  //
  virtual class q_base_class #(parameter type Q_T = logic);

    Q_T            tr_h;
    mailbox #(Q_T) q;

    // --------------------------------------------------------------------
    //
    pure virtual task run_q;


    // --------------------------------------------------------------------
    //
    task put(ref Q_T tr_h);
      q.put(tr_h);
    endtask: put


    // --------------------------------------------------------------------
    //
    task get(ref Q_T tr_h);
      q.get(tr_h);
    endtask: get


    //--------------------------------------------------------------------
    function new;
      this.q = new();
      fork
        forever
          run_q();
      join_none
    endfunction: new


  // --------------------------------------------------------------------
  //
  endclass: q_base_class


  // --------------------------------------------------------------------
  //
  virtual class nonblocking_transmission_q_class #(parameter type Q_T = logic)
    extends q_base_class #(Q_T);

    // --------------------------------------------------------------------
    //
    pure virtual task transmit(ref Q_T tr_h);
    pure virtual task idle();


    // --------------------------------------------------------------------
    //
    task automatic run_q;
      if(q.try_get(tr_h) != 0)
        transmit(tr_h);
      else
        idle();
    endtask: run_q


  // --------------------------------------------------------------------
  //
  endclass: nonblocking_transmission_q_class


  // --------------------------------------------------------------------
  //
  virtual class blocking_transmission_q_class #(parameter type Q_T = logic)
    extends q_base_class #(Q_T);

    // --------------------------------------------------------------------
    //
    pure virtual task transmit(ref Q_T tr_h);


    // --------------------------------------------------------------------
    //
    task run_q;
      q.get(tr_h);
      transmit(tr_h);
    endtask: run_q


  // --------------------------------------------------------------------
  //
  endclass: blocking_transmission_q_class


  // --------------------------------------------------------------------
  //
  virtual class blocking_receiver_q_class #(parameter type Q_T = logic)
    extends q_base_class #(Q_T);

    // --------------------------------------------------------------------
    //
    pure virtual task receive(ref Q_T tr_h);


    // --------------------------------------------------------------------
    //
    task run_q;
      receive(tr_h);
      q.put(tr_h);
    endtask: run_q


  //--------------------------------------------------------------------
  //
  endclass: blocking_receiver_q_class


//--------------------------------------------------------------------
//
endpackage: q_pkg