OpenCores
URL https://opencores.org/ocsvn/qaz_libs/qaz_libs/trunk

Subversion Repositories qaz_libs

[/] [qaz_libs/] [trunk/] [axi4_stream_lib/] [src/] [recursive_axis_mux.sv] - Rev 36

Compare with Previous | Blame | View Log

//////////////////////////////////////////////////////////////////////
////                                                              ////
//// Copyright (C) 2015 Authors and OPENCORES.ORG                 ////
////                                                              ////
//// This source file may be used and distributed without         ////
//// restriction provided that this copyright statement is not    ////
//// removed from the file and that any derivative work contains  ////
//// the original copyright notice and the associated disclaimer. ////
////                                                              ////
//// This source file is free software; you can redistribute it   ////
//// and/or modify it under the terms of the GNU Lesser General   ////
//// Public License as published by the Free Software Foundation; ////
//// either version 2.1 of the License, or (at your option) any   ////
//// later version.                                               ////
////                                                              ////
//// This source is distributed in the hope that it will be       ////
//// useful, but WITHOUT ANY WARRANTY; without even the implied   ////
//// warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR      ////
//// PURPOSE.  See the GNU Lesser General Public License for more ////
//// details.                                                     ////
////                                                              ////
//// You should have received a copy of the GNU Lesser General    ////
//// Public License along with this source; if not, download it   ////
//// from http://www.opencores.org/lgpl.shtml                     ////
////                                                              ////
//////////////////////////////////////////////////////////////////////


module
  recursive_axis_mux
  #(
    N, // data bus width in bytes
    I = 1, // TID width
    D = 1, // TDEST width
    U = 1, // TUSER width
    MA, // mux select width
    MD = 2 ** MA
  )
  (
    input [MA-1:0]  select,
    axis_if         axis_in [MD-1:0],
    axis_if         axis_out,
    input           aclk,
    input           aresetn
  );

  // --------------------------------------------------------------------
  //
  generate
    if(MA == 1)
    begin: mux_gen
      axis_mux #(.N(N), .I(I), .D(D), .U(U))
        axis_mux_i(.*);
    end
    else
    begin: recurse_mux_gen
      axis_if #(.N(N), .I(I), .D(D), .U(U)) axis_mux_out[1:0](.*);

      recursive_axis_mux #(.N(N), .I(I), .D(D), .U(U), .MA(MA - 1))
        mux_lo
        (
          .select(select[MA-2:0]),
          .axis_in(axis_in[(MD/2)-1:0]),
          .axis_out(axis_mux_out[0]),
          .*
        );

      recursive_axis_mux #(.N(N), .I(I), .D(D), .U(U), .MA(MA - 1))
        mux_hi
        (
          .select(select[MA-2:0]),
          .axis_in(axis_in[MD-1:(MD/2)]),
          .axis_out(axis_mux_out[1]),
          .*
        );

      axis_mux #(.N(N), .I(I), .D(D), .U(U))
        axis_mux_i
        (
          .select(select[MA-1]),
          .axis_in(axis_mux_out),
          .*
        );
    end
  endgenerate


// --------------------------------------------------------------------
//
endmodule

Compare with Previous | Blame | View Log

powered by: WebSVN 2.1.0

© copyright 1999-2020 OpenCores.org, equivalent to Oliscience, all rights reserved. OpenCores®, registered trademark.