OpenCores
URL https://opencores.org/ocsvn/qaz_libs/qaz_libs/trunk

Subversion Repositories qaz_libs

[/] [qaz_libs/] [trunk/] [PCIe/] [sim/] [src/] [RIFFA/] [riffa_rp_rx_driver.svh] - Rev 50

Compare with Previous | Blame | View Log

//////////////////////////////////////////////////////////////////////
////                                                              ////
//// Copyright (C) 2019 Authors and OPENCORES.ORG                 ////
////                                                              ////
//// This source file may be used and distributed without         ////
//// restriction provided that this copyright statement is not    ////
//// removed from the file and that any derivative work contains  ////
//// the original copyright notice and the associated disclaimer. ////
////                                                              ////
//// This source file is free software; you can redistribute it   ////
//// and/or modify it under the terms of the GNU Lesser General   ////
//// Public License as published by the Free Software Foundation; ////
//// either version 2.1 of the License, or (at your option) any   ////
//// later version.                                               ////
////                                                              ////
//// This source is distributed in the hope that it will be       ////
//// useful, but WITHOUT ANY WARRANTY; without even the implied   ////
//// warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR      ////
//// PURPOSE.  See the GNU Lesser General Public License for more ////
//// details.                                                     ////
////                                                              ////
//// You should have received a copy of the GNU Lesser General    ////
//// Public License along with this source; if not, download it   ////
//// from http://www.opencores.org/lgpl.shtml                     ////
////                                                              ////
//////////////////////////////////////////////////////////////////////

class riffa_rp_rx_driver #(N) extends uvm_driver #(riffa_sequence_item);
  `uvm_component_param_utils(riffa_rp_rx_driver #(N))

  // --------------------------------------------------------------------
  virtual riffa_chnl_if #(N) vif;

  //--------------------------------------------------------------------
  function void set_default;
    vif.cb_rp_rx.tx_ack <= 0;
    vif.cb_rp_rx.tx_data_ren <= 0;
  endfunction: set_default

  //--------------------------------------------------------------------
  virtual task run_phase(uvm_phase phase);
    riffa_sequence_item item;
    super.run_phase(phase);

    set_default();

    forever
    begin
      wait(~vif.tx_reset);
      seq_item_port.get_next_item(item);

      @(vif.cb_rp_rx iff vif.cb_rp_rx.tx);

      item.init( N
               , vif.cb_rp_rx.tx_len
               , vif.cb_rp_rx.tx_off
               , vif.cb_rp_rx.tx_last);

      vif.cb_rp_rx.tx_ack <= 1;
      vif.cb_rp_rx.tx_data_ren <= 1;

      fork
        @(vif.cb_rp_rx)
          vif.cb_rp_rx.tx_ack <= 0;
      join_none

      for(int i = 0; i < item.beats; i++)
      begin
        @(vif.cb_rp_rx iff vif.cb_rp_rx.tx_data_valid)
          {<<byte{item.data[i*N +: N]}} = vif.cb_rp_rx.tx_data;

        // $display("^^^^^ %16.t | TX | %d | %h", $time, i, vif.cb_rp_rx.tx_data);
      end

      set_default();
      seq_item_port.item_done();
    end
  endtask : run_phase

  //--------------------------------------------------------------------
  function new(string name, uvm_component parent);
    super.new(name, parent);
  endfunction

// --------------------------------------------------------------------
endclass

Compare with Previous | Blame | View Log

powered by: WebSVN 2.1.0

© copyright 1999-2020 OpenCores.org, equivalent to Oliscience, all rights reserved. OpenCores®, registered trademark.