OpenCores
URL https://opencores.org/ocsvn/zipcpu/zipcpu/trunk

Subversion Repositories zipcpu

[/] [zipcpu/] [trunk/] [rtl/] [peripherals/] [ziptimer.v] - Rev 2

Go to most recent revision | Compare with Previous | Blame | View Log

///////////////////////////////////////////////////////////////////////////
//
// Filename:	ziptimer.v
//
// Project:	Zip CPU -- a small, lightweight, RISC CPU soft core
//
// Purpose:
//
// Interface:
//	Two options:
//	1. One combined register for both control and value, and ...
//		The reload value is set any time the timer data value is "set".
//		Reading the register returns the timer value.  Controls are
//		set so that writing a value to the timer automatically starts
//		it counting down.
//	2. Two registers, one for control one for value.
//		The control register would have the reload value in it.
//	On the clock when the interface is set to zero the interrupt is set.
//		Hence setting the timer to zero will disable the timer without
//		setting any interrupts.  Thus setting it to five will count
//		5 clocks: 5, 4, 3, 2, 1, Interrupt.
//
//
//	Control bits:
//		Start_n/Stop.  Writing a '0' starts the timer, '1' stops it.
//			Thus, ignoring this bit sets it to start.
//		AutoReload.  If set, then on reset the timer automatically
//			loads the last set value and starts over.  This is
//			useful for distinguishing between a one-time interrupt
//			timer, and a repetitive interval timer.
//		(COUNT: If set, the timer only ticks whenever an external
//			line goes high.  What this external line is ... is
//			not specified here.  This, however, breaks my 
//			interface ideal of having our peripheral set not depend
//			upon anything.  Hence, this is an advanced option
//			enabled at compile time only.)
//		(INTEN.  Interrupt enable--reaching zero always creates an
//			interrupt, so this control bit isn't needed.  The
//			interrupt controller can be used to mask the interrupt.)
//		(COUNT-DOWN/UP: This timer is *only* a count-down timer.
//			There is no means of setting it to count up.)
//	WatchDog
//		This timer can be implemented as a watchdog timer simply by
//		connecting the interrupt line to the reset line of the CPU.
//		When the timer then expires, it will trigger a CPU reset.
//
//
// Creator:	Dan Gisselquist, Ph.D.
//		Gisselquist Tecnology, LLC
//
///////////////////////////////////////////////////////////////////////////
//
// Copyright (C) 2015, Gisselquist Technology, LLC
//
// This program is free software (firmware): you can redistribute it and/or
// modify it under the terms of  the GNU General Public License as published
// by the Free Software Foundation, either version 3 of the License, or (at
// your option) any later version.
//
// This program is distributed in the hope that it will be useful, but WITHOUT
// ANY WARRANTY; without even the implied warranty of MERCHANTIBILITY or
// FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
// for more details.
//
// License:	GPL, v3, as defined and found on www.gnu.org,
//		http://www.gnu.org/licenses/gpl.html
//
//
///////////////////////////////////////////////////////////////////////////
//
module	ziptimer(i_clk, i_rst, i_ce,
		i_wb_cyc, i_wb_stb, i_wb_we, i_wb_data,
			o_wb_ack, o_wb_stall, o_wb_data,
		o_int);
	parameter	BW = 32, VW = (BW-2);
	input			i_clk, i_rst, i_ce;
	// Wishbone inputs
	input			i_wb_cyc, i_wb_stb, i_wb_we;
	input	[(BW-1):0]	i_wb_data;
	// Wishbone outputs
	output	reg			o_wb_ack;
	output	wire			o_wb_stall;
	output	wire	[(BW-1):0]	o_wb_data;
	// Interrupt line
	output	reg		o_int;
 
	reg			r_auto_reload, r_running;
	reg	[(VW-1):0]	r_reload_value;
	initial	r_running = 1'b0;
	initial	r_auto_reload = 1'b0;
	always @(posedge i_clk)
		if (i_rst)
		begin
			r_running <= 1'b0;
			r_auto_reload <= 1'b0;
		end else if ((i_wb_cyc)&&(i_wb_stb)&&(i_wb_we))
		begin
			r_running <= (~i_wb_data[(BW-1)])&&(|i_wb_data[(BW-2):0]);
			r_auto_reload <= (i_wb_data[(BW-2)]);
 
			// If setting auto-reload mode, and the value to other
			// than zero, set the auto-reload value
			if ((i_wb_data[(BW-2)])&&(|i_wb_data[(BW-3):0]))
				r_reload_value <= i_wb_data[(BW-3):0];
		end
 
	reg	[(VW-1):0]	r_value;
	initial	r_value = 0;
	always @(posedge i_clk)
		if ((r_running)&&(|r_value)&&(i_ce))
		begin
			r_value <= r_value - 1;
		end else if ((r_running)&&(r_auto_reload))
			r_value <= r_reload_value;
		else if ((~r_running)&&(i_wb_cyc)&&(i_wb_stb)&&(i_wb_we))
			r_value <= i_wb_data[(VW-1):0];
 
	// Set the interrupt on our last tick.
	initial	o_int   = 1'b0;
	always @(posedge i_clk)
		if (i_ce)
		o_int <= (r_running)&&(r_value == { {(VW-1){1'b0}}, 1'b1 });
		else
			o_int <= 1'b0;
 
	initial	o_wb_ack = 1'b0;
	always @(posedge i_clk)
		o_wb_ack <= (i_wb_cyc)&&(i_wb_stb);
	assign	o_wb_stall = 1'b0;
 
	assign	o_wb_data = { ~r_running, r_auto_reload, r_value };
 
endmodule
 

Go to most recent revision | Compare with Previous | Blame | View Log

powered by: WebSVN 2.1.0

© copyright 1999-2022 OpenCores.org, equivalent to Oliscience, all rights reserved. OpenCores®, registered trademark.