OpenCores
URL https://opencores.org/ocsvn/qaz_libs/qaz_libs/trunk

Subversion Repositories qaz_libs

[/] [qaz_libs/] [trunk/] [BFM/] [src/] [SPI/] [spi_driver.svh] - Rev 50

Compare with Previous | Blame | View Log

//////////////////////////////////////////////////////////////////////
////                                                              ////
//// Copyright (C) 2018 Authors and OPENCORES.ORG                 ////
////                                                              ////
//// This source file may be used and distributed without         ////
//// restriction provided that this copyright statement is not    ////
//// removed from the file and that any derivative work contains  ////
//// the original copyright notice and the associated disclaimer. ////
////                                                              ////
//// This source file is free software; you can redistribute it   ////
//// and/or modify it under the terms of the GNU Lesser General   ////
//// Public License as published by the Free Software Foundation; ////
//// either version 2.1 of the License, or (at your option) any   ////
//// later version.                                               ////
////                                                              ////
//// This source is distributed in the hope that it will be       ////
//// useful, but WITHOUT ANY WARRANTY; without even the implied   ////
//// warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR      ////
//// PURPOSE.  See the GNU Lesser General Public License for more ////
//// details.                                                     ////
////                                                              ////
//// You should have received a copy of the GNU Lesser General    ////
//// Public License along with this source; if not, download it   ////
//// from http://www.opencores.org/lgpl.shtml                     ////
////                                                              ////
//////////////////////////////////////////////////////////////////////

class spi_driver #(N)
  extends uvm_driver #(spi_sequence_item);
   `uvm_component_param_utils(spi_driver #(N))

  // --------------------------------------------------------------------
  virtual spi_if #(N) vif;

  //--------------------------------------------------------------------
  function void set_default;
    vif.sclk <= 0;
    vif.ss_n <= '1;
    vif.mosi <= 'x;
  endfunction: set_default

  //--------------------------------------------------------------------
  virtual task run_phase(uvm_phase phase);
    spi_sequence_item item;
    int index;

    set_default();

    forever
    begin
      index = 0;
      seq_item_port.get_next_item(item);

      vif.ss_n <= ~(1 << item.ss_index);

      vif.mosi <= item.mosi_data[index];
      #(vif.period / 2);

      fork
        repeat(item.data_width)
        begin
          #(vif.period / 2);
          vif.sclk <= 1;
          #(vif.period / 2);
          vif.sclk <= 0;
        end
      join_none

      repeat(item.data_width)
      begin
        @(vif.cb_rise);
        item.miso_data[index] = vif.miso;
        index++;
        @(vif.cb_fall);
        vif.mosi <= item.mosi_data[index];
      end

      #(vif.period / 2);
      vif.ss_n <= '1;

      set_default();
      seq_item_port.item_done();
    end

  endtask : run_phase

  //--------------------------------------------------------------------
  function new(string name, uvm_component parent);
    super.new(name, parent);
  endfunction

// --------------------------------------------------------------------
endclass

Compare with Previous | Blame | View Log

powered by: WebSVN 2.1.0

© copyright 1999-2024 OpenCores.org, equivalent to Oliscience, all rights reserved. OpenCores®, registered trademark.